home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / magazine / msysjour / vol04 / 02b / project / classes / ganttwin.cls < prev    next >
Text File  |  1988-11-24  |  6KB  |  236 lines
  1. /* Maintain a Gantt chart in a Window. The GanttWindow is
  2.    responsible for drawing the project.
  3.  
  4.    GanttWindow descends from the Window class and inherits all
  5.    of its methods and instance variables.
  6. */!!
  7.  
  8. inherit(Window, #GanttWindow, #(project     /* the project */
  9. activities  /* in the project */
  10. barWidth    /* width of a unit */
  11. barHeight   /* based on scrnsize */
  12. activHeight /* bar + dead space */), 2, nil)!!
  13.  
  14. now(GanttWindowClass)!!
  15.  
  16. /* Return the name of this class's MS-Windows window class
  17.   either for registration or new window creation. */
  18. Def wndClass(self)
  19. { ^"GanttWindow"  }!!
  20.  
  21. /* Create a new window class Struct.
  22.    Change the cursor to a cross.  */
  23. Def newWClass(self, lpCl, lpIcon | wc)
  24. { wc := newWClass(self:WindowClass, lpCl, lpIcon);
  25.   putWord(wc, Call LoadCursor(0, IDC_CROSS), 14);
  26.   ^wc;
  27. } !!
  28.  
  29. now(GanttWindow)!!
  30.  
  31. /* For a Task, draw a critical bar.  Make sure we don't draw
  32.    draw over the titles if the node hasn't been hooked up yet.
  33.    Uses early binding, direct Windows calls for speed. */
  34. Def  drawTask(self, aNode, x, y, hDC | startX)
  35. {
  36.    startX := max(GW_STARTX, x - asInt(getTime(aNode)*barWidth));
  37.    Call FillRect(hDC, rect(startX:Int, y, x, y + barHeight), 
  38.           stock(BLACK_BRUSH));
  39. }!!
  40.  
  41. /* Create the window using a regular window style. */
  42. Def  create(self, par, wName, rect, style)
  43. { 
  44.   ^create(self:Window, par, wName, rect, 
  45.      WS_POPUPWIND);
  46. }!!
  47.  
  48. /* If we close, be sure to tell the parent. 
  49.    For testing a standalone Gantt chart delete this method. */
  50. Def  close(self)
  51. {
  52.   close(self:Window);
  53.   closeGantt(parent);  /* assumes parent is a ProjWindow */
  54. }!!
  55.  
  56. /* Make sure the parent window knows that the project
  57.    has changed. */
  58. Def  dirty(self)
  59. {
  60.   invalidate(self);
  61.   invalidate(parent);
  62. }!!
  63.  
  64. /* Set up a dummy project, menus and the method table. */
  65. Def  init(self)
  66. {  
  67.   setProject(self, new(Project));
  68.   recalc(project);  
  69.   setMenus(self);
  70.   setResolution(self);
  71. }!!
  72.  
  73. /* Set the resolution for the size of bars, spacing etc.
  74.    For CGA, bars should be smaller. */
  75. Def  setResolution(self | hDC, ts)
  76. {
  77.   hDC := getContext(self);
  78.   ts := textSize(self, hDC);
  79.   releaseContext(self, hDC);
  80.   barHeight := y(ts);
  81.   activHeight := asInt(1.25 * y(ts));
  82. }!!
  83.  
  84. /* Handle menu commands. */
  85. Def  command(self, wp, lp)
  86. {
  87.   select
  88.     case wp == GW_HELP
  89.       help(self);
  90.     endCase
  91.     
  92.     /* use the same accelerator to open and close */
  93.     
  94.     case wp == PW_VIEW_GANTT  
  95.       close(self);
  96.     endCase
  97.   endSelect;
  98. }!!
  99.  
  100. /* Load menu resources. */
  101. Def  setMenus(self)
  102. {
  103.   loadMenu(self, "GWMenus");
  104.   setMenu(self, hMenu);
  105. }
  106. !!
  107.  
  108. /* Display help information from resource file. */
  109. Def  help(self | dlg)
  110. {
  111.   dlg := new(Dialog);
  112.   checkRunModal(dlg, GW_HELP_BOX, self);
  113. }!!
  114.  
  115. /* Draw a Milestone diamond in the window. */
  116. Def  drawMilestone(self, aNode, x, y, hDC)
  117. {
  118.     draw(new(Polygon,
  119.       tuple(
  120.         point(x, y),                 /* top */
  121.         point(x - GW_DMWIDTH, 
  122.               y + barHeight/2),      /* left */
  123.         point(x, y + barHeight),     /* bottom */
  124.         point(x + GW_DMWIDTH,
  125.               y + barHeight/2)       /* right */
  126.       )), hDC);
  127. }!!
  128.  
  129. /* Draw a slack bar in the window. 
  130.    Uses direct Windows call for speed. */
  131. Def  drawSlackBar(self, aNode, x, y, hDC | hBrush)
  132. {
  133.    Call FillRect(hDC, rect(x:Int, y, 
  134.                 x + asInt(getSlack(aNode)*barWidth),
  135.                 y + barHeight), stock(GRAY_BRUSH)
  136.            );
  137. }!!
  138.  
  139. /* Draw text info in the window. */
  140. Def  drawTextInfo(self, aNode, x, y, hDC | str)
  141. {
  142.       if critical(aNode)
  143.         str := "*" + getName(aNode);
  144.       else
  145.         str := " " + getName(aNode);
  146.       endif;
  147.       Call TextOut(hDC, x, y, str, size(str));  
  148. }!!
  149.  
  150. /* Set the bar width so that the chart fits in the window. 
  151.    Adjust in case it's very large or very small. */
  152. Def  setBarWidth(self, time)
  153. {
  154.   barWidth := asInt((right(clientRect(self)) - GW_STARTX) / 
  155.                 (time + 1));
  156.   barWidth := min(75, max(2, barWidth));
  157. }!!
  158.  
  159. /* Set the project. */
  160. Def  setProject(self, aProject)
  161. {
  162.   project := aProject;
  163.   recalc(project);
  164. }!!
  165.  
  166. /* See if the user has clicked on a bar in the chart.
  167.    If so, bring up a dialog for editing. */
  168. Def  WM_LBUTTONDOWN(self, wP, lP | idx)
  169. {
  170.   idx:= (y(asPoint(lP)) - barHeight) / activHeight;
  171.   if idx <= size(activities) - 1 
  172.     if editInfo(activities[idx]) == IDOK
  173.       dirty(self);
  174.     endif;
  175.   else
  176.     beep();
  177.   endif;
  178. }!!
  179.  
  180. /* Draw the axis for the window. 
  181.    Uses direct Windows calls for speed. */
  182. Def  drawAxis(self, hDC | endX, endY, str)
  183. {
  184.     endX := GW_STARTX + barWidth * 
  185.                (max(2,asInt(getTime(project)+getSlack(project)))) ;  
  186.     endY := activHeight * (size(nodes(project))+1); 
  187.        
  188.     /* draw a rectangle for x and y axis */ 
  189.     
  190.     Call Rectangle(hDC, GW_STARTX, GW_STARTY, endX, endY+1);
  191.         
  192.     /* draw notches on the x axis */    
  193.     do(overBy(GW_STARTX, endX, barWidth),
  194.       {using(i) 
  195.         Call MoveTo(hDC, i, GW_STARTY);           /* top */
  196.         Call LineTo(hDC, i, GW_STARTY + GW_NOTCH);
  197.         Call MoveTo(hDC, i,endY);                 /* bot */
  198.         Call LineTo(hDC, i, endY - GW_NOTCH);
  199.     });
  200.     str := asString(getEarlyStart(project));
  201.     Call TextOut(hDC, GW_STARTX, endY + 10, str, size(str));  
  202. }!!
  203.  
  204. /* Respond to MS-Windows messages to paint the window. 
  205.    Show the project as a Gantt chart. 
  206.    Draw the axis, then for each node draw the graphics. */
  207. Def  paint(self, hDC | y, t)
  208. {
  209.   setBarWidth(self, asInt(getTime(project)+getSlack(project)));
  210.   activities := sortedActivities(project);
  211.   
  212.   drawAxis(self, hDC);
  213.   y := barHeight;         /* starting positions for bars */
  214.   
  215.   do(activities,
  216.     {using(aNode) 
  217.    
  218.      drawTextInfo(self, aNode, 10, y, hDC);
  219.      
  220.       /* make a temp to avoid calculating starting position */
  221.       t := max(GW_STARTX, GW_STARTX + barWidth *
  222.             asInt(getEarlyStart(aNode)-getEarlyStart(project)+getTime(aNode)));
  223.       
  224.       /* draw a slack bar if necessary. */  
  225.       if getSlack(aNode) > 0  
  226.         drawSlackBar(self, aNode, t, y, hDC)
  227.       endif;
  228.  
  229.       draw(aNode, self, t, y, hDC);  /* node knows how */
  230.  
  231.       y := y + activHeight;     /* move down for next bar */
  232.   });
  233. }!!
  234.  
  235.  
  236.