home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / skydiv.ba < prev    next >
Text File  |  2006-10-19  |  3KB  |  91 lines
  1. 0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
  2. 2 'Skydiv, from Tab book of M100 game programs; Wind, 2 player option added by Russ Hall
  3. 5 DIMSC(2),TJ(2)
  4. 10 CLS:PRINT:PRINTTAB(12)"= =  SKYDIVER  = ="
  5. 20 FORN=1TOVAL(RIGHT$(TIME$,2)):T=RND(1):NEXT
  6. 30 PRINT:PRINTTAB(14)"Instructions?"
  7. 40 PRINT:PRINTTAB(20)"(Y/N)"
  8. 50 A$=INKEY$:IFA$=""THEN50
  9. 60 IFA$="Y"ORA$="y"THEN140 ELSE GOTO205
  10. 140 CLS:PRINT
  11. 150 PRINT"     Difficulty level sets size of the"
  12. 160 PRINT"landing pad.  Hit any key to jump and"
  13. 170 PRINT"release chute. Considering wind and"
  14. 180 PRINT"difficulty, you get adjusted points for"
  15. 190 PRINT"safe landings and lose five for a crash.";
  16. 200 GOSUB1000
  17. 205 CLS:PRINT:PRINT"  For 1 player or 2?
  18. 206 K$=INKEY$:IFK$=""THEN206
  19. 207 IFK$="2"THENNP=2:GOTO210
  20. 208 Z=1:GOTO220
  21. 210 CLS:IFZ=1THENZ=2 ELSE Z=1
  22. 215 PRINT:PRINTTAB(6)"Player #";Z:GOTO221
  23. 220 CLS:PRINT
  24. 221 C=0
  25. 222 W=INT(RND(1)*60)+1'wind
  26. 223 W=W-30:IFW>0THENAR$=CHR$(154)
  27. 224 IFW<0THENAR$=CHR$(155)
  28. 225 PRINTTAB(12)"Wind is"ABS(W)"mph. "AR$
  29. 230 PRINT:PRINTTAB(5)"Enter difficulty level:"
  30. 240 PRINT:PRINTTAB(4)"[1] Hard to [4] Easy, [Q]uit"
  31. 250 A$=INKEY$:IFA$=""THEN250
  32. 255 IFA$="Q"ORA$="q"THEN800
  33. 260 DF=VAL(A$):FF=VAL(A$)
  34. 270 IFDF<1ORDF>4THEN250
  35. 275 DF=DF+2:TJ(Z)=TJ(Z)+1'pad size, counter
  36. 280 T=INT(RND(1)*10)+292
  37. 290 CLS
  38. 300 A=1
  39. 310 FORN=1TODF'display pad
  40. 320 PRINT@T+N,CHR$(239);
  41. 330 NEXT
  42. 340 PARA$=CHR$(159)
  43. 350 PLANE$=CHR$(62)
  44. 360 PRINT@28,"Score:";SC(Z);
  45. 370 A$=INKEY$
  46. 380 PRINT@A,PLANE$;
  47. 390 PRINT@A-1,CHR$(32);
  48. 400 A=A+1
  49. 410 FORN=1TO100:NEXT
  50. 420 IFA$=""THEN360
  51. 425 REM - Jumped -
  52. 430 PRINT@A-1,CHR$(32);
  53. 440 PRINT@A,PARA$;
  54. 450 FORN=1TO450:NEXT
  55. 455 C=(C+.02*W):WC=INT(C+.5)'figure wind into position
  56. 460 PRINT@A,CHR$(32);
  57. 470 A=A+40+WC
  58. 480 IFA>320THENA=A-41:GOTO590'detect miss
  59. 490 IFPEEK(A-512)=239THEN510'detect pad hit
  60. 500 GOTO440
  61. 510 CLS:PRINT
  62. 520 PRINTTAB(12)"Nice landing!"
  63. 525 FORD=9000TO1000STEP-1000
  64. 526 SOUNDD,2:NEXT
  65. 529 FF=FF*FF:W=ABS(W):FG=INT(W+21-.33*W-FF)
  66. 530 PRINTTAB(12)"You get"FG"points."
  67. 550 SC(Z)=SC(Z)+FG
  68. 560 GOSUB1000
  69. 580 IFNP=2THEN210 ELSE GOTO220
  70. 590 FORN=1TO50
  71. 600 PRINT@A,CHR$(190);
  72. 610 GOSUB730
  73. 620 PRINT@A,CHR$(199);
  74. 630 NEXTN
  75. 640 CLS:PRINT
  76. 650 PRINTTAB(12)"You crashed!"
  77. 660 PRINT
  78. 670 PRINTTAB(12)"You lose five points."
  79. 690 SC(Z)=SC(Z)-5
  80. 700 GOSUB1000
  81. 710 GOTO580
  82. 730 SOUND7000,1:RETURN
  83. 800 IFNP=2THEN830 ELSE CLS:PRINT:PRINT" You earned"SC(Z)"points from"TJ(Z)"jumps."
  84. 810 PRINT:PRINT" Your rating as a skydiver is"INT(SC(Z)/TJ(Z))*4"%"
  85. 820 FORN=1TO2000:NEXT:MENU
  86. 830 CLS:PRINT:PRINTTAB(5)"Player #1:";SC(1);"points":PRINT:PRINTTAB(5)"Player #2:";SC(2);"points"
  87. 840 PRINT:PRINTTAB(5)"From";TJ(1);"jumps.":GOTO820
  88. 1000 PRINT:PRINTTAB(11)"==  HIT ANY KEY ==";
  89. 1010 A$=INKEY$:IFA$=""THEN1010
  90. 1020 RETURN
  91.