home *** CD-ROM | disk | FTP | other *** search
/ Total C++ 2 / TOTALCTWO.iso / vfp5.0 / vfp / samples / tastrade / progs / utility.prg < prev   
Encoding:
Text File  |  1996-08-21  |  2.3 KB  |  86 lines
  1. *-- (c) Microsoft Corporation 1995
  2.  
  3. *-- General purpose utility functions independent of any classes
  4. *-- for better performance and accessibility
  5.  
  6. #INCLUDE "INCLUDE\TASTRADE.H"
  7.  
  8. ************************************
  9. FUNCTION IsTag (tcTagName, tcAlias)
  10.   *-- Receives a tag name and an alias (which is optional) as
  11.   *-- parameters and returns .T. if the tag name exists in the
  12.   *-- alias. If no alias is passed, the current alias is assumed.
  13.   LOCAL llIsTag, ;
  14.         lcTagFound
  15.  
  16.   IF PARAMETERS() < 2
  17.     tcAlias = ALIAS()
  18.   ENDIF
  19.   
  20.   IF EMPTY(tcAlias)
  21.     RETURN .F.
  22.   ENDIF
  23.  
  24.   llIsTag = .F.
  25.   tcTagName = UPPER(ALLTRIM(tcTagName))
  26.  
  27.   lnTagNum = 1
  28.   lcTagFound = TAG(lnTagNum, tcAlias)
  29.   DO WHILE !EMPTY(lcTagFound)
  30.     IF UPPER(ALLTRIM(lcTagFound)) == tcTagName
  31.       llIsTag = .T.
  32.       EXIT
  33.     ENDIF
  34.     lnTagNum = lnTagNum + 1
  35.     lcTagFound = TAG(lnTagNum, tcAlias)
  36.   ENDDO
  37.  
  38.   RETURN llIsTag
  39. ENDFUNC
  40.  
  41. FUNCTION NotYet()
  42.   *-- Used during construction of Tastrade to indicate those
  43.   *-- parts of the application that were not yet completed.
  44.   =MESSAGEBOX(NOTYET_LOC, MB_ICONINFORMATION)
  45.   RETURN
  46. ENDFUNC
  47.  
  48. FUNCTION FileSize(tcFileName)
  49.   *-- Returns the size of a file. SET COMPATIBLE must be ON for
  50.   *-- FSIZE() to return the size of a file. Otherwise, it returns
  51.   *-- the size of a field.
  52.   LOCAL lcSetCompatible, lnFileSize
  53.  
  54.   lcSetCompatible = SET('COMPATIBLE')
  55.   SET COMPATIBLE ON
  56.   lnFileSize = FSIZE(tcFileName)
  57.   SET COMPATIBLE &lcSetCompatible
  58.   RETURN lnFileSize
  59. ENDFUNC
  60.  
  61. FUNCTION FormIsObject()
  62.   *-- Return .T. if the active form is of type "O" and its baseclass
  63.   *-- is "Form". 
  64.   RETURN (TYPE("_screen.activeform") == "O" AND ;
  65.           UPPER(_screen.ActiveForm.BaseClass) = "FORM")
  66. ENDFUNC
  67.  
  68. FUNCTION ToolBarEnabled
  69.   *- Return value of Toolbar object
  70.   PARAMETER oObject
  71.   LOCAL oToolObj
  72.   oToolObj = "oApp.oToolBar." + oobject + ".enabled"
  73.   IF TYPE(oToolObj) # "L"
  74.     RETURN .F. 
  75.   ELSE
  76.     RETURN EVAL(oToolObj)
  77.   ENDIF
  78. ENDFUNC
  79.  
  80. FUNCTION OnShutdown()
  81.   *-- Custom message called via the ON SHUTDOWN command to indicate
  82.   *-- that the user must exit Tastrade before exiting Visual Foxpro.
  83.   =MESSAGEBOX(CANNOTQUIT_LOC, ;
  84.               MB_ICONEXCLAMATION, ;
  85.               TASTRADE_LOC)
  86. ENDFUNC