home *** CD-ROM | disk | FTP | other *** search
/ Usenet 1994 October / usenetsourcesnewsgroupsinfomagicoctober1994disk2.iso / misc / volume6 / fdecs < prev    next >
Text File  |  1989-03-21  |  5KB  |  242 lines
  1. Newsgroups: comp.sources.misc
  2. From: allbery@uunet.UU.NET (Brandon S. Allbery - comp.sources.misc)
  3. Message-Id: <8903141605.AA01288@m10ux>
  4. Subject: v06i073: fdecs - generate pANS prototypes from K&R C code
  5. Reply-To: mnc@m10ux.UUCP (52171.3-Michael Condict-- MHx5911 (MH0000)M999)
  6.  
  7. Posting-number: Volume 6, Issue 73
  8. Submitted-by: mnc@m10ux.UUCP (52171.3-Michael Condict-- MHx5911 (MH0000)M999)
  9. Archive-name: fdecs
  10.  
  11. [My, there's a lot of this kind of thing floating around recently.  ++bsa]
  12.  
  13. This shell script (fdecs) extracts ANSI-C function prototype declarations,
  14. suitable for use in a .h file, from C source files that contain old-style
  15. function definitions.  See the comment at the top of fdecs for more info.
  16.  
  17. The only option is "-Idir", which causes the C source to be run through the
  18. C preprocessor before the prototype extraction is done.
  19.  
  20. Mike Condict
  21.  
  22. ---------------------------- cut here --------------------------------------
  23. #!/bin/sh
  24. # This is a shar archive.
  25. # The rest of this file is a shell script which will extract:
  26. #
  27. # fdecs fdecs1.sed fdecs2.sed fdecs3.sed
  28. #
  29. # To extract the files from this shell archive file simply
  30. # create a directory for this file, move the archive file
  31. # to it and enter the command
  32. #
  33. #    sh filename
  34. # 
  35. # The files will be extracted automatically.
  36. # Note: Do not use csh.
  37. #
  38. # Archive created: Tue Mar 14 10:29:50 EST 1989
  39. #
  40. echo x - fdecs
  41. sed 's/^X//' > fdecs << '@FUNKY STUFF@'
  42.  
  43. # This script, given C source files, finds all the function definitions
  44. # of the form "type_decl f(a,b,...) type_decl a; type_decl b; ... { body }",
  45. # and outputs a file of extern function declarations suitable for a .h file.
  46. # There need not be a type_decl for each argument (defaults to int) and the
  47. # type_decl's can be in a different order from the arg list.  Multiple args
  48. # can be declared in the standard abbreviated fashion: "int a, *b;".
  49. #
  50. # The only restriction is that the type_decl's must be no more complicated
  51. # than what can be formed with type words, names, "*" and "[]".  That is the
  52. # type_decl's may not contain "struct ... {...}" or "float (*x)()" although,
  53. # e.g., "struct A" is allowed.
  54. #
  55. # The output is one line of the form 
  56. #
  57. #    type_decl f(type_decl a, type_decl b, . . . );
  58. #
  59. # for each function f defined in the source files, i.e. a legal ANSI-C
  60. # function prototype.
  61.  
  62. SEDDIR=~mnc/src/fdecs
  63.  
  64. Iflag=""
  65. while [ "$#" -gt 0 ]; do
  66.     case "$1" in
  67.     -I*)    Iflag="$Iflag $1"; shift
  68.         ;;
  69.     -*)    echo "Usage: $0 [ -Iincl_dir ] ... file ..."
  70.         echo "       (use -I only if C preprocessor is wanted)"
  71.         exit 1
  72.         ;;
  73.     *)    break ;;
  74.     esac
  75. done
  76.  
  77. if [ "$#" -eq 0 ] ; then
  78.     sed -f $SEDDIR/fdecs1.sed |
  79.     sed -f $SEDDIR/fdecs2.sed | sed -f $SEDDIR/fdecs3.sed
  80. elif [ "X$Iflag" != X ] ; then
  81.     # User wants to run the C files through the preprocessor, with
  82.     # the specified -I flag.  We delete the contents of the
  83.     # .h files from the preprocessor's output.  We also need to
  84.     # delete any occurrences of '^$filename:', which some versions
  85.     # of cc -E put out at the beginning of every file:
  86.     cc -E $Iflag "$@" | \
  87.         sed -e '#n No automatic printing
  88.  
  89.             # Delete contents of included .h files:
  90.             : chkhdr
  91.             /^# [1-9][0-9]* ".*\.h"/{
  92.                 : delhdr
  93.                     n
  94.                 /^#/!b delhdr
  95.                 b chkhdr
  96.             }
  97.             # Delete "filename:" inserted by "cc -E":
  98.             /^[^     ]*\.[ch]:[     ]*$/d
  99.             ' \
  100.             -f $SEDDIR/fdecs1.sed \
  101.             -e 'p' |
  102.         sed -f $SEDDIR/fdecs2.sed | sed -f $SEDDIR/fdecs3.sed
  103. else
  104.     sed -f $SEDDIR/fdecs1.sed "$@" |
  105.         sed -f $SEDDIR/fdecs2.sed | sed -f $SEDDIR/fdecs3.sed
  106. fi
  107. @FUNKY STUFF@
  108. ls -l fdecs
  109. echo x - fdecs1.sed
  110. sed 's/^X//' > fdecs1.sed << '@FUNKY STUFF@'
  111.  
  112. : morebs
  113. /\\$/ {
  114.     N
  115.     s/\\\n//
  116.     b morebs
  117. }
  118.  
  119. /^[     ]*$/d
  120.  
  121. : delcom
  122. /\/\*/{
  123.     s/@/ /g
  124.     s:/\*:@:
  125.  
  126.     : morecm
  127.     /\*\//!{
  128.         s/@.*/@/
  129.         N
  130.         b morecm
  131.     }
  132.  
  133.     s/\$/ /g
  134.  
  135.     s:\*/:$:
  136.     s/@[^$]*\$/ /
  137.  
  138.     b delcom
  139. }
  140.  
  141. /^#/d
  142.  
  143. s/\\"/ /g
  144. s/"[^"]*"/0/g
  145. s/\\'/ /g
  146. s/'[^']*'/0/g
  147.  
  148. /^[     ]*$/d
  149. @FUNKY STUFF@
  150. ls -l fdecs1.sed
  151. echo x - fdecs2.sed
  152. sed 's/^X//' > fdecs2.sed << '@FUNKY STUFF@'
  153. : delcbrc
  154. /{/{
  155.     s/{[^{}]*/{/g
  156.     : getcbrc
  157.     /}/!{
  158.         N
  159.         s/{[^{}]*/{/g
  160.         b getcbrc
  161.     }
  162.     s/{[^{}]*}/#/g
  163.     b delcbrc
  164. }
  165. s/#/{}/g
  166. @FUNKY STUFF@
  167. ls -l fdecs2.sed
  168. echo x - fdecs3.sed
  169. sed 's/^X//' > fdecs3.sed << '@FUNKY STUFF@'
  170.  
  171.  
  172. : doline
  173.  
  174.  
  175. : getsbr
  176. /[;{]/!{
  177.     N
  178.     b getsbr
  179. }
  180.  
  181. s/\n/ /g
  182. s/[     ][     ]*/ /g
  183.  
  184.  
  185. /;/{
  186.     /^[^;]*) *[a-zA-Z_{]/!{
  187.         s/^[^;]*;//
  188.         /^ *$/d
  189.         b doline
  190.     }
  191. }
  192.  
  193.  
  194. /[;)] *{}/!{
  195.     N
  196.     b doline
  197. }
  198.  
  199. s/^  *//
  200. s/( */(/g
  201. s/ *)/)/g
  202. s/ *, */, /g
  203. s/ *; */; /g
  204. s/ *\*/ \*/g
  205. s/\*  */\*/g
  206.  
  207.  
  208.  
  209. /() *{/b no_arg
  210.     s/, /, %/g
  211.     s/(/(, %/
  212.  
  213.     t more_t
  214.     : more_t
  215.         s/, %\([A-Za-z_][A-Za-z0-9_]*\)\(.*[);] *\)\([A-Za-z_][A-Za-z0-9_{} ]*\)\( *\)\(\**\1[][]*\)\([,;]\)/, \3 \5\2\3\4@\6/
  216.         s/, %\([A-Za-z_][A-Za-z0-9_]*\)\(.*[);] *\)\([A-Za-z_][A-Za-z0-9_{} ]*\)\( [^;]*, %\)\(\**\1[][]*\)\([,;]\)/, \3 \5\2\3\4@\6/
  217.     t more_t
  218.     
  219.     s/(, /(/
  220.     
  221.     s/%/int /g
  222.  
  223.     s?(\([^)]*\)).*?(\1);?
  224.  
  225.     / register/{
  226.         s/\([A-Za-z_0-9]\) register\([^A-Za-z0-9_]\)/\1\2/g
  227.         s/ register\([^A-Za-z0-9_][^A-Za-z0-9_]*[A-Za-z_][A-Za-z0-9_]*\),/ int\1,/g
  228.         s/ register\([^A-Za-z0-9_]\)/ \1/g
  229.     }
  230.  
  231.     s/   */ /g
  232.  
  233.     b done_a
  234. : no_arg
  235.     s/).*/void);/
  236. : done_a
  237. @FUNKY STUFF@
  238. ls -l fdecs3.sed
  239. # The following exit is to ensure that extra garbage 
  240. # after the end of the shar file will be ignored.
  241. exit 0
  242.