home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
prg
/
hex.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
1KB
|
39 lines
0 'Club 100 Library - 415/939-1246 BBS, 937-5039 Newsletter, 932-8856 Voice
1 'HEX.BA by Robert Benson (Ver 1.4)
10 CLS:PRINT@172,"(D)ec or (H)ex ?"
11 GOSUB44
12 IFINSTR("Hh",Q$)GOTO15
13 IFINSTR("Dd",Q$)GOTO28ELSE11
14 'Hex to Decimal
15 CLS:CLEAR50:PRINT:INPUT"Hex number";H$
16 FORX=LEN(H$)TO1STEP-1:ONERRORGOTO21
17 A$=MID$(H$,X,1):A=ASC(A$)-55
18 IFA>15THENA=A-32:IFA>15GOTO21
19 IFA<10THENA=VAL(A$)
20 M=16^C:D=D+(A*M):C=C+1:NEXTX
21 P$="Dec ="+STR$(D):PRINT@66,P$
22 PRINT@169,"Hit [ENTER] to Continue"
23 PRINT@249,"Spacebar for (D)ec mode"
24 GOSUB44
25 IFQ$=CHR$(13)GOTO15
26 IFQ$=" "GOTO28ELSE24
27 'Decimal to Hex
28 CLS:H$="":PRINT:INPUT"Dec number";DE
29 D0=DE/16:D1=INT(D0):D2=(D0-D1)*16
30 IFD2>9THEND2=D2+55:A$=CHR$(D2):GOTO33
31 A$=STR$(D2)
32 IFLEFT$(A$,1)=" "THENA$=RIGHT$(A$,(LEN(A$)-1))
33 H$=A$+H$
34 IFSGN(D0)=0THEN36
35 DE=D1:GOTO29
36 IFH$="0"THENPRINT@66,"Hex = 00":GOTO39
37 L=LEN(H$):IFL=2ORL=4THENPRINT@66,"Hex = "+H$:GOTO39
38 MID$(H$,1)=" ":PRINT@66,"Hex ="+H$
39 PRINT@169,"Hit [ENTER] to Continue"
40 PRINT@249,"Spacebar for (H)ex mode"
41 GOSUB44
42 IFQ$=CHR$(13)GOTO28
43 IFQ$=" "GOTO15ELSE41
44 Q$=INKEY$:IFQ$=""GOTO44
45 Z=PEEK(65451):IFZ=7THENMENUELSERETURN