home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / ping.ba < prev    next >
Text File  |  2006-10-19  |  2KB  |  40 lines
  1. 0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
  2. 5 'PING by Russ Hall, 1380 Diane Dr., Salt Lake City, UT 84123, 03/28/87
  3. 10 GOSUB400' Initialize
  4. 20 GOSUB200' Move paddle
  5. 30 GOSUB300' Move ball
  6. 50 GOTO20
  7. 110 P=P+1:PRINT@120,P:FORJ=1TO100:NEXT:IFP=4THEN600
  8. 120 GOTO20
  9. 200 A$=INKEY$:IFA$=""THEN230
  10. 202 PRINT@T," ":PRINT@T+40," ":PRINT@T-40," "
  11. 205 IFA$="D"THENU=U+1:T=T+1:B=0:IFU>20THENT=T-1
  12. 206 IFA$="A"THENU=U-1:T=T-1:B=1:IFU<0THENT=T+1
  13. 210 IFA$="S"THENT=T+40:IFT>242+UTHENT=242+U
  14. 220 IFA$="W"THENT=T-40:IFT<42+UTHENT=42+U
  15. 230 PRINT@T,R$:PRINT@T+40,R$:PRINT@T-40,R$:RETURN
  16. 300 IFX>38THENC=-1:SOUND6000,1
  17. 310 IFX<1THENC=1:SOUND6000,1
  18. 320 IFY>6THENB=-B:IFB<>0THENSOUND4000,1
  19. 330 IFY<1THENB=-B:IFB<>0THENSOUND4000,1
  20. 340 PRINT@A," ":X=X+C:Y=Y+B
  21. 351 IFY<0THENY=0
  22. 355 A=X+Y*40:IFPEEK(A-512)=234THENSOUND5000,1:C=-C
  23. 356 IFX<1THEN110
  24. 360 PRINT@A,B$:RETURN
  25. 400 CLS:DEFINTA-Z:NS$=CHR$(27)+CHR$(86):R$=CHR$(234):B$=CHR$(225):PRINTNS$
  26. 420 PRINTTAB(10)"PING PONG BREAKOUT":PRINTTAB(10)"------------------":PRINT:PRINT"  Please press CAPS-LOCK.":PRINT"Instructions?":GOSUB1000
  27. 440 IFA$="N"THENCLS:GOTO500
  28. 450 CLS:PRINT"    Press 'W' to move the paddle up.":PRINTTAB(10)"'A' to move backwards":PRINTTAB(10)"'S' to move down,":PRINTTAB(10)"And 'D' to move forwards."
  29. 455 PRINT"  Forward straightens ball's path, back-wards returns to angles.  Knock out all"
  30. 460 PRINT"Bricks!  The new  balls will  come in atthe same angle the old one left.":GOSUB1000
  31. 500 CLS:U=0:P=1:C=1:B=1:T=42:X=2:Y=1:FORJ=0TO7:FORK=30TO39:PRINT@J*40+K,R$:NEXT:NEXT:RETURN
  32. 600 FORJ=30TO310STEP40:FORK=0TO9
  33. 610 IFPEEK(J+K-512)=234THENSOUND10000,20:PRINT@160,"YOU LOSE!":GOTO2000
  34. 620 NEXT:NEXT
  35. 630 PRINT@160,"YOU WIN!!":BEEP:GOTO2000
  36. 1000 A$=INKEY$:IFA$=""THEN1000
  37. 1010 RETURN
  38. 2000 FORJ=1TO1500:NEXT:PRINT@296,"Run":PRINT@314," Menu"
  39. 2010 GOSUB1000:IFA$="R"THEN500ELSEIFA$="M"THENMENUELSE2000
  40.