home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
gam
/
lander.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
3KB
|
70 lines
0 'Club 100 Library - 415/939-1246 BBS 937-5039 NEWSLETTER, 932-8856 VOICE
20 'Lander.ba, M100 version by Russ Hall
30 CLEAR 500:DIMY(50)
50 X$=STRING$(40,"*")
60 M$=" - - - - - - LUNAR LANDER - - - - -"
70 CLS:PRINTX$;:PRINTM$:PRINTX$
75 FOR T=1TO500:NEXT
80 FOR N=1TO9:READD$
90 FOR X=1TOLEN(D$):PRINTMID$(D$,X,1);
100 FOR T=1TO10:NEXT
110 NEXTX:PRINT:NEXTN
120 DATA You are the pilot of a lunar-lander mod-ule. Your objective is
130 DATA "to land the module and crew safely on the surface of the moon."
140 DATA ,"You must retro-fire your engines in order to control your rate of descent."
150 DATA "There is, of course, the risk of chrashing; either because the rate"
160 DATA "of descent is too high, or you've burned all the available fuel.
180 DATA, "Three things can happen to you, and two of them are bad."
190 FOR T=1TO500:NEXTT
200 DATA "Keep cool, and control the module by entering burn-rate values."
210 TX=60:PX=120:MX$="WARNING:":CLS:GOSUB770
215 PRINT:PRINT"Burn rates of 75 or more DESTROY THE ENGINES."
230 PRINT"Strike any key to begin..."
235 FORTI=1TOVAL(RIGHT$(TIME$,2)):A=RND(1):NEXT
240 K$=INKEY$:IFK$=""THEN240
260 A$="Altitude:":S$="Speed:":F$="Fuel:":B$="Burn rate:":R$="Rising.":D$="Descending."
306 A=480+INT(100*(RND(1)*40))/100
308 F=245+INT(100*(RND(1)*25))/100
310 S=40+INT(100*(RND(1)*10))/100
320 BR=0:I$="":I$=I$+"INSTRUMENT PANEL"
360 CLS:PRINTM$:PRINT@50,I$:PRINTTAB(10)A$;A
390 PRINTTAB(10)F$;F:PRINTTAB(10)S$;S:PRINTTAB(10)B$;BR:IFF<=0THENBR=0:GOTO500
430 PRINT"You're ";:IFS>=0THENPRINTD$
450 IFS<0THENPRINTR$
460 PRINT@260,"Enter burn rate";:INPUT"";BR
480 BR=BR+.1:IFBR<0THEN460
490 IF BR>=75THEN680
500 F=F-BR:IFF<=0THEN730
510 S=S+10-BR:A=A-S:IM=(A+S*2+10)/10
530 IFA>=0THEN580
540 GOSUB1000:CLS:PRINTM$
550 PRINT@165,"You have buried the ship"IM
560 PRINT"meters into the lunar surface.":GOTO610
580 IFIM>3THEN360
590 CLS:PRINTM$:TX=60:PX=164:MX$="** YOU HAVE LANDED THE SHIP **":GOSUB770
605 FORN=1TO500:NEXT:GOTO900
610 FORN=1TO1000:NEXT
620 PRINT:PRINT"Do you want to try again?"
630 K$=INKEY$:IF K$=""THEN630
650 IFK$="N"ORK$="n"THENMENU
660 IFK$="Y"ORK$="y"THEN260
670 GOTO630
680 CLS:PRINTM$
690 TX=60:PX=170:MX$="BURN RATE IS TOO HIGH":GOSUB 770
700 PRINT:PRINT"THIS HAS COMPLETELY DESTROYED YOUR SHIP"
710 FORF=1TO1000:NEXT:GOTO610
730 TX=60:PX=240:MX$=" YOU HAVE EXHAUSTED THE FUEL SUPPLY ":GOSUB770
750 FOR T=1TO1000:NEXT:GOTO540
770 FOR T=1TOTX
780 IFINT(T/5)/2=INT(INT(T/5)/2)THENPRINT@PX,MX$;:GOTO800
790 PRINT@PX,STRING$(LEN(MX$),32);
800 NEXT:RETURN
900 IFF<90THENPRINT:PRINT:PRINT"However, you haven't enough fuel to take off again from the lunar surface."
910 IFF<90THENPRINT"Welcome to your new home...":GOTO620
920 PRINT:PRINT:PRINT" Your skill rating is"INT(F*10-S*10):GOTO620
1000 CLS:X=300
1040 FORS=5TO11:PRINT@X,"-CRASH!-"
1055 FORV=5TOS+5:Z=INT(RND(1)*20)+30:Y(S)=X-Z
1090 PRINT@Y(V),"-CRASH!-":NEXTV:NEXTS
1130 PRINT@X,"-CRASH!-";:FORT=1TO500:NEXT:RETURN