home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / lan / driver6s / at&t.asm < prev    next >
Assembly Source File  |  1990-04-13  |  6KB  |  209 lines
  1. version    equ    0
  2.  
  3.     include    defs.asm
  4.  
  5. ;Ported from Tim Krauskopf's micnet.asm, an assembly language
  6. ;driver for the MICOM-Interlan NI5210, by Russell Nelson.  Any bugs
  7. ;are due to Russell Nelson.
  8. ;Updated to version 1.08 Feb. 17, 1989 by Russell Nelson.
  9. ;Updated to support 1500 byte MTU April 27, 1989 By Brad Clements.
  10. ;converted to an AT&T driver Feb 16, 1990 by Russell Nelson
  11.  
  12. ;  Copyright, 1988, 1989, 1990, Russell Nelson
  13.  
  14. ;   This program is free software; you can redistribute it and/or modify
  15. ;   it under the terms of the GNU General Public License as published by
  16. ;   the Free Software Foundation, version 1.
  17. ;
  18. ;   This program is distributed in the hope that it will be useful,
  19. ;   but WITHOUT ANY WARRANTY; without even the implied warranty of
  20. ;   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21. ;   GNU General Public License for more details.
  22. ;
  23. ;   You should have received a copy of the GNU General Public License
  24. ;   along with this program; if not, write to the Free Software
  25. ;   Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  26.  
  27. code    segment    byte public
  28.     assume    cs:code, ds:code
  29.  
  30. ;
  31. ;  Equates for controlling the AT&T boards
  32. ;
  33. ;  I/O addresses, writing anything in AL trips these gates
  34. ;
  35. ;  First six addresses are the EPROM board Ether address (read)
  36. ;
  37. IORESET    EQU    0            ; reset the board
  38. IOCA    EQU    1            ; Channel Attention
  39. IOREV    EQU    6            ; Board Revision/Type
  40. IOATTR    EQU    7            ; Attribute Register.
  41.  
  42. ;Attribute register contents:
  43. attr_mem    equ    03h        ;mask for memory size
  44. attr_mem_64    equ    0
  45. attr_mem_16    equ    1
  46. attr_mem_32    equ    2
  47. attr_mem_8    equ    3
  48. ;
  49. attr_bw        equ    04h        ;Bus width (0=8 bit, 1=16 bit)
  50. attr_speed    equ    08h        ;Board speed (0=10 Mhz, 1=1 Mhz)
  51. attr_c        equ    10h        ;Manchester code (0=Manchester, 1=NRZ)
  52. attr_hw        equ    20h        ;Host bus width (0=16, 1=8 bit)
  53. attr_es        equ    40h        ;Ethernet/Starlan (0 = E, 1 = S)
  54. attr_b        equ    80h        ;Boot Rom (0=No ROM, 1=ROM)
  55.  
  56.  
  57. BASE_OFFSET    equ    0
  58. GET_ADDR_INC    equ    1
  59.  
  60. ;
  61. ;  Data segment
  62. ;
  63.  
  64.     public    int_no
  65. int_no        db    2,0,0,0        ; interrupt number. 
  66. io_addr        dw    0360h,0        ; I/O address for card (jumpers)
  67. base_addr    dw      0d000h,0    ; base segment for board (jumper set)
  68.  
  69.     public    driver_class, driver_type, driver_name, driver_function, parameter_list
  70. driver_class    db    1        ;from the packet spec
  71. driver_type    db    48        ;from the packet spec
  72. driver_name    db    20 dup(?)    ;name of the driver.
  73. driver_function    db    2
  74. parameter_list    label    byte
  75.     db    1    ;major rev of packet driver
  76.     db    9    ;minor rev of packet driver
  77.     db    14    ;length of parameter list
  78.     db    EADDR_LEN    ;length of MAC-layer address
  79.     dw    GIANT    ;MTU, including MAC headers
  80.     dw    MAX_MULTICAST * EADDR_LEN    ;buffer size of multicast addrs
  81.     dw    0    ;(# of back-to-back MTU rcvs) - 1
  82.     dw    0    ;(# of successive xmits) - 1
  83.     dw    0    ;Interrupt # to hook for post-EOI
  84.             ;processing, 0 == none,
  85.  
  86. lbca:
  87. doca:
  88. ;we may be called from places in which ds is unknown.
  89.     assume    ds:nothing
  90.     loadport
  91.     setport    IOCA
  92.     out    dx,al            ; send it
  93.     ret
  94.     assume    ds:code
  95. ;yet, we really should assume ds==code for the rest of this stuff.
  96.  
  97. ;
  98. ; Here we include the code that is common between 82586 implementations.
  99. ; Everything above this is resident.
  100.     include    82586.asm
  101. ; Everything below this is discarded upon installation.
  102.  
  103.     public    usage_msg
  104. usage_msg    db    "usage: at&t <packet_int_no> <int_no> <io_addr> <base_addr>",CR,LF,'$'
  105.  
  106.     public    copyright_msg
  107. copyright_msg    db    "Packet driver for the AT&T Starlan/Ethernet boards, version ",'0'+majver,".",'0'+version,".",'0'+i82586_version,CR,LF
  108.         db    "Portions Copyright 1988 The Board of Trustees of the University of Illinois",CR,LF,'$'
  109.  
  110. board_name_list    dw    board_00, board_01, board_11, board_02
  111.         dw    board_03, board_unk
  112.  
  113. board_00    db    00h, "StarLAN 1",0,47
  114. board_01    db    01h, "StarLAN 10 NAU",0,48
  115. board_11    db    11h, "StarLAN 10 R2 NAU",0,48
  116. board_02    db    02h, "EN100",0,49
  117. board_03    db    03h, "StarLAN Fiber NAU",0,55
  118. board_unk    db    -1h, "Unknown AT&T",48        ;just a guess.
  119.  
  120.     extrn    chrout: near
  121.  
  122. check_board:
  123.     assume    ds:code
  124.     loadport
  125.     setport    IOREV
  126.     in    al,dx
  127.     mov    bx,offset board_name_list
  128. check_board_name:
  129.     mov    si,[bx]            ;get a pointer to a string.
  130.     add    bx,2
  131.     cmp    byte ptr [si],-1    ;is this the end?
  132.     je    check_board_found
  133.     cmp    al,[si]            ;is this the right one?
  134.     jne    check_board_name
  135. check_board_found:
  136.     inc    si            ;skip the board revision number.
  137.  
  138.     mov    dx,offset this_board_msg
  139.     mov    ah,9
  140.     int    21h
  141.  
  142.     mov    ax,ds            ;copy the driver name to where
  143.     mov    es,ax            ;  we need it.
  144.     mov    di,offset driver_name
  145. check_board_copy:
  146.     lodsb
  147.     stosb
  148.     or    al,al
  149.     je    check_board_done_print
  150.     call    chrout            ;print the character.
  151.     jmp    check_board_copy
  152. check_board_done_print:
  153.     lodsb                ;copy the driver type number over
  154.     mov    driver_type,al
  155.     mov    al,CR
  156.     call    chrout
  157.     mov    al,LF
  158.     call    chrout
  159.  
  160.     loadport
  161.     setport    IOATTR
  162.     in    al,dx            ;get the bus width bit into bit zero.
  163.     shr    al,1
  164.     shr    al,1
  165.     not    al
  166.     and    al,1            ;and negate it.
  167.     mov    SCP,al            ;that makes it into the bus width flag.
  168.  
  169.     in    al,dx            ;get the manchester code
  170.     shr    al,1
  171.     shr    al,1
  172.     not    al            ;the bit is flipped.
  173.     and    al,4            ;isolate just the manchester/~nrz bit.
  174.     mov    byte ptr CBCONF_FLAGS,al
  175.  
  176.     mov    dx,io_addr    ; i/o address
  177.     in    al,dx
  178.     mov    bl,al        ; assemble pattern to check
  179.     inc    dx
  180.     in    al,dx
  181.     mov    bh,al
  182.     cmp    bx,0008h    ; pattern known to be there in ROM
  183.     jz    have_att_io
  184.     pop    dx            ;drop our return address
  185.     mov    dx,offset no_att_io_msg
  186.     jmp    error
  187. have_att_io:
  188.  
  189.     mov    ax,base_addr
  190.     mov    cx,2000h        ;test only what we are going to use.
  191.     call    memory_test
  192.     jz    have_att_mem
  193.     pop    dx            ;drop our return address
  194.     mov    dx,offset no_att_mem_msg
  195.     jmp    error
  196. have_att_mem:
  197.     ret
  198.  
  199.  
  200. this_board_msg    db    "This board is an AT&T ",'$'
  201. no_att_io_msg    db    "No AT&T board found at that I/O address.",CR,LF,'$'
  202. no_att_mem_msg    db    "No AT&T board found at that memory address.",CR,LF,'$'
  203.  
  204.     include    memtest.asm
  205.  
  206. code    ends
  207.  
  208.     end
  209.