home *** CD-ROM | disk | FTP | other *** search
/ Usenet 1994 January / usenetsourcesnewsgroupsinfomagicjanuary1994.iso / sources / misc / volume5 / grabchars1.3 / Config next >
Encoding:
Text File  |  1989-02-03  |  2.3 KB  |  104 lines
  1. #!/bin/csh -f
  2. #
  3. #    $Header: Config,v 1.3 88/12/05 19:45:39 daniel grabchars_1_3 $
  4. #
  5. #    Config - set up Makefile for grabchars
  6. #
  7. #    Dan Smith (daniel@island.uu.net), November 1988
  8. #
  9. #    Config file for grabchars... must be csh, no attempt
  10. #    made to be eunice (i.e. echo " ") compatible...
  11. #
  12. clear
  13. cat << GUMBY
  14.  
  15.     Config for grabchars
  16.  
  17.     This csh script will figure out a few things about your
  18. system, and then will run a "make clean", a "make depend", and
  19. a "make release".  You should then try out grabchars, and, once assured
  20. that it's behaving itself, you should run a "make install"
  21.  
  22. GUMBY
  23. echo -n 'press return to start...'
  24. set ignore=$<
  25.  
  26. #    figure out where to put this when the user types
  27. #    "make install"...we'll try in three likely places...
  28.  
  29. foreach try_bin (/usr/local{/bin,} /usr/public/bin)
  30.     echo -n looking at $try_bin...
  31.     if (-w $try_bin) then
  32.         set bin_dir=$try_bin && echo yep... && break
  33.     endif
  34.     echo ""
  35. end
  36.  
  37. #    figure out where to put the man pages when the user
  38. #    "make install"...a few places come to mind...
  39.  
  40. foreach try_man (/usr/{,local/,public/}man/man1)
  41.     echo -n looking at $try_man...
  42.     if (-w $try_man) then
  43.         set man_dir=$try_man && echo yep... && break
  44.     endif
  45.     echo ""
  46. end
  47.  
  48. if ($?bin_dir) then
  49.     echo BIN_DIR looks like it will be $bin_dir
  50. else
  51.     echo BIN_DIR is unknown...check the Makefile when it comes up...
  52.     set bin_dir=""
  53. endif
  54.  
  55. if ($?man_dir) then
  56.     echo MAN_DIR looks like it will be $man_dir
  57. else
  58.     echo MAN_DIR is unknown...check the Makefile when it comes up...
  59.     set man_dir=""
  60. endif
  61.  
  62. set myedit=vi
  63. if ($?EDITOR) then
  64.     set myedit=$EDITOR
  65. endif
  66.  
  67. oh_really:
  68.     if (! -e $myedit) then
  69.         echo -n "I don't see a $myedit...where is your editor? "
  70.         set myedit=$<
  71.         echo ok...
  72.     endif
  73.  
  74. echo editor of choice seems to be \"$myedit\"...
  75.  
  76. if  (-e Makefile) mv Makefile{,.old} >& /dev/null
  77.  
  78. echo making makefile...
  79. sed    -e "s+^BIN_DIR.*+BIN_DIR = $bin_dir+" \
  80.     -e "s+^MAN_DIR.*+MAN_DIR = $man_dir+" \
  81.     -e "s+^EDITOR.*+EDITOR = $myedit+" \
  82.     < Makefile.dist > Makefile
  83.  
  84. echo going to $myedit with Makefile for you to check out..
  85. echo -n press return...
  86. set ignore=$<
  87. $myedit Makefile || \
  88.     echo where is your editor\?\!\!  && goto oh_really
  89.  
  90. echo " "
  91. echo clean up any residue from before, doing a \"make clean\"
  92. sleep 2
  93. make clean
  94.  
  95. echo " "
  96. echo going to run a \"make depend\"...
  97. sleep 2
  98. make depend
  99.  
  100. echo " "
  101. echo ok, let\'s try to make this with \"make release\"
  102. sleep 2
  103. make release
  104.