home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / magazine / pcmagazi / 1989 / 11 / extmem.asm < prev    next >
Assembly Source File  |  1989-02-03  |  4KB  |  144 lines
  1.         title   EXTMEM --- get/put extended memory
  2.         page    55,132
  3.  
  4. ; EXTMEM.ASM --- Routines to transfer data between
  5. ;                conventional and extended memory.
  6. ;                For use with small model C programs.
  7. ; Copyright (C) 1989 Ziff Davis Communications
  8. ; PC Magazine * Ray Duncan
  9. ;
  10. ; Assemble with: MASM /Zi /Mx EXTMEM;
  11.  
  12. DGROUP  group   _DATA
  13.  
  14. _DATA   segment word public 'DATA'
  15.  
  16. gdt     db      30h dup (0)     ; global descriptor table
  17.  
  18. _DATA   ends
  19.  
  20.  
  21. _TEXT   segment word public 'CODE'
  22.  
  23.         assume  cs:_TEXT,ds:DGROUP
  24.  
  25. args    equ     [bp+4]          ; offset of arguments, small model
  26. source  equ     word ptr args
  27. dest    equ     word ptr source+4
  28. len     equ     word ptr dest+4
  29.  
  30. ;
  31. ; GETXM copies data from extended memory to conventional memory.
  32. ; 
  33. ; status = getxm(unsigned long source, void far *dest, unsigned len)
  34. ;
  35. ; Status is zero if move successful, nonzero if move failed:
  36. ; 1 = parity error, 2 = exception interrupt error, 3 = gate A20 failed
  37. ;
  38.         public  _getxm
  39. _getxm  proc    near
  40.  
  41.         push    bp              ; set up stack frame
  42.         mov     bp,sp
  43.         push    si              ; protect register variables
  44.         push    di
  45.  
  46.         push    ds              ; let ES:SI point to
  47.         pop     es              ; global descriptor table
  48.         mov     si,offset DGROUP:gdt
  49.  
  50.                                 ; store access rights bytes
  51.         mov     byte ptr es:[si+15h],93h
  52.         mov     byte ptr es:[si+1dh],93h
  53.  
  54.         mov     ax,source       ; store source address
  55.         mov     es:[si+12h],ax  ; into descriptor
  56.         mov     ax,source+2
  57.         mov     es:[si+14h],al
  58.  
  59.         mov     ax,dest+2       ; destination segment * 16
  60.         mov     dx,16
  61.         mul     dx
  62.         add     ax,dest         ; + offset -> linear address
  63.         adc     dx,0
  64.         mov     es:[si+1ah],ax  ; store destination address
  65.         mov     es:[si+1ch],dl  ; into descriptor
  66.  
  67.         mov     cx,len  ; store length into source
  68.         mov     es:[si+10h],cx  ; and destination descriptors
  69.         mov     es:[si+18h],cx 
  70.  
  71.         shr     cx,1            ; convert length to words
  72.         mov     ah,87h          ; Int 15H Fxn 87h = block move
  73.         int     15h             ; transfer to ROM BIOS 
  74.  
  75.         mov     al,ah           ; form status in AX     
  76.         cbw
  77.  
  78.         pop     di              ; restore registers
  79.         pop     si
  80.         pop     bp
  81.         ret                     ; back to caller
  82.  
  83. _getxm  endp
  84.  
  85. ;
  86. ; PUTXM copies data from conventional memory to extended memory.
  87. ; 
  88. ; status = putxm(void far *source, unsigned long dest, unsigned len)
  89. ;
  90. ; Status is zero if move successful, nonzero if move failed:
  91. ; 1 = parity error, 2 = exception interrupt error, 3 = gate A20 failed
  92. ;
  93.         public  _putxm
  94. _putxm  proc    near
  95.  
  96.         push    bp              ; set up stack frame
  97.         mov     bp,sp
  98.         push    si              ; protect register variables
  99.         push    di
  100.  
  101.         push    ds              ; let ES:SI point to
  102.         pop     es              ; global descriptor table
  103.         mov     si,offset DGROUP:gdt
  104.  
  105.                                 ; store access rights bytes
  106.         mov     byte ptr es:[si+15h],93h
  107.         mov     byte ptr es:[si+1dh],93h
  108.  
  109.         mov     ax,dest         ; store destination address
  110.         mov     es:[si+1ah],ax  ; into descriptor
  111.         mov     ax,dest+2
  112.         mov     es:[si+1ch],al
  113.  
  114.         mov     ax,source+2     ; source segment * 16
  115.         mov     dx,16
  116.         mul     dx
  117.         add     ax,source       ; + offset -> linear address
  118.         adc     dx,0
  119.         mov     es:[si+12h],ax  ; store source address
  120.         mov     es:[si+14h],dl  ; into descriptor
  121.  
  122.         mov     cx,len          ; store length into source
  123.         mov     es:[si+10h],cx  ; and destination descriptors
  124.         mov     es:[si+18h],cx 
  125.  
  126.         shr     cx,1            ; convert length to words
  127.         mov     ah,87h          ; Int 15H Fxn 87h = block move
  128.         int     15h             ; transfer to ROM BIOS 
  129.  
  130.         mov     al,ah           ; form status in AX
  131.         cbw
  132.  
  133.         pop     di              ; restore registers
  134.         pop     si
  135.         pop     bp
  136.         ret                     ; back to caller
  137.  
  138. _putxm  endp
  139.  
  140. _TEXT   ends
  141.  
  142.         end
  143.  
  144.