home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / crash.ba < prev    next >
Text File  |  2006-10-19  |  10KB  |  180 lines
  1. 0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
  2. 20 GOSUB5000'  INITIALIZE
  3. 30 GOSUB1000'  INPUT
  4. 40 GOSUB2000'  SORT
  5. 45 GOSUB4400'  CHECKS
  6. 50 IFWF=0ANDLF=0THEN30
  7. 60 GOSUB5500' END
  8. 70 END
  9. 1000 VB$="":NO$=""
  10. 1020 INPUT"WHAT DO YOU DO NEXT";R$
  11. 1030 FORI=1TOLEN(R$)
  12. 1040 IFMID$(R$,I,1)=" "THENVB$=LEFT$(R$,3):NO$=MID$(R$,I+1,3):I=LEN(R$)
  13. 1050 NEXTI
  14. 1060 IFNO$<>""THENRETURN
  15. 1070 R$=LEFT$(R$,3)
  16. 1080 IFR$="NOR"ORR$="SOU"ORR$="EAS"ORR$="WES"THENVB$="GO ":NO$=R$:RETURN
  17. 1090 IFR$="HEL"ORR$="INV"ORR$="LOO"ORR$="SLE"THENNO$="DOO":VB$=R$:RETURN
  18. 1100 PRINT"I DON'T UNDERSTAND THAT."
  19. 1110 GOTO1000
  20. 2000 VB=0:NO=0:FORI=1TOVV
  21. 2020 IFVB$=LEFT$(VB$(I),3)THENVB=I:I=VV
  22. 2030 NEXTI
  23. 2040 FORI=1TONN
  24. 2050 IFNO$=NO$(I)THENNO=I:I=NN
  25. 2060 NEXTI
  26. 2070 IFNO=0ORVB=0THENPRINT"I DON'T UNDERSTAND THAT.":RETURN
  27. 2080 ONVBGOTO3000,3100,3200,3300,3400,3500,3620,3700,3800,3900,4000,4200,4300
  28. 3000 ' ************ GO ****************
  29. 3010 IFNO>4THENPRINT"GO WHERE ?":RETURN
  30. 3020 IFEX(CP,NO)=0THENPRINT"NO MOVEMENT POSSIBLE THAT WAY.":RETURN
  31. 3030 IFEX(CP,NO)=99THENLF=2:RETURN
  32. 3035 IF(CP=10ORCP=14ORCP=15)ANDDELAY<2THENDELAY=DELAY+1:GOTO4000ELSEDELAY=0
  33. 3037 IFDARK=1THENLF=8:RETURN
  34. 3040 CP=EX(CP,NO):GOTO4000
  35. 3100 ' ************ GET ***************
  36. 3120 IFNO<7THENPRINT"DON'T BE SILLY.":RETURN
  37. 3130 IFOB(NO-6)=99THENPRINT"YOU'VE ALREADY GOT IT!":RETURN
  38. 3140 IFOB(1)=99ANDOB(9)<>50ANDOB(9)<>99THENOB(9)=3
  39. 3170 IFOB(NO-6)=CPTHENPRINT"O.K.":OB(NO-6)=99:IN=IN+1:RETURN
  40. 3180 PRINT"IT ISN'T HERE!":RETURN
  41. 3200 ' ************** FEED ************
  42. 3210 IFNO<13THENPRINT"DON'T BE SILLY!":RETURN
  43. 3250 IFOB(3)<>99ANDOB(6)<>99THENPRINT"YOU DON'T HAVE ANYTHING TO USE!":RETURN
  44. 3255 IFCP<>4ANDCP<>23THENPRINT"YOU CAN'T HERE.":RETURN
  45. 3260 IFFIRE<>1THENPRINT"IT ISN'T LIT YET!":RETURN
  46. 3265 IFCP=23ANDFI2<>1THENPRINT"IT ISN'T LIT YET!":RETURN
  47. 3270 IFCP=4THENOB(3)=0:PRINT"O.K.":RETURN
  48. 3280 IFCP=23THENOB(6)=0:PRINT"O.K.":LD=LD+1:RETURN
  49. 3300 ' ************* MELT *************
  50. 3305 IFCP<>4THENPRINT"YOU CAN'T HERE!":RETURN
  51. 3310 IFOB(4)<>99THENPRINT"YOU DON'T HAVE ANYTHING TO USE.":RETURN
  52. 3320 IFFIRE<>1THENPRINT"YOU CAN'T... YET.":RETURN
  53. 3325 IFNO<>16THENPRINT"MELT WHAT?":RETURN
  54. 3330 PRINT"O.K.":MELT=1:RETURN
  55. 3400 ' ************* DRINK ************
  56. 3410 IFNO<>17THENPRINT"DRINK WHAT?":RETURN
  57. 3420 IFMELT<>1THENPRINT"YOU DON'T HAVE ANY!":RETURN
  58. 3430 PRINT"THAT'S REFRESHING.":DRINK=1:RETURN
  59. 3500 ' ************** EAT *************
  60. 3510 IFOB(9)<>99THENPRINT"YOU DON'T HAVE ANYTHING":RETURN
  61. 3515 IFNO<>15THENPRINT"EAT WHAT?":RETURN
  62. 3520 PRINT"IT'S HARD BUT TASTES MIGHTY GOOD.":OB(9)=50:RETURN
  63. 3620 ' ************* MAKE *************
  64. 3630 IFNO=13ANDCP<>4THENPRINT"YOU CAN'T HERE.":RETURN
  65. 3640 IFNO=14AND(CP=4ORCP=23)THEN3700
  66. 3650 IFOB(5)<>99THENPRINT"YOU DON'T HAVE ONE.":RETURN
  67. 3660 IFNO=13ANDOB(5)=99THENPRINT"O.K. THAT FEELS BETTER":OB$(5)="SPLINT":RETURN
  68. 3670 PRINT"MAKE WHAT?":RETURN
  69. 3700 ' ************* LIGHT ************
  70. 3710 IFOB(2)<>99THENPRINT"YOU DON'T HAVE ANY MATCHES!":RETURN
  71. 3720 IFCP=4ANDOB(3)<>99THENPRINT"YOU DON'T HAVE ANY FUEL":RETURN
  72. 3730 IFCP=4ANDGAS<>1THENPRINT"THEY WON'T BURN... YET.":RETURN
  73. 3740 IFCP=23ANDOB(6)<>99THENPRINT"YOU DON'T HAVE ANY FUEL":RETURN
  74. 3745 IFCP<>4ANDCP<>23THENPRINT"YOU CAN'T HERE.":RETURN
  75. 3750 PRINT"O.K.":FIRE=1:IFCP=4THENOB(3)=5:OB(8)=4:RETURN
  76. 3760 IFCP=23THENOB(6)=25:FI2=1:LD=LD+1:OB(8)=23:RETURN
  77. 3800 ' ********** INVENTORY ***********
  78. 3810 PRINT:PRINT"YOU ARE CARRYING:"
  79. 3820 IFIN=0THENPRINT"NOTHING!":RETURN
  80. 3830 FORI=1TO10
  81. 3840 IFOB(I)=99THENPRINT", A "OB$(I);
  82. 3850 NEXTI:PRINT:RETURN
  83. 3900 ' ************** HELP ************
  84. 3910 PRINT:PRINT"THESE ARE THE VERBS YOU MAY USE:"
  85. 3920 FORI=1TOVV:PRINTVB$(I)", ";:NEXT:PRINT
  86. 3930 PRINT"(You need only type the first three     letters.)":RETURN
  87. 4000 ' ************ LOOK **************
  88. 4010 PRINT:PRINTLO$(CP):IFCP=22ORCP=6ORCP=11THENLF=1:RETURN
  89. 4020 FORI=1TO9
  90. 4040 IFOB(I)=CPTHENPRINT"A "OB$(I)" IS HERE"
  91. 4050 NEXTI
  92. 4060 PRINTCHR$(27)+"p";"Possible movement: ";
  93. 4070 IFEX(CP,1)>0THENPRINT"north ";
  94. 4080 IFEX(CP,2)>0THENPRINT"south ";
  95. 4090 IFEX(CP,3)>0THENPRINT"east ";
  96. 4100 IFEX(CP,4)>0THENPRINT"west";
  97. 4110 PRINTCHR$(27)+"q":RETURN
  98. 4200 '*********** DRAIN ***************
  99. 4210 IFNO<>18THENPRINT"DRAIN WHAT?":RETURN
  100. 4220 IFCP<>3THENPRINT"THERE'S NONE HERE...":RETURN
  101. 4230 IFOB(4)<>99THENPRINT"INTO WHAT?":RETURN
  102. 4240 PRINT"O.K.":GAS=1:RETURN
  103. 4300 '************** SLEEP ************
  104. 4310 IFFIRE<>1ORCP<>4THENPRINT"IT'S TOO COLD HERE!":RETURN
  105. 4320 IFDRINK<>1THENPRINT"YOU'RE TOO THIRSTY TO SLEEP.":RETURN
  106. 4330 PRINT"YOU QUICKLY DOZE OFF BY THE FIRE.":FORI=1TO1000:NEXT:PRINT:PRINT"AFTER FIRST LIGHT THE SOUND OF A NEARBY PLANE AWAKENS YOU!":BEEP:PRINT"TOO BAD THE FOG'S SO THICK.":SLEEP=1:RETURN
  107. 4400 MOVE=MOVE+1:IFOB$(5)<>"SPLINT"THENPRINT" YOUR LEG IS VERY PAINFUL":IFMOVE>6THENLF=3:RETURNELSERETURN
  108. 4410 IFOB(1)<>99THENPRINT" IT'S VERY COLD.":IFMOVE>8THENLF=4:RETURNELSERETURN
  109. 4415 IFMOVE<10THENRETURN
  110. 4420 IFDRINK<>1ANDMOVE/2=INT(MOVE/2)THENPRINT" YOU'RE VERY THIRSTY":IFMOVE>24THENLF=5:RETURN
  111. 4430 IFOB(9)<>50ANDMOVE/2<>INT(MOVE/2)THENPRINT" YOU'RE VERY HUNGRY.":IFMOVE>20THENLF=6:RETURN
  112. 4440 IFMOVE>18ANDSLEEP<>1ANDMOVE/2<>INT(MOVE/2)THENPRINT" IT'S GETTING DARK.":IFMOVE>25THENDARK=1:RETURN
  113. 4445 IFMOVE=45THENPRINT:PRINT"YOU HEAR A HELICOPTER APPROACHING.":BEEP:FORI=1TO1000:NEXT:IFLD>1THENPRINT"THEY SEEM TO SEE YOUR LARGE FIRE...":FORI=1TO1000:NEXT:WF=1:RETURN
  114. 4447 IFMOVE=45THENPRINT"BUT THEY DON'T SEE YOU...":FORI=1TO1000:NEXT:RETURN
  115. 4450 IFMOVE>49THENLF=7:RETURN
  116. 4460 RETURN
  117. 5000 CLS:PRINT:PRINTTAB(10)"CAN YOU SURVIVE?":PRINT:FORI=1TO500:NEXT:PRINTTAB(15)"By Russ Hall":PRINT:PRINT"Please press CAPS-LOCK.":FORI=1TO1000:NEXT
  118. 5010 CLS:PRINT" You were on a business trip in a singleengine plane.  Bad weather crossing high";
  119. 5020 PRINT"mountains suddenly came up, causing you to crash into a rough slope.  You much"
  120. 5030 PRINT"later awake to consciousness in a cold, quiet, and foggy world with a terrible"
  121. 5040 PRINT"pain inside  your right  leg.  (If you  need game assistance, type 'help'.";
  122. 5050 FORI=1TO4500:NEXT:PRINT
  123. 5090 NN=18:VV=13:CP=3:IN=1:WF=0:LF=0:UF=0:CF=0
  124. 5100 DIMLO$(25):DIMEX(25,4):DIMNO$(NN):DIMVB$(VV):DIMOB$(10):DIMOB(10)
  125. 5110 FORI=1TO25
  126. 5120 IFI=11THENLO$(I)=LO$(6):GOTO5140
  127. 5124 IFI=14ORI=15THENLO$(I)=LO$(10):GOTO5140
  128. 5126 IFI=20ORI=25THENLO$(I)=LO$(16):GOTO5140
  129. 5130 READD$:LO$(I)=D$
  130. 5140 NEXTI
  131. 5150 FORI=1TO25:FORJ=1TO4:READEX(I,J):NEXTJ,I
  132. 5160 FORI=1TO9:READOB$(I):READOB(I):NEXT
  133. 5170 FORI=1TONN:READNO$(I):NEXT
  134. 5180 FORI=1TOVV:READVB$(I):NEXT
  135. 5190 GOSUB4000:RETURN' LOOK
  136. 5500 BEEP:IFWF=1THEN5610ELSEONLFGOTO5510,5520,5530,5540,5550,5560,5570,5580,5590
  137. 5510 IFCP=22THENPRINT"   YOU SLIP ON THE SNOW AND SLIDE INTO  ROCKS BELOW.":GOTO5600
  138. 5515 PRINT"   YOU SLIP AND TUMBLE OVER THE ROCKS.":GOTO5600
  139. 5520 PRINT"YOU HAVE FALLEN OFF THE CLIFF!":GOTO5600
  140. 5530 PRINT"YOUR PAIN KEEPS YOU FROM MOVING FURTHER,AND YOU CANNOT KEEP WARM.":GOTO5600
  141. 5540 PRINT"HYPOTHERMIA SETS IN AND YOU SHIVVER     UNCONTROLABLY.":GOTO5600
  142. 5550 PRINT"ONE CAN'T LAST LONG WITHOUT WATER.":GOTO5600
  143. 5560 PRINT"WITHOUT THE ENERGY OF FOOD, HYPOTHERMIA SETS IN.":GOTO5600
  144. 5570 PRINT"YOU HAVE BEEN TOO LONG IN THE COLD.":GOTO5600
  145. 5580 PRINT"YOU CAN'T SEE TO MANEUVER SAFELY AND    STUMBLE IN THE ROCKS, KNOCKING YOURSELF UNCONSCIOUS.":GOTO5600
  146. 5600 PRINT"YOU HAVE FAILED TO SURVIVE.":GOTO5640
  147. 5610 PRINT"THE  RESCUE COPTER  LOWERS A  LADDER AND MAN TO ASSIST YOU GRATEFULLY UP.       CONGRADULATIONS!  YOU HAVE SURVIVED!"
  148. 5640 FORI=1TO1000:NEXT:INPUT"DO YOU WISH TO TRY AGAIN?";R$
  149. 5650 IFLEFT$(R$,1)="Y"THENRUN
  150. 5660 PRINT"BYE-BYE":FORF=1TO1000:NEXT:MENU
  151. 6010 DATA "THE MOUNTAIN SIDE SLOPES DOWN STEEPLY TOTHE SOUTH.  THE WAY  WEST IS BLOCKED BY A ROCKSLIDE."
  152. 6020 DATA "SOME CHRASH DEBRIS  SHOWS HERE  THROUGH THE FOG AND SNOW COVERING."
  153. 6030 DATA "YOU ARE AT  THE CRASH SITE.   PIECES OF THE PLANE SURROUND YOU."
  154. 6040 DATA "YOU ARE ON  A GENTLE, SOUTHERN  SLOPING,SNOWY MOUNTAIN  SIDE."
  155. 6060 DATA "YOU CAN  SEE VERY  DENSE FOREST  TO THE SOUTH AND EAST."
  156. 6070 DATA "THE MOUNTAIN SIDE HERE  IS VERY  STEEP, YOU HAVE TROUBLE MANEUVERING"
  157. 6080 DATA "HERE YOU SEE  THE HILLSIDE  SLOPE DOWN  MORE STEEPLY ON THE WEST."
  158. 6090 DATA "THE FOG  SEEMS TO  BE THINNING DOWN THE MOUNTAIN,  AND A  ROCKY CLIFF EDGE RUNS ALONG THE SOUTH HERE."
  159. 6100 DATA "A CLIFF EDGE IS TO  THE SOUTH AND DENSE FOREST ON THE EAST."
  160. 6120 DATA "YOU ARE IN THE THICK FOREST.  IT'S  DIF-FICULT TO KNOW YOUR WAY."
  161. 6121 DATA "THIS IS A BEAUTIFUL, WIDE MORAINE FIELD WITH STEEP SLOPES WEST."
  162. 6122 DATA "YOU ARE AT THE  BASE OF  A ROCKY  CLIFF TO THE NORTH, DENSE FOREST TO THE EAST."
  163. 6130 DATA "YOU ARE ON A BEAUTIFUL FORESTED MOUNTAINSIDE."
  164. 6140 DATA "THERE IS A LARGE, STEEP SNOWFIELD TO THESOUTH."
  165. 6145 DATA " YOU ARE  ON A ROCKY, SLOPING  MOUNTAIN SIDE."
  166. 6150 DATA "THE FOREST  IS THINNER  HERE BUT  MUCH  DENSER TO THE NORTH."
  167. 6155 DATA "A STEEP, SLICK SNOWFIELD BLOCKS YOUR WAY EAST."
  168. 6160 DATA "YOU ARE ON A STEEP, SLICK SNOWFIELD."
  169. 6170 DATA "YOU'RE IN A CLEARING HERE, WITH A STEEP SNOWFIELD WEST."
  170. 6180 DATA "YOU'RE ON A SLOPING MOUNTAIN  SIDE WITH CLOUDS HIGH ABOVE YOU."
  171. 6220 DATA 0,6,2,0, 0,0,3,1, 0,0,4,2, 0,9,5,3, 0,10,0,4
  172. 6230 DATA 1,11,7,0, 0,12,8,6, 0,99,9,7, 4,99,10,8, 5,15,0,9
  173. 6240 DATA 6,16,12,0, 7,17,13,11, 0,18,14,12, 0,19,15,13, 10,0,0,14
  174. 6250 DATA 11,21,17,0, 12,22,18,16, 13,23,19,17, 14,24,20,18, 15,0,0,19
  175. 6260 DATA 16,0,22,0, 17,0,23,21, 18,0,24,22, 19,0,25,23, 20,0,0,24
  176. 6310 DATA COAT,3,BUTANE LIGHTER,2,BUNCH OF STICKS,5,ALUMINUM CAN,1,STRAIGHT LIMB,4,MESS OF FALLEN TIMBER,25
  177. 6320 DATA SPLINT,0,FIRE,0,CANDY BAR,0
  178. 6510 DATA NOR,SOU,EAS,WES,DOO,PLA,COA,LIG,STI,CAN,LIM,TIM,SPL,FIR,BAR,SNO,WAT,GAS
  179. 6530 DATA GO ,GET,FEED,MELT,DRINK,EAT,MAKE,LIGHT,INVENTORY,HELP,LOOK,DRAIN,SLEEP
  180.