home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / magazine / msysjour / vol04 / 02b / project / act / install.act < prev    next >
Text File  |  1988-08-21  |  4KB  |  140 lines
  1. /* install.act          --utilities to be used in the seal off process
  2.  
  3.  revision history:
  4.         
  5.         02/01/88 mas    -removeCompiler, removeNames, removeGlobals defined
  6.                         -cleanup redefined to not print to the display
  7.         03/16/88 mas    -added the Object:fail method to prevent hanging
  8.                          if a message is not understood.  
  9.         07/12/88 mzu    -added the Object:error method to prevent hanging
  10.                          on untrapped high level errors.
  11.         07/21/88 acr    -added the Object:primError method to prevent hanging
  12.                          on untrapped prim errors.                            */
  13.  
  14. /* include an error handling routine to trap attempted execution of a 
  15.    non-existent method.  The errorBox, asString, class and other
  16.    related methods must also exist.
  17.  */
  18.  
  19. now(Object)!!
  20.  
  21. /* This method is executed any time a 
  22.   late-bound message is not understood. */
  23. Def fail(self, stackTop, selector)
  24. { errorBox("Method not in system",
  25.     "<a " + asString(class(self)) + 
  26.     "> does not understand " +
  27.     asString(selector));
  28.   abort(TheApp:late);
  29. }
  30. !!
  31.  
  32. /* All high-level errors are handled via this 
  33.   method.  The first parameter should be stackTop(), 
  34.   which gives a pointer to the activation of the 
  35.   caller.  The second parameter is a symbol that 
  36.   describes the error.  If the symbol is defined as 
  37.   an integer constant, the value is taken to be the 
  38.   ID of an error string.  Executes abort (never 
  39.   returns). 
  40.   
  41.   runtime version -- don't print a message or invoke debugger!
  42.   mzu 07/12/88 
  43. */
  44. Def error(self, stackTop, sym | str)
  45. { 
  46.   if not(str := errorString(sym))
  47.     then str := loadString(343) + sym;
  48.   endif;
  49.   
  50.   errorBox("Fatal runtime error", str);
  51.   abort(TheApp:late);
  52. } 
  53. !!
  54.  
  55. /* All primitive errors are handled 
  56.    through this method.  The second 
  57.    parameter is the primitive error number, 
  58.    which corresponds to an error string ID 
  59.    in the resource file.
  60.    
  61.    runtime version -- don't print a message or invoke debugger!
  62. */
  63. Def primError(self, stacktop, id | str)
  64. {
  65.    if not(str := loadString(id))
  66.       then str := loadString(343) + asString(id);
  67.    endif;
  68.    
  69.    errorBox("Fatal runtime primitive error", str);
  70.    abort(TheApp:late);
  71. }
  72. !!
  73.  
  74. now(Behavior)!!
  75. Def removeMethods(self, coll)
  76. {       do(coll, {using(sym) 
  77.         if methods[sym] 
  78.               print(self); 
  79.               print(":");
  80.               print(remove(methods, sym));
  81.               eol(ThePort); 
  82.         endif;});
  83. }!!
  84.  
  85. now(Symbol)!!
  86. Def removeGlobal(self)
  87. { if assocAt(Actor,self)
  88.   then print(self); 
  89.     Actor[self] := nil;
  90.     remove(Actor,self);
  91.     print(" removed."); eol(ThePort);
  92.   endif;
  93. }!!
  94.  
  95. now(Object)!!
  96.  
  97. /* to avoid errors */
  98. Def removeMethods(self, dummy)
  99. {
  100. }!!
  101.  
  102. Def removeNames(self)
  103. { classesDo(Actor,
  104.          { using(cl) cl.name := nil;
  105.            class(cl).name := nil;
  106.   });
  107. }!!
  108.  
  109.  
  110. Def removeCompiler(self)
  111. { do( #(
  112. Lex Lex1 CurrentParser Parser Loader Analyzer 
  113. ActorAnalyzer YaccMachine ActorParser
  114. ParseNode InfixNode EmptyList ListNode BlockNode RPN ImmedFunction
  115. IfNode IfElseNode LoopNode RetNode MsgNode CallNode
  116. CompileState Compiler IvChain AssgnNode IdNode 
  117. WCalls WTraps Functions CVars
  118. InfixOps EarlyMethods SpecialMethods KeyWords
  119. Constants SourceFile Source
  120. CStream CompileBuf LoadBuf BlockTemps Demos 
  121. Bug Context Debugger ActorApp
  122. ), {using(name)  removeGlobal(name) });
  123. }!!
  124.  
  125. now(File)!!
  126. /* redefine cleanup to NOT output to the display */
  127. Def cleanup(self | str)
  128. { initCache();
  129.   str := new(String, 24);
  130.   Call GetTempFileName(0,
  131.     asciiz("ACT"), 0, str);
  132.   setName(self, removeNulls(str));
  133.   create(self);
  134.   checkError(self);
  135.   gc(self);
  136.   delete(self);
  137. }
  138. !!
  139.  
  140.