home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / haunt.ba < prev    next >
Text File  |  2006-10-19  |  8KB  |  175 lines
  1. 0 'HAUNT.BA Barry Gaskins
  2. 1 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  3. 10 REM
  4. 100 CLS:PRINT"DO YOU WANT INSTRUCTIONS? (Y/N)":ZZ$=INPUT$(1):IFZZ$="N"ORZZ$="n"THEN120
  5. 110 GOSUB170
  6. 120 CLEAR(300):GOSUB480
  7. 130 REM
  8. 140 GOSUB620
  9. 150 GOSUB750
  10. 160 GOTO130
  11. 170 REM
  12. 190 PRINT"              HAUNTED HOUSE"
  13. 200 PRINT"            BY BARRY GASKINS"
  14. 210 PRINT"ANY KEY TO CONTINUE"
  15. 220 ZZ$=INPUT$(1)
  16. 240 PRINT"           HAUNTED HOUSE"
  17. 250 PRINT"YOU ARE LOST IN THE WOODS AND ARE AT THE ENTRANCE TO A STRANGE LOOKINGHOUSE.    LOOKING FOR HELP AND FOOD YOU"
  18. 280 PRINT"DECIDE TO GO IN...  SUDDENLY THE DOOR":INPUTZZ$
  19. 290 PRINT"SLAMS SHUT. YOU HEAR AN EVIL LAUGH AND"
  20. 300 PRINT"A VOICE COMMING FROM THE VERY WALLS"
  21. 310 PRINT"    'YOU WILL NEVER LEAVE THIS "
  22. 320 PRINT"HOUSE. YOU WILL STAY FOREVER TO":INPUTZZ$
  23. 330 PRINT"WALK ITS ROOMS AND HALLS. HEAR THESE    WORDS AND KNOW YOUR "
  24. 350 PRINT"     DOOM!!!!! HA HA HA HA...."
  25. 360 ZZ$=INPUT$(1)
  26. 380 CLS:PRINT"LOOKING AROUND YOU SEE THAT THERE ARE   SEVERAL EXITS BUT NO WINDOWS.           MAYBE YOU HAVE A CHANCE?"
  27. 410 PRINT"IF YOU TELL ME WHAT YOU WANT TO DO I    WILL TELL YOU WHAT IS HAPPENING. AND IF YOU NEED HELP JUST TYPE HELP IN PLACE OF YOUR COMMAND"
  28. 450 ZZ$=INPUT$(1)
  29. 470 RETURN
  30. 480 DIMS(13):DIMS$(13):L=1
  31. 490 DIMR$(13):DIME$(13):DIMCO$(14)
  32. 500 FORX=1TO13:S(X)=X:READS$(X):NEXT
  33. 510 FORX=1TO13:READR$(X):NEXT
  34. 520 FORX=1TO12:READE$(X):NEXT
  35. 530 FORX=1TO14:READCO$(X):NEXT
  36. 540 RETURN
  37. 550 DATA   ROPE,SWORD,KEY,BUCKET OF WATER,RUG,WAND,MOLDY FOOD,WINE,KEGS,ASHES,ROCKS,LEAVES,NULL
  38. 560 DATA  THE DEN,A TROPHY ROOM,THE SERVANTS QUARTERS,THE DINING ROOM,THE KITCHEN,THE CELLAR,A STORAGE ROOM,THE WINE CELLAR,AGING ROOM,A NARROW PASSAGE,A HUGE CAVE,A SMALL CAVE,THE OUTSIDE WORLD
  39. 570 DATA SOUTH EAST AND WEST,WEST,NORTH,NORTH,SOUTH AND EAST
  40. 580 DATA UP AND EAST,SOUTH,WEST EAST AND NORTH,WEST
  41. 590 DATA  EAST AND WEST,EAST AND WEST,WEST
  42. 600 DATA NORTH,SOUTH,EAST,WEST,UP,DOWN
  43. 610 DATA GET,DROP,USE,OFFER,DRINK,SEARCH,ATTACK WITH,INVENTORY
  44. 620 CLS:PRINT"YOU ARE IN "R$(L)
  45. 630 PRINT"VISIBLE ITEMS: ";
  46. 640 FORX=1TO13:IFS(X)=LTHENPRINTS$(X)" ";
  47. 650 NEXT:PRINT
  48. 660 PRINT"YOU SEE EXITS "E$(L)
  49. 670 IFL=6ANDNOTF2THENPRINT"THERE IS A GHOST IN THIS ROOM !!!"
  50. 680 IFL=10ANDNOTF4THENPRINT"A WALL OF FIRE BLOCKS YOUR WAY !!!"
  51. 690 IFL=11ANDNOTF5THENPRINT"THERE IS A HUGE HUNGRY GIANT IN HERE"
  52. 700 IFL=12THENPRINT"THERE IS A HOLE IN THE CEILING AND YOU  CAN SEE THE OPEN SKY ABOVE !!!"
  53. 710 RETURN
  54. 720 PRINT"LEGAL COMMANDS ARE:"
  55. 730 FORX=1TO6:PRINT"     "CO$(X):NEXT:FORX=7TO13:PRINT"    "CO$(X)" SOMETHING":NEXT:PRINT"    "CO$(14):PRINT
  56. 740 PRINT"I ONLY LOOK AT THE FIRST 3 LETTERS OF   EACH WORD SO YOU ONLY NEED TO TYPE THE  FIRST 3 LETTERS ":GOTO1890
  57. 750 REM
  58. 760 INPUT"WHAT DO YOU WANT TO DO ";DO$
  59. 770 IFDO$="UP"THENX=5:GOTO810
  60. 780 IFLEN(DO$)<3THEN720
  61. 790 FORX=1TO14:IFLEFT$(DO$,3)=LEFT$(CO$(X),3)THEN810
  62. 800 NEXT:GOTO720
  63. 810 IFX<7THEN910
  64. 820 IFX=14THEN1320
  65. 830 IFX=7THEN1360
  66. 840 IFX=8THEN1470
  67. 850 IFX=9THEN1530
  68. 860 IFX=11THEN1590
  69. 870 IFX=10THEN1640
  70. 880 IFX=12THEN1690
  71. 890 IFX=13THEN1750
  72. 900 GOTO720
  73. 910 ONLGOTO920,970,990,1010,1030,1070,1110,1130,1170,1200,1230,1270
  74. 920 IFX=1THEN1350
  75. 930 IFX=2THENL=3:RETURN
  76. 940 IFX=3THENL=2:RETURN
  77. 950 IFX=4THENL=5:RETURN
  78. 960 GOTO1350
  79. 970 IFX=4THENL=1:RETURN
  80. 980 GOTO1350
  81. 990 IFX=1THENL=1:RETURN
  82. 1000 GOTO1350
  83. 1010 IFX=1THENL=5:RETURN
  84. 1020 GOTO1350
  85. 1030 IFX=2THENL=4:RETURN
  86. 1040 IFX=3THENL=1:RETURN
  87. 1050 IFX=6ANDF1THENL=6:RETURN
  88. 1060 GOTO1350
  89. 1070 IFX=3ANDF2THENL=8:RETURN
  90. 1080 IFX=3THENPRINT"THE GHOST BLOCKS YOUR WAY !"
  91. 1090 IFX=5THENL=5:RETURN
  92. 1100 GOTO1350
  93. 1110 IFX=2THENL=8:RETURN
  94. 1120 GOTO1350
  95. 1130 IFX=1THENL=7:RETURN
  96. 1140 IFX=3THENL=9:RETURN
  97. 1150 IFX=4THENL=6:RETURN
  98. 1160 GOTO1350
  99. 1170 IFX=3ANDF3THENL=10:RETURN
  100. 1180 IFX=4THENL=8:RETURN
  101. 1190 GOTO1350
  102. 1200 IFX=3ANDF4THENL=11:RETURN
  103. 1210 IFX=4THENL=9:RETURN
  104. 1220 GOTO1350
  105. 1230 IFX=3ANDF5THENL=12:RETURN
  106. 1240 IFX=4THENL=10:RETURN
  107. 1250 IFX=3THENPRINT"YOU WERE BURNED UP IN THE FIRE":GOTO1820
  108. 1260 GOTO1350
  109. 1270 IFX=4THENL=11:RETURN
  110. 1280 IFX=5ANDF6THEN1300
  111. 1290 GOTO1350
  112. 1300 CLS:PRINT"YOU MADE IT OUT  ALIVE !!!"
  113. 1310 PRINT"GOOD JOB ":END
  114. 1320 CLS:PRINT"  INVENTORY:"
  115. 1330 FORX=1TO13:IFS(X)=0THENPRINTS$(X)
  116. 1340 NEXT:GOTO1890
  117. 1350 PRINT" YOU CANT GO THAT WAY":GOTO1890
  118. 1360 DO$=DO$+" ":N=LEN(DO$)-1:FORX=1TON:IFLEFT$(DO$,1)=" "THENX=N
  119. 1370 DO$=RIGHT$(DO$,LEN(DO$)-1)
  120. 1380 NEXT:IFLEN(DO$)<2THEN1430
  121. 1390 DO$=LEFT$(DO$,LEN(DO$)-1):IFLEN(DO$)<3THEN1430
  122. 1400 FORX=1TO13:IFLEFT$(DO$,3)=LEFT$(S$(X),3)THEN1420
  123. 1410 NEXT:GOTO1430
  124. 1420 IFS(X)=LTHENS(X)=0:GOTO1440
  125. 1430 PRINT"I SEE NO "DO$" HERE":GOTO1890
  126. 1440 IFDO$="RUG"ANDNOTF1THENF1=1:PRINT" THERE WAS A TRAPDOOR UNDER THE RUG !":PRINT:E$(5)="DOWN "+E$(5):GOTO1890
  127. 1450 IFX=9THENS(X)=L:PRINT"THE KEGS ARE MUCH TOO BIG TO CARRY":GOTO1890
  128. 1460 RETURN
  129. 1470 DO$=DO$+" ":N=LEN(DO$):FORX=1TON:IFLEFT$(DO$,1)=" "THENX=N
  130. 1480 DO$=RIGHT$(DO$,LEN(DO$)-1):NEXT:IFLEN(DO$)<2THEN1520
  131. 1490 DO$=LEFT$(DO$,LEN(DO$)-1):IFLEN(DO$)<3THEN1520
  132. 1500 FORX=1TO13:IFLEFT$(DO$,3)=LEFT$(S$(X),3)ANDS(X)=0THENS(X)=L:RETURN
  133. 1510 NEXT
  134. 1520 PRINT"YOU DONT HAVE A "DO$:GOTO1890
  135. 1530 REM 
  136. 1540 GOSUB1840:IFLEN(DO$)<3THEN1580
  137. 1550 IFLEFT$(DO$,3)="KEY"ANDS(3)=0ANDL=9ANDFOTHENPRINT"YOU OPENED THE KEG TO REVEAL A PASSAGE!":F3=1:E$(9)=E$(9)+" AND EAST":GOTO1890
  138. 1560 IFLEFT$(DO$,3)="BUC"ANDL=10ANDS(4)=0THENPRINT"THE WATER PUT THE FIRE OUT":F4=1:GOTO1890
  139. 1570 IFLEFT$(DO$,3)="ROP"AND(S(1)=0ORS(1)=L)ANDL=12THENF6=1:E$(12)=E$(12)+" AND UP":PRINT"YOUR ROPE CATCHES SOMETHING OUTSIDE":GOTO1890
  140. 1580 PRINT"THAT HAD NO USEFUL EFFECT ":GOTO1890
  141. 1590 REM
  142. 1600 GOSUB1840:IFLEN(DO$)<3THEN1630
  143. 1610 IFLEFT$(DO$,3)="WIN"AND(S(8)=0ORS(8)=L)THENPRINT"WHILE YOU WERE DRUNK A TROLL CAME BY    AND ATE YOU ":GOTO1820
  144. 1620 IF(LEFT$(DO$,3)="BUC"ORLEFT$(DO$,3)="WAT")AND(S(4)=0ORS(4)=L)THENPRINT"THE WATER WAS POISON":GOTO1820
  145. 1630 PRINT"I SEE NOTHING TO DRINK AROUND HERE":GOTO1890
  146. 1640 REM
  147. 1650 IFNOT(L=6ORL=11)THENPRINT"THERE IS NOBODY HERE TO OFFER ANYTHING":GOTO1890
  148. 1660 IFL=6THENPRINT"THE GHOST DOESNT WANT IT":GOTO1890
  149. 1670 GOSUB1840:IFLEFT$(DO$,3)="WIN"ANDS(8)=0THENPRINT"THE GIANT DRINKS THE WINE AND FALLS     OVER ON THE FLOOR DRUNK":F5=1:GOTO1890
  150. 1680 PRINT"THE GIANT GETS MAD AND THROWS A ROCK AT YOU. ":GOTO1820
  151. 1690 REM
  152. 1700 GOSUB1840
  153. 1710 IFLEN(DO$)<3THEN1740
  154. 1720 IFLEFT$(DO$,3)="RUG"ANDL=5THENPRINT"THERE WAS A TRAPDOOR UNDER THE RUG !!":E$(5)="DOWN "+E$(5):F1=1:GOTO1890
  155. 1730 IFLEFT$(DO$,3)="KEG"ANDL=9THENPRINT"YOU FOUND A KEYHOLE IN ONE OF THE KEGS!":FO=1:GOTO1890
  156. 1740 PRINT" THERE IS NOTHING SPECIAL ABOUT THAT":GOTO1890
  157. 1750 REM
  158. 1760 DO$=" "+DO$:N=LEN(DO$):FORX=NTO1STEP-1:IFMID$(DO$,X,1)=" "THENDO$=RIGHT$(DO$,N-X):FORX=1TO13:IFLEFT$(S$(X),3)=LEFT$(DO$,3)THEN1780
  159. 1770 NEXT:GOTO1810
  160. 1780 IFLEFT$(DO$,3)="SWO"ANDS(2)=0ANDL=6THENF2=1:PRINT"THE GHOST IS DEAD !!!":GOTO1890
  161. 1785 IFLEFT$(DO$,3)="SWO"ANDS(2)<>0THEN1810
  162. 1790 IFL=11THENPRINT"THE GIANT GRABBED YOU AND SQUEEZED YOU   TO DEATH !!!":GOTO1820
  163. 1800 PRINT"THERE IS NOTHING TO ATTACK":GOTO1890
  164. 1810 PRINT"YOU DONT HAVE ONE OF THOSE ":GOTO1890
  165. 1820 PRINT"OH NO .....":PRINT"YOU DIED ":INPUT"DO YOU WANT TO PLAY AGAIN?";A$:IFLEFT$(A$,1)="N"THENEND
  166. 1830 GOTO10
  167. 1840 DO$=DO$+" ":N=LEN(DO$)-1:FORX=1TON:IFLEFT$(DO$,1)=" "THENX=N
  168. 1850 DO$=RIGHT$(DO$,LEN(DO$)-1)
  169. 1860 NEXT:IFLEN(DO$)<2THEN1880
  170. 1870 DO$=LEFT$(DO$,LEN(DO$)-1):IFLEN(DO$)<3THEN1880
  171. 1880 RETURN
  172. 1890 REM
  173. 1900 PRINT"HIT RETURN TO CONTINUE":ZZ$=INPUT$(1)
  174. 1920 RETURN
  175.