home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
bus
/
brkevn.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
3KB
|
47 lines
0 'BRKEVN.BA Bill Templeton, 06/86
1 'CLUB 100 Library - 415/939-1246 BBS, 937-5039 NEWSLETTER, 932-8856 VOICE
2 CLEAR1500:DIMX(10),Y(10):CLS:A$="1234567890.+-":AZ$=CHR$(29)+CHR$(31)+CHR$(30)+CHR$(28)+"Q"+"q":J1=0:J2=4:JS=2:J9=1
3 ONERRORGOTO44:E$=CHR$(27):R$=E$+"p":N$=E$+"q":GOSUB40:GOSUB43:CLS:GOSUB16
4 Z$="":CLS:XI=X(4)/5:XM=10*X(4):PRINT@40,R$" Press <Q><ENTER> to exit program "N$
5 PRINT@130,"Xmax="XM:PRINT@200,R$" Enter your Xmax or press <ENTER> "N$;:INPUTZ$
6 IFZ$=""THEN7ELSEIFZ$="q"ORZ$="Q"THENMENUELSEXM=VAL(Z$)
7 YI=X(2)*XI-X(1)*XI-X(0):YM=X(2)*XM-X(1)*XM-X(0):DX=XM-XI:DY=YM-YI:SX=180/DX:SY=54/DY:X2=.1*DX:X0=XI-X2
8 CLS:PRINT@286,INT(XI);:L$=STR$(XM):L=LEN(L$):PRINT@(319-L),L$;
9 PRINT@299,R$" UNITS "N$;:PRINT@240,;:PRINTUSING"#######";YI;:PRINT@0,;:PRINTUSING"#######";YM;
10 LINE(47,54)-(227,54):LINE(227,54)-(227,56):LINE(47,54)-(47,56):LINE(47,54)-(47,0)
11 X0=X0+X2:XP=X0-XI:XP=48+XP*SX:Y0=X0*X(2)-X(1)*X0-X(0):YP=Y0-YI:YP=YP*SY:YP=54-YP
12 X1=X0+X2:XX=X1-XI:XX=48+XX*SX:Y1=X1*X(2)-X(1)*X1-X(0):YY=Y1-YI:YY=YY*SY:YY=54-YY:LINE(XP,YP)-(XX,YY):IFX1<XMTHEN11
13 X=47:LINE(X,54)-(X,56):X=X(4)-XI:X=48+X*SX:LINE(X,54)-(X,50):Y=0:Y=Y-YI:Y=Y*SY:Y=54-Y:LINE(47,Y)-(227,Y)
14 PRINT@80,R$"PROFIT$"N$;
15 Y$=INKEY$:IFY$=""THEN15
16 CLS:PRINT@10,R$" BREAKEVEN ANALYSIS "N$:PRINT:IFJ1<0THENJ1=0:J2=4
17 FORJ=J1TOJ2:PRINT" "X$(J),SPACE$(12);:PRINTUSINGF$(J);X(J):NEXTJ:PRINT@(JS*40)+14,">";
18 PRINT@281,R$" "CHR$(146)" =Move `>' "N$" "R$" "CHR$(154)" =Calculate "N$" "R$" "CHR$(155)" =Plot "N$;
19 Y$=INKEY$:IFY$=""THEN19
20 IFINSTR(A$,Y$)<>0THEN29
21 JZ=INSTR(AZ$,Y$):IFJZ=0THEN19
22 ONJZGOTO4,23,25,27,28,28
23 PRINT@(JS*40)+14," ";:JS=JS+1:IFJS>6THENJS=2
24 PRINT@(JS*40)+14,">";:GOTO19
25 PRINT@(40*JS)+14," ";:JS=JS-1:IFJS<2THENJS=6
26 PRINT@(40*JS)+14,">";:GOTO19
27 X(4)=INT(X(0)/(X(2)-X(1))):X(3)=X(0)+X(4)*X(1):GOTO16
28 MENU
29 PRINT@(40*JS)+14," ";:PRINT@280,R$" Enter data, press <ENTER>... "N$;:V$=Y$
30 PRINT@(40*JS)+15,V$CHR$(95)" ";
31 Y$=INKEY$:IFY$=""THEN31
32 IFY$=CHR$(13)THEN38
33 IFY$<>CHR$(29)THEN36
34 IFLEN(V$)=0THEN30
35 V$=LEFT$(V$,LEN(V$)-1):Y$="":GOTO30
36 IFINSTR(A$,Y$)=0THEN30
37 V$=V$+Y$:GOTO30
38 X(J1+JS-2)=VAL(V$):JS=JS+1:IFJS>6THENJS=2
39 GOTO16
40 J=-1
41 J=J+1:READX$:IFX$="END"THENJN=J-1:RETURN
42 X$(J)=X$:GOTO41:DATA Fixed Cost,Vari Cost,Unit Price,Total Cost,Breakeven,END
43 FORJ=0TO4:READF$(J):NEXTJ:RETURN:DATA"$$,###,###.##","$$,###,###.##","$$,###,###.##","$$,###,###.##","##########
44 IFERR=11THENCLS:PRINT@122,R$" Error in data, please re-enter..."N$:PRINT@214,"press <ENTER>...
45 IFERRTHENRESUME15ELSERESUME15