home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / bus / amort.ba next >
Text File  |  2006-10-19  |  3KB  |  91 lines
  1. 1 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
  2. 10 CLS
  3. 20 PRINT"Loan amortization version 2.0"
  4. 30 PRINT"By Jim Gerritz & Phil Estrem"
  5. 40 FORD=1TO1500:NEXTD:CLS
  6. 42 CLS:PRINT"PD=Payment date. IP=Interest paid"
  7. 44 PRINT"PP=Principle paid. RP=Remaining"
  8. 46 PRINT"principle."
  9. 48 INPUT"Press enter to continue";XX$
  10. 49 CLS
  11. 50 AT=0:LC=0:AM=0:ZZ=0
  12. 55 CC=0
  13. 60 PN=1:PA=1
  14. 130 C=0:INPUT"Principle";P
  15. 140 INPUT"Number of payments";L
  16. 150 INPUT"interest rate";R
  17. 160 INPUT"Month of first payment (06)";MM
  18. 165 INPUT"Year of first payment (84)";Y
  19. 170 ZZ=0
  20. 180 INPUT "Do you want a printout";A$:IF LEFT$(A$,1)="Y"OR LEFT$(A$,1)="y"THENZZ=1
  21. 190 I=R/12:I=I/100
  22. 200 T=1:FORX=1TOL
  23. 210 T=T*(1+I):NEXTX:T=1/T
  24. 220 T=1-T
  25. 230 M=P*I/T
  26. 240 M=INT(M*100+.5)/100
  27. 241 CLS
  28. 242 PRINT"Your monthly payment is ";:PRINTUSING "$$######.##";M
  29. 245 INPUT "Press enter to continue";XX$
  30. 250 GOSUB 600
  31. 260 FORZ=1TOL
  32. 270 IFC<5THEN300
  33. 280 IF ZZ=1THEN300
  34. 290 INPUT"Enter to continue";ZZ$:C=0:GOSUB600
  35. 300 A=(INT(P*I*100+.5))/100
  36. 305 CC=CC+A
  37. 310 B=M-A
  38. 320 IFB>PTHENM=A+P
  39. 330 IFB>PTHENB=P
  40. 340 P=P-B:P=INT(P*100+.5)/100
  41. 350 IFP<1THENB=B+P:IFP<1THENM=M+P:IFP<1THENP=0
  42. 360 PRINT USING"##";MM;:PRINT"/";Y;
  43. 365 PRINTTAB(1)
  44. 380 PRINTUSING"$$####.##";A,
  45. 385 PRINTTAB(12):PRINTUSING"$$####.##";B;
  46. 390 PRINTTAB(19);
  47. 395 PRINTUSING"$$######.##";P
  48. 400 IFZZ<>1THEN450
  49. 410 LPRINT TAB(3);:LPRINTUSING"###";PN;:LPRINT TAB(12);:LPRINTUSING"##";MM;
  50. 420 LPRINT" /";Y;:LPRINT TAB(24);:LPRINTUSING"$$####.##";M;:LPRINT TAB(36);
  51. 430 LPRINTUSING"$$####.##";A;:LPRINT TAB(48);:LPRINTUSING"$$####.##";B;
  52. 440 LPRINT TAB(60);:LPRINTUSING"$$#####.##";P
  53. 450 AM=AM+1:LC=LC+1
  54. 460 PN=PN+1
  55. 470 MM=MM+1:IFMM=13THENGOSUB820
  56. 480 IFZZ<>1THEN510
  57. 490 IFLC<67THEN510ELSELPRINTCHR$(12)
  58. 500 PA=PA+1:GOSUB600
  59. 510 AT=AT+A
  60. 520 C=C+1:NEXTZ
  61. 530 GOSUB820
  62. 540 PRINT"Total interest paid ";:PRINTUSING"$$#######.##";AT
  63. 550 IFZZ<>1THEN599
  64. 560 LPRINT
  65. 570 LPRINT TAB(12);"Total interest paid  ";:LPRINTTAB(35);:LPRINTUSING"$$#######.##";AT
  66. 580 LPRINTCHR$(12)
  67. 599 PRINT"Any more":INPUT ZZ$:IF ZZ$="y"THEN42 ELSE MENU
  68. 600 CLS
  69. 610 PRINT" PD        IP        PP        RP"
  70. 640 IFZZ<>1THEN810
  71. 710 IFPA>1THENLC=14:IFPA>1THEN770
  72. 720 LPRINT"Amount of loan: ";:LPRINTUSING"$$#####.##";P
  73. 730 LPRINT"Interest rate: ";R;"%"
  74. 740 LPRINT"Number of payments ";L
  75. 750 LPRINT"Monthly payment ";:LPRINTUSING"$$#####.##";M;:LPRINT:LPRINT
  76. 760 LC=20
  77. 770 LPRINT "   Payment    Payment    Monthly    Interest    Principle    Remaining"
  78. 780 LPRINT "   Number     Date       Payment     Paid       Paid         Principle"
  79. 790 LPRINT:LC=LC+3
  80. 800 C=0
  81. 810 RETURN
  82. 820 PRINT"Interest paid in ";Y;"  ";:PRINT USING "$$####.##";CC
  83. 840 IFZZ<>1THEN890
  84. 850 LPRINT:LPRINTTAB(12);"Interest paid in ";Y;:LPRINTTAB(36);CC
  85. 870 LPRINT
  86. 880 LC=LC+3
  87. 890 AM=0:MM=1:Y=Y+1
  88. 892 CC=0
  89. 895 IFY=100 THENY=0
  90. 900 RETURN
  91.