home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / lan / driver6s / pktaddr.asm < prev    next >
Assembly Source File  |  1990-03-14  |  4KB  |  181 lines
  1. version    equ    0
  2.  
  3. ;  Russell Nelson, Clarkson University.  September 14, 1989
  4. ;  Copyright, 1989, Russell Nelson
  5.  
  6. ;   This program is free software; you can redistribute it and/or modify
  7. ;   it under the terms of the GNU General Public License as published by
  8. ;   the Free Software Foundation, version 1.
  9. ;
  10. ;   This program is distributed in the hope that it will be useful,
  11. ;   but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ;   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ;   GNU General Public License for more details.
  14. ;
  15. ;   You should have received a copy of the GNU General Public License
  16. ;   along with this program; if not, write to the Free Software
  17. ;   Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  18.  
  19.     include    defs.asm
  20.  
  21. code    segment byte public
  22.     assume    cs:code, ds:code
  23.  
  24.     org    80h
  25. phd_dioa    label    byte
  26.  
  27.     org    100h
  28. start:
  29.     jmp    start_1
  30.  
  31. copyleft_msg    label    byte
  32.  db "Packet address version ",'0'+majver,".",'0'+version," copyright 1990, Russell Nelson.",CR,LF
  33.  db "This program is free software; see the file COPYING for details.",CR,LF
  34.  db "NO WARRANTY; see the file COPYING for details.",CR,LF
  35. crlf_msg    db    CR,LF,'$'
  36.  
  37. int_pkt    macro
  38.     pushf
  39.     cli
  40.     call    their_isr
  41.     endm
  42.  
  43. their_isr    dd    ?
  44. packet_int_no    db    ?,?,?,?
  45. ether_bdcst    db    EADDR_LEN dup(-1)    ;ethernet broadcast address.
  46. ether_addr    db    EADDR_LEN dup(-1)
  47.  
  48. handle        dw    ?
  49.  
  50. bogus_type    db    1,2,3,4,5,6,7,8        ;totally bogus type code.
  51.  
  52. signature    db    'PKT DRVR',0
  53. signature_len    equ    $-signature
  54. no_signature_msg    db    "No packet driver at that address",'$'
  55. usage_msg    db    "usage: pktaddr <packet_int_no> [<addr>]",'$'
  56.  
  57. eaddr_msg    db    "My Ethernet address is ",'$'
  58.  
  59. usage_error:
  60.     mov    dx,offset usage_msg
  61. error:
  62.     mov    ah,9
  63.     int    21h
  64.     int    20h
  65.  
  66. start_1:
  67.     mov    dx,offset copyleft_msg
  68.     mov    ah,9
  69.     int    21h
  70.  
  71.     mov    si,offset phd_dioa+1
  72.     cmp    byte ptr [si],CR    ;end of line?
  73.     je    usage_error
  74.  
  75.     mov    di,offset packet_int_no
  76.     call    get_number
  77.  
  78.     mov    di,offset ether_addr
  79.     call    get_address
  80.  
  81.     mov    ah,35h            ;get their packet interrupt.
  82.     mov    al,packet_int_no
  83.     int    21h
  84.     mov    their_isr.offs,bx
  85.     mov    their_isr.segm,es
  86.  
  87.     lea    di,3[bx]
  88.     mov    si,offset signature
  89.     mov    cx,signature_len
  90.     repe    cmpsb
  91.     je    have_signature
  92.     mov    dx,offset no_signature_msg
  93.     jmp    error
  94. have_signature:
  95.  
  96.     push    ds
  97.     pop    es
  98.     mov    cx,EADDR_LEN
  99.     mov    si,offset ether_addr
  100.     mov    di,offset ether_bdcst
  101.     repe    cmpsb
  102.     je    get_mode        ;no address specified.
  103.  
  104.     mov    ah,25            ;set the ethernet address.
  105.     mov    di,offset ether_addr
  106.     mov    cx,EADDR_LEN
  107.     int_pkt
  108.     call    fatal_error
  109.     jmp    okay
  110. get_mode:
  111.     mov    ah,2            ;access all packets.
  112.     mov    al,1            ;Ethernet class.
  113.     mov    bx,-1            ;generic type.
  114.     mov    dl,0            ;generic number.
  115.     mov    cx,MAX_P_LEN        ;use the max type length.
  116.     mov    si,offset bogus_type
  117.     push    cs            ;es:di -> our receiver.
  118.     pop    es
  119.     mov    di,offset our_recv
  120.     int_pkt
  121.     call    fatal_error
  122.     mov    handle,ax
  123.  
  124.     mov    ah,6            ;get the ethernet address.
  125.     mov    di,offset ether_addr
  126.     mov    cx,EADDR_LEN
  127.     mov    bx,handle
  128.     int_pkt
  129.     jc    bad
  130.  
  131.     mov    dx,offset eaddr_msg
  132.     mov    ah,9
  133.     int    21h
  134.  
  135.     mov    si,offset ether_addr
  136.     call    print_ether_addr
  137.  
  138.     mov    dx,offset crlf_msg    ;can't depend on DOS to newline for us.
  139.     mov    ah,9
  140.     int    21h
  141.     jmp    short now_close
  142. bad:
  143.     call    print_error
  144. now_close:
  145.     mov    ah,3            ;release_type
  146.     mov    bx,handle
  147.     int_pkt
  148.     call    fatal_error
  149.  
  150. okay:
  151.     int    20h
  152.  
  153.  
  154. our_recv:
  155.     or    ax,ax            ;first or second call?
  156.     jne    our_recv_1        ;second -- we ignore the packet
  157.     push    cs
  158.     pop    es
  159.     mov    di,offset our_buffer
  160. our_recv_1:
  161.     db    0cbh            ;masm 4.0 doesn't grok "retf"
  162.  
  163.  
  164.     include    printea.asm
  165.  
  166.     assume    ds:code
  167.  
  168.     include    pkterr.asm
  169.     include    getea.asm
  170.     include    getnum.asm
  171.     include    skipblk.asm
  172.     include    getdig.asm
  173.     include    digout.asm
  174.     include    chrout.asm
  175.  
  176. our_buffer    label    byte
  177.  
  178. code    ends
  179.  
  180.     end    start
  181.