home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / prt / cgp115.ba < prev    next >
Text File  |  2006-10-19  |  4KB  |  70 lines
  1. 0 'CGP115.BA  v3.3      9-Mar-88
  2. 1 'Bill Templeton - Danville, CA
  3. 2 'Club 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  4. 3 '
  5. 10 CLS:PI=3.14159:CALL17001:PRINT@40,"  TRS-80  Model 100 + CGP-115 Software  ":CALL17006
  6. 11 LINE (0,5)-(239,5):LINE (0,7)-(239,7):LINE (0,17)-(239,17)
  7. 12 PRINT@123,"1 = LINE GRAPH
  8. 13 PRINT@163,"2 = BAR GRAPH
  9. 14 PRINT@203,"3 = SINE/COSINE CURVES
  10. 15 PRINT@243,"4 = SCALED CIRCLES
  11. 16 PRINT@283,"5 = MENU";
  12. 17 PRINT@230,"Your":PRINT@269,"choice? ";
  13. 18 A$=INPUT$(1):A=VAL(A$):PRINT@276,A;:FORT=1TO300:NEXT
  14. 19 IFA<1ORA>5THEN17
  15. 20 IFA=1THEN21ELSEIFA=2THEN34ELSEIFA=3THEN49ELSEIFA=4THEN63ELSEIFA=5THENMENU
  16. 21 ' Line Graph Routine
  17. 22 CLS:CALL17001:PRINT@90,"  This program shows  ":PRINT@130," a 3-color line graph ": PRINT@170," on a CGP-115 plotter ":CALL17006
  18. 23 LPRINT"----------------LINE GRAPH-------------":RESTORE32
  19. 24 LPRINTCHR$(18);"M75,-200":LPRINT"C0":LPRINT"I":LPRINT"X0,10,20":LPRINT"HX1,30,12
  20. 25 LPRINT"R0,20":LPRINT"J-360,0":LPRINT"R0,20":LPRINT"J360,0":LPRINT"R0,20
  21. 26 LPRINT"J-360,0":LPRINT"R0,20":LPRINT"J360,0":LPRINT"R0,20":LPRINT"J-360,0
  22. 27 LPRINT"S2":LPRINT"Q3":LPRINT"M-10,50":LPRINT"PSALES":LPRINT"M80,-40":LPRINT"Q0":LPRINT"P    1988
  23. 28 LPRINT"C1":GOSUB31:LPRINT"S0":LPRINT"M300,70":LPRINT"PSCREWS":LPRINT"C2
  24. 29 LPRINT"L3":GOSUB31:LPRINT"M300,50":LPRINT"PNUTS":LPRINT"C3":LPRINT"L6":GOSUB31:LPRINT"M300,30":LPRINT"PBOLTS
  25. 30 LPRINT"M0,-150":LPRINT"C0":LPRINT"L0":LPRINT"S1":LPRINT"A":GOTO10
  26. 31 READX,Y:LPRINT"M";X","Y:FORT=1TO3:READX,Y:LPRINT"D";X",";Y:NEXT:RETURN
  27. 32 ' Data for line graph
  28. 33 DATA 0,0,30,60,60,40,90,50,0,0,30,80,60,60,90,100,0,0,30,20,60,80,90,40
  29. 34 ' Bar Graph Routine
  30. 35 CLS:CALL17001:PRINT@90," This programs shows  ":PRINT@130," a 3-color bar graph  ":PRINT@170," on a CGP-115 plotter ":CALL17006
  31. 36 LPRINT"----------------BAR GRAPH--------------":RESTORE47
  32. 37 LPRINTCHR$(18);"M75,-200":LPRINT"C0":LPRINT"I":LPRINT"X0,20,10":LPRINT"HX1,30,12
  33. 38 LPRINT"R0,20":LPRINT"J-360,0":LPRINT"R0,20":LPRINT"J360,0":LPRINT"R0,20
  34. 39 LPRINT"J-360,0":LPRINT"R0,20":LPRINT"J360,0":LPRINT"R0,20":LPRINT"J-360,0
  35. 40 LPRINT"S2":LPRINT"Q3":LPRINT"M-10,50":LPRINT"PSALES":LPRINT"M80,-40":LPRINT"Q0":LPRINT"P    1988":LPRINT"S0
  36. 41 LPRINT"C1":GOSUB45:LPRINT"M300,70":LPRINT"PSCREWS
  37. 42 LPRINT"C2":GOSUB45:LPRINT"M300,50":LPRINT"PNUTS
  38. 43 LPRINT"C3":GOSUB45:LPRINT"M300,30":LPRINT"PBOLTS
  39. 44 LPRINT"M0,-150":LPRINT"C0":LPRINT"S1":LPRINT"A":GOTO10
  40. 45 FORT=1TO3:READX,Y:LPRINT"M";X",0":GOSUB46:NEXT:RETURN
  41. 46 LPRINT"J0,";Y:LPRINT"R1,0":LPRINT"J0,";-Y:LPRINT"R1,0":LPRINT"J0,";Y:LPRINT"R1,0":LPRINT"J0,";-Y:RETURN
  42. 47 ' Data for bar graph
  43. 48 DATA 25,60,55,40,85,50,29,80,59,60,89,100,33,20,63,80,93,40
  44. 49 ' SINE & COSINE ROUTINES
  45. 50 CLS:CALL17001:PRINT@90,"  This program shows  ":PRINT@130," Sine & Cosine curves ":PRINT@170," on a CGP-115 plotter ":CALL17006
  46. 51 LPRINT"----------SINE & COSINE CURVES---------
  47. 52 LPRINTCHR$(18);"R0,-100,240,0":LPRINT"I":LPRINT"C0":LPRINT"L0":LPRINT"X1,-20,10
  48. 53 LPRINT"HX1,20,10":LPRINT"HX0,16,5":LPRINT"HX0,-16,5
  49. 54 B=30:H=15:C=0:GOSUB59
  50. 55 LPRINT"C1":LPRINT"L3":B=-100:H=80:C=0:GOSUB59
  51. 56 LPRINT"C2":LPRINT"L5":B=100:H=80:C=1:GOSUB59
  52. 57 LPRINT"C3":LPRINT"L0":B=100:H=80:C=0:GOSUB59
  53. 58 LPRINT"C0":LPRINT"S1":LPRINT"M50,-150":LPRINT"A":GOTO10
  54. 59 A$="M":FORI=-200TO200STEP4:S=I/B*PI
  55. 60 IFC=0THENY=INT(SIN(S)*H)
  56. 61 IFC=1THENY=INT(COS(S)*H)
  57. 62 LPRINTA$;I;",";Y:A$="D":NEXTI:RETURN
  58. 63 '  Scaled Circles Routine
  59. 64 CLS:CALL17001:PRINT@90,"   This program shows   ":PRINT@130," 2-color scaled circles ":PRINT@170,"  on a CGP-115 plotter  "
  60. 65 LPRINT"------------SCALED CIRCLES-------------
  61. 66 LPRINTCHR$(18):LPRINT"R125,-50":LPRINT"I":LPRINT"S2":LPRINT"C1
  62. 67 LPRINT"PSCALE FACTOR":LPRINT"HP____________":LPRINT"M-12,-25":LPRINT"S1
  63. 68 LPRINT"C3":LPRINT"PR=50  (Radius = 1 cm)":LPRINT"M-24,-50":LPRINT"C0
  64. 69 LPRINT"PR=127  (Radius = 1 inch)":LPRINT"M115,-200":LPRINT"I
  65. 70 LPRINT"M0,10":LPRINT"J0,-20":LPRINT"M-10,0":LPRINT"J20,0":R=127:GOSUB74:R=50:LPRINT"C3":GOSUB74
  66. 71 LPRINT"HJ-35.35,35.35":LPRINT"R8,-2":LPRINT"J-8,2":LPRINT"R2,-8":LPRINT"J-2,8":LPRINT"R7,-35":LPRINT"PR
  67. 72 LPRINT"C0":LPRINT"H":LPRINT"J89.8,89.8":LPRINT"R-8,-2":LPRINT"J8,2":LPRINT"R-2,-8":LPRINT"J2,8":LPRINT"R-25,-50":LPRINT"PR
  68. 73 LPRINT"HR0,-200":LPRINT"A":GOTO10
  69. 74 A$="M":LPRINT"M0,";R:FORI=1TO101STEP2:S=I/100*(PI*2):X=INT(SIN(S)*R):Y=INT(COS(S)*R):LPRINTA$;X;",";Y:A$="D":NEXTI:RETURN
  70.