home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / bus / names.ba < prev    next >
Text File  |  2006-10-19  |  2KB  |  64 lines
  1. 0 'NAMES.BA by Bill Templeton - 4/9/86 
  2. 1 'CLUB 100 LIBRARY - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  3. 20 CLEAR
  4. 30 MAXFILES=1
  5. 40 DEFSTRA-M,N,R
  6. 50 I=CHR$(27)
  7. 60 R=I+"p
  8. 70 N=I+"q
  9. 80 T=1
  10. 90 PRINTI"V
  11. 100 CLS
  12. 110 L=LEFT$(DATE$,2)+MID$(DATE$,4,2)
  13. 120 M="na"+L
  14. 130 OPENMFORAPPENDAS1
  15. 140 PRINT#1,
  16. 150 PRINT#1,"Date: "DATE$" ("DAY$") "LEFT$(TIME$,5)"PST
  17. 160 PRINT@0,"- Club 100 -";
  18. 170 GOSUB530
  19. 180 PRINT@40,R"       name: "N;
  20. 190 INPUTA
  21. 200 PRINT@80,R"    company: "N;
  22. 210 INPUTB
  23. 220 PRINT@120,R"     street: "N;
  24. 230 INPUTC
  25. 240 PRINT@160,R" city,state: "N;
  26. 250 INPUTD,E
  27. 260 PRINT@200,R"        zip: "N;
  28. 270 INPUTF
  29. 280 PRINT@240,R" home phone: "N;
  30. 290 INPUTG
  31. 300 PRINT@280,R" work phone: "N;
  32. 310 INPUTH
  33. 320 PRINT@13,R"  Is this Correct (Y/N)?  "N;
  34. 330 K=INPUT$(1)
  35. 340 IFINSTR("Yy",K)THEN350ELSEIFK=ITHENMENUELSE550
  36. 350 PRINT#1,
  37. 360 PRINT#1,USING"####";T;
  38. 370 PRINT#1," "A
  39. 380 PRINT#1,"     "B
  40. 390 PRINT#1,"     "C
  41. 400 PRINT#1,"     "D", "E" "F
  42. 410 PRINT#1,"      H:"G
  43. 420 PRINT#1,"      O:"H
  44. 430 CLS
  45. 440 T=T+1
  46. 450 A="
  47. 460 B="
  48. 470 C="
  49. 480 D="
  50. 490 E="
  51. 500 F="
  52. 510 G="
  53. 520 H="":GOTO160
  54. 530 PRINT@13,R"    Enter Name & Address   "N;
  55. 540 RETURN
  56. 550 PRINT@13,R"  Press <ENTER> if correct "N;
  57. 560 GOTO180
  58. 570 'Simple 1,2,3 instructions are:
  59. 580 "   (1) Don't use commas except between City and State.
  60. 590 '   (2) Press <ENTER> if the info is correct on the line being reviewed.
  61. 600 '   (3) Retype the entire line when making a correction.
  62. 610 'You can exit to Menu at `Is this correct (Y/N)?' prompt by pushing <ESC>.
  63. 620 'The resulting .DO file is date coded with month & day, i.e., `NA0409'
  64.