home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / boxgam.ba < prev    next >
Text File  |  2006-10-19  |  3KB  |  45 lines
  1. 0 'BOXGAM.BA   Emmett J. Carmody, from     Portable 100 (Sept 1987), pp. 36-39.    Prep. for Club 100 by Chia-Chi Chao,    08/03/88
  2. 1 'Club 100 Library (415) 939-1246 BBS,    937-5039 Newsletter, 932-8856 Voice
  3. 2 'CRAZY LIKE A BOX game, for 2 players
  4. 10 CALL16959:CLEAR1000:Z$=CHR$(27)+"pcRaZy LikE a BOX"+CHR$(27)+"q":DEFINTC,D,F,I,N,P,S,X,Y:DIMA(40,5),S(2):P=1
  5. 20 CLS:PRINTZ$:PRINT@80,"Two players take turns.    ";CHR$(227);" 1 ";CHR$(228),"Connect dot-pairs to draw  4   ";CHR$(234)
  6. 30 PRINT"sides and close boxes.         ";CHR$(234);" 2","Select boxes, sides by     ";CHR$(225);" 3 ";CHR$(226),"coordinates - e.g. a3, 2    BOX a3"
  7. 40 PRINT"Close box & keep turn.      SIDE 2":FORI=1TO7500:NEXT:CLS:PRINTZ$:PRINT@25,"abcdefgh"
  8. 50 FORX=1TO5:PRINT@22+(X+1)*40,X:NEXT:FORY=15TO55STEP8:FORX=149TO197STEP6:PSET(X,Y):PSET(X+1,Y):PSET(X,Y+1):PSET(X+1,Y+1):NEXT:NEXT
  9. 60 B$="a0":S=0:F=0:PRINT@80,"PLAYER";P:BEEP:INPUT"BOX, SIDE";B$,S:C=ASC(LEFT$(B$,1)):D=VAL(RIGHT$(B$,1)):IFC<97ORC>104ORD<1ORD>5ORS<1ORS>4THEN390
  10. 70 N=(C-72)+(D+1)*40:N1=N-(72+D*32):IFA(N1,S)ORA(N1,5)=4THEN390
  11. 80 X=(NMOD40)*6:Y=8*INT(N/40):ONSGOTO90,150,210,270
  12. 90 LINE(X,Y-1)-(X+5,Y-1):LINE(X,Y)-(X+5,Y):GOSUB380:A(N1,1)=1:A(N1,5)=A(N1,5)+1:IFD=1THEN110
  13. 100 A(N1-8,3)=1:A(N1-8,5)=A(N1-8,5)+1
  14. 110 GOSUB400:IFD=1THEN130
  15. 120 IFA(N1-8,5)=4THENBEEP:PRINT@N-40,P$:S(P)=S(P)+1:F=1
  16. 130 IFFTHEN330
  17. 140 P=3-P:PRINT@120,SPACE$(20):GOTO60
  18. 150 LINE(X+5,Y)-(X+5,Y+7):LINE(X+6,Y)-(X+6,Y+7):GOSUB380:A(N1,2)=1:A(N1,5)=A(N1,5)+1:IFC=104THEN170
  19. 160 A(N1+1,4)=1:A(N1+1,5)=A(N1+1,5)+1
  20. 170 GOSUB400:IFC=104THEN190
  21. 180 IFA(N1+1,5)=4THENBEEP:PRINT@N+1,P$:S(P)=S(P)+1:F=1
  22. 190 IFFTHEN330
  23. 200 GOTO140
  24. 210 LINE(X,Y+7)-(X+5,Y+7):LINE(X,Y+8)-(X+5,Y+8):GOSUB380:A(N1,3)=1:A(N1,5)=A(N1,5)+1:IFD=5THEN230
  25. 220 A(N1+8,1)=1:A(N1+8,5)=A(N1+8,5)+1
  26. 230 GOSUB400:IFD=5THEN250
  27. 240 IFA(N1+8,5)=4THENBEEP:PRINT@N+40,P$:S(P)=S(P)+1:F=1
  28. 250 IFFTHEN330
  29. 260 GOTO140
  30. 270 LINE(X-1,Y)-(X-1,Y+7):LINE(X,Y)-(X,Y+7):GOSUB380:A(N1,4)=1:A(N1,5)=A(N1,5)+1:IFC=97THEN290
  31. 280 A(N1-1,2)=1:A(N1-1,5)=A(N1-1,5)+1
  32. 290 GOSUB400:IFC=97THEN310
  33. 300 IFA(N1-1,5)=4THENBEEP:PRINT@N-1,P$:S(P)=S(P)+1:F=1
  34. 310 IFFTHEN330
  35. 320 GOTO140
  36. 330 FORI=1TO40:IFA(I,5)<>4THENPRINT@120,SPACE$(20):GOSUB370:I=50
  37. 340 NEXT:IFI=51THEN60
  38. 350 GOSUB370:BEEP:BEEP:PRINT@240,"FINAL":IFINKEY$=""THEN350
  39. 360 MENU
  40. 370 PRINT@280,"SCORE: #1:";S(1);" #2:";S(2):RETURN
  41. 380 P$=RIGHT$(STR$(P),1):RETURN
  42. 390 BEEP:PRINT@120,"INPUT ERROR     ":BEEP:BEEP:FORI=1TO500:NEXT:BEEP:P=3-P:GOTO60
  43. 400 IFA(N1,5)=4THENBEEP:PRINT@N,P$:S(P)=S(P)+1:F=1
  44. 410 RETURN
  45.