home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
edu
/
mathex.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
7KB
|
112 lines
0 'MATHEX.BA v1.5- DREW BLANCHAR 10/89
1 'Club 100 Library -(415)939-1246 BBS, 932-8856 VOICE
2 'A=inkey answer,B=wild card,C=correct answers,D=test area/dec,H$=hex,Q=question #,R=random #,S=wild card,T=TIME$,U=QUESTION$,V=print pattern,X & Y=operands,Z=result
10 CLS:CLEAR:DEFINTA-D,W-Z:DEFSTRH,I,U,V
30 CLS:V="#####":PRINT" ARITHMETIC AND NUMBER EXERCISES"
32 PRINT@80,"press for LEVEL 1 LEVEL 2":PRINT"ADD/SUBTRACT 1 2":PRINT"MULTIPLY/DIVIDE 3 4":PRINT"BINARY/HEX 5 6":PRINT"OTHER NUMBERS 7 8":PRINT"EXIT <ENTER>";
35 U=INKEY$:IFU=""GOTO35
39 IFU=CHR$(13)GOTOMENUELSED=VAL(U):IFD<1ORD>8GOTO30
40 C=0:ONDGOTO100,100,200,200,300,400,500,550
90 CLS:PRINT:PRINTU:PRINT:PRINTQ-1;"PROBLEMS GIVEN.":PRINTC;"ANSWERED CORRECTLY.":PRINT:PRINT"PRESS ANY KEY FOR MORE EXERCISES";
95 IFINKEY$=""GOTO95ELSEGOTO30
100 FORQ=1TO20:CLS
102 B=0:GOSUB990:IFD=1THENX=FIX(12*R):GOSUB990:Y=FIX(12*R):GOTO105
104 X=FIX(1000*R):GOSUB990:Y=FIX(1000*R):B=0
105 IFX=0ANDY=0GOTO102ELSEPRINT:IF(QMOD2)THENZ=X+Y:PRINT" ";:PRINTUSINGV;X:PRINT"+";:PRINTUSINGV;Y:LINE(1,26)-(40,26):GOTO110
107 X=X+Y:Z=X-Y:PRINT" ";:PRINTUSINGV;X:PRINT"-";:PRINTUSINGV;Y:LINE(1,26)-(40,26)
110 PRINT:INPUT" ";A:IFA=ZTHENC=C+1:PRINT@250,"CORRECT";:GOSUB995:GOTO125
115 IFB=0THENB=1:PRINT" NO. TRY AGAIN.";:GOTO110
120 PRINT" NO. THE ANSWER IS ";Z;:GOSUB995
125 NEXTQ:IFD=1THENU="ADDITION AND SUBTRACTION - LEVEL 1":GOTO90
130 U="ADDITION AND SUBTRACTION - LEVEL 2":GOTO90
200 FORQ=1TO20:CLS:B=0:PRINT
202 GOSUB990:IFD=3THENX=FIX(12*R+1):GOSUB990:Y=FIX(12*R):GOTO205
204 X=FIX(151*R+1):GOSUB990:Y=FIX(22*R+1)
205 IF(QMOD2)=0GOTO250
210 Z=X*Y:PRINT" ";:PRINTUSINGV;X:PRINT"x";:PRINTUSINGV;Y:LINE(1,26)-(40,26)
215 PRINT:INPUT" ";A:IFA=ZTHENC=C+1:PRINT@250,"CORRECT";:GOSUB995:GOTO290
220 IFB=0THENPRINT" NO. TRY AGAIN.";:B=1:GOTO215
225 PRINT" NO. THE ANSWER IS ";Z;:GOSUB995:GOTO290
250 IFY=0GOTO202ELSEX=X*Y:Z=X/Y:PRINT@120,USINGV;Y;:PRINT"/";X:LINE(35,25)-(38,22):LINE-(66,22)
255 PRINT@44,"";:INPUT" ";A
260 IFA=ZTHENC=C+1:PRINT@55,"CORRECT";:GOSUB995:GOTO290
265 PRINT@160," NO. TRY AGAIN.":INPUT" ";A:IFA=ZTHENC=C+1:PRINT" CORRECT";:GOSUB995:GOTO290
270 PRINT" NO. THE ANSWER IS ";Z;:GOSUB995
290 NEXTQ:IFD=3THENU="MULTIPLICATION AND DIVISION LEVEL 1":GOTO90
292 U="MULTIPLICATION AND DIVISION LEVEL 2":GOTO90
300 FORQ=1TO20:CLS:PRINT@40,"CONVERT ";
302 I="-1":B=0:GOSUB990:S=0:D=FIX(16*R):GOSUB390
305 ON((QMOD6)+1)GOTO320,322,324,326,328,330
320 Z=S*10000:PRINT"hexadecimal ";H;" to binary":GOTO340
322 Z=S*10000:PRINT"decimal";D;"to binary":GOTO340
324 IFD<10GOTO326
325 PRINT"decimal";D;"to hexadecimal":GOTO350
326 Z=D:PRINT"binary";:PRINTUSING".####";S;:PRINT" to decimal":PRINT@54," ":GOTO340
328 PRINT"binary";:PRINTUSING".####";S;:PRINT" to hexadecimal":PRINT@54," ":GOTO350
330 IFD<9GOTO320
331 Z=D:PRINT"hexadecimal ";H;" to decimal"
340 INPUT" ";I:A=VAL(I):IFA=ZTHENC=C+1:PRINT@250,"CORRECT";:GOSUB995:GOTO349
342 IFB=0THENB=1:PRINT" NO. TRY AGAIN.";:GOTO340
345 PRINT@200," NO. THE ANSWER IS":PRINT" decimal binary hexadecimal":PRINT@289,USINGV;D,:PRINTUSING" .####";S,:PRINT" ";H;:PRINT@296," ";:GOSUB995:GOSUB995:GOSUB995
349 NEXTQ:U="BINARY AND HEXADECIMAL - LEVEL 1":GOTO90
350 INPUT" ";I:IFI=HTHENC=C+1:PRINT@250,"CORRECT";:GOSUB995:GOTO349
352 IFB=0THENB=1:PRINT" NO. TRY AGAIN.";:GOTO350
355 GOTO345
390 IFDAND8THENS=.1
391 IFDAND4THENS=S+.01
392 IFDAND2THENS=S+.001
393 IFDAND1THENS=S+.0001
394 H=MID$("0123456789ABCDEF",D+1,1):RETURN
400 FORQ=1TO16:CLS:B=0:PRINT" HEX MATH 0123456789ABCDEF 00--FF"
402 GOSUB990:X=FIX(26*R):IFX<10GOTO402
404 GOSUB990:Y=FIX(11*R):IFY<2ORY>11GOTO404
405 ON((QMOD4)+1)GOTO416,410,412,414
410 Z=X+Y:GOTO420
412 X=X+Y:Z=X-Y:GOTO420
414 Z=X*Y:GOTO420
416 X=X*Y:Z=X/Y
420 D=X/16:GOSUB394:U=H:D=(XMOD16):GOSUB394:U=U+H
422 D=Y/16:GOSUB394:V=H:D=(YMOD16):GOSUB394:V=V+H
424 D=Z/16:GOSUB394:I=H:D=(ZMOD16):GOSUB394:H=I+H
430 PRINT:PRINT" ";U;MID$("/+-x",(QMOD4)+1,1);V;" = ";:I="HEX"
435 INPUT" ";I:IFI=HTHENC=C+1:PRINT@250,"CORRECT";:GOSUB995:GOTO450
440 IFB=0THENB=1:PRINT" NO. TRY AGAIN.";:GOTO435
445 PRINT:PRINT" NO. THE ANSWER IS (HEXADECIMAL) ";H;:GOSUB995
450 NEXTQ:U="HEXADECIMAL ARITHMETIC":GOTO90
500 RESTORE:GOSUB990:IF(TMOD2)THENGOSUB998
502 FORQ=1TO10:CLS:B=0:GOSUB998:PRINTU;:INPUT" ";A
504 IFA=ZTHENC=C+1:PRINT:PRINT"CORRECT":GOSUB995:GOSUB998:NEXTQ:GOTO510
506 IFB=0THENB=1:INPUT" NO. TRY AGAIN. ";A:GOTO504
508 PRINT" NO. THE ANSWER IS ";Z:GOSUB995:GOSUB998:NEXTQ
510 U="OTHER NUMBERS OF INTEREST LEVEL 1":GOTO90
520 DATA2,"How many WHEELS on a BICYCLE",3,"How many WHEELS on a TRICYCLE"
521 DATA100,"How many PENCILS in an HUNDRED",12,"How many EGGS in a DOZEN"
522 DATA4,"How many CORNERS in a SQUARE",3,"How many CORNERS in a TRIANGLE"
523 DATA16,"How many OUNCES in a POUND",2000,"How many POUNDS in a TON"
524 DATA3,"How many FEET in a YARD",12,"How many INCHES in a FOOT"
525 DATA60,"How many MINUTES in an HOUR",24,"How many HOURS in a DAY"
526 DATA6,"How many LEGS on a FLY",8,"How many LEGS on a SPIDER"
527 DATA7,"How many DAYS in a WEEK",12,"How many MONTHS in a YEAR"
528 DATA25,"How many CENTS in a QUARTER",10,"How many DIMES in a DOLLAR"
529 DATA2,"How many CUPS in a PINT",4,"How many QUARTS in a GALLON"
550 RESTORE:FORQ=1TO20:GOSUB998:NEXTQ:GOSUB990:IF(TMOD2)THENGOSUB998
552 FORQ=1TO10:CLS::GOSUB998:B=0:PRINTU;:INPUT" ";A
554 IFA=ZTHENC=C+1:PRINT:PRINT"CORRECT":GOSUB995:GOSUB998:NEXTQ:GOTO560
556 IFB=0THENB=1:INPUT" NO. TRY AGAIN. ";A:GOTO554
558 PRINT" NO. THE ANSWER IS ";Z:GOSUB995:GOSUB998:NEXTQ
560 U="OTHER NUMBERS OF INTEREST LEVEL 2":GOTO90
570 DATA411,"What is the AVERAGE of 321, 654 and 258",78,"What is the AVERAGE of 68, 97, 72 and 75"
571 DATA5,"How many CORNERS in a PENTAGRAM",6,"How many CORNERS in an HEXAGRAM"
572 DATA12,"How many 3-CENT STAMPS in a DOZEN",12,"How many FACES on a PAIR OF DICE"
573 DATA49,"How much is 7 SQUARED",25,"How much is 5 SQUARED"
574 DATA212,"What is the boiling temperature of water (in Fahrenheit)",32,"What is the freezing temperature of water (in Fahrenheit)"
575 DATA144,"How many PENCILS in a GROSS",500,"How many PAPERS in a REAM"
576 DATA144,"How many SQUARE INCHES in a SQUARE FOOT",27,"How many CUBIC FEET in a CUBIC YARD"
577 DATA7,"What is the PRIME NUMBER between 5 and 11",13,"What is the PRIME NUMBER between 11 and 17"
578 DATA34,"ROMAN NUMERAL XXXIV means",29,"ROMAN NUMERAL XXIX means"
579 DATA8,"How many LEGS on an OCTOPUS",1000,"How many METERS in a KILOMETER"
599 DATA0,"What is a NULL"
990 T=VAL(RIGHT$(TIME$,2))+Q:FORS=1TOT:R=RND(1):NEXTS:RETURN
995 FORS=1TO700:NEXTS:RETURN
998 READZ:READU:RETURN