home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
prt
/
lfutl.100
< prev
next >
Wrap
Text File
|
2006-10-19
|
1KB
|
21 lines
0 ' FLUTL.BA - By Phil Wheeler Club 100 Library - 415/939-1246, 937-5039 NEWSLETTER, 932-8856 VOICE
1 'A "universal" Line Feed Utility which implements Hugo Ferreyra's FIXLF.HF1 and Don Corbitt's TELCOM linefeed patch
2 'in a single, menu-driven utility. It is a module of my current on-board Utility program, hence the structure.
3 'Note that FIXLF.HF1 is copyrighted by Hugo, and released "for non-commercial use only".
4 ' Phil Wheeler:4/14/84
5 '
6 GOTO8
7 MAXFILES=1:CLEAR256,MAXRAM:DATE$=LEFT$(DATE$,6)+"84":MENU
8 CLS:RV$=CHR$(27)+"p":NO$=CHR$(27)+"q":A=64228:B=63066:KEY8,"Menu"+CHR$(13)+CHR$(254)+CHR$(13)+CHR$(245)+CHR$(62)+CHR$(10)+CHR$(204)+CHR$(63)+CHR$(109)+CHR$(241)+CHR$(201):PRINT:PRINT"Select Option:":PRINT:PRINT,"P)rnt LF",,"C)omm LF",,"T)op Menu"
9 ONINSTR("pPcCtT",INPUT$(1))GOTO10,10,15,15,7,7:GOTO9
10 CLS:F$=" Off ":P=PEEK(A)+256*PEEK(A+1):IFP=63615THENF$=" On "
11 PRINT:PRINT"Printer LF"RV$F$NO$:PRINT:PRINT,"E)nable",,"D)isable",,"T)op Menu"
12 ONINSTR("eEdDtT",INPUT$(1))GOTO13,13,14,14,7,7:GOTO12
13 POKEA,127:POKEA+1,248:GOTO10
14 POKEA,243:POKEA+1,127:GOTO10
15 CLS:F$=" Off ":IFPEEK(B)<>0THENF$=" On "
16 PRINT:PRINT"Upload LF"RV$F$NO$:PRINT:PRINT,"E)nable",,"D)isable",,"T)op Menu"
17 ONINSTR("eEdDtT",INPUT$(1))GOTO18,18,19,19,7,7:GOTO17
18 POKEB,1:GOTO15
19 POKEB,0:GOTO15