home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / fortran / library / linpack / saxpy.for < prev    next >
Text File  |  1984-01-01  |  1KB  |  48 lines
  1.       SUBROUTINE SAXPY(N,SA,SX,INCX,SY,INCY)
  2. C
  3. C     CONSTANT TIMES A VECTOR PLUS A VECTOR.
  4. C     USES UNROLLED LOOPS FOR INCREMENTS EQUAL TO ONE.
  5. C     JACK DONGARRA, LINPACK, 3/11/78.
  6. C
  7.       REAL SX(1),SY(1),SA
  8.       INTEGER I,INCX,INCY,IXIY,M,MP1,N
  9. C
  10.       IF(N.LE.0)RETURN
  11.       IF (SA .EQ. 0.0E0) RETURN
  12.       IF(INCX.EQ.1.AND.INCY.EQ.1)GO TO 20
  13. C
  14. C        CODE FOR UNEQUAL INCREMENTS OR EQUAL INCREMENTS
  15. C          NOT EQUAL TO 1
  16. C
  17.       IX = 1
  18.       IY = 1
  19.       IF(INCX.LT.0)IX = (-N+1)*INCX + 1
  20.       IF(INCY.LT.0)IY = (-N+1)*INCY + 1
  21.       DO 10 I = 1,N
  22.         SY(IY) = SY(IY) + SA*SX(IX)
  23.         IX = IX + INCX
  24.         IY = IY + INCY
  25.    10 CONTINUE
  26.       RETURN
  27. C
  28. C        CODE FOR BOTH INCREMENTS EQUAL TO 1
  29. C
  30. C
  31. C        CLEAN-UP LOOP
  32. C
  33.    20 M = MOD(N,4)
  34.       IF( M .EQ. 0 ) GO TO 40
  35.       DO 30 I = 1,M
  36.         SY(I) = SY(I) + SA*SX(I)
  37.    30 CONTINUE
  38.       IF( N .LT. 4 ) RETURN
  39.    40 MP1 = M + 1
  40.       DO 50 I = MP1,N,4
  41.         SY(I) = SY(I) + SA*SX(I)
  42.         SY(I + 1) = SY(I + 1) + SA*SX(I + 1)
  43.         SY(I + 2) = SY(I + 2) + SA*SX(I + 2)
  44.         SY(I + 3) = SY(I + 3) + SA*SX(I + 3)
  45.    50 CONTINUE
  46.       RETURN
  47.       END
  48.