home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
gam
/
alien.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
3KB
|
75 lines
0 'Club 100 Library - 415/939-1246 BBS 937-5039 NEWSLETTER, 932-8856 VOICE
1 CLS'ALIEN' <GA-35> from CREATIVE COMP-UTING BUYER'S GUIDE 1984 p.77
2 'LCD-FENDER by JOHN ANDERSON * INTRO, RULES,ETC-S.KENDALL WILMETTE, IL 5/85
9 GOTO700
10 PRINT@290,"<ENTER>";:IF INKEY$=""THEN10 ELSE RETURN
35 SC=0:PRINT@83," <P> PLAY * <Q> MENU ":I$=INKEY$
40 IF I$="Q"ORI$="q"THEN MENU
45 IF I$="P"ORI$="p"THEN 60
50 GOTO35
60 M=0:SCREEN 0,0:CLS:T=350
70 R=0:X=RND(1)*35+1
80 T=T-1:PRINT@X+R," ^";CHR$(144);"^ ";
90 I$=INKEY$
100 IF I$="."THEN M=M+1
110 IF I$=","THEN M=M-1
120 IF I$=""THEN GOSUB 230
121 'IF I$=CHR$(32) INSTEAD OF "" WORKS BUT MAKES THE GAME A SNAP
130 IFT<0THEN 460
140 IF M<0THEN M=39:PRINT@6*40," ";
150 IF M>39THEN M=0:PRINT@39+(6*40)," ";
160 PRINT@M-1+(6*40)," ";CHR$(133);" ";
170 PRINT@(7*40),T;" hi-score:";HS;
180 PRINT@27+(7*40),"score:";SC;
190 P=RND(1)*3-1:S=RND(1)*2
192 IF S=1THEN P=-P
194 X=X+P
200 IF X<1THEN X=1
210 IF X>35THEN X=35
215 IF T<50THEN SOUND 4000,1
220 GOTO80
230 '........
240 FOR Y=5TO 0STEP -1
250 PRINT@M+(Y*40),CHR$(152)
260 SOUND Y*1000,1
270 PRINT@M+(Y*40)," "
280 NEXT
290 IF M=X+1 OR M=X+3 THEN SC=SC+50:BEEP:GOSUB330:GOTO70
300 IF M=X+2THEN GOTO390
305 PRINT@X+R," ":R=R+40:SC=SC-5
307 IF R>200THEN SC=SC-10:GOTO70
310 RETURN
320 '..ASSORTED SUBROUTINES
330 FOR I=0 TO 10
340 PRINT@X+1+R,"BLORK!"
350 FOR J=0 TO 20:NEXT:PRINT@X+1+R," "
360 SOUND 16000,1:NEXT
370 GOTO70
380 '...
390 SC=SC+100:SOUND 440,10
400 FOR I=0 TO 10
410 PRINT@X+1+R,"WAAGH!"
420 SOUND 1760,1
430 NEXT I
440 PRINT@X+1+R," "
450 GOTO70
460 IF SC>HS THEN HS=SC
470 PRINT@175,"GAME OVER":LINE(0,0)-(239,63),1,BF
475 PRINT@164," Score:"SC;"Hi-score:";HS
500 FORX=1TO 4000:NEXT::BEEP:GOTO35
699 ''''''''''''
700 BEEP:DEFINT A-Z:FOR A=20TO 220STEP 40:LINE(A,0)-(A,63):NEXT:BEEP
710 FORA=11TO 55STEP 10:LINE(10,A)-(230,A):NEXT:BEEP
730 PRINT@83,"'ALIEN'":PRINT@150,"<GA-35>"
740 PRINT@164,"SPACE":PRINT@171,"INVADER"
742 PRINT@96,"^"+CHR$(144)+"^"
750 PRINT@303,"^"+CHR$(144)+"^"+" "+"^"+CHR$(144)+"^";
765 GOSUB10
790 CLS:BEEP:PRINT@41,"Move your Gun with < > keys- fire with"
800 PRINT" SPACEBAR. Winging an Alien is worth 50":PRINT" points and a direct hit 100 points."
810 PRINT" Missing loses points and brings the":PRINT" aliens closer. You are warned when 50"
820 PRINT" time units are left."
830 GOSUB10
840 CLS:BEEP:PRINT@82,"Your player has Wrap around."
850 PRINT@208,"GOOD LUCK !":GOSUB10:CLS:GOTO35