home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Time Riders in American History
/
TR_AMAZ.BIN
/
tr
/
strip.inf
< prev
next >
Wrap
INI File
|
1996-06-03
|
41KB
|
1,579 lines
DefineVariables
Text [ProgramName] := Time Riders
Text [VersionNumber] := Version 1.0
Text [ProgramExecutable] := TR.EXE
Text [ShortCommandLine] := TR
Text [BatchFileName] := TR.BAT
Text [IconFileName] := TR.ICO
Text [PifFilename] := TR.PIF
Text [ProgramStart] := TR
Directory [DefaultDirectory] := \TLC\TR
Number [RequiredRAM] := 563200
Logical [MouseRequired] := N
Number [HardDiskSpaceNeeded] := 2740000
Text [RequiredDosVersion] := version 3.0
Text [OtherProducts] := Student Writing Center Operation Neptune Ancient Empires
Logical [SoundBlasterSupported] := Y
Logical [AdLibSupported] := Y
Logical [RolandSupported] := Y
Logical [MicrosoftSoundSupported] := N
Logical [Tandy1000Supported] := Y
Logical [PS1Supported] := N
Logical [NoSoundSupported] := N
Text [SoundBlasterSwitch] := -SA
Text [AdLibSwitch] := -SA
Text [RolandSwitch] := -SR
Text [MicrosoftSoundSwitch] := -SA
Text [Tandy1000Switch] := -ST
Text [PS1Switch] := -ST
Text [PCSpeakerSwitch] := -SI
Text [NoSoundSwitch] := -SI
Logical [CGASupported] := N
Logical [MCGASupported] := Y
Logical [EGASupported] := Y
Logical [TGASupported] := Y
Logical [VGASupported] := Y
Text [CGASwitch] := -V
Text [MCGASwitch] := -M
Text [TGASwitch] := -T
Text [EGASwitch] := -E
Text [VGASwitch] := -V
Logical [Demo] := N
Logical [ForceHardDisk] := N
Logical [HardDiskInstall] := Y
Number [N]
Number [MenuItemToHighlight]
Directory [ExistingCopyPath]
Directory [SourceDirectory]
Number [ButtonWidth]
Number [ButtonHeight]
Number [DlgReturn]
Text [InstallerName]
Logical [RamChecked] := N
Logical [DosChecked] := N
Logical [MouseChecked] := N
Logical [SoundChecked] := N
Logical [VideoChecked] := N
Logical [DrivesChecked] := N
TextArray [Array1]
Number [SOUNDCHKcode] := 0
Text [DetectedSoundCard] := BlankString
Text [SoundCard] := BlankString
Text [SoundSwitch]
Text [VoiceSwitch]
Number [NumSoundOptions]
TextArray [Array2]
Number [VIDEOCHKcode] := 0
Text [DetectedVideoCard] := BlankString
Text [VideoCard] := BlankString
Text [VideoSwitch]
Number [NumVideoOptions]
TextArray [Array3]
TextArray [Array4]
Number [VideoCardIndex] := 4
Logical [ValidDrive]
Text [Drive]
Number [NumDrives]
Logical [Test]
Text [TargetDrive]
Text [CurrentFile]
Text [CurrentDiskName]
Text [ProgramCommandLine]
Logical [ConfirmCancel] := N
Logical [Continue]
Number [FreeDiskSpace]
Number [AdditionalSpace]
Number [FreeRam]
Number [AvailableRAM]
Number [AdditionalRAM]
Logical [NotEnoughDiskSpace]
Number [PercentComplete]
Number [OldNumSolidBlocks] := 1
Number [NumSolidBlocks] := 0
Text [SolidBar] := BlankString
Text [StatusBar] := BlankString
Number [SizeOfCopiedFiles]
Number [TopY]
Number [BottomY]
Number [LeftX]
Number [RightX]
Number [BarTopY]
Number [BarBottomY]
Number [BarLeftX]
Number [BarRightX]
Text [CompanyName] := The Learning Company
Text [LogoFilename] := TLC.BMP
Text [Indent] := " "
Number [SizeOfInstall] := 479000
Number [NoSoundCard] := 1
Number [SoundBlaster] := 3
Number [AdLib] := 3
Number [Roland] := 4
Number [MicrosoftSound] := 3
Number [Tandy1000] := 2
Number [PS1SoundChip] := 2
Text [PCSpeakerString] := no supported sound card.
Text [SoundBlasterString] := a SoundBlaster-compatible sound card.
Text [AdLibString] := an AdLib-compatible sound card.
Text [RolandString] := a Roland sound card.
Text [MicrosoftSoundString] := a Microsoft Sound System.
Text [Tandy1000String] := a Tandy 1000 sound system.
Text [PS1String] := a PS/1 Sound Chip.
Text [NoSoundMenu] := Turn Sound Off
Text [PCSpeakerMenu] := Internal Speaker
Text [SoundBlasterMenu] := SoundBlaster
Text [AdLibMenu] := AdLib
Text [RolandMenu] := Roland
Text [MicrosoftSoundMenu] := Microsoft Sound System
Text [Tandy1000Menu] := Tandy 1000 sound system
Text [PS1Menu] := PS/1 sound chip
Number [CGA] := 1
Number [MCGA] := 3
Number [EGA] := 2
Number [TGA] := 5
Number [VGA] := 4
Text [CGAString] := a CGA display card.
Text [MCGAString] := an MCGA display card.
Text [EGAString] := an EGA display card.
Text [TGAString] := a Tandy Graphics Adapter.
Text [VGAString] := a VGA display card.
Text [CGAMenu] := CGA graphics (4 colors)
Text [MCGAMenu] := MCGA graphics (256 colors)
Text [EGAMenu] := EGA graphics (16 colors)
Text [TGAMenu] := Tandy 1000 graphics (16 colors)
Text [VGAMenu] := VGA graphics (256 colors)
EndDefineVariables
ClearScreen
Do Initialize
Do WelcomeScreen
:LoopMainMenu
Do MainMenu
SoLong
Procedure AddProgramToGroup
BuildProgramGroup "The Learning Company" THELEARN.GRP
[InstallationDirectory]\[PIFFilename] "[ProgramName]" [InstallationDirectory]\[IconFileName] 1 [InstallationDirectory]
EndBuildProgramGroup
EndProcedure
Procedure BlankBottomLine
If .NOT. Windows
SetBottomLineTo " "
EndIf
EndProcedure
Procedure BuildCommandLine
Do SetVideoSwitch
Do SetSoundSwitch
[ProgramCommandLine] := [ProgramExecutable] [SoundSwitch] [VideoSwitch] [VoiceSwitch] %1 %2
EndProcedure
Procedure BuildSoundCardList
[NumSoundOptions] := 1
[Array2][1] := [PCSpeakerMenu]
If [SoundBlasterSupported]
IncrementNumber [NumSoundOptions]
[Array2][[NumSoundOptions]] := [SoundBlasterMenu]
EndIf
If [AdLibSupported]
IncrementNumber [NumSoundOptions]
[Array2][[NumSoundOptions]] := [AdLibMenu]
EndIf
If [RolandSupported]
IncrementNumber [NumSoundOptions]
[Array2][[NumSoundOptions]] := [RolandMenu]
EndIf
If [MicrosoftSoundSupported]
IncrementNumber [NumSoundOptions]
[Array2][[NumSoundOptions]] := [MicrosoftSoundMenu]
EndIf
If [Tandy1000Supported]
IncrementNumber [NumSoundOptions]
[Array2][[NumSoundOptions]] := [Tandy1000Menu]
EndIf
If [PS1Supported]
IncrementNumber [NumSoundOptions]
[Array2][[NumSoundOptions]] := [PS1Menu]
EndIf
If [NoSoundSupported]
IncrementNumber [NumSoundOptions]
[Array2][[NumSoundOptions]] := [NoSoundMenu]
EndIf
EndProcedure
Procedure BuildVideoCardList
[NumVideoOptions] := 0
If [VGASupported]
IncrementNumber [NumVideoOptions]
[Array3][[NumVideoOptions]] := [VGAMenu]
[Array4][[NumVideoOptions]] := [VGA]
EndIf
If [EGASupported]
IncrementNumber [NumVideoOptions]
[Array3][[NumVideoOptions]] := [EGAMenu]
[Array4][[NumVideoOptions]] := [EGA]
EndIf
If Windows
Else
If [TGASupported]
IncrementNumber [NumVideoOptions]
[Array3][[NumVideoOptions]] := [TGAMenu]
[Array4][[NumVideoOptions]] := [TGA]
EndIf
If [MCGASupported]
IncrementNumber [NumVideoOptions]
[Array3][[NumVideoOptions]] := [MCGAMenu]
[Array4][[NumVideoOptions]] := [MCGA]
EndIf
If [CGASupported]
IncrementNumber [NumVideoOptions]
[Array3][[NumVideoOptions]] := [CGAMenu]
[Array4][[NumVideoOptions]] := [CGA]
EndIf
EndIf
EndProcedure
Procedure CancelInstall
If Windows
Exit
EndIf
Dialog [ConfirmCancel] WhiteOnRed
Do you really want to cancel the installation?
EndDialog
If [ConfirmCancel] = Y
SoLong
EndIf
EndProcedure
Procedure ChangeSettings
Do GetDriveList
Do FindExistingCopy
Do ConfirmSoundCard
Do ConfirmVideoCard
Do BuildCommandLine
TextBox @xy(Center,Center) BlueOnWhite
Saving new settings...
EndTextBox
Do ModifyBatchFile
ClearScreen
Dialog PressAKey WhiteOnBlue UseHeader " Settings Saved "
Your new settings have been saved.
EndDialog
SetCompletionStatusTo Finished
ClearScreen
EndProcedure
Procedure CheckDOS
If [DosChecked]
Exit
EndIf
[DosChecked] := Y
[String1] := version of DOS.
If Windows
[String1] := "[String1] "
Else
EndIf
If OSVersion<2.0 .OR. [Demo]
Beep
[String2] := [ProgramName] requires DOS [RequiredDOSVersion] or higher.
:LoopCheckDos
Dialog [Continue] WhiteOnRed UseHeader " Incorrect DOS Version "
Your computer does not have the correct version of DOS.
[String2]
You can still install the program on your hard disk.
However, it will not work until you install a supported
[String1]
Do you want to continue with the installation?
EndDialog
If Escaped
If Windows
Else
Do CancelInstall
GoTo LoopCheckDos
EndIf
EndIf
If [Continue]
Else
SoLong
EndIf
EndIf
EndProcedure
Procedure CheckHardDiskSpace
[NotEnoughDiskSpace] := N
[FreeDiskSpace] := FreeSpaceOnDrive InstallationDrive
[AdditionalSpace] := [HardDiskSpaceNeeded]-[FreeDiskSpace]
If [FreeDiskSpace]<[HardDiskSpaceNeeded] .OR. [ForceHardDisk]
[ForceHardDisk] := N
[NotEnoughDiskSpace] := Y
[Number1] := [AdditionalSpace]/1024
Beep
:LoopCheckHardDiskSpace
Dialog [Continue] WhiteOnRed UseHeader " Not Enough Disk Space "
You do not have enough room on this hard disk to install
[ProgramName]. You need an additional [Number1] KB.
You can either install to a different hard disk
OR you can quit the installer to make more
room on this hard disk by deleting unused files.
Remember to make copies of any files
you might need in the future.
Do you want to install the program on a different hard disk?
EndDialog
If Escaped
Do CancelInstall
GoTo LoopCheckHardDiskSpace
EndIf
If [Continue]
If [NumDrives]>1
GoTo LoopGetDrive
Else
Dialog PressAKey WhiteOnRed UseHeader " Only One Drive "
Your computer only has one hard disk. This hard
disk does not have enough room to install
[ProgramName]. Please quit and make more room
available on your hard disk.
EndDialog
GoTo LoopMainMenu
EndIf
Else
SoLong
EndIf
EndIf
EndProcedure
Procedure CheckIfProgramExists
If FileExists [InstallationDirectory]\[ProgramExecutable]
:LoopCheckIfProgramExists
Dialog [Continue] WhiteOnRed UseHeader "Program Already Installed"
A version of [ProgramName] already exists
in the directory [InstallationDirectory].
If you continue the installation, this
version will be replaced.
Do you want to re-install [ProgramName]?
EndDialog
If Escaped
Do CancelInstall
GoTo LoopCheckIfProgramExists
EndIf
If .NOT. [Continue]
GoTo LoopMainMenu
EndIf
EndIf
EndProcedure
Procedure CheckMouse
If [MouseChecked]
Exit
EndIf
[MouseChecked] := Y
If .NOT. [MouseRequired]
Exit
EndIf
If .NOT. Windows
If .NOT. MouseDriverLoaded .OR. [Demo]
Beep
:LoopCheckMouse
Dialog PressAKey WhiteOnRed UseHeader " No Mouse "
[ProgramName] requires a mouse. Your computer does not
currently have a mouse driver installed. You can install
a mouse driver by modifying either your CONFIG.SYS or
AUTOEXEC.BAT files.
See your computer manual or the manual for your mouse
for instructions on loading a mouse driver.
EndDialog
If Escaped
Do CancelInstall
GoTo LoopCheckMouse
EndIf
EndIf
EndIf
EndProcedure
Procedure CheckRAM
If [RamChecked]
Exit
EndIf
[RamChecked] := Y
If Windows
Exit
Else
[FreeRam] := FreeRunMemory
EndIf
[AvailableRAM] := [FreeRam] + [SizeOfInstall]
[AdditionalRAM] := [RequiredRAM] - [AvailableRAM]
[RequiredRAM] := [RequiredRAM]/1024
[AvailableRAM] := [AvailableRam]/1024
[AdditionalRAM] := [AdditionalRAM]/1024
If [AvailableRAM]<[RequiredRAM] .OR. [Demo]
Beep
:LoopCheckRam
Dialog [Continue] WhiteOnRed UseHeader " Not Enough Memory "
Your computer does not have enough RAM memory to run
[ProgramName].
[ProgramName] requires [RequiredRAM] KB of RAM to run.
Your computer has only [AvailableRAM] KB of RAM available.
You need an additional [AdditionalRAM] KB of RAM.
To free additional memory, you may:
.iRemove memory-resident programs (TSR's).
.iUse a memory manager.
.iLoad DOS in high memory. (See your DOS manual.)
.cDo you still want to install [ProgramName]?
EndDialog
If Escaped
Do CancelInstall
GoTo LoopCheckRAM
EndIf
If [Continue]
Else
SoLong
EndIf
EndIf
EndProcedure
Procedure CheckSameDirectory
If [InstallationDirectory] = [InstallFromDrive]:[DefaultDirectory]
Dialog PressAKey WhiteOnRed UseHeader "Can't copy to this directory!"
You are trying to copy files from one directory
into the same directory!
Please select a different installation directory.
EndDialog
GoTo LoopMainMenu
EndIf
EndProcedure
Procedure CheckValidDrive
[ValidDrive] := N
[N] := 1
[String1] := InstallationDrive:
While [N]<=[NumDrives]
If [String1] = [Array1][[N]]
[ValidDrive] := Y
Exit
Else
EndIf
IncrementNumber [N]
EndWhile
EndProcedure
Procedure ConfirmSoundCard
Do DetectSoundCard
If Windows
Do ConfirmSoundCardWin
Else
Do ConfirmSoundCardDos
EndIf
EndProcedure
Procedure ConfirmSoundCardDos
[String1] := [ProgramName] supports the following sound options.
[String2] := [InstallerName] has detected that your computer has
[String3] := [SoundCard]
[String4] := Please confirm this setting or choose a different
[String5] := sound option from the list below.
[String6] := .cUse the arrow keys to highlight the
[String7] := .csound option you want. Then press Enter.
Do SetSoundCardMenuItem
:LoopConfirmSoundDos
TextBox @xy(Center,3) WhiteOnBlue UseHeader " Sound Options "
[String1]
[String2]
[String3]
[String4]
[String5]
[String6]
[String7]
EndTextBox
GetMenuChoice BlueOnWhite Highlight [MenuItemToHighlight]
[Array2]
EndGetMenuChoice
If Escaped
Do CancelInstall
GoTo LoopConfirmSoundDOS
Else
[SoundCard] := ChoiceText
EndIf
ClearScreen
EndProcedure
Procedure ConfirmSoundCardWin
SetCoordinatesTo Pixel
[String1] := [ProgramName] supports the following
[String2] := sound options. Please choose a sound option
[String3] := from the list below.
[String4] := Use the arrow keys or mouse to highlight
[String5] := the sound option you want. Then click OK.
[ButtonWidth] := 50
[ButtonHeight] := 20
[String10] := [Array2][1]
[Number1] := [NumSoundOptions]
[Number2] := 6*8 + 4*10 + 15 + [ButtonHeight] + [Number1]*9+2
[Number3] := 150
[Number4] := [Number1]*9+2
[Number5] := [Number3]+20
[Number6] := [Number2] - 15 - [ButtonHeight]
[Number7] := [Number6] - 16
[Number8] := [Number7] - 8
[Number9] := [Number5]/2-50
[Number10] := ([Number5]/2)-8-[ButtonWidth]
[Number11] := ([Number5]/2)+16
:LoopConfirmSoundWin
DialogBox @xy(CenterWindow,CenterWindow) [Number5] [Number2] Returns [DlgReturn] UseHeader "Sound Options" ModalFrame SysMenu BorDlg
Font "Helv" 8
LText @xy(10,10) [Number3] 10 [String1]
LText @xy(10,18) [Number3] 10 [String2]
LText @xy(10,26) [Number3] 10 [String3]
LText @xy([Number9],42) 100 10 "Sound Options"
ListBox @xy([Number9],50) 100 [Number4] Uses [DetectedSoundCard] LoadWith [Array2] Border
LText @xy(10,[Number8]) [Number3] 10 [String4]
LText @xy(10,[Number7]) [Number3] 10 [String5]
BorDefPushButton @xy([Number10],[Number6]) [ButtonWidth] [ButtonHeight] "OK" OK
BorPushButton @xy([Number11],[Number6]) [ButtonWidth] [ButtonHeight] "Cancel" Cancel
EndDialogBox
If Escaped
GoTo LoopConfirmSoundWin
EndIf
SetCoordinatesTo 80x25
ClearScreen
If [DlgReturn]=1
[SoundCard] := [DetectedSoundCard]
Else
GoTo LoopMainMenu
EndIf
EndProcedure
Procedure ConfirmVideoCard
If [NumVideoOptions] = 1
[DetectedVideoCard] := [EGAMenu]
[VideoCardIndex] := [EGA]
Exit
EndIf
Do DetectVideoCard
[String1] := [ProgramName] supports the following graphics
[String2] := adapters. [InstallerName] has detected that your
[String3] := computer has [VideoCard]
[String4] := Please confirm this setting or choose a different
[String5] := graphics option from the list below.
If Windows
Do WinConfirmVideoCard
Else
Do DosConfirmVideoCard
EndIf
EndProcedure
Procedure DosConfirmVideoCard
Do SetVideoCardMenuItem
[String6] := .cUse the arrow keys to highlight the
[String7] := .csound option you want. Then press Enter.
:LoopConfirmVideoDos
TextBox @xy(Center,3) WhiteOnBlue UseHeader " Graphics Options "
[String1]
[String2]
[String3]
[String4]
[String5]
[String6]
[String7]
EndTextBox
GetMenuChoice BlueOnWhite Highlight [MenuItemToHighlight] UseHeader " Graphics Options "
[Array3]
EndGetMenuChoice
If Escaped
Do CancelInstall
GoTo LoopConfirmVideoDos
Else
InCase Choice is
=1: [VideoCardIndex] := [Array4][1]
=2: [VideoCardIndex] := [Array4][2]
=3: [VideoCardIndex] := [Array4][3]
=4: [VideoCardIndex] := [Array4][4]
=5: [VideoCardIndex] := [Array4][5]
EndInCase
EndIf
ClearScreen
EndProcedure
Procedure WinConfirmVideoCard
SetCoordinatesTo Pixel
[String6] := Use the arrow keys or mouse to highlight
[String7] := the graphics option you want. Then click OK.
[ButtonWidth] := 50
[ButtonHeight] := 20
[String10] := [Array3][1]
[Number1] := [NumVideoOptions]
[Number2] := 8*8 + 4*10 + 15 + [ButtonHeight] + [Number1]*9+2
[Number3] := 170
[Number4] := [Number1]*9+2
[Number5] := [Number3]+20
[Number6] := [Number2] - 15 - [ButtonHeight]
[Number7] := [Number6] - 16
[Number8] := [Number7] - 8
[Number9] := [Number5]/2-50
[Number10] := ([Number5]/2)-8-[ButtonWidth]
[Number11] := ([Number5]/2)+16
:LoopConfirmVideoWin
DialogBox @xy(CenterWindow,CenterWindow) [Number5] [Number2] Returns [DlgReturn] UseHeader "Graphics Options" ModalFrame SysMenu BorDlg
Font "Helv" 8
LText @xy(10,10) [Number3] 10 [String1]
LText @xy(10,18) [Number3] 10 [String2]
LText @xy(10,26) [Number3] 10 [String3]
LText @xy(10,34) [Number3] 10 [String4]
LText @xy(10,42) [Number3] 10 [String5]
LText @xy([Number9],60) 100 10 "Graphics Options"
ListBox @xy([Number9],68) 100 [Number4] Uses [DetectedVideoCard] LoadWith [Array3] Border
LText @xy(10,[Number8]) [Number3] 10 [String6]
LText @xy(10,[Number7]) [Number3] 10 [String7]
BorDefPushButton @xy([Number10],[Number6]) [ButtonWidth] [ButtonHeight] "OK" OK
BorPushButton @xy([Number11],[Number6]) [ButtonWidth] [ButtonHeight] "Cancel" Cancel
EndDialogBox
If Escaped
GoTo LoopConfirmVideoWin
EndIf
SetCoordinatesTo 80x25
ClearScreen
If [DlgReturn]= 1
If [DetectedVideoCard] = [VGAMenu]
[VideoCardIndex] := [VGA]
EndIf
If [DetectedVideoCard] = [EGAMenu]
[VideoCardIndex] := [EGA]
EndIf
If [DetectedVideoCard] = [TGAMenu]
[VideoCardIndex] := [TGA]
EndIf
If [DetectedVideoCard] = [MCGAMenu]
[VideoCardIndex] := [MCGA]
EndIf
If [DetectedVideoCard] = [CGAMenu]
[VideoCardIndex] := [CGA]
EndIf
Else
GoTo LoopMainMenu
EndIf
EndProcedure
Procedure CopyAllFiles
ClearScreen
Do CheckSameDirectory
Do CopyFilesTextBox
[SizeOfCopiedFiles] := 0
Do RegistrationReminder
[PercentComplete] := 0
If Windows
Do StatusBarWinSetup
Else
Do StatusBar
EndIf
[SourceDirectory] := [InstallFromDrive]:\TR\
If Windows
SetCopyAttrTo 20
CopyFiles from [InstallFromDrive]:\TR to [InstallationDirectory] Quietly
SETUP.EXE
TLC.BMP
EndCopyFiles
[SizeOfCopiedFiles] := 8630 + SizeOfFile [InstallationDirectory]\TR\SETUP.EXE
Else
CopyFiles from [InstallFromDrive]:\TR\ to [InstallationDirectory] Quietly
INSTALL.EXE
VIDEOCHK.EXE
SOUNDCHK.EXE
TLC.BMP
EndCopyFiles
[SizeOfCopiedFiles] := 8630 + 6560 + 8576 + SizeOfFile [InstallationDirectory]\TR\INSTALL.EXE
EndIf
Do StatusBar
[SourceDirectory] := [InstallFromDrive]:[DefaultDirectory]
[CurrentFile] := HOF.DAT
Do CopyCurrentFile
[CurrentFile] := TR.BAT
Do CopyCurrentFile
[CurrentFile] := TR.ICO
Do CopyCurrentFile
[CurrentFile] := TR.PIF
Do CopyCurrentFile
[CurrentFile] := USERS.DAT
Do CopyCurrentFile
[CurrentFile] := TR.EXE
Do CopyCurrentFile
Do CrossSell
[CurrentFile] := X000.DAT
Do CopyCurrentFile
Do ModifyBatchFile
[PercentComplete] := 95
If Windows
Do ModifyProgramGroup
EndIf
SetCompletionStatusTo Finished
[PercentComplete] := 100
Do StatusBar
Delay 2000
ClearScreen
EndProcedure
Procedure CopyCurrentFile
If Windows
Else
SetAllowExit On
EndIf
QueFiles
[CurrentFile]
EndQueFiles
GetQuedFiles Quietly
If Windows
Else
If QueSize >0
SoLong
EndIf
SetAllowExit Off
EndIf
[SizeOfCopiedFiles] := [SizeOfCopiedFiles] + SizeOfFile [InstallationDirectory]\[CurrentFile]
Do StatusBar
EndProcedure
Procedure CopyFilesTextBox
SetShadows Off
[String1] := Installing [ProgramName]...
If Windows
[String1] := [String1] Press ESC to cancel.
EndIf
TextBox @xy(Center,3) BlueOnWhite
[String1]
EndTextBox
SetShadows On
EndProcedure
Procedure CrossSell
If Windows
[OtherProducts] := " [OtherProducts]"
Else
[OtherProducts] := .c[OtherProducts]
EndIf
SetShadows Off
TextBox @xy(Center,7) BlueOnWhite
The Learning Company's unique system of products focuses on
important curricular, thinking, and problem-solving skills
appropriate for your child's age and stage of development.
Given your child's age, the following Learning Company products
are most appropriate:
[OtherProducts]
Stop by your local retail store or call 1-800-852-2255
to purchase these and other Learning Company products.
EndTextBox
SetShadows On
EndProcedure
Procedure DetectSoundCard
If [SoundChecked]
Exit
EndIf
[SoundChecked] := Y
[SOUNDCHKcode] := [NoSoundCard]
[SoundCard] := [PCSpeakerString]
If Windows
[SOUNDCHKcode] := [SoundBlaster]
Else
Run [InstallFromDirectory]SOUNDCHK.EXE Quietly NoPrompt
[SOUNDCHKcode] := OSExitCode
EndIf
If [SOUNDCHKcode] = [NoSoundCard]
[DetectedSoundCard] := [PCSpeakerMenu]
[SoundCard] := [PCSpeakerString]
EndIf
If [RolandSupported]
If [SOUNDCHKcode] = [Roland]
[DetectedSoundCard] := [RolandMenu]
[SoundCard] := [RolandString]
EndIf
EndIf
If [PS1Supported]
If [SOUNDCHKcode] = [PS1SoundChip]
[DetectedSoundCard] := [PS1Menu]
[SoundCard] := [PS1String]
EndIf
EndIf
If [Tandy1000Supported]
If [SOUNDCHKcode] = [Tandy1000]
[DetectedSoundCard] := [Tandy1000Menu]
[SoundCard] := [Tandy1000String]
EndIf
EndIf
If [MicrosoftSoundSupported]
If [SOUNDCHKcode] = [MicrosoftSound]
[DetectedSoundCard] := [MicrosoftSoundMenu]
[SoundCard] := [MicrosoftSoundString]
EndIf
EndIf
If [AdLibSupported]
If [SOUNDCHKcode] = [AdLib]
[DetectedSoundCard] := [AdLibMenu]
[SoundCard] := [AdLibString]
EndIf
EndIf
If [SoundBlasterSupported]
If [SOUNDCHKcode] = [SoundBlaster]
[DetectedSoundCard] := [SoundBlasterMenu]
[SoundCard] := [SoundBlasterString]
EndIf
EndIf
EndProcedure
Procedure DetectVideoCard
If [VideoChecked]
Exit
EndIf
[VideoChecked] := Y
If [NumVideoOptions] = 1
Exit
EndIf
[VIDEOCHKcode] := [VGA]
[DetectedVideoCard] := [VGAMenu]
[VideoCard] := [VGAString]
If Windows
If VGA
[VIDEOCHKcode] := [VGA]
EndIf
If EGA
[VIDEOCHKcode] := [EGA]
EndIf
Else
Run [InstallFromDirectory]VIDEOCHK.EXE Quietly NoPrompt
[VIDEOCHKcode] := OSExitCode
EndIf
[VideoCardIndex] := [VIDEOCHKcode]
If [CGASupported]
If [VIDEOCHKcode] = [CGA]
[DetectedVideoCard] := [CGAMenu]
[VideoCard] := [CGAString]
EndIf
EndIf
If [MCGASupported]
If [VIDEOCHKcode] = [MCGA]
[DetectedVideoCard] := [MCGAMenu]
[VideoCard] := [MCGAString]
EndIf
EndIf
If [EGASupported]
If [VIDEOCHKcode] = [EGA]
[DetectedVideoCard] := [EGAMenu]
[VideoCard] := [EGAString]
EndIf
If [VGASupported]
Else
If [VIDEOCHKcode] = [VGA]
[DetectedVideoCard] := [VGAMenu]
[VideoCard] := [VGAString]
EndIf
EndIf
EndIf
If [TGASupported]
If [VIDEOCHKcode] = [TGA]
[DetectedVideoCard] := [TGAMenu]
[VideoCard] := [TGAString]
EndIf
EndIf
If [VGASupported]
If [VIDEOCHKcode] = [VGA]
[DetectedVideoCard] := [VGAMenu]
[VideoCard] := [VGAString]
EndIf
EndIf
EndProcedure
Procedure FindExistingCopy
[N] := 1
While [N]<=[NumDrives].AND. [ExistingCopyPath]=BlankString
[Dir1] := [Array1][[N]]\
If Windows
[ExistingCopyPath] := FullPathTo [ProgramExecutable] Quietly
Else
[ExistingCopyPath] := FullPathTo [ProgramExecutable] Quietly Origin=[Dir1]
EndIf
IncrementNumber [N]
EndWhile
[String1] := [InstallerName] could not find a copy of [ProgramName]
If [ExistingCopyPath]= BlankString
Beep
Dialog @xy(Center, Center) WhiteOnRed UseHeader "[ProgramName] Not Found!"
[String1]
on your computer. You must install [ProgramName]
before changing any of the hardware settings.
EndDialog
If Escaped
Do CancelInstall
EndIf
GoTo LoopMainMenu
EndIf
[Number1] := LengthOf [ExistingCopyPath]
[Number2] := LengthOf [ProgramExecutable]
[Number1] := ([Number1]-[Number2]-1)
[String1] := SubstringOf [ExistingCopyPath] from 1 to [Number1]
[InstallationDirectory] := [String1]
[String1] := [InstallerName] has found a copy of [ProgramName]
:LoopProgramFound
Dialog [Continue] WhiteOnRed UseHeader "[ProgramName] Found"
[String1]
in the directory [InstallationDirectory].
Is this the copy you want to modify?
EndDialog
If Escaped
Do CancelInstall
GoTo LoopProgramFound
EndIf
If [Continue]
Exit
EndIf
:LoopGetDirectory
[InstallationDirectory] := C:\
Do BlankBottomLine
Dialog [InstallationDirectory] UseHeader "Locate Program"
Please enter the name of the drive and directory
which contains the program you want to modify.
EndDialog
Do SetBottomLineToEsc
If DirectoryExists [InstallationDirectory]
Else
Dialog [Continue] WhiteOnRed UseHeader " Directory Not Found "
The directory you entered does not exist.
Do you want to choose a different directory?
EndDialog
If Escaped
Do CancelInstall
GoTo LoopGetDirectory
EndIf
If [Continue]
GoTo LoopGetDirectory
Else
GoTo LoopMainMenu
EndIf
EndIf
If Windows
Else
If MediaIsWriteProtected InstallationDrive
:LoopWriteProtected
Dialog [Continue] WhiteOnRed UseHeader " Write-Protected Disk "
This disk is write-protected. Either remove the
write protection or select another drive.
Do you want to try again?
EndDialog
If Escaped
Do CancelInstall
GoTo LoopWriteProtected
EndIf
If [Continue]
GoTo LoopGetDirectory
Else
GoTo LoopMainMenu
EndIf
EndIf
EndIf
If FileExists [InstallationDirectory]\[ProgramExecutable]
Exit
EndIf
Beep
[String1] := [InstallerName] could not find a copy of [ProgramName]
:LoopProgramNotFound
Dialog [Continue] WhiteOnRed UseHeader "Program Not Found"
[String1]
in the directory [InstallationDirectory].
Do you want to choose a different directory?
EndDialog
If Escaped
Do CancelInstall
GoTo LoopProgramNotFound
EndIf
If [Continue]
GoTo LoopGetDirectory
EndIf
GoTo LoopMainMenu
EndProcedure
Procedure GetDriveList
If [DrivesChecked]
Exit
EndIf
[DrivesChecked] := Y
TextBox BlueOnWhite
Looking for drives...
EndTextBox
[Drive] := A
[NumDrives] := 0
[Number1] := 1
[AdditionalSpace] := [HardDiskSpaceNeeded]-[FreeDiskSpace]
While [Number1] <=26
If DriveIsPresent [Drive]
If DriveIsRemoveable [Drive]
Else
If DriveIsCDROM [Drive]
Else
If DriveIsRam [Drive]
Else
If DriveIsRemote [Drive]
Else
IncrementNumber [NumDrives]
[Array1][[NumDrives]] := [Drive]:
EndIf
EndIf
EndIf
EndIf
EndIf
IncrementString [Drive]
IncrementNumber [Number1]
EndWhile
ClearScreen
EndProcedure
Procedure GetTargetDirectory
[InstallationDirectory] := InstallationDrive:[DefaultDirectory]
:LoopGetTargetDirectory
Do BlankBottomLine
[String1] := [ProgramName] installed.
Dialog [InstallationDirectory] UseHeader " Select Installation Directory"
Enter the name of the directory where you want
[String1]
EndDialog
Do SetBottomLineToEsc
Do CheckValidDrive
If [ValidDrive]
Else
[String1] := InstallationDrive:
:LoopInvalidDrive
Dialog [Continue] WhiteOnRed UseHeader " Not a Valid Drive "
The drive you entered is not a valid drive.
Do you want to enter a different drive and directory?
EndDialog
If Escaped
Do CancelInstall
GoTo LoopInvalidDrive
EndIf
If [Continue]
GoTo LoopGetTargetDirectory
Else
GoTo LoopMainMenu
EndIf
EndIf
EndProcedure
Procedure GetTargetDrive
[InstallationDirectory] := C:[DefaultDirectory]
[String1] := You can install [ProgramName]
[String2] := to any of the drives listed below.
[String5] := Available Drives
If Windows
[String3] := Use the arrow keys or mouse to highlight
[String4] := the drive you want to use, then click OK.
[String2] := [String2]
Else
[String3] := Use the arrow keys to highlight the
[String4] := drive you want to use, then press Enter.
[String3] := .c[String3]
[String4] := .c[String4]
EndIf
If Windows
SetCoordinatesTo Pixel
[ButtonWidth] := 50
[ButtonHeight] := 20
[String10] := [Array1][1]
If [NumDrives]>5
[Number1] := 5
Else
[Number1] := [NumDrives]
EndIf
[Number2] := 8*5 + 4*10 + 15 + [ButtonHeight] + [Number1]*9 +2
[Number3] := 150
[Number4] := [Number1]*9 +2
[Number5] := [Number3]+20
[Number6] := [Number2] - 15 - [ButtonHeight]
[Number7] := [Number6] - 20
[Number8] := [Number7] - 8
[Number9] := [Number5]/2-30
[Number10] := ([Number5]/2)-8-[ButtonWidth]
[Number11] := ([Number5]/2)+16
:LoopGetDriveWin
DialogBox @xy(CenterWindow,CenterWindow) [Number5] [Number2] Returns [DlgReturn] UseHeader "Select an Installation Drive" ModalFrame SysMenu BorDlg
Font "Helv" 8
LText @xy(10,10) [Number3] 10 [String1]
LText @xy(10,18) [Number3] 10 [String2]
LText @xy([Number9],36) 60 10 [String5]
ListBox @xy([Number9],44) 60 [Number4] Uses [String10] LoadWith [Array1] Border
LText @xy(10,[Number8]) [Number3] 10 [String3]
LText @xy(10,[Number7]) [Number3] 10 [String4]
BorDefPushButton @xy([Number10],[Number6]) [ButtonWidth] [ButtonHeight] "OK" OK
BorPushButton @xy([Number11],[Number6]) [ButtonWidth] [ButtonHeight] "Cancel" Cancel
EndDialogBox
If Escaped
GoTo LoopGetDriveWin
EndIf
SetCoordinatesTo 80x25
If [DlgReturn]=1
[TargetDrive] := [String10]
Else
GoTo LoopMainMenu
EndIf
Else
:LoopGetDriveDos
TextBox @xy(Center,4) WhiteOnBlue UseHeader "Select an Installation Drive"
[String1]
[String2]
[String3]
[String4]
EndTextBox
SetShadows Off
GetMenuChoice BlueOnWhite UseHeader "Available Drives"
[Array1]
EndGetMenuChoice
SetShadows On
If Escaped
Do CancelInstall
GoTo LoopGetDriveDos
EndIf
[TargetDrive] := ChoiceText
EndIf
[InstallationDirectory] := [TargetDrive][DefaultDirectory]
ClearScreen
EndProcedure
Procedure Initialize
SetSound ON
SetReadOnlyInquiry On
SetReplacementInquiry Off
If Windows
[InstallerName] := Setup
SetDithering On
SetBackGroundColor 0 0 255 0 0 127
SetDefaultBitmap Off
[Number1] := MaxX-445
If FileExists [InstallFromDirectory]\[LogoFilename]
LoadBitMap [InstallFromDirectory]\[LogoFilename] @xy([Number1],0)
ShowBitMap [InstallFromDirectory]\[LogoFilename]
EndIf
SetCoordinatesTo 80x25
ShowWindow Maximize
SetTopLineTo [ProgramName] Setup Program Copyright ⌐ 1994 The Learning Company
Else
[InstallerName] := Install
DelayScreenDraw
SetDirectVideo On
SetAllowExit Off
SetOneMoment On
SetAllowEscape On
SetCheckMarks Off
SetTopLineAttrTo BlueOnWhite
SetTopLineTo " [ProgramName] Install Program "
SetBottomLineAttrTo BlueOnWhite
SetBottomLineTo " Copyright 1994 The Learning Company "
SetAttentionAttrTo WhiteOnRed
SetPopUpAttrTo WhiteOnBlue
SetShadows On
SetClearScreenOnExit On
SetBackgroundCharTo B2
SetMainBorderTo None
EndIf
SetPopupBorderTo Single
SetScreenAttrTo LightGrayOnBlue
SetShadowAttrTo DarkGrayOnBlack
ClearScreen
SetCompletionStatusTo Unfinished
SetSupportInformation
.cThere is a problem installing the program.
.cPlease call Technical Support at:
.c1-800-852-2255.
EndSetSupportInformation
Do BuildSoundCardList
Do BuildVideoCardList
If [Demo]
ForceError
EndIf
EndProcedure
Procedure Install
Do CheckDOS
Do CheckRAM
Do CheckMouse
Do GetDriveList
If [NumDrives]=0
Do NoDriveMessage
GoTo LoopMainMenu
EndIf
:LoopGetDrive
If [NumDrives]>1
Do GetTargetDrive
Else
Do SingleDriveMessage
[InstallationDirectory] := [Array1][1]\
EndIf
Do CheckHardDiskSpace
Do GetTargetDirectory
Do CheckHardDiskSpace
Do CheckIfProgramExists
Do ConfirmSoundCard
Do ConfirmVideoCard
Do BuildCommandLine
Do CopyAllFiles
Do InstallationComplete
EndProcedure
Procedure InstallationComplete
[String1] := [ProgramName] has been installed on your
[String2] := computer's hard drive in the directory
[String3] := named [InstallationDirectory].
If Windows
Dialog @xy(Center,Center) PressAKey UseHeader "Installation Complete"
[String1]
[String2]
[String3]
A [ProgramName] icon has also been added
to the program group named "The Learning Company".
The temporary directory created by Setup
has been removed from your computer.
To play [ProgramName], double-click
on the [ProgramName] icon.
EndDialog
Else
Dialog @xy(Center,Center) PressAKey UseHeader "Installation Complete"
[String1]
[String2]
[String3]
To play [ProgramName], type "[ShortCommandLine]"
at the DOS prompt and press Enter.
EndDialog
EndIf
SoLong
EndProcedure
Procedure MainMenu
[String1] := Choose this option to cancel the installation
If Windows
[String2] := and return to Windows.
Else
[String2] := and return to DOS.
EndIf
:ShowMainMenu
GetMenuChoice Highlight 1 UseHeader "Installation Options"
Install [ProgramName]
;Choose this option to install
;[ProgramName] on your computer.
Change Program Settings
;Choose this option if you have already
;installed [ProgramName] and want to
;change some of the hardware settings.
Quit the Install Program
;[String1]
;[String2]
EndGetMenuChoice
If Escaped
Do CancelInstall
GoTo ShowMainMenu
EndIf
InCase Choice is
=1: Do Install
=2: Do ChangeSettings
=3: SetCompletionStatusTo Finished
EndInCase
SoLong
EndProcedure
Procedure ModifyBatchFile
If FileExists [InstallationDirectory]\[BatchFileName]
Else
[String1] := [ProgramName]. Please choose Install from the
:LoopBatchFileNotFound
Dialog PressAKey WhiteOnRed UseHeader " File Not Found "
The file [BatchFileName] was not found.
This file is used to store the settings for
[String1]
Install Options menu to install a copy of this
file on your hard disk.
EndDialog
If Escaped
Do CancelInstall
GoTo LoopBatchFileNotFound
EndIf
ClearScreen
GoTo LoopMainMenu
EndIf
[String1] := "if not exist [InstallationDirectory]\[ProgramExecutable] goto :notthere"
[String2] := CD [InstallationDirectory]
[String3] := [ProgramCommandLine]
[String4] := CD \
ExamineTextFile [InstallationDirectory]\[BatchFileName]
[N] := 0
[N] := LineNumberWith (if not exist,,)
If [N]>0
ModifyTextFile [InstallationDirectory]\[BatchFileName] Quietly
DeleteLine [N]
InsertAtLine [N] [String1]
EndModifyTextFile
EndIf
[N] := 0
[N] := LineNumberWith ([ProgramExecutable],%,%)
[N] := [N] -2
If [N]>0
ModifyTextFile [InstallationDirectory]\[BatchFileName] Quietly NoBackup
DeleteLine [N]
DeleteLine [N]
DeleteLine [N]
DeleteLine [N]
InsertAtLine [N] [String4]
InsertAtLine [N] [String3]
InsertAtLine [N] [String2]
InsertAtLine [N] InstallationDrive:
EndModifyTextFile
EndIf
ForgetTextFile
SetReadOnlyInquiry Off
CopyFiles from [InstallationDirectory] to InstallationDrive:\ Quietly
[BatchFileName]
EndCopyFiles
SetReadOnlyInquiry On
EndProcedure
Procedure ModifyProgramGroup
[Array5] := GetProgramManagerGroupInfo The Learning Company
[Number1] := LengthOf [Array5][1]
If [Number1]<>0
[String4] := "",""
[String5] := """
[Number2] := 2
While [Number2]<256
[String2] := [Array5][[Number2]]
[Number1] := LengthOf [String2]
If [Number1]= 0
[Number2] := 99999
Else
[Number1] := PositionOf [String4] in [String2]
[Number1] := [Number1] -1
[String7] := SubstringOf [String2] from 2 to [Number1]
If [String7] = [ProgramName]
[Number1] := PositionOf [InstallationDirectory] in [String2]
If [Number1]=0
Do AddProgramToGroup
EndIf
Exit
EndIf
EndIf
IncrementNumber [Number2]
EndWhile
EndIf
Do AddProgramToGroup
EndProcedure
Procedure NoDriveMessage
Dialog WhiteOnRed PressAKey UseHeader "No Hard Drive"
Your computer does not have a hard disk with enough free
space to install [ProgramName].
EndDialog
SoLong
EndProcedure
Procedure RegistrationReminder
SetShadows Off
TextBox @xy(Center,10) BlueOnWhite
Now would be a good time to fill out your registration card!
EndTextBox
SetShadows On
EndProcedure
Procedure SetBottomLineToEsc
If .NOT. Windows
SetBottomLineTo " Press ESC to cancel. "
EndIf
EndProcedure
Procedure SetSoundCardMenuItem
[N] := 1
[MenuItemToHighlight] := 1
While [N]<=[NumSoundOptions]
If [DetectedSoundCard]=[Array2][[N]]
[MenuItemToHighlight] := [N]
Exit
EndIf
IncrementNumber [N]
EndWhile
EndProcedure
Procedure SetSoundSwitch
If [NoSoundSupported]
If [SoundCard]= [NoSoundMenu]
[SoundSwitch] := [NoSoundSwitch]
EndIf
EndIf
If [SoundCard]= [PCSpeakerMenu]
[SoundSwitch] := [PCSpeakerSwitch]
EndIf
If [SoundBlasterSupported]
If [SoundCard]= [SoundBlasterMenu]
[SoundSwitch] := [SoundBlasterSwitch]
EndIf
EndIf
If [AdLibSupported]
If [SoundCard]= [AdLibMenu]
[SoundSwitch] := [AdLibSwitch]
EndIf
EndIf
If [RolandSupported]
If [SoundCard]= [RolandMenu]
[SoundSwitch] := [RolandSwitch]
EndIf
EndIf
If [MicrosoftSoundSupported]
If [SoundCard]= [MicrosoftSoundMenu]
[SoundSwitch] := [MicrosoftSoundSwitch]
EndIf
EndIf
If [Tandy1000Supported]
If [SoundCard]= [Tandy1000Menu]
[SoundSwitch] := [Tandy1000Switch]
EndIf
EndIf
If [PS1Supported]
If [SoundCard]= [PS1Menu]
[SoundSwitch] := [PS1Switch]
EndIf
EndIf
EndProcedure
Procedure SetVideoCardMenuItem
[N] := 1
[MenuItemToHighlight] := 1
While [N]<=[NumVideoOptions]
If [DetectedVideoCard]=[Array3][[N]]
[MenuItemToHighlight] := [N]
Exit
EndIf
IncrementNumber [N]
EndWhile
EndProcedure
Procedure SetVideoSwitch
If [VGASupported]
If [VideoCardIndex] = [VGA]
[VideoSwitch] := [VGASwitch]
EndIf
EndIf
If [TGASupported]
If [VideoCardIndex] = [TGA]
[VideoSwitch] := [TGASwitch]
EndIf
EndIf
If [MCGASupported]
If [VideoCardIndex] = [MCGA]
[VideoSwitch] := [MCGASwitch]
EndIf
EndIf
If [EGASupported]
If [VideoCardIndex] = [EGA]
[VideoSwitch] := [EGASwitch]
EndIf
EndIf
If [CGASupported]
If [VideoCardIndex] = [CGA]
[VideoSwitch] := [CGASwitch]
EndIf
EndIf
EndProcedure
Procedure SingleDriveMessage
[String1] := [InstallerName] has detected just one hard drive on your system.
[String2] := [ProgramName] will be installed to your [Array1][1] drive.
:LoopSingleDriveMessage
Dialog WhiteOnBlue PressAKey UseHeader "Hard Drive Selected"
[String1]
[String2]
EndDialog
If Escaped
Do CancelInstall
GoTo LoopSingleDriveMessage
EndIf
EndProcedure
Procedure StatusBar
Delay 1
[PercentComplete] := (100*[SizeOfCopiedFiles])/[HardDiskSpaceNeeded]
If Windows
Do StatusBarWin
Else
Do StatusBarDOS
EndIf
EndProcedure
Procedure StatusBarDOS
[NumSolidBlocks] := [PercentComplete]/2
If [NumSolidBlocks] = [OldNumSolidBlocks]
Exit
EndIf
If [NumSolidBlocks] = 0
[OldNumSolidBlocks] := 0
EndIf
[N] := [OldNumSolidBlocks] +1
While [N] <= [NumSolidBlocks]
[SolidBar] := [SolidBar]█
IncrementNumber [N]
EndWhile
[StatusBar] := [SolidBar]
While [N] <=50
[StatusBar] := [StatusBar]░
IncrementNumber [N]
EndWhile
[OldNumSolidBlocks] := [NumSolidBlocks]
SetShadows Off
TextBox @xy(Center,21) RedOnWhite UseHeader "Percent Complete"
0 % [StatusBar] 100 %
EndTextBox
SetShadows On
EndProcedure
Procedure StatusBarWin
Delay 1
SetScreenAttrTo RedOnRed
[BarRightX] := [BarLeftX]+(4*[PercentComplete])
Rectangle @xy([BarLeftX],[BarTopY]) @xy([BarRightX],[BarBottomY])
EndProcedure
Procedure StatusBarWinSetup
[TopY] := MaxY-70-70
[BottomY] := MaxY-70
[LeftX] := (MaxX/2) - 250
[RightX] := (MaxX/2) + 250
[BarTopY] := MaxY-70-40
[BarBottomY] := MaxY-70-15
[BarLeftX] := (MaxX/2) - 200
[BarRightX] := (MaxX/2) + 200
SetScreenAttrTo RedOnWhite
Rectangle @xy([LeftX],[TopY]) @xy([RightX],[BottomY])
Rectangle @xy([BarLeftX],[BarTopY]) @xy([BarRightX],[BarBottomY])
[Number1] := [LeftX] + 24
[Number2] := [BarTopY] + 5
TextOut @xy([Number1],[Number2]) 0%
[Number1] := [RightX] - 45
TextOut @xy([Number1],[Number2]) 100%
[Number1] := (MaxX/2) - 60
[Number2] := [TopY] +5
TextOut @xy([Number1],[Number2]) Percent Complete
EndProcedure
Procedure WelcomeScreen
[String1] := [ProgramName] on your computer's hard drive.
:LoopWelcome
Dialog WhiteOnBlue PressAnyKey UseHeader " Welcome! "
Welcome to The Learning Company's [InstallerName] program.
This program makes it easy for you to install
[String1]
Each screen in the [InstallerName] program includes
instructions to help you complete a step in
the installation process.
EndDialog
If Escaped
Do CancelInstall
GoTo LoopWelcome
EndIf
Do SetBottomLineToEsc
EndProcedure
EndScript