home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / magazine / msysjour / vol04 / 02b / project / classes / task.cls < prev    next >
Text File  |  1988-11-30  |  5KB  |  209 lines
  1. /* A Task is an activity that requires time and resources to
  2.    complete.  Tasks should only have a single input and output.
  3.    Tasks can connect to other tasks or to Milestones.  When
  4.    a path must split or join, a Milestone is required.  
  5.  
  6.    Tasks descend from Activity and inherit all of
  7.    their methods and instance variables.
  8. */!!
  9.  
  10. inherit(Activity, #Task, #(resources   /* a collection */
  11. time        /* required by task */
  12. cost        /* total task cost */
  13. fixedCost 
  14. ), 2, nil)!!
  15.  
  16. now(TaskClass)!!
  17.  
  18. now(Task)!!
  19.  
  20. /* Return the class name.  Uses resources for translation. */
  21. Def className(self)
  22. {
  23.   ^loadString(PW_TASK);
  24. }!!
  25.  
  26.  
  27. /* Return true if the task is "complete", e.g.
  28.    connected, time set etc.  
  29.    This is for experimental use only.   */
  30. Def  complete(self)
  31. { 
  32.   ^complete(self:Activity)
  33.      cand time <> 0
  34.      cand size(resources) > 0;
  35. }!!
  36.  
  37. /* Draw a Task at a location in a window.
  38.    The window manages the details of what the
  39.    Task will look like, since it could be
  40.    a PERT chart or a Gantt chart.    */
  41. Def  draw(self, window, x, y, hDC)
  42. { 
  43.   drawTask(window, self, x, y, hDC);
  44. }!!
  45.  
  46. /* Tasks can have only a single connection at
  47.    inputs and outputs.  If you attempt to connect
  48.    multiple inputs or outputs, an error message
  49.    will be displayed.  */
  50. Def  maxConnectionNames(self, names | connected)
  51. {   
  52.   if size(names) > 1
  53.     beep();
  54.     errorBox(loadString(PW_ERRCONNECT1),
  55.       loadString(PW_ERRCONNECT2) + CR_LF +
  56.       loadString(PW_ERRCONNECT3));
  57.     names := copyFrom(names, 0, 1);
  58.   endif;
  59.   ^names;
  60. }!!
  61.  
  62. /* Check to see if the resources have changed.
  63.    If so, remove the old ones add the new ones. */
  64. Def  checkResources(self, newResNames | oldResNames, res)
  65. {
  66.   oldResNames := getResourceNames(self);
  67.   
  68.   if newResNames <> oldResNames       /* resources changed */
  69.     do(resources,
  70.       {using(oldRes) 
  71.        removeResource(self, oldRes);
  72.      });
  73.     res := parseResNames(network, newResNames);
  74.     
  75.     do(res,
  76.       {using(newRes)
  77.        addResource(self, newRes);       
  78.     });    
  79.     calcCost(self);   /* update cost */
  80.   endif;  
  81. }!!
  82.  
  83. /* Return a string of resource names. */
  84. Def  getResourceNames(self | str)
  85. {
  86.   str := "";
  87.   do(resources,
  88.     {using(res) str := str + getName(res) + " ";
  89.   });
  90.   ^str;  
  91. }!!
  92.  
  93. /* Return the appropriate dialog class to be used
  94.    by editInfo(). */
  95. Def  dialogClass(self)
  96. {
  97.   ^TaskDialog;
  98. }!!
  99.  
  100. /* Set the values of an activity. 
  101.    Values is an array of name, desc,
  102.    userEarlyStart, userLateFinish, time, 
  103.    fixedCost, resources. */
  104. Def  setValues(self, values | oldUES, oldULF, oldTime)
  105. {
  106.   oldUES := userEarlyStart;
  107.   oldULF := userLateFinish;
  108.   oldTime := time;
  109.   
  110.   name := values[0];
  111.   desc := values[1];
  112.   userEarlyStart := values[2];
  113.   userLateFinish := values[3];
  114.   time := values[4];
  115.   
  116.   setFixedCost(self, values[5]);
  117.   checkResources(self, values[6]);
  118.  
  119.   if network cand autoCalc(network) cand 
  120.      (oldUES <> userEarlyStart cor
  121.       oldULF <> userLateFinish cor
  122.       oldTime <> time)
  123.     recalc(self);
  124.   endif;
  125. }!!
  126.  
  127. /* Get the fixed cost. */
  128. Def  getFixedCost(self)
  129. { ^fixedCost;
  130. }!!
  131.  
  132. /* Get the cost. */
  133. Def  getCost(self)
  134. { ^cost;
  135. }!!
  136.  
  137. /* Calculate the cost of a Task and update the project cost. */
  138. Def  calcCost(self | oldCost)
  139. { 
  140.   oldCost := cost;
  141.   cost := fixedCost;
  142.   do(resources,
  143.     {using(elem)
  144.     cost := cost + getFixedCost(elem)
  145.                  + getTime(self) * getVariableCost(elem);
  146.   });
  147.   updateCost(network, cost - oldCost);
  148.   ^cost;
  149. }!!
  150.  
  151. /* Update the cost based on a change to a resource.
  152.    Pass the change in cost to the network also. */
  153. Def  updateCost(self, change)
  154. { 
  155.   cost := cost + change;
  156.   updateCost(network, change);
  157. }!!
  158.  
  159. /* Remove the resource for a task.  Also remove
  160.    the resource's reference to the task.  
  161.    Recalculate the cost if necessary. */
  162. Def  removeResource(self, res)
  163. { 
  164.   remove(resources, res);
  165.   removeReference(res, self);
  166.   if (getVariableCost(res) <> 0 
  167.       cor getFixedCost(res) <> 0)
  168.     calcCost(self);
  169.   endif;
  170. }!!
  171.  
  172. /* Add to the resources for a task creating the resource is
  173.    necessary.  The resource should also know where it is
  174.    referenced, in case it changes. Update cost if necessary. */
  175. Def  addResource(self, res)
  176. { 
  177.   add(resources, res);
  178.   addReference(res,self);     
  179.   if (getVariableCost(res) <> 0)
  180.     calcCost(self);
  181.   endif;
  182. }!!
  183.  
  184. /* Set the fixed cost for a task. */
  185. Def  setFixedCost(self, aCost | change)
  186. { 
  187.   change := aCost - fixedCost;
  188.   if (change <> 0)
  189.     fixedCost := aCost;
  190.     cost := cost + change;
  191.     updateCost(network, change);
  192.   endif;
  193. }!!
  194.  
  195. /* Initialize a new Task. */
  196. Def  init(self)
  197. {
  198.   init(self:Activity);      /* use ancestor init */
  199.   resources := new(Set, 5);
  200.   time := slack := cost := fixedCost := 0;
  201. } !!
  202.  
  203. /* Get the time. */
  204. Def  getTime(self)
  205. { ^time;
  206. }!!
  207.  
  208.  
  209.