home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
bus
/
shoppr.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
2KB
|
76 lines
0 'SHOPPR.BA - Author Unknown
1 'Club 100 Library - 415/939-1246 BBS, 937-5039 NEWSLETTER, 932-8856 VOICE
100 MAXFILES=2
110 MSG$="Shopper!"
120 GOSUB600
130 CLS
140 PRINT@160,"(S)imple shopping or (L)ist ";
150 A$=INPUT$(1)
160 IF A$="S"ORA$="L"THEN170ELSE130
170 IFA$="L"THENOPEN"SHPLST.DO"FORAPPENDAS1:PRINT#1,"List for ";DAY$;", ";DATE$;" at ";TIME$
180 CLS
190 PRINT@40,"L=LST, ==TTL, T=TAX, E=END, *=END/KILL"
200 PRINT@130,"COST QTY CODE TOTAL"
210 PRINT@160,"PREVIOUS ";
220 PRINTUSING"$$#.## ##.## ! $$#.##";PC,PN,TX$,PT
230 PRINT@200,"-----> ";
240 INPUTCC
250 PRINT@215," ";
260 INPUTCN
270 PRINT@223," ";
280 INPUTTX$
290 IFTX$="E"ANDA$="L"THENPRINT#1,"Total for this list is ";USING"$$##.##";RT:CLOSE1:MSG$="The End - List Kept!":GOSUB600:MENU
300 IF TX$="E"THENMSG$="The End - No List!":GOSUB600:MENU
310 IFTX$="*"ANDA$="L"THENCLOSE1:CLS:KILL"SHPLST.DO":MSG$="The End - List Killed!":GOSUB600:MENU
320 IFTX$="*"THENMSG$="The End - No List!":GOSUB600:MENU
330 IFTX$="="THENCLS:PRINT@160,"Total at this point is: ";:PRINTUSING"$$##.##";RT:SOUND2348,25:GOTO180
340 IFTX$="L"THENGOSUB460:GOTO180
350 CT=CC*CN
360 IFTX$="T"THENCT=((CT*.06)+CT):CT=INT((100*CT)+.5)/100
370 PRINT@229," ";
380 PRINTUSING"$$#.##";CT
390 PC=CC
400 PN=CN
410 PT=CT
420 SOUND2348,25
430 RT=RT+CT
440 IFA$="L"THENPRINT#1,USING"$$#.## ##.## ! $$#.##";PC;PN;TX$;PT
450 GOTO 180
460 IFA$="S"THENCLS:PRINT@200,"SORRY, THERE IS NO LIST!":SOUND2348,100:RETURN
470 CLOSE1
480 OPEN"SHPLST.DO"FORINPUTAS2
490 CLS
500 FORX=1TO6
510 LINEINPUT#2,LI$
520 PRINTLI$
530 IFEOF(2)THEN130ELSENEXTX
540 PRINT"<ENTER> TO CONT, <R> TO RETURN";
550 X$=INPUT$(1)
560 IFEOF(2)THEN570ELSEIFX$="R"THEN570ELSE490
570 CLOSE2
580 OPEN"SHPLST.DO"FORAPPENDAS1
590 RETURN
600 ' OPENING DISPLAY
610 CLS
620 LINE(0,0)-(239,63)
630 LINE(239,0)-(0,63)
640 A=0
650 B=0
660 C=239
670 D=63
680 A=A+2
690 B=B+2
700 C=C-2
710 D=D-2
720 LINE(A,B)-(C,D),1,B
730 IFA=60THEN740ELSE680
740 SP=LEN(MSG$)
750 TM=40-SP
760 SP=TM/2
770 SP=SP+120
780 PRINT@SP,CHR$(27)"p";MSG$;CHR$(27)"q"
790 FORX=1TO400
800 Y=RND(X)
810 NEXTX
820 RETURN