home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / forth / compiler / fpc / tcom / debugger / ftchstor.seq < prev    next >
Text File  |  1990-09-11  |  3KB  |  86 lines
  1. \ FTCHSTOR.SEQ    words that fetch or store data in the target micro
  2.  
  3. \ *******************************************************************
  4. \
  5. \       Write and Read bytes and words in target micro memory
  6. \
  7. \ -------------------------------------------------------------------
  8.  
  9. : (t!)  ( word target-addr -- )  \ write one target memory word
  10.         sendword        \ address
  11.         1 com-out       \ count = 1
  12.         sendword        \ data word
  13.         key? if key drop ." aborted" then  ;
  14.  
  15. : t!   ( word target-addr -- ) \ write one target memory word
  16.         6 command (t!)  ;
  17.  
  18. : t!w  ( word target-addr -- ) \ write a word in the alternate register set
  19.         14 command (t!)  ;
  20.  
  21. : (tc!)  ( byte target-addr -- ) \ write one target memory byte
  22.         sendword        \ address
  23.         1 com-out       \ count = 1
  24.         com-out         \ send the byte
  25.         ;
  26.  
  27. : tc!   ( byte target-addr -- ) \ write one target memory byte
  28.         3 command (tc!)  ;
  29.  
  30. : tc!w  ( byte target-addr -- ) \ write a byte in the alternate register set
  31.         12 command (tc!)  ;
  32.  
  33. : tfill ( target-addr length value -- ) \ fill target memory with a byte
  34.         24 command
  35.         rot sendword    \ address
  36.         swap sendword   \ length
  37.         com-out         \ send the byte value
  38.         ;
  39.  
  40. : (t@) ( target-address -- w ) \ fetch one target memory word
  41.         sendword        \ address
  42.         1 com-out       \ count = 1
  43.         getword  ;      \ get data
  44.  
  45. : t@ ( target-address -- ) \ fetch one target memory word
  46.         7 command (t@)  ;
  47. : t@w ( target-address -- ) \ fetch a word in the alternate register set
  48.         15 command (t@)  ;
  49.  
  50. : (tc@) ( target-address -- ) \ fetch one target memory byte
  51.         sendword        \ address
  52.         1 com-out       \ count = 1
  53.         getbyte  ;      \ get data
  54.  
  55. : tc@ ( target-address -- ) \ fetch one target memory byte
  56.         4 command (tc@)  ;
  57. : tc@w ( target-address -- ) \ fetch a byte in the alternate register set
  58.         13 command (tc@)  ;
  59.  
  60. : 0seg-dump ( a n -- )  0 -rot ldump ;  \ byte dump with segment = 0
  61. : 0seg-wdump ( a n -- ) 0 -rot lwdump ; \ word dump with segment = 0
  62.  
  63. : tdump ( a n -- ) \ dump target memory bytes
  64.         ['] tc@ is dumpc@  0seg-dump  ['] %dumpc@ is dumpc@ ;
  65.  
  66. : alt-tdump ( a n -- ) \ dump target memory bytes of alternate register set
  67.         ['] tc@w is dumpc@  0seg-dump  ['] %dumpc@ is dumpc@ ;
  68.  
  69. : twdump ( addr len -- ) \ dump out target word contents
  70.         ['] t@ is dump@   0seg-wdump   ['] %dump@ is dump@  ;
  71.  
  72. : alt-twdump ( a n -- ) \ dump target memory words of alternate register set
  73.         ['] t@w is dump@  0seg-wdump  ['] %dump@ is dump@ ;
  74.  
  75.  
  76. : tEDIT ( a n -- ) \ edit target byte memory
  77.         2 !> nwidth
  78.         ['] dln is medln        ['] 0seg-dump is medump
  79.         ['] tc@ is dumpc@       ['] tc! is mec!         mem-edit   ;
  80.  
  81. : twEDIT ( a n -- ) \ edit target word memory
  82.         4 !> nwidth
  83.         ['] dlnw is medln       ['] 0seg-wdump is medump
  84.         ['] t@ is dump@         ['] t! is mec!          mem-edit   ;
  85.  
  86.