home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
bus
/
cshreg.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
3KB
|
36 lines
0 'CSHREG.103 by Richard Hanson 9/85 Mods by Bill Templeton 4/86 <<<Cash Register Program>>>
1 ' Club 100 Library - 415/939-1246 BBS, 937-5039 NEWSLETTER, 932-8856 VOICE
2 CLEAR:MAXFILES=3:DEFINTA-D:E$=CHR$(27):R$=E$+"p":N$=E$+"q":B=0:ONERRORGOTO33:CLS:PRINT@53,R$" CASH REGISTER "N$;:B=INP(187)AND6:IFB=2THENA=1:F$="LPT:":GOTO4
3 PRINT@130,"Printer not connected...":PRINT@171,"Use LCD display (Y/N)?":W$=INPUT$(1):IFINSTR("yY",W$)THENA=2:F$="LCD:":GOTO6ELSEMENU
4 PRINT@172,"Printer connected...":PRINT@248,R$" Going to main program... "N$:FORD=1TO2000:NEXT
5 OPEN"grand"FOROUTPUTAS2
6 CLS:CLOSE:OPEN"temp"FOROUTPUTAS1:C=1:RESTORE32
7 READT$(C),I$(C),P(C):IFP(C)=0THEN9
8 C=C+1:GOTO7
9 CLS:PRINT:FORR=1TOC-1:PRINT" <"T$(R)">"I$(R)" ";:NEXT:PRINT@280,R$" Go "N$" "R$" Clr"N$" "R$" Sum"N$" <SELECT ITEM ABOVE> "R$"Menu"N$;
10 KEY(8)ON:ONKEYGOSUB14,5,24,,,,,31:Z$=INKEY$:IFZ$=""THEN10
11 Z=VAL(Z$):IFZ>C-1ORZ<1THEN10
12 KEYON:CLS:PRINT@80,"Quantity & ENTER or just ENTER to abort":PRINT@160," Item: "I$(Z);:PRINT@204,"Price: "USING"$###.##";P(Z);:PRINT" each":PRINT@241,"Quantity: ";:INPUTQ:IFQ=0THEN9
13 PRINT#1,Q","I$(Z)","Q*P(Z):GOTO9
14 KEY(1)OFF:CLOSE:OPEN"temp"FORINPUTAS1:OPEN"grand"FORAPPENDAS2:OPENF$FOROUTPUTAS3:IFA=1ANDQ<>0THENCLS:PRINT@170,R$" Printing receipt..."N$
15 IFQ<>0THENPRINT#3,:PRINT#3,DATE$:PRINT#3,:PRINT#3,"Hanson-McBride Services
16 IFQ<>0THENPRINT#3,"P.O. Box 23438":PRINT#3,"Pleasant Hill, CA 94523":PRINT#3,:PRINT#3," 415/932-8856 (voice)
17 IFQ<>0THENPRINT#3," 415/939-1246 (data)":PRINT#3,
18 INPUT#1,Q,I$,QP:IFQ<10THENPRINT#3," "Q;I$" "USING"#####.##";QP:PRINT#2," "Q","I$",";:PRINT#2,USING"#####.##";QP
19 IFQ>9ANDQ<100THENPRINT#3,Q;I$" "USING"#####.##";QP:PRINT#2,Q","I$",";:PRINT#2,USING"#####.##";QP
20 ST=ST+QP:IFEOF(1)THENCLOSE1:GOTO22
21 GOTO18
22 PRINT#3,STRING$(39,"-"):PRINT#3," Subtotal: "USING"$$####.##";ST:TX=.065*ST:PRINT#3," Tax: "USING"######.##";TX:PRINT#3," TOTAL: "USING"$$####.##";ST+TX:PRINT#3,:IFA=1THENFORD=1TO15:LPRINT:NEXT
23 PRINT#3,"THANK YOU FOR YOUR SUPPORT!":Q=0:GOTO6
24 CLS:PRINT@130,R$" Today's Grand Total "N$:PRINT@280,R$" Go "N$" "R$"More"N$SPACE$(26)R$"Menu"N$;
25 KEYON:ONKEYGOSUB26,6,,,,,,31:GOTO25
26 CLS:PRINT@130,R$" Updating Grand Total..."N$:ST=0:CLOSE2:OPEN"grand"FORINPUTAS2
27 INPUT#2,N,I$,QP:ST=ST+QP:IFEOF(2)THEN29
28 GOTO27
29 TX=.065*ST:GT=ST+TX:CLOSE2:OPEN"grand"FORAPPENDAS2:PRINT#2,STRING$(30,45)DATE$"-":PRINT#2," SUBTOTAL: "USING"$$####.##";ST:PRINT#2," TAX: "USING"$$####.##";TX:PRINT#2," TOTAL: "USING"$$####.##";GT:PRINT#2,
30 ONERRORGOTO34:NAME"grand.do"AS"gt"+LEFT$(DATE$,2)+MID$(DATE$,4,2)+".do
31 KILL"temp.do":MAXFILES=1:MENU
32 DATA"1","Power Pillows ",14.95:DATA"2","Keyboard Bands",1.95:DATA"3","Null Cable ",19.95:DATA"4","IBM Adapter ",9.95:DATA"5","TTXpress Prter",99.00:DATA"6","Hush-80 Prter ",179.95:DATA"0","",0
33 IFERRTHENCLS:PRINT@121,R$" There is no transaction to process..."N$:FORD=1TO999:NEXT:RESUME6
34 IFERR=5THENCLS:PRINT@121,R$" Kill/Rename today's GT-#.DO file..."N$:KILL"grand.do":KILL"temp.do":MAXFILES=1:MENU