home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / escape.ba < prev    next >
Text File  |  2006-10-19  |  2KB  |  50 lines
  1. 0 'ESCAPE.100 by Robby DeMarco  2/86
  2. 1 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  3. 2 'mods by Bill Templeton  6/86
  4. 3 CLS:S%=VAL(RIGHT$(TIME$,2)):FORI%=1TOS%:DUMMY=RND(1):NEXTI%:E$=CHR$(27):R$=E$+"p":N$=E$+"q
  5. 4 PRINT@94,R$" Escape.100 "N$:PRINT@168,"Do you need instructions?";
  6. 5 A$=INKEY$:IFA$=""THEN5
  7. 6 IFA$="Y"ORA$="y"THENGOSUB38
  8. 7 CLS:FL=0:CALL16959:FORI=0TO39:PRINT@I,CHR$(239):PRINT@I+280,CHR$(239):NEXTI:FORI=0TO319STEP40
  9. 8 PRINT@I,CHR$(239):PRINT@I+39,CHR$(239):NEXTI
  10. 9 CE=INT(RND(1)*320):IFPEEK(65024+CE)=32THEN9
  11. 10 PRINT@CE,CHR$(255):PP=175:PP$=CHR$(144)
  12. 11 EC=INT(RND(1)*320):IFPEEK(65024+EC)<>32THEN11
  13. 12 PRINT@EC,CHR$(150)
  14. 13 IFFL=1THENPRINT@CE,CHR$(224)
  15. 14 A$=INKEY$:IFA$=""THENA$="L
  16. 15 A=ASC(A$):IFA=28THENPO=1
  17. 16 IFA=29THENPO=-1
  18. 17 IFA=30THENPO=-40
  19. 18 IFA=31THENPO=40
  20. 19 PP=PP+PO:IFPEEK(65024+PP)=42THEN33
  21. 20 IFPEEK(65024+PP)=239THENPP=PP-PO:PO=-PO
  22. 21 IFPEEK(65024+PP)=255THENPP=PP-PO:PO=-PO
  23. 22 IFPEEK(65024+PP)=224THEN29
  24. 23 IFPEEK(65024+PP)=150THENFL=1
  25. 24 C=INT(RND(1)*320):IFPEEK(65024+C)=42THENPRINT@C," ":GOTO28
  26. 25 IFPEEK(65024+C)=32THEN27
  27. 26 GOTO24
  28. 27 PRINT@C,"*";
  29. 28 PRINT@PP,PP$:FORI=1TO20:NEXTI:PRINT@PP," ":GOTO13
  30. 29 FORI=41TO241STEP40:PRINT@I,STRING$(38," "):NEXT:FORI=0TO10000STEP500:SOUNDI,5:PRINT@95,R$" ESCAPED "N$:NEXTI:GOSUB37
  31. 30 IFINKEY$<>""THEN30
  32. 31 A$=INKEY$:IFA$=CHR$(13)THENMENUELSEIFA$<>""THEN7
  33. 32 GOTO31
  34. 33 FORI=3000TO2600STEP-50:PRINT@PP,R$PP$:SOUNDI,5:PRINT@PP,N$PP$:FORC=1TO20:NEXT:NEXTI:SOUND2000,100:GOSUB37
  35. 34 IFINKEY$<>""THEN34
  36. 35 A$=INKEY$:IFA$=CHR$(13)THENMENUELSEIFA$<>""THEN7
  37. 36 GOTO35
  38. 37 PRINT@164,"Any key to play, <ENTER> for menu":RETURN
  39. 38 GOSUB48
  40. 39 PRINT" OBJECT - The object of this game is to  get the key("CHR$(150)") so the locked door("CHR$(255)")    will open";
  41. 40 PRINT" and you can leave the arena.  However there are mines(*).  If you     hit one, then you will die.  Use the";
  42. 41 PRINT"    arrow keys to move.  You continue":PRINTR$"        Press any key to continue      "N$;
  43. 42 A$=INKEY$:IFA$=""THEN42
  44. 43 GOSUB48:PRINT" moving in that direction, until you     press another arrow key. Since this is
  45. 44 PRINT" a reflex game, don't get frustrated. It may seem impossible at first, but there is a 4 to 1 chance to win.";
  46. 45 PRINT" Your chances increase as your reflexes improve.":PRINTR$"        Press any key to continue      "N$;
  47. 46 A$=INKEY$:IFA$=""THEN46
  48. 47 RETURN
  49. 48 CLS:PRINT@0,R$"              Instructions              "N$;:RETURN
  50.