home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / txtadv.ba < prev    next >
Text File  |  2006-10-19  |  14KB  |  296 lines
  1. 0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
  2. 10 ' Teeny Tiny Text Adventure  v1.1 By Tim Ekdom.
  3. 20 ' in lines 10 through 20.
  4. 100 DEFINTA-Z:CLEAR1500:DEFSTRT:T="  ":Z=0:N=Z:I=1:GOSUB3100:CLS
  5. 102 PRINT:PRINTT;"Time: 4:37 PM, mid November":CT=Z:GOSUB1650
  6. 104 PRINTT;"Location: ";LO$(CH(Z))
  7. 106 GOSUB400:GOSUB500:MF=Z:MG=Z:LINEINPUT"  >";IN$:CT=CT+1
  8. 108 GOSUB600:IFMGTHENPRINTT;MG$(MG):GOTO106
  9. 110 IFMFTHENGOSUB1200:IFMG=ZTHENGOTO104ELSEPRINTT;MG$(MG):GOTO106
  10. 112 IFVE<3ORVE=7ORVE=15ORVE=21THEN116
  11. 114 GOSUB700:IFMGTHENPRINTT;MG$(MG):GOTO106
  12. 116 ONVEGOSUB1700,1650,1950,1400,1450,1750,2150,2200,1300,1350,1500,1550,1600,1800,1850,1900,2000,2050,2100,2250,1860
  13. 117 IFMGTHENPRINTT;MG$(MG)
  14. 118 IFMFTHEN104ELSE106
  15. 200 OF=Z:OD=Z:FORN=ITO10:IFOC=IT(CH(Z),N)THENOF=I:OD=N:N=11
  16. 202 NEXT:RETURN
  17. 300 OF=Z:OA=Z:FORN=4TO8:IFOC=CH(N)THENOF=I:OA=N:N=9
  18. 302 NEXT:RETURN
  19. 400 IFCH(Z)<>ZTHENRETURN
  20. 402 OC=33:GOSUB200:IFOF=ZTHENRETURN
  21. 404 IFOB(33,4)<>32THENRETURN
  22. 406 FORN=ITO200:NEXT
  23. 408 CLS:PRINT@82,"CONGRATULATIONS!!"
  24. 410 PRINT@122,"Mission accomplished...";:GOTO1852
  25. 500 IFCT<19THENRETURN
  26. 502 IFCT=19THENPRINTT;"It's getting dark"
  27. 504 IFCT<29THENRETURN
  28. 506 IFCT=29THENPRINTT;"It's cold here"
  29. 508 IFCT<39THENRETURN
  30. 510 OC=19:GOSUB300:IFOFAND(CT=39ORCT=59)THENPRINTT;"The flashlight is getting dim"
  31. 512 IFCT<49THENRETURN
  32. 514 IFCT=49THENCH(I)=I:PRINTT;"You're thirsty":RETURN
  33. 516 IFCT<63THENRETURN
  34. 517 IFCT=63ANDCF=ZANDSM=ZTHENCH(2)=I:PRINTT;"You're getting cold":RETURN
  35. 518 IFCT<73THENRETURN
  36. 520 IFOF=ZANDLT=ZTHENCH(3)=Z:IFCT=73THENPRINTT;MG$(13):RETURN
  37. 522 IFCT<79THENIFOFTHENCH(3)=I:RETURNELSERETURN
  38. 524 IFCT=79THENOB(19,5)=Z:IFOFANDLT=ZTHENCH(3)=Z:PRINTT;MG$(13)
  39. 525 IFOFANDCT=79THENPRINTT;"The batteries are dead":RETURN
  40. 526 IFCT>=79THENIFLT=ZTHENCH(3)=ZELSECH(3)=I
  41. 528 IFCH(I)AND(CT/11=INT(CT/11))THENPRINTT;"You're very thirsty":RETURN
  42. 530 IFCH(2)AND(CT/13=INT(CT/13))THENPRINTT;"You're freezing cold":RETURN
  43. 532 IFSMAND(CT/8=INT(CT/8))ANDCH(Z)>2ANDCH(Z)<10THENPRINTT;"It's really smoky in here":RETURN
  44. 534 IFCT<199THENRETURN
  45. 536 IFSMANDCH(Z)>ITHENDD=I:GOTO800
  46. 538 IFCH(I)THENDD=2:GOTO800
  47. 540 IFCH(2)THENDD=3:GOTO800
  48. 542 RETURN
  49. 600 VE=Z:OJ=Z:IFLEN(IN$)=ITHENIFINSTR(I,"NSEWUD",IN$)THENMF=I:RETURNELSEMG=11:RETURN
  50. 602 SP=INSTR(I,IN$," "):IFSP=ZTHENVE$=IN$:GOTO606
  51. 604 VE$=LEFT$(IN$,SP-I)
  52. 606 FORN=ITO21:IFVE$=VB$(N)THENVE=N:N=22
  53. 610 NEXT
  54. 612 IFVE=ZTHENMG=11:RETURN
  55. 613 IFVE<3ORVE=15ORVE=21THENRETURN
  56. 614 OJ$=RIGHT$(IN$,LEN(IN$)-SP)
  57. 616 LO=I:HI=48
  58. 618 IFLO>HITHENMG=11:RETURN
  59. 620 MD=INT((HI+LO)/2)
  60. 622 IFOJ$=OB$(MD)THENOJ=MD:RETURN
  61. 624 IFOJ$<OB$(MD)THENHI=MD-1:GOTO618
  62. 626 IFOJ$>OB$(MD)THENLO=MD+1:GOTO618
  63. 700 IFVE=5THENRETURNELSEX=VM(VE)
  64. 702 FORN=XTOX+21
  65. 704 IFVM(N)=OJTHENN=X+22:GOTO708
  66. 706 IFVM(N)=ZTHENMG=12:N=X+22
  67. 708 NEXT:RETURN
  68. 800 CLS:PRINT@82,"SORRY!":PRINT@122,"You died from ";DD$(DD):GOTO1852
  69. 1200 IFINSTR(I,MV$(CH(Z)),IN$)=ZTHENMG=8:RETURN
  70. 1202 ONCH(Z)+IGOTO1205,1210,1215,1220,1225,1230,1235,1240,1245,1250,1255,1260,1265,1270,1275,1280,1285
  71. 1205 MG=14:RETURN
  72. 1210 IFIN$="N"THENCH(Z)=2:RETURNELSEMG=14:RETURN
  73. 1215 IFIN$="E"THENCH(Z)=13:RETURN
  74. 1216 IFIN$="W"THENCH(Z)=16:RETURN
  75. 1217 IFIN$="S"THENCH(Z)=I:RETURN
  76. 1218 IFIN$="N"THENCH(Z)=3:RETURN
  77. 1220 IFIN$="N"THENCH(Z)=7:RETURN
  78. 1221 IFIN$="S"THENCH(Z)=2:RETURN
  79. 1222 IFIN$="W"THENCH(Z)=4:RETURN
  80. 1225 IFIN$="N"THENCH(Z)=6:RETURN
  81. 1226 IFIN$="W"THENCH(Z)=5:RETURN
  82. 1227 IFIN$="E"THENCH(Z)=3:RETURN
  83. 1230 IFIN$="E"THENCH(Z)=4:RETURNELSECH(Z)=8:RETURN
  84. 1235 IFIN$="S"THENCH(Z)=4:RETURN
  85. 1240 IFIN$="S"THENCH(Z)=3:RETURN
  86. 1241 IFIN$="D"THENCH(Z)=9:RETURN
  87. 1242 IFIN$="N"THENCH(Z)=11:RETURN
  88. 1245 IFIN$="D"THENCH(Z)=5:RETURN
  89. 1250 IFIN$="U"THENCH(Z)=7:RETURN
  90. 1255 IFIN$="N"THENCH(Z)=14:RETURNELSECH(Z)=13:RETURN
  91. 1260 IFIN$="E"THENCH(Z)=14:RETURN
  92. 1261 IFIN$="W"THENCH(Z)=15:RETURN
  93. 1262 IFIN$="S"THENCH(Z)=7:RETURN
  94. 1265 IFIN$="N"THENCH(Z)=15:RETURNELSECH(Z)=16:RETURN
  95. 1270 IFIN$="N"THENCH(Z)=10:RETURNELSECH(Z)=2:RETURN
  96. 1275 IFIN$="S"THENCH(Z)=10:RETURNELSECH(Z)=11:RETURN
  97. 1280 IFIN$="S"THENCH(Z)=12:RETURNELSECH(Z)=11:RETURN
  98. 1285 IFIN$="N"THENCH(Z)=12:RETURNELSECH(Z)=2:RETURN
  99. 1300 IFCH(Z)=ITHEN1312
  100. 1302 IFCH(Z)=ZTHENCH(Z)=I:GOTO1316
  101. 1304 IFCH(Z)=7THENCH(Z)=9:GOTO1316
  102. 1306 IFCH(Z)=9THENCH(Z)=7:GOTO1316
  103. 1308 IFCH(Z)=5THENCH(Z)=8:GOTO1316
  104. 1310 IFCH(Z)=8THENCH(Z)=5:GOTO1316
  105. 1311 MG=5:RETURN
  106. 1312 OC=33:GOSUB300:IFOFTHENPRINTT;"OOF!! Too heavy!":RETURN
  107. 1314 CH(Z)=Z
  108. 1316 MF=I:RETURN
  109. 1350 OC=7:GOSUB300:IFOF=ZTHENMG=6:RETURN
  110. 1352 IFOB(7,4)=46THENOB(7,4)=Z:CH(I)=Z:MG=I:RETURN
  111. 1354 MG=4:RETURN
  112. 1400 OC=OJ:GOSUB300:IFOF=ZTHENMG=6:RETURN
  113. 1402 OC=Z:GOSUB200:IFOF=ZTHENPRINTT;"This room is full":RETURN
  114. 1404 IFCH(Z)=3ANDOJ=18THENOB(17,4)=18:OB(18,3)=17
  115. 1410 CH(OA)=Z:IT(CH(Z),OD)=OJ:MG=I
  116. 1412 IFOJ=26THENLT=Z
  117. 1414 RETURN
  118. 1450 IFCH(3)=ZTHENMG=13:RETURN
  119. 1451 IFOJ=9THEN1478
  120. 1452 IFOJ=15THEN1480
  121. 1453 IFOJ=20THEN1470
  122. 1454 IF(OJ=3OROJ=26OROJ=30)AND(OB(OJ,Z)=CH(Z))THENOC=Z:GOSUB200:IT(CH(Z),OD)=OJ:OB(OJ,Z)=19:GOTO1478
  123. 1455 IFOB(OJ,Z)=CH(Z)THEN1460
  124. 1456 OC=OJ:GOSUB300:IFOFTHEN1460
  125. 1458 OC=OJ:GOSUB200:IFOF=ZTHENMG=7:RETURN
  126. 1460 IFOB(OJ,3)>ZTHENIFOB(OB(OJ,3),I)<>3THENMG=7:RETURN
  127. 1462 IFOB(OJ,I)=ZTHEN1478
  128. 1464 IFOB(OJ,I)=ITHENMG=2:IFOB(OJ,5)<>ZTHEN1478ELSERETURN
  129. 1466 IFOB(OJ,I)=2THENMG=3:IFOB(OJ,5)<>ZTHEN1478ELSERETURN
  130. 1468 IFOB(OJ,I)=3THENIFOB(OJ,4)=ZTHENMG=4:IFOB(OJ,5)<>ZTHEN1478ELSERETURN
  131. 1470 PRINTT;"It contains: ";OB$(OB(OJ,4))
  132. 1471 IF(OB(OJ,4)=3OROB(OJ,4)=26OROB(OJ,4)=30)AND(OB(OB(OJ,4),Z)=CH(Z))THENOB(OB(OJ,4),Z)=19
  133. 1472 OC=OB(OJ,4):GOSUB200:IFOFTHENRETURN
  134. 1474 OC=Z:GOSUB200:IT(CH(Z),OD)=OB(OJ,4):RETURN
  135. 1478 PRINTT;DE$(OB(OJ,5)):RETURN
  136. 1480 IFCH(Z)=2ANDFD=ZTHENMG=3:RETURN
  137. 1481 IFCH(Z)=3ANDFD=ZTHENMG=2:RETURN
  138. 1482 IF(CH(Z)=2ORCH(Z)=3)ANDFD=ITHENPRINTT;DE$(Z):RETURN
  139. 1484 IF(CH(Z)=7ORCH(Z)=11)ANDOB(OJ,I)=ITHENMG=2:RETURN
  140. 1486 IFCH(Z)=7THENPRINTT;DE$(Z):RETURN
  141. 1488 IFCH(Z)<>11THENMG=5:RETURN
  142. 1490 IFOB(OJ,I)=2THENMG=3:RETURN
  143. 1492 PRINTT;DE$(Z):RETURN
  144. 1500 IFOJ=33THEN1508
  145. 1502 OC=OJ:GOSUB300:IFOF=ZTHENMG=5:RETURN
  146. 1504 IFCH(Z)<>6THENPRINTT;"There's no water here!":RETURN
  147. 1506 OB(OJ,4)=46:MG=I:RETURN
  148. 1508 OC=33:GOSUB300:IFOF=ZTHENMG=6:RETURN
  149. 1510 OC=32:GOSUB200:IFOF=ZTHENMG=15:RETURN
  150. 1512 OB(33,4)=32:OB(33,5)=Z:OB(32,3)=33:OB(32,5)=15:OC=32:GOSUB200:IT(CH(Z),OD)=Z:MG=I:RETURN
  151. 1550 IFCH(Z)<>4THENMG=5:RETURN
  152. 1552 PRINTT;"There's a paper under it"
  153. 1554 OB(34,3)=Z:OB(31,5)=Z:OC=Z:GOSUB200:IT(4,OD)=34:RETURN
  154. 1600 OC=30:GOSUB300:IFOF=ZTHENMG=15:RETURN
  155. 1602 IFOJ=16THEN1608
  156. 1604 OC=26:GOSUB300:IFOF=ZTHENMG=12:RETURN
  157. 1606 CH(3)=I:LT=I:MG=I:RETURN
  158. 1608 IFCH(Z)<>3THENMG=12:RETURN
  159. 1610 IFOB(17,4)<>18THENMG=12:RETURN
  160. 1612 OB(17,4)=16:OB(18,3)=Z:OB(16,3)=17:PRINTT;MG$(I):OC=18:GOSUB200:IT(3,OD)=Z
  161. 1614 IFOB(20,4)=6THENPRINTT;"Smoke gets in your eyes":SM=I
  162. 1616 OB(16,Z)=3:OC=Z:GOSUB200:IT(3,OD)=16:CH(2)=Z:RETURN
  163. 1650 X=Z:PRINTT;"You have: ":FORN=4TO8:IFCH(N)THENPRINTT;OB$(CH(N)):X=X+1
  164. 1652 NEXT:IFX=ZTHENPRINTT;N$
  165. 1654 RETURN
  166. 1700 IFCH(3)=ZTHENMG=13:RETURN
  167. 1702 X=Z:PRINTT;"You see: "
  168. 1704 FORN=ITO10:IFIT(CH(Z),N)THENPRINTT;OB$(IT(CH(Z),N)):X=X+1
  169. 1706 NEXT:IFX=ZTHENPRINTT;N$
  170. 1708 RETURN
  171. 1750 IFOB(OJ,I)=ZTHENMG=12:RETURN
  172. 1751 IFOJ=15THEN1764
  173. 1752 IFOB(OJ,Z)<19ANDOB(OJ,Z)<>CH(Z)THENMG=5:RETURN
  174. 1753 IFOB(OJ,I)=2THENMG=3:RETURN
  175. 1754 IFOB(OJ,2)=ZTHEN1758
  176. 1756 OC=OB(OJ,2):GOSUB300:IFOF=ZTHENMG=12:RETURN
  177. 1758 OB(OJ,I)=3:IFOB(OJ,4)=ZTHENMG=I:RETURN
  178. 1760 PRINTT;"There's something inside!"
  179. 1762 OC=Z:GOSUB200:IT(CH(Z),OD)=OB(OJ,4):RETURN
  180. 1764 IF(CH(Z)=3ORCH(Z)=2)ANDFDTHENMG=16:RETURN
  181. 1765 IFCH(Z)=3THENFD=I:MV$(2)="NSEW":MV$(3)="NSW":MG=I:RETURN
  182. 1766 IFCH(Z)=2THENMG=12:RETURN
  183. 1768 IFCH(Z)<>7ANDCH(Z)<>11THENMG=5:RETURN
  184. 1769 IFOB(OJ,I)=3THENMG=16:RETURN
  185. 1770 IFCH(Z)=7THEN1774
  186. 1772 IFOB(OJ,I)=2THENMG=3:RETURN
  187. 1774 OB(OJ,I)=3:MV$(11)="SEW":MV$(7)="NSD":MG=I:RETURN
  188. 1800 OC=35:GOSUB300:IFOF=ITHEN1814
  189. 1802 OC=7:GOSUB300:IFOF=ZTHENMG=12:RETURN
  190. 1804 IFOB(7,4)=ZTHENMG=4:RETURNELSEOB(7,4)=Z
  191. 1806 IFCH(Z)<>3THENMG=I:RETURN
  192. 1808 IFSM=ITHENSM=Z:OB(16,Z)=21:OB(16,3)=Z:OB(17,4)=18:OB(18,3)=I:PRINTT;"The fire's out"
  193. 1810 IFCF=0ANDCT>=49THENCH(2)=I
  194. 1812 RETURN
  195. 1814 IFOB(35,4)=ZTHENMG=4:RETURNELSEOB(35,4)=Z:GOTO1806
  196. 1850 CLS
  197. 1852 PRINT@202,"You have completed";CT-1;"turns.":FORN=ITO600:NEXT:MENU
  198. 1860 MF=I:RETURN
  199. 1900 IFCH(3)=ZTHENMG=13:RETURN
  200. 1902 IFOJ=28THENIFOB(5,I)<>3THENMG=7:RETURN
  201. 1903 IF(OJ=3OROJ=28)ANDOB(OJ,Z)=19THENMG=1:RETURN
  202. 1904 IFOJ=3OROJ=28THENOC=Z:GOSUB200:IT(CH(Z),OD)=OJ:OB(OJ,Z)=19:MG=1:RETURN
  203. 1906 IFOB(34,3)<>0THENMG=7:RETURN
  204. 1908 PRINTT;"It reads: 11-6-23":PA=I:RETURN
  205. 1950 IF(OJ=3OROJ=26OROJ=30)AND(OB(OJ,Z)=CH(Z))THEN1966
  206. 1952 OC=OJ:GOSUB300:IFOFTHENMG=10:RETURN
  207. 1954 GOSUB200:IFOF=ZTHENMG=7:RETURN
  208. 1958 OC=Z:GOSUB300:IFOF=ZTHENMG=9:RETURN
  209. 1960 IT(CH(Z),OD)=Z
  210. 1962 CH(OA)=OJ:IFOB(OJ,3)=ZTHENMG=I:RETURN
  211. 1964 OB(OB(OJ,3),4)=Z:OB(OJ,3)=Z:MG=I:RETURN
  212. 1966 OB(OJ,Z)=19:OC=Z:GOSUB300:IFOF<>ZTHEN1962
  213. 1968 OC=Z:GOSUB200:IT(CH(Z),OD)=OJ:MG=9:RETURN
  214. 2000 IFOJ=33ANDCH(Z)=ITHEN2004
  215. 2002 GOSUB1400:RETURN
  216. 2004 OC=OJ:GOSUB300:IFOF=ITHENCH(OA)=ZELSEMG=6:RETURN
  217. 2006 CH(Z)=Z:OC=Z:GOSUB200:IT(Z,OD)=33:CH(Z)=I:MG=I:RETURN
  218. 2050 IFCH(Z)<>5THENMG=5:RETURN
  219. 2052 IFPA=ZTHENPRINTT;"What's the combination?":RETURN
  220. 2054 OB(36,I)=I:PRINTT;"It clicked!":MG=I:RETURN
  221. 2100 OC=10:GOSUB300:IFOF=ITHENCH(OA)=Z:GOTO2106
  222. 2102 GOSUB200:IFOF=ITHENIT(CH(Z),OD)=Z:GOTO2106
  223. 2104 MG=12:RETURN
  224. 2106 MG=I:CF=I:CH(2)=Z:RETURN
  225. 2150 OC=I:GOSUB300:IFOF=ZTHENMG=12:RETURN
  226. 2152 OC=OJ:GOSUB200:IFOF=ZTHENMG=5:RETURN
  227. 2154 IFOJ=18THENMG=1:RETURN
  228. 2156 PRINTT;"Destructive bugger, aren't you?":IFOJ<>47THENRETURN
  229. 2158 IFCH(Z)=2THENOB(47,I)=3:OB(47,5)=Z:MV$(2)="NSEW":MV$(3)="NSW"
  230. 2160 PRINTT;"You broke through":RETURN
  231. 2200 OC=25:GOSUB300:IFOF=ZTHENMG=12:RETURN
  232. 2202 OC=6:GOSUB300IFOFTHEN2204ELSEGOSUB200
  233. 2204 IFOFTHENMG=I:GOSUB1762:OB(6,I)=3:OB(6,4)=Z:RETURN
  234. 2206 MG=5:RETURN
  235. 2250 IFOJ=36THENIFCH(Z)=5THENPRINTT;"How?":RETURNELSEMG=5:RETURN
  236. 2251 IF((CH(Z)=11ORCH(Z)=7)ANDOB(15,I)<>2)ORCH(Z)=3THENPRINTT;"It's not locked":RETURN
  237. 2252 OC=24:GOSUB300:IFOF=ZTHENPRINTT;"With what?":RETURN
  238. 2254 IFCH(Z)<>11THENPRINTT;"That key doesn't fit here":RETURN
  239. 2255 IFOB(15,I)<>2THENPRINTT;"It's not locked":RETURN
  240. 2256 OB(15,I)=I:OB(15,2)=Z:MG=I:RETURN
  241. 2258 MG=5:RETURN
  242. 3100 DIMCH(8),LO$(16),IT(16,12),MV$(16),OB$(48),MG$(16),DE$(17),VB$(21),OB(48,5),VM(83),DD$(3)
  243. 3102 CLS:LINE(20,8)-(219,48),1,B:PRINT@87,"Teeny Tiny Text Adventure"
  244. 3104 PRINT@130,"     BY Tim Ekdom":
  245. 3106 FORN=ZTO8:READCH(N):NEXT
  246. 3108 FORN=ZTO16:READLO$(N),MV$(N):NEXT
  247. 3110 FORN=ZTO16:FORJ=ITO8:READX:IFX=99THENJ=9ELSEIT(N,J)=X
  248. 3112 NEXT:NEXT
  249. 3120 CLS:PRINT:PRINT"  Rumors say that the old man had a":PRINT"million in cash when he died. But it"
  250. 3122 PRINT"wasn't in the bank. Where is it? There":PRINT"are no heirs. It's finders keepers!"
  251. 3124 PRINT"Your mission: to search his old house...";
  252. 3132 FORN=ITO48:READOB(N,Z),OB(N,I),OB(N,2),OB(N,3),OB(N,4),OB(N,5):NEXT
  253. 3134 FORN=ITO48:READOB$(N):NEXT
  254. 3136 FORN=ITO16:READMG$(N):NEXT
  255. 3138 FORN=ZTO17:READDE$(N):NEXT
  256. 3140 FORN=ITO21:READVB$(N):NEXT
  257. 3141 FORN=ITO83:READVM(N):NEXT
  258. 3142 FORN=ITO3:READDD$(N):NEXT
  259. 3144 N$="Nothing":PRINT:PRINT "Caps Lock On?  Press RETURN";
  260. 3146 A$=INKEY$:IFA$=""THEN3146ELSERETURN
  261. 3200 DATA 0,0,0,1,19,7,0,0,0
  262. 3202 DATA ROAD,N,PATH,NS,FRONT PORCH,SEW,LIVING ROOM,NW,BEDROOM,NWE,CLOSET,EU,BATH,S
  263. 3203 DATA KITCHEN,SD,ATTIC,D,CELLAR,U,EAST SIDE,NS,BACK SIDE,EW,WEST SIDE,NS
  264. 3204 DATA S.E. CORNER,NW,N.E. CORNER,SW,N.W. CORNER,SE,S.W. CORNER,NE
  265. 3205 DATA 22,29,45,99,22,45,23,99,15,47,99,4,13,17,15,99,2,8,99,10,36,41,99,43,44,99
  266. 3206 DATA 12,21,39,42,41,15,99,5,41,99,38,48,41,99,18,1,99,15,99,99,99,99,99,99
  267. 3211 DATA 19,0,0,0,0,0,4,3,0,0,31,0,3,0,0,4,0,0,3,3,0,0,3,0
  268. 3215 DATA 19,1,0,0,28,0,19,1,25,0,32,1,19,3,0,0,46,0,4,1,37,0,40,2
  269. 3219 DATA 3,3,0,0,20,3,19,0,0,0,0,0,3,0,0,13,0,14,7,1,0,0,25,0
  270. 3223 DATA 3,1,0,0,11,0,5,0,0,0,0,0,11,2,24,0,0,0,21,0,0,0,0,0
  271. 3227 DATA 3,3,0,0,0,16,19,0,0,0,0,0,19,0,0,0,0,7,3,3,0,0,6,0
  272. 3231 DATA 7,1,0,0,35,0,0,0,0,0,0,17,1,0,0,0,0,0,19,0,0,29,0,0
  273. 3235 DATA 19,0,0,12,0,0,9,0,0,38,0,8,11,2,24,0,0,0,19,0,0,5,0,9
  274. 3239 DATA 0,1,0,0,24,0,7,0,0,42,0,0,4,0,0,0,0,6,3,0,0,6,0,13
  275. 3243 DATA 19,3,0,36,0,0,19,0,0,31,0,11,19,3,0,0,0,0,5,2,0,0,33,4
  276. 3247 DATA 19,0,0,48,0,0,9,3,0,0,26,0,7,3,0,0,0,0,19,0,0,8,0,15
  277. 3251 DATA 7,0,0,0,0,0,7,3,0,0,30,0,6,1,0,0,0,0,6,3,0,0,46,0
  278. 3255 DATA 0,0,0,0,0,0,6,0,0,0,0,10,2,0,0,0,0,12,9,3,0,0,37,0
  279. 3298 DATA AX,BED,BOOKS,BOOKSHELF,BOX,BUNDLE,CANTEEN,CHEST,CHIMNEY,COAT,COMPUTER,CUPBOARD,DESK,DIAL
  280. 3300 DATA DOOR,FIRE,FIREPLACE,FIREWOOD,FLASHLIGHT,FLUE,FRIDGE,GATE,HOUSE,KEY,KNIFE,LANTERN,LOCK
  281. 3302 DATA MAGAZINES,MAILBOX,MATCHES,MATTRESS,MONEY,MONEYBAG,PAPER,POT,SAFE,SCREWDRIVER,SHELF
  282. 3304 DATA SINK,SOX,STAIRS,STOVE,TOILET,TUB,WALL,WATER,WINDOW,WORKBENCH
  283. 3306 DATA OK,It's closed,It's locked,It's empty,It's not here,You don't have it
  284. 3307 DATA You can't see it,You can't go that way,You can't take it,You already have it
  285. 3308 DATA I don't understand,You can't do that,It's too dark to see,The gate is shut,With what?,It's open
  286. 3310 DATA It looks uninteresting,It's a heavy nylon bag,The drawer is stuck,The flue is blocked
  287. 3312 DATA It has a numbered dial,It has a mattress,There's something underneath,The batteries are weak,It's full
  288. 3314 DATA Portable 100 back issues,It's wet,There's writing on it,It's boarded up,It's scattered all over
  289. 3315 DATA It's not a portable,Phew!!,It has a large chimney,"It's padlocked, but not too high"
  290. 3320 DATA LOOK,LIST,TAKE,DROP,EXAMINE,OPEN,CHOP,CUT,CLIMB,DRINK,FILL,LIFT
  291. 3322 DATA LIGHT,POUR,QUIT,READ,THROW,TURN,WEAR,UNLOCK,WHERE
  292. 3324 DATA 0,0,22,22,0,41,0,55,57,60,62,66,68,60,0,71,22,75,77,79,0
  293. 3326 DATA 1,3,5,6,7,10,18,19,24,25,26,28,30,33,34,35,37,40,0,5,6,7,8,12,13,15,21,27,29,33,36,43,0
  294. 3328 DATA 6,0,22,41,0,46,0,7,33,35,0,31,0,16,26,0,3,28,34,0,14,0,10,0,15,27,36,0,0
  295. 3330 DATA smoke inhalation,dehydration,hypothermia
  296.