home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Power-Programmierung
/
CD1.mdf
/
basic
/
library
/
zbasic
/
pia
/
address.bas
next >
Wrap
BASIC Source File
|
1987-10-30
|
2KB
|
49 lines
100 DEFINT A,G,I,K,M,N,P,S,T,U,W: DEFDBL B,C,D,L,O
101 DEFSNG E,F,H,J,Q,R,V,X,Y,Z
105 REM $INCLUDE: 'COMMON.BAS'
110 REM $INCLUDE: 'GETSTRN.BAS'
1000 REM Retrieve current address
1005 OPEN "I",1,"ADDRESS.DAT"
1010 FOR K1=1 TO 4: INPUT #1,T$(K1): NEXT K1: CLOSE #1
1015 REM Print address correction menu
1020 CLS: GOSUB 2000: PRINT " ";: GOSUB 9870
1025 PRINT STRING$(20," ");"Set social security office address";
1030 PRINT STRING$(21," "): GOSUB 2000
1035 PRINT: PRINT: PRINT " Current address is:"
1040 FOR K1=1 TO 4: PRINT " (";K1;") ";
1045 PRINT T$(K1): NEXT K1: PRINT
1050 GOSUB 9860: PRINT " Enter line number to change, or 0 if";
1055 PRINT " okay > ";: K8=VAL(FNGETSTRN$(1)): GOSUB 9850
1060 IF K8<0 OR K8>4 THEN BEEP: GOTO 1050
1065 IF K8=0 THEN 1200
1070 GOSUB 9860: PRINT " Enter new line";K8;"(RETURN if none)"
1075 PRINT " > ";: T$(K8)=FNGETSTRN$(34): GOSUB 9850
1080 GOTO 1015
1200 REM Save new address
1205 OPEN "O",1,"ADDRESS.DAT"
1210 FOR K1=1 TO 4: PRINT #1,CHR$(34);T$(K1);CHR$(34): NEXT K1: CLOSE #1
1400 REM Print exit menu
1405 CLS: GOSUB 2000: PRINT " ";: GOSUB 9870
1410 PRINT STRING$(29," ");"Program selection";STRING$(29," ")
1415 GOSUB 2000: PRINT: PRINT
1420 GOSUB 9860: PRINT " Enter desired program:"
1425 PRINT " 0 to calculate a PIA"
1427 PRINT " 1 to review or change configuration"
1430 PRINT " 2 to review or update historical amounts"
1435 PRINT " > ";: K8=VAL(FNGETSTRN$(1))
1440 IF K8<0 OR K8>2 THEN BEEP: GOTO 1420
1445 CLS: GOSUB 9850: ON K8+1 GOTO 1600,1460,1450
1450 PRINT " Loading data-update program; please wait..."
1455 CHAIN "OLDAWBI"
1460 PRINT " Loading configuration program; please wait..."
1465 CHAIN "CONFIG"
1600 PRINT " Loading PIA data-input program; please wait..."
1605 CHAIN "PIAIN"
2000 REM Subroutine to draw 75 hyphens
2005 GOSUB 9860: PRINT " ";STRING$(75,"-"): RETURN
9800 REM 1-line subroutines
9813 REM For Macintosh, $INCLUDE "COLOR.MAC"
9814 REM $INCLUDE: 'COLOR.BAS'
9900 GOSUB 9860: CLS: END
9999 REM ADDRESS.BAS - 10/30/87 - 03:45 PM