home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / pong.ba < prev    next >
Text File  |  2006-10-19  |  2KB  |  45 lines
  1. 0 'PONG.BA by Rick Perry, Villanova University, EE Dept.
  2. 1 'CLUB 100 LIBRARY - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  3. 32 DEFINTA-Z:S1=0:S2=0:P=2:C$=CHR$(27)+"12 -="+CHR$(8):PRINT"Wait..."
  4. 33 FORI=1TOVAL(RIGHT$(TIME$,2))+VAL(MID$(TIME$,5,1))*60:D#=RND(1):NEXTI
  5. 34 IFP=2AND(S1>9999ORS2>9999)THEN66
  6. 35 IFP=2THENP=1ELSEP=2
  7. 36 PRINT@240," Player #";P;" Ready ? ";:PRINT@259,"";
  8. 37 A=ASC(INPUT$(1)):IFA<>13THEN37
  9. 38 CLS:Y1=-1:D=19:W=1:LINE(59,60)-(59,D):LINE(177,D)-(177,60):LINE(59,D)-(177,0),1,BF
  10. 39 PRINT@41,"PLAYER";:PRINT@83,"#1";:PRINT@71,"PLAYER";:PRINT@113,"#2";
  11. 40 PRINT@161,S1;:PRINT@191,S2;
  12. 41 Z=114:LINE(Z,60)-(Z+8,60):GOSUB73
  13. 42 X=60+115*RND(1):Y=D+3:GOSUB70:LINE(X,Y)-(X+2,Y-2),1,BF:
  14. 43 GOSUB55:IFW=0THEN34
  15. 44 A$=INKEY$:IFA$=""THEN43ELSEONINSTR(C$,A$)GOTO46,47,48,49,50,51,52
  16. 45 GOTO43
  17. 46 Z1=60-Z:GOTO53
  18. 47 Z1=87-Z:GOTO53
  19. 48 IFZ>62THENZ1=-3:GOTO53ELSE43
  20. 49 Z1=114-Z:GOTO53
  21. 50 IFZ<168THENZ1=3:GOTO53ELSE43
  22. 51 Z1=141-Z:GOTO53
  23. 52 Z1=168-Z
  24. 53 LINE(Z,60)-(Z+8,60),0:Z=Z+Z1:LINE(Z,60)-(Z+8,60),1
  25. 54 GOTO43
  26. 55 IFY=59AND(X>Z+8ORX+2<Z)THENSOUND9394,15:W=0:GOSUB73:RETURN
  27. 56 IFY=59ORY=D+3THENY1=-Y1
  28. 57 IFY=59THEND=D+1:LINE(59,D)-(177,D):GOSUB70:GOSUB63:IFW=0THENRETURN
  29. 58 IFX=174THENX1=-1ELSEIFX=60THENX1=1
  30. 59 LINE(X+X1,Y+Y1)-(X+X1+2,Y+Y1-2),1,BF:LINE(X,Y-1-Y1)-(X+2,Y-1-Y1),0
  31. 60 IFX1>0THENLINE(X,Y)-(X,Y-2),0ELSEIFX1<0THENLINE(X+2,Y)-(X+2,Y-2),0
  32. 61 X=X+X1:Y=Y+Y1
  33. 62 RETURN
  34. 63 IFD=53THEND=1053:W=0:BEEP:GOSUB73
  35. 64 IFP=1THENS1=S1+D:PRINT@161,S1;ELSES2=S2+D:PRINT@191,S2;
  36. 65 RETURN
  37. 66 IFS1=S2THENPRINT@241,"Tie game!";
  38. 67 IFS1>S2THENPRINT@241,"Player #1 wins!";
  39. 68 IFS2>S1THENPRINT@241,"Player #2 wins!";
  40. 69 END
  41. 70 X1=INT(7*RND(1))
  42. 71 IFX1=3THENX1=0ELSEIFX1>3THENX1=1ELSEX1=-1
  43. 72 RETURN
  44. 73 FORJ=1TO1000:NEXTJ:RETURN
  45.