home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
prt
/
feeds.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
1KB
|
27 lines
1 'FEEDS.BA originally FLUTL.BA by Phil Wheeler, modified by Robert Benson
2 'A Universal Line Feed Utility which implements Hugo Ferreyra's FIXLF.HF1
3 'and Don Corbitt's TELCOM linefeed patch in a single menu-driven utility.
4 'The machine code routine that was poked behind the string for the F8 key
5 'has been moved into the area containing the optional ROM access routine.
6 'WARNING: Do not use this version if an optional ROM is installed!
7 '
10 CLS:RV$=CHR$(27)+"p":NO$=CHR$(27)+"q":A=64228:B=63066
12 FORX=62981TO62991
14 READY:POKEX,Y
16 NEXT
18 DATA201,254,13,245,62,10,204,63,109,241,201
20 POKE63018,255
22 PRINT@40,"Select Option:":PRINT:PRINT,"P)rinter LF",,"T)elcom LF",,"M)enu"
24 ONINSTR("pPtTmM",INPUT$(1))GOTO26,26,36,36,46,46:GOTO24
26 CLS:F$=" Off ":P=PEEK(A)+256*PEEK(A+1):IFP=62982THENF$=" On "
28 PRINT:PRINT"Printer LF"RV$F$NO$:PRINT:PRINT,"E)nable",,"D)isable",,"M)enu"
30 ONINSTR("eEdDmM",INPUT$(1))GOTO32,32,34,34,46,46:GOTO30
32 POKEA,6:POKEA+1,246:GOTO26
34 POKEA,243:POKEA+1,127:GOTO26
36 CLS:F$=" Off ":IFPEEK(B)<>0THENF$=" On "
38 PRINT:PRINT"Upload LF"RV$F$NO$:PRINT:PRINT,"E)nable",,"D)isable",,"M)enu"
40 ONINSTR("eEdDmM",INPUT$(1))GOTO42,42,44,44,46,46:GOTO40
42 POKEB,1:GOTO36
44 POKEB,0:GOTO36
46 MENU