home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / milton.ba < prev    next >
Text File  |  2006-10-19  |  4KB  |  65 lines
  1. 0 'Milton, v1.0 by Mark Lutton 12/19/85
  2. 1 'You might think this is similar to an electronic game made by Milton Bradley a few years ago.
  3. 2 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  4. 40 CLS:PRINT:PRINT:PRINT "                 MILTON":PRINT"Adapted for Tandy 100/200 by Mark Lutton":PRINT
  5. 50 CLEAR 1000
  6. 60 DEFINT A-Z:DIM S1$(9), S2$(9),N$(10),S(10),R(9),Q$(9),V$(9)
  7. 70 RESTORE 7000:FOR I=0 TO 9:READ Q$(I),V$(I):NEXT I
  8. 100 PRINT "Would you like instructions?";:GOSUB 5000:PRINT A$:IF A$="N" OR A$="n" THEN 120
  9. 110 IF A$<>"Y" AND A$<>"y" THEN 100:ELSE GOSUB 9000
  10. 120 INPUT "How many players (1 to 9)";NN:IF NN<1 OR NN>9 GOTO 120
  11. 130 FOR P=1 TO NN
  12. 140 PRINT "Name of player ";P;:INPUT "";N$(P):NEXT:F=0
  13. 150 CLS:PRINT"Here are the phrases.  Watch carefully!"
  14. 160 RESTORE 8000:FOR I=1 TO 10
  15. 170 READ S1$,S2$:PRINT S1$;" ";S2$
  16. 180 GOSUB 5100:NEXT
  17. 190 PRINT:PRINT "      Hit any key to begin!":GOSUB 5000
  18. 1000 CLS:FOR I=1 TO 10:S(I)=0:NEXT
  19. 1010 FOR I=0 TO 9:R(I)=I:NEXT
  20. 1020 FOR I=9 TO 1 STEP -1:J=RND(1)*I:K=R(I):R(I)=R(J):R(J)=K:NEXT
  21. 1030 RESTORE 8000:FOR I=0 TO 9:K=R(I):READ S1$(K),S2$(K):NEXT
  22. 1040 FOR I=0 TO 9:R(I)=0:NEXT:G=0
  23. 1050 F=F+1:IF F>NN THEN F=1
  24. 1060 P=F:PRINT "This time ";N$(P);" goes first.":GOSUB 5100
  25. 2000 IF G=10 THEN 3000
  26. 2010 R=RND(1)*10:IF R(R)=1 THEN 2010
  27. 2020 CLS:PRINT "It's your turn, ";N$(P)
  28. 2030 PRINT S1$(R);"... ";
  29. 2040 GOSUB 5000:A=ASC(A$)-ASC("0"):IF A<0 OR A>9 THEN 2040
  30. 2050 PRINT S2$(A)
  31. 2060 T = RND(1)*10:IF R=A THEN 2080
  32. 2070 PRINT Q$(T):GOSUB 5600:GOTO 2090
  33. 2080 PRINT V$(T):GOSUB 5500:S(P)=S(P)+10:R(R)=1:G=G+1
  34. 2090 GOSUB 5100
  35. 2100 P=P+1:IF P<=NN THEN 2000
  36. 2110 P=1:GOTO 2000
  37. 3000 CLS:PRINT "End of this round.  Scores:"
  38. 3010 FOR I=1 TO NN:PRINT N$(I);":  ";S(I):NEXT
  39. 3020 PRINT "Play again?";:GOSUB 5000:PRINT A$:IF A$="Y" OR A$="y" THEN 1000:ELSE IF A$="N" OR A$="n" THEN 3030:ELSE GOTO 3020
  40. 3030 MENU
  41. 5000 A=RND(1):A$=INKEY$:IF A$<>"" THEN 5000
  42. 5010 A=RND(1):A$=INKEY$:IF A$="" THEN 5010
  43. 5020 RETURN
  44. 5100 FOR L=1 TO 3000:NEXT:RETURN
  45. 5500 SOUND 6269,4:SOUND 4697,4:SOUND3728,4:SOUND3134,8:SOUND3728,4:SOUND3134,8:RETURN
  46. 5600 FOR I=8000 TO 15000 STEP 300:SOUND I,1:NEXT:FOR J=1 TO 5:SOUND I,2:NEXT
  47. 5610 RETURN
  48. 7000 DATA "RIDICULOUS!","CORRECT!","That's ABSURD!","Right!","Impossible!","Absolutely RIGHT!"
  49. 7010 DATA "No way, Jose!","Out of sight!","Uh-uh.  Sorry.","Way to go!!","Yukko!","You got it!"
  50. 7020 DATA "That doesn't make sense!","Absolutely Correct!","HUH??? WHAT???!!","Yee-Haw!","Perish forbid!!","Indubitably!"
  51. 7030 DATA "Ludicrous!","Very good!"
  52. 8000 DATA "Drive your","car.","Flush your","toilet.","Roast a","turkey.","Crack your","whip."
  53. 8010 DATA "Kiss my","lips.","Lick a","stamp.","Pet your","kitty cat.","Floss your","teeth."
  54. 8020 DATA "Read a","book.","Wear your","hat."
  55. 8030 REM You can put in other sentences if you want, but nothing NASTY!
  56. 9000 CLS:PRINT "MILTON is a game for 1 to 9 players,    similar to Concentration.  There are 10 short sentences in the program.
  57. 9010 PRINT "Each sentence ending has a number from  0 to 9 and you have to guess what the   numbers are.  Players take turns.       Hit any key to continue."
  58. 9020 GOSUB 5000
  59. 9030 CLS:PRINT "The first part of the sentence is       displayed, for instance:                Drive your ...."
  60. 9040 PRINT "The correct ending is 'car'.  If you    think 5 is 'car', hit the 5 key.  If youthink 0 is 'car', hit 0."
  61. 9045 PRINT "Hit any key to continue.":GOSUB 5000
  62. 9055 CLS:PRINT"You get 10 points for each correct      guess and no points for wrong guesses."
  63. 9060 PRINT "Clear as mud?  Good.  Let's play.       Hit any key.":GOSUB 5000
  64. 9070 RETURN
  65.