home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / turbo55 / tdinstal / taexmpl2.arc / OBYTELOW.ASM < prev    next >
Assembly Source File  |  1989-05-02  |  3KB  |  109 lines
  1.  
  2. ;    FILENAME: OBYTELOW.ASM
  3. ;    Copyright (c) 1988, 1989 by Borland International, Inc.
  4. ;
  5. ;    Description: This module implements the routine ByteLow. ByteLow
  6. ;    processes the current low byte value in al.
  7. ;    This module uses MASM mode syntax and standard segment directives. 
  8. ; 
  9. ;    ASSEMBLY INSTRUCTIONS: To assemble this module use the following 
  10. ;    TASM command line. 
  11. ; 
  12. ;        TASM obytelow
  13.  
  14. include globals.inc
  15.  
  16. _TEXT   segment
  17.  
  18.     ByteLow proc
  19.  
  20.     ;    This procedure processes a low byte character (ASCII value < 32) 
  21.     ;    in al.  
  22.     ;
  23.     ;    Input 
  24.     ;       al - low byte character
  25.     ;       cx - byte count
  26.     ;       dx - number of spaces to insert
  27.     ;       EOL -  defined to be the end of line character
  28.     ;       InpSta - input status
  29.     ;       INP_EOL - designates an end-of-line condition
  30.     ;       Options - the options being used
  31.     ;       REP_TAB - replace tabs without spaces
  32.     ;       TAB - tab character defined to be ASCII 09
  33.     ;       Sav_CR -  denotes CR are to be saved
  34.     ;       CR - ASCII 13
  35.     ;       SKP_EOF - skip input eof
  36.     ;       EOF - ASCII 26
  37.     ;       INP_EOF - designates the end of the input file
  38.     ;       STR_LOB - strip low (control) bytes
  39.     ;
  40.     ;    Output 
  41.     ;       al - low byte processed
  42.     ;       cx - byte count incremented
  43.     ;    Registers modified 
  44.     ;       ax, cx
  45.  
  46.     ; Process low byte.
  47.  
  48.     ;--- end of line
  49.  
  50.     cmp     al, EOL         ;check if end of line
  51.     jne     bytlo1
  52.     or      InpSta, INP_EOL
  53.     ret
  54.  
  55.     ;--- replace tabs with spaces
  56.  
  57. bytlo1:
  58.     test    Options, REP_TAB ;test if replace tabs
  59.     jz      bytlo3
  60.     cmp     al, TAB  ;check if tab
  61.     jne     bytlo3
  62.     call    TabNext         ;get spaces needed
  63.     call    Spaces          ;store spaces
  64.     add     cx, dx          ;byte count
  65.     ret
  66.  
  67.     ;--- carriage return
  68.  
  69. bytlo3:
  70.     test    Options, SAV_CR  ;check if saving CR's
  71.     jnz     bytlo4
  72.     cmp     al, CR    ;check if carriage return
  73.     jne     bytlo4
  74.     ret
  75.  
  76.     ;--- end of file
  77.  
  78. bytlo4:
  79.     test    Options, SKP_EOF ;check if ignore EOF
  80.     jnz     bytlo6
  81.     cmp     al, EOF   ;check if end of page
  82.     jne     bytlo6
  83.     or      InpSta, INP_EOF ;set flag
  84.     or      cx, cx          ;check if any bytes
  85.     jz      bytlo5
  86.     or      InpSta, INP_EOL ;set end of line also
  87. bytlo5:
  88.     ret
  89.  
  90.     ;--- remove low bytes
  91.  
  92. bytlo6:
  93.     test    Options, STR_LOB ;test if remove low bytes
  94.     jz      bytlo7
  95.     ret
  96.  
  97.     ;--- write byte
  98.  
  99. bytlo7:
  100.     stosb
  101.     inc     cx
  102.     ret
  103.  
  104.     ByteLow endp
  105.  
  106. _TEXT    ends
  107.  
  108. end
  109.