home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / assemblr / library / sampler1 / dev.asm < prev    next >
Assembly Source File  |  1985-08-28  |  6KB  |  234 lines
  1.         name    dev
  2.         page    60,132
  3.         title   'DEV --- Report installed device drivers'
  4.  
  5. ; DEV --- a utility to report device header information for
  6. ;         all installed device drivers
  7. ; 
  8. ; Requires PC-DOS or MS-DOS 2.0.
  9. ;
  10. ; Used in the form:
  11. ; A>DEV 
  12. ;
  13. ; version 1.0   December 12, 1984
  14. ; Copyright (c) 1984 by Ray Duncan
  15.  
  16. cr      equ     0dh             ;ASCII carriage return
  17. lf      equ     0ah             ;ASCII line feed
  18. blank    equ    20h        ;ASCII space code
  19. eom    equ    '$'        ;end of string marker
  20.  
  21.  
  22. cseg    segment    para public 'CODE'
  23.  
  24.     assume    cs:cseg,ds:data,es:data,ss:stack
  25.  
  26.  
  27. dev     proc    far             ;entry point from PC-DOS
  28.  
  29.         push    ds              ;save DS:0000 for final
  30.         xor     ax,ax           ;return to PC-DOS
  31.         push    ax
  32.         mov     ax,data         ;make our data segment
  33.     mov    ds,ax        ;addressable via DS and ES.
  34.     mov     es,ax 
  35.         mov     ah,30h        ;check version of PC-DOS.    
  36.         int     21h
  37.         cmp     al,2
  38.         jae     dev1        ;proceed, DOS 2.0 or greater.
  39.         mov     dx,offset msg2  ;DOS 1.x --- print error message.
  40.     jmp    dev6
  41.  
  42. dev1:    mov    cx,ax        ;save DOS version number.
  43.     mov    ah,15        ;now try and open the "NUL" device.
  44.     mov    dx,offset nulfcb
  45.     int    21h
  46.     or    al,al        ;opened successfully?
  47.     jz    dev2        ;yes, jump.
  48.     mov    dx,offset msg1    ;no, print error msg and exit.
  49.     jmp    dev6
  50.  
  51. dev2:                ;Pick up double pointer to device 
  52.                 ;driver chain out of reserved
  53.                 ;area in fcb.  This area is mapped
  54.                 ;differently in DOS 2.x and DOS 3.x.
  55.     cmp    cl,2        ;is this DOS 2.x?
  56.     ja    dev3        ;no, jump.
  57.     mov    bx,word ptr nulfcb+25
  58.     mov    es,word ptr nulfcb+27
  59.     jmp    dev4
  60.  
  61. dev3:                ;come here if DOS 3.0 or greater.
  62.     mov    bx,word ptr nulfcb+26
  63.     mov    es,word ptr nulfcb+28
  64.  
  65. dev4:    call    header        ;print sign-on message and 
  66.                 ;column headings.
  67.  
  68. dev5:                ;trace through the device chain
  69.  
  70.     call    prdev        ;print device header information
  71.                 ;for driver pointed to by ES:BX.
  72.                 ;pick up addr of next header.
  73.     les    bx,dword ptr es:[bx]
  74.     cmp    bx,-1        ;found last one yet?
  75.     jne    dev5        ;no, try next.
  76.     
  77.           mov    dx,offset msg3    ;yes, print "end of device chain".
  78.  
  79. dev6:     mov    ah,9        ;print the string whose address
  80.     int    21h        ;is in DX.
  81.     ret            ;then return to DOS.
  82.  
  83. dev       endp
  84.  
  85.  
  86. header    proc    near        ;print out headings for device
  87.     mov    dx,offset hdr    ;driver information.
  88.     mov    ah,9
  89.     int    21h
  90.     ret
  91. header    endp
  92.  
  93.  
  94. prdev    proc    near        ;print out device driver info.
  95.                 ;ES:BX is pointer to device header,
  96.                 ;which must be preserved.
  97.     mov    ax,es        ;convert segment of device header
  98.     mov    di,offset inf1
  99.     call    hexasc
  100.     mov    ax,bx        ;convert offset of device header.
  101.     mov    di,offset inf2
  102.     call    hexasc
  103.     mov    ax,es:[bx+4]    ;get attribute word, save a 
  104.     push    ax        ;copy of it, then convert it.
  105.     mov    di,offset inf3
  106.     call    hexasc
  107.     mov    ax,es:[bx+6]    ;convert ptr to device strategy.
  108.     mov    di,offset inf4
  109.     call    hexasc
  110.     mov    ax,es:[bx+8]    ;convert ptr to device int handler.
  111.     mov    di,offset inf5
  112.     call    hexasc
  113.  
  114.                 ;if not char device, clear out name
  115.                 ;field and set number of units.
  116.     pop    ax        ;get back attribute word.
  117.     test    ax,08000h    ;is bit 15 = 1 ?
  118.     jnz    prdev7        ;yes, it's character dev, jump.
  119.                           ;no, it's block device.
  120.                 ;set flag to skip device name.
  121.     mov     byte ptr inf8,eom
  122.     mov    al,es:[bx+10]    ;pick up number of units.
  123.     aam            ;convert to ASCII decimal and
  124.     add    ax,'00'        ;store into output string.
  125.     mov    byte ptr inf7+1,al
  126.     mov    byte ptr inf7,ah
  127.                 ;set type = B for Block
  128.     mov    byte ptr inf6,'B'    
  129.     jmp    prdev9
  130.  
  131. prdev7:                ;if char device, move its 8-character
  132.                 ;name into the output string.
  133.     xor    si,si
  134. prdev8:    mov    al,es:[si+bx+10]
  135.     mov    [si+inf8],al
  136.     inc    si
  137.     cmp    si,8
  138.     jne    prdev8
  139.                 ;remove # of units field.
  140.     mov    word ptr inf7,'  '
  141.                 ;set type = C for Character.
  142.     mov    byte ptr inf6,'C'
  143.  
  144. prdev9: mov    dx,offset inf    ;now print device information
  145.     mov    ah,9        ;and exit.
  146.     int    21h
  147.     ret
  148. prdev    endp
  149.  
  150. hexasc    proc    near        ;convert binary word to hex ASCII.
  151.                 ;call with AX=binary value
  152.                 ;          DI=addr to store string 
  153.                 ;returns AX, CX, DI destroyed.
  154.     push    ax        ;save copy of original value.
  155.     mov    al,ah
  156.     call    btoa        ;convert upper byte.
  157.     add    di,2        ;increment output address.
  158.     pop    ax
  159.     call    btoa        ;convert lower byte.
  160.     ret            ;return to caller.
  161. hexasc    endp
  162.  
  163. btoa    proc    near        ;convert binary byte to hex ASCII.
  164.                 ;call with AL=binary value 
  165.                 ;          DI=addr to store string
  166.                 ;returns AX, CX destroyed.
  167.     mov    ah,al        ;save lower nibble.
  168.     mov    cx,4        ;shift right 4 positions
  169.     shr    al,cl        ;to get upper nibble.
  170.     call    ascii        ;convert 4 bits to ASCII equivalent
  171.     mov    [di],al        ;store into output string.
  172.     mov    al,ah        ;get back lower nibble.
  173.     and    al,0fh
  174.     call    ascii        ;convert 4 bits to ASCII
  175.     mov     [di+1],al    ;and store into output string.
  176.     ret            ;back to caller.
  177. btoa    endp
  178.  
  179. ascii    proc    near        ;convert 4 lower bits of AL
  180.     add    al,'0'        ;into the equivalent ASCII char.
  181.     cmp    al,'9'        ;in the range {0...9,A...F}
  182.     jle    ascii2        ;and return char. in AL.
  183.     add    al,'A'-'9'-1    ;"fudge factor" for range A-F.
  184. ascii2:    ret            ;return to caller.
  185. ascii    endp
  186.  
  187. cseg    ends
  188.  
  189.  
  190. data    segment para public 'DATA'
  191.  
  192. msg1    db    cr,lf
  193.     db    'Failed to open NUL device.'
  194.     db    cr,lf,eom
  195.  
  196. msg2    db      cr,lf
  197.         db      'Requires DOS version 2 or greater.'
  198.         db      cr,lf,eom
  199.  
  200. msg3    db    cr,lf
  201.     db    'End of device chain.'
  202.     db    cr,lf,eom
  203.  
  204. hdr    db    cr,lf
  205.     db    'Addr      Attr '
  206.     db    'Str  Int   Type  Units  Name   '
  207.     db    eom
  208.  
  209.  
  210. inf     db    cr,lf
  211. inf1    db    'XXXX:'        ;seg device header
  212. inf2    db    'XXXX '        ;offs device header
  213. inf3    db    'XXXX '        ;attribute
  214. inf4    db    'XXXX '        ;strategy
  215. inf5    db    'XXXX   '    ;interrupt handler
  216. inf6    db    'X     '    ;type (block or char)
  217. inf7    db    'XX    '    ;units (if block device)
  218. inf8    db    '         '    ;name  (if char device)
  219.     db    eom
  220.  
  221.                 ;fcb to open NUL device
  222. nulfcb    db    0        ;drive
  223.     db    'NUL'        ;name of NUL device
  224.     db    8 dup (' ')
  225.     db    25 dup (0)
  226. data    ends    
  227.  
  228.  
  229. stack   segment para stack 'STACK'
  230.         db      64 dup (?)
  231. stack   ends
  232.  
  233.         end     dev
  234.