home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / fortun.ba < prev    next >
Text File  |  2006-10-19  |  4KB  |  83 lines
  1. 0 'FORTUN.BA author unknown
  2. 1 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  3. 10 DEFINTA-O,Q-Z
  4. 20 CLS:X=113:Y=30:X1=130:Y1=30
  5. 30 FORZ=1TO25
  6. 40 LINE(X,Y)-(X1,Y1),1,B
  7. 50 IFZ<16THENLINE(X,Y)-(X1,Y1),0,B
  8. 60 X=X-1:Y=Y-1:X1=X1+1:Y1=Y1+1
  9. 70 NEXT
  10. 80 PRINT@13,"WHEEL of FORTUNE":GOSUB760:PRINT@293,"with VANNA and PAT":GOSUB760
  11. 90 CLS: PRINT@169,"How Many Players ";:N$=INPUT$(1):IFVAL(N$)>3ORVAL(N$)<1THEN90ELSEN=VAL(N$)
  12. 100 CLS:PRINT"Secret Phrase":LINEINPUTA$:IFLEN(A$)>39ORLEN(A$)<1THEN100
  13. 110 IFA$="END"ORA$="end"THENMENUELSEA$=" "+A$
  14. 120 L=LEN(A$):H=1:P(1)=0:P(2)=0:P(3)=0:B$=SPACE$(L):D$=SPACE$(40):B=0:L1=INT((40-L)/2)
  15. 130 FORZ=1TOL:T$=MID$(A$,Z,1):IFT$>="a"ANDT$<="z"THENMID$(A$,Z,1)=CHR$(ASC(T$)-32)
  16. 140 NEXT
  17. 150 CLS:AB$="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  18. 160 FORZ=1TOL:IFMID$(A$,Z,1)<>" "THENMID$(B$,Z,1)=CHR$(157)
  19. 170 IFMID$(A$,Z,1)="'"THENMID$(B$,Z,1)="'"
  20. 180 IFMID$(A$,Z,1)="-"THENMID$(B$,Z,1)="-"
  21. 190 NEXT
  22. 200 FORZ=1TOL:T$=MID$(A$,Z,1):IFINSTR("AEIOU '-",T$)>0THENB=B+1
  23. 210 NEXT:B=L-B:CLS
  24. 220 FORZ=1TON:PRINT@150+13*Z,"PLAYER"Z:NEXT
  25. 230 PRINT@80+L1,B$
  26. 240 PRINT@241,"Unused >"AB$:PRINT@120+L1,CHR$(148)
  27. 250 FORZ=1TON:PRINT@190+13*Z,USING"######";P(Z):NEXT
  28. 260 PRINT@149+13*H,CHR$(27);"p";" PLAYER";H;CHR$(27);"q"
  29. 270 PRINT@280,CHR$(27)"p""Spin";:PRINT@285,"Vowel";:PRINT@291,"Guess"CHR$(27)"q";
  30. 280 IFB$=A$THEN730
  31. 290 IFB<>0THEN310
  32. 300 PRINT@170,"ONLY VOWELS ARE LEFT":FORZ=1TO8:SOUND4E3,8:NEXT:GOSUB770:PRINT@171,"Buy Vowel or Guess":KEY(2)ON:KEY(3)ON:GOTO320
  33. 310 KEYON
  34. 320 ONKEYGOSUB340,520,650
  35. 330 GOTO320
  36. 340 PRINT@0,D$;D$:PRINT@1,"SPINNING":T=VAL(RIGHT$(TIME$,2)):FORZ=1TOT:R=RND(1):NEXTZ
  37. 350 FORZ=1TO18:FORY=112TO113:V=(RND(1)*35+1):PRINTCHR$(27)CHR$(Y):PRINT@10,USING"#####";V*50:SOUND10,1:NEXTY,Z
  38. 360 IFV=21THENGOSUB770:PRINT@41,"LOSE YOUR TURN":SOUND8E3,50:GOSUB770:GOSUB780:GOTO230
  39. 370 IFV=19THENGOSUB770:PRINT@46,"BANKRUPT":P(H)=0:SOUND8E3,50:GOSUB770:GOSUB780:GOTO230
  40. 380 IFV=29THENV=2E3ELSEV=V*50
  41. 390 GOSUB770:PRINT@0,"    Value >";V:PRINT@24,">Select Letter":I$=INKEY$
  42. 400 I$=INKEY$:IFI$=""THEN400
  43. 410 IFI$>="a"ANDI$<="z"THENI$=CHR$(ASC(I$)-32)
  44. 420 IFINSTR("AEIOU",I$)>0ORASC(I$)<65ORASC(I$)>90THEN400
  45. 430 IFMID$(AB$,ASC(I$)-64,1)=" "THENGOSUB770:PRINT@173,"ALREADY CHOSEN":GOSUB760:GOSUB780:GOTO230
  46. 440 FORZ=1TOL:PRINT@119+Z+L1,CHR$(148)
  47. 450 IFMID$(A$,Z,1)=I$THENP(H)=P(H)+V:MID$(B$,Z,1)=I$:B=B-1:D=1:SOUND1E4,10
  48. 460 PRINT@80+L1,B$:PRINT@119+Z+L1," "
  49. 470 NEXTZ:MID$(AB$,ASC(I$)-64,1)=" ":GOSUB790:GOSUB770
  50. 480 IFD=1THEND=0:GOTO230
  51. 490 GOSUB770:PRINT@174,CHR$(27)"p";" ";I$;" ";CHR$(27)"q";" Not Found":D=0:GOSUB760:GOSUB780
  52. 500 IFN=1THENP(H)=P(H)-V/2:IFP(H)<0THENP(H)=0
  53. 510 GOTO230
  54. 520 IFP(H)<250THENGOSUB 770:PRINT@171,"NEED $250 MINIMUM":GOSUB760:GOTO270
  55. 530 GOSUB770:PRINT@174,"Select Vowel":I$=INKEY$
  56. 540 I$=INKEY$:IFI$=""THEN540
  57. 550 IFI$>="a"ANDI$<="z"THENI$=CHR$(ASC(I$)-32)
  58. 560 IFINSTR("AEIOU",I$)<1THEN540
  59. 570 IFMID$(AB$,ASC(I$)-64,1)=" "THENPRINT@173,"ALREADY CHOSEN":P(H)=P(H)-250:GOSUB760:GOSUB780:GOTO230
  60. 580 MID$(AB$,ASC(I$)-64,1)=" ":P(H)=P(H)-250
  61. 590 FORZ=1TOL:PRINT@119+Z+L1,CHR$(148)
  62. 600 IFMID$(A$,Z,1)=I$THENMID$(B$,Z,1)=I$:D=1:SOUND1E4,10
  63. 610 PRINT@80+L1,B$:PRINT@119+Z+L1," "
  64. 620 NEXTZ:GOSUB790:GOSUB770
  65. 630 IFD=1THEND=0:GOTO230
  66. 640 GOSUB770:PRINT@174,CHR$(27)"p";" ";I$;" ";CHR$(27)"q";" Not Found":D=0:GOSUB760:GOSUB780:GOTO220
  67. 650 GOSUB770:IFB$=A$THENC$=A$:GOTO 400ELSEPRINT@166,"Enter Guess   Type Carefully"
  68. 660 C$=B$:FORZ=1TOL
  69. 670 IFMID$(C$,Z,1)<>CHR$(157)THENPRINT@39+Z+L1,MID$(C$,Z,1):GOTO710
  70. 680 PRINT@39+Z+L1,"";:E$=INPUT$(1)
  71. 690 IFE$>="a"ANDE$<="z"THENE$=CHR$(ASC(E$)-32)
  72. 700 MID$(C$,Z,1)=E$:PRINT@39+Z+L1,E$
  73. 710 NEXTZ:IFC$<>A$THEN740
  74. 720 IFP(H)<250THENP(H)=250
  75. 730 GOSUB770:BEEP:BEEP:PRINT@170,"** YOU WIN $"P(H)"**":GOSUB800:GOTO100
  76. 740 GOSUB770:SOUND16E3,25:PRINT@175,"INCORRECT":GOSUB760:PRINT@40,D$:GOSUB780
  77. 750 GOTO230
  78. 760 FORZ=1TO1500:NEXT
  79. 770 PRINT@160,D$:RETURN
  80. 780 PRINT@149+13*H," PLAYER"H:H=1-H*(H<N):RETURN
  81. 790 FORZ=LTO1STEP-1:PRINT@119+Z+L1,CHR$(148):FORY=1TO50:NEXT:PRINT@119+Z+L1," ":NEXT:PRINT@120+L1,CHR$(148):RETURN
  82. 800 FORZ=1TO4000:NEXT:RETURN
  83.