home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / alien.ba < prev    next >
Text File  |  2006-10-19  |  3KB  |  75 lines
  1. 0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
  2. 1 CLS'ALIEN' <GA-35> from CREATIVE COMP-UTING BUYER'S GUIDE 1984 p.77
  3. 2 'LCD-FENDER by JOHN ANDERSON * INTRO, RULES,ETC-S.KENDALL WILMETTE, IL 5/85
  4. 9 GOTO700
  5. 10 PRINT@290,"<ENTER>";:IF INKEY$=""THEN10 ELSE RETURN
  6. 35 SC=0:PRINT@83," <P> PLAY    *    <Q> MENU ":I$=INKEY$
  7. 40 IF I$="Q"ORI$="q"THEN MENU
  8. 45 IF I$="P"ORI$="p"THEN 60
  9. 50 GOTO35
  10. 60 M=0:SCREEN 0,0:CLS:T=350
  11. 70 R=0:X=RND(1)*35+1
  12. 80 T=T-1:PRINT@X+R," ^";CHR$(144);"^ ";
  13. 90 I$=INKEY$
  14. 100 IF I$="."THEN M=M+1
  15. 110 IF I$=","THEN M=M-1
  16. 120 IF I$=""THEN GOSUB 230
  17. 121 'IF I$=CHR$(32) INSTEAD OF "" WORKS BUT MAKES THE GAME A SNAP
  18. 130 IFT<0THEN 460
  19. 140 IF M<0THEN M=39:PRINT@6*40,"   ";
  20. 150 IF M>39THEN M=0:PRINT@39+(6*40),"  ";
  21. 160 PRINT@M-1+(6*40)," ";CHR$(133);" ";
  22. 170 PRINT@(7*40),T;"   hi-score:";HS;
  23. 180 PRINT@27+(7*40),"score:";SC;
  24. 190 P=RND(1)*3-1:S=RND(1)*2
  25. 192 IF S=1THEN P=-P
  26. 194 X=X+P
  27. 200 IF X<1THEN X=1
  28. 210 IF X>35THEN X=35
  29. 215 IF T<50THEN SOUND 4000,1
  30. 220 GOTO80
  31. 230 '........
  32. 240 FOR Y=5TO 0STEP -1
  33. 250 PRINT@M+(Y*40),CHR$(152)
  34. 260 SOUND Y*1000,1
  35. 270 PRINT@M+(Y*40)," "
  36. 280 NEXT
  37. 290 IF M=X+1 OR M=X+3 THEN SC=SC+50:BEEP:GOSUB330:GOTO70
  38. 300 IF M=X+2THEN GOTO390
  39. 305 PRINT@X+R,"     ":R=R+40:SC=SC-5
  40. 307 IF R>200THEN SC=SC-10:GOTO70
  41. 310 RETURN
  42. 320 '..ASSORTED SUBROUTINES
  43. 330 FOR I=0 TO 10
  44. 340 PRINT@X+1+R,"BLORK!"
  45. 350 FOR J=0 TO 20:NEXT:PRINT@X+1+R,"      "
  46. 360 SOUND 16000,1:NEXT
  47. 370 GOTO70
  48. 380 '...
  49. 390 SC=SC+100:SOUND 440,10
  50. 400 FOR I=0 TO 10
  51. 410 PRINT@X+1+R,"WAAGH!"
  52. 420 SOUND 1760,1
  53. 430 NEXT I
  54. 440 PRINT@X+1+R,"      "
  55. 450 GOTO70
  56. 460 IF SC>HS THEN HS=SC
  57. 470 PRINT@175,"GAME OVER":LINE(0,0)-(239,63),1,BF
  58. 475 PRINT@164," Score:"SC;"Hi-score:";HS
  59. 500 FORX=1TO 4000:NEXT::BEEP:GOTO35
  60. 699 ''''''''''''
  61. 700 BEEP:DEFINT A-Z:FOR A=20TO 220STEP 40:LINE(A,0)-(A,63):NEXT:BEEP
  62. 710 FORA=11TO 55STEP 10:LINE(10,A)-(230,A):NEXT:BEEP
  63. 730 PRINT@83,"'ALIEN'":PRINT@150,"<GA-35>"
  64. 740 PRINT@164,"SPACE":PRINT@171,"INVADER"
  65. 742 PRINT@96,"^"+CHR$(144)+"^"
  66. 750 PRINT@303,"^"+CHR$(144)+"^"+"      "+"^"+CHR$(144)+"^";
  67. 765 GOSUB10
  68. 790 CLS:BEEP:PRINT@41,"Move your Gun with < > keys- fire with"
  69. 800 PRINT" SPACEBAR. Winging an Alien is worth 50":PRINT" points and a direct hit 100 points."
  70. 810 PRINT" Missing loses points and brings the":PRINT" aliens closer. You are warned when 50"
  71. 820 PRINT" time units are left."
  72. 830 GOSUB10
  73. 840 CLS:BEEP:PRINT@82,"Your player has Wrap around."
  74. 850 PRINT@208,"GOOD LUCK !":GOSUB10:CLS:GOTO35
  75.