home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / assemblr / library / sampler0 / freecopy.asm < prev    next >
Assembly Source File  |  1985-06-06  |  94KB  |  2,855 lines
  1. Page    55,132
  2. Title    FREECOPY Version 1.13 (C)Copyright 1984
  3. ;***********************  F R E E C O P Y  ******************************
  4. ;*                                    *
  5. ;*    Program: FREECOPY                        *
  6. ;*                                    *
  7. ;*    Author: Donald L. Buresh, C.D.P.                *
  8. ;*        Squire Buresh Associates, Inc.                *
  9. ;*        Post Office Box 112                    *
  10. ;*        Millbury, MA  01527                    *
  11. ;*        (617) 865-3435                        *
  12. ;*                                    *
  13. ;*    !!!!!!!!!!!!!!!!!!!!!!   N O T I C E   !!!!!!!!!!!!!!!!!!!!!!     *
  14. ;*                                    *
  15. ;*    A limited license is granted to all users of this program to    *
  16. ;*    make copies of this source code and to distribute them to    *
  17. ;*    other users under the following conditions:            *
  18. ;*                                    *
  19. ;*    1. The notice contained in the variable MES00_Copy_Notice    *
  20. ;*       is not to be altered, bypassed or removed.            *
  21. ;*                                    *
  22. ;*    2. The program is not to be distributed to others in        *
  23. ;*       modified form.                        *
  24. ;*                                    *
  25. ;*    3. If you think that this program has helped you, we request    *
  26. ;*       a $25.00 contribution.                    *
  27. ;*                                    *
  28. ;*    4. No other fee is to be charged or any consideration received    *
  29. ;*       for copying or distributing the program without the        *
  30. ;*       expressed written permission of Squire Buresh Assoc, Inc.    *
  31. ;*                                    *
  32. ;*                                    *
  33. ;*  (C) Copyright  1984        Squire Buresh Associates, Inc.        *
  34. ;*                                    *
  35. ;************************************************************************
  36. Page
  37. ;************************************************************************
  38. ;*                                    *
  39. ;*    REVISION HISTORY                        *
  40. ;*                                    *
  41. ;*    Version                                *
  42. ;*    Number    Date        Comments                *
  43. ;*                                    *
  44. ;*    1.00    16-SEP-84    This is the first version of FREECOPY    *
  45. ;*                                    *
  46. ;*    1.01    13-OCT-84    Corrected a problem when copying    *
  47. ;*                diskettes on 512K systems. Reversed    *
  48. ;*                the order of testing the ES:BX table    *
  49. ;*                counter and the read/write track    *
  50. ;*                counter. Fix was near C2005, C2006,    *
  51. ;*                C2105 and C2106.            *
  52. ;*                                    *
  53. ;*    1.02    13-OCT-84    Flushed the standard input keyboard    *
  54. ;*                buffer before accepting a character.    *
  55. ;*                Fix was near U1101 and U1102.        *
  56. ;*                                    *
  57. ;*    1.03    21-OCT-84    Added parsing a tab character on the    *
  58. ;*                command line.  Fix was below C1215.    *
  59. ;*                                    *
  60. ;*    1.04 - 1.09        These versions never really existed in    *
  61. ;*                any decent form.  They are incorporated    *
  62. ;*                into fixing the memory allocation    *
  63. ;*                problems stemming from the original    *
  64. ;*                version of FREECOPY.            *
  65. ;*                                    *
  66. ;*    1.10    02-FEB-85    Allocated and freed memory when running    *
  67. ;*                FREECOPY under PC-DOS versions 2.00    *
  68. ;*                and greater.  The fix involved finding    *
  69. ;*                out the version of the operating system,*
  70. ;*                allocating the memory, establishing    *
  71. ;*                the ES:BX table entries and freeing    *
  72. ;*                memory before returning control to    *
  73. ;*                PC-DOS.                    *
  74. ;*                                    *
  75. ;*    1.11    06-JUN-85    Modified the sequence of turning inter- *
  76. ;*                rupts on and off in the S1000 and S1100 *
  77. ;*                modules.                *
  78. ;*                                    *
  79. ;*    1.12    06-JUN-85    Allowed users to write more than one    *
  80. ;*                target diskette, by setting FLG17 to    *
  81. ;*                True and jumping to B1105A after ini-    *
  82. ;*                tializing the appropriate variables.    *
  83. ;*                                    *
  84. ;*    1.13    07-JUN-85    Fixed a stack imbalance that appeared    *
  85. ;*                only when running PC-DOS 3.00 on a PC    *
  86. ;*                rather than on an XT or AT        *
  87. ;*                                    *
  88. ;************************************************************************
  89. Page
  90. ;************************************************************************
  91. ;*                                    *
  92. ;*    EQUATES                                *
  93. ;*                                    *
  94. ;*    The constants defined below are used to to specify:        *
  95. ;*                                    *
  96. ;*            o Disk commands,                *
  97. ;*                                    *
  98. ;*            o Keyboard commands,                *
  99. ;*                                    *
  100. ;*            o Video commands                *
  101. ;*                                    *
  102. ;*            o Miscellaneous parameters,            *
  103. ;*                                    *
  104. ;*            o Various ASCII characters.            *
  105. ;*                                    *
  106. ;************************************************************************
  107. ;
  108. Disk_Parameter_Addr    Equ    001EH*4    ; Address of Disk Parameter Table
  109. ;
  110. Reset_Command        Equ    0000D    ; Diskette reset command
  111. Status_Command        Equ    0001D    ; Diskette status command
  112. Read_Command        Equ    0002D    ; Diskette read command
  113. Write_Command        Equ    0003D    ; Diskette write command
  114. Verify_Command        Equ    0004D    ; Diskette verify command
  115. Format_Command         Equ    0005D    ; Diskette format command
  116. ;
  117. Time_Out_Error        Equ    0080H    ; Diskette error codes
  118. Seek_Error        Equ    0040H    ; .
  119. Controller_Error    Equ    0020H    ; .
  120. CRC_Error        Equ    0010H    ; .
  121. DMA_Boundary_Error    Equ    0009H    ; .
  122. DMA_Error        Equ    0008H    ; .
  123. Sector_Error        Equ    0004H    ; .
  124. Write_Protect_Error    Equ    0003H    ; .
  125. Address_Mark_Error    Equ    0002H    ; .
  126. Command_Error        Equ    0001H    ; ..End
  127. ;
  128. Video_Address        Equ    0A000H    ; Starting segment addr of Video RAM
  129. ;
  130. Set_Mode_Command    Equ    0000D    ; Set the video mode
  131. Set_CType_Command    Equ    0001D    ; Set the cursor type
  132. Set_CPos_Command    Equ    0002D    ; Set the cursor position
  133. Read_Cursor_Command    Equ    0003D    ; Get cursor position and attributes
  134. Read_LPen_Command    Equ    0004D    ; Get the light pen position
  135. Set_ADPage_Command    Equ    0005D    ; Set the active display page
  136. Scroll_Up_Command    Equ    0006D    ; Scrool up or blank a portion of
  137.                     ; . the video display
  138. ;
  139. Page
  140. ;************************************************************************
  141. ;*                                    *
  142. ;*    EQUATES        Page 2                        *
  143. ;*                                    *
  144. ;************************************************************************
  145. ;
  146. Scroll_Down_Command    Equ    0007D    ; Scroll down or blank a portion
  147.                     ; . of the video display
  148. Read_AChar_Command    Equ    0008D    ; Read the attribute and character
  149. Write_AChar_command    Equ    0009D    ; Write the attribute and character
  150. Write_Char_Command    Equ    0010D    ; Write the character only
  151. Set_Color_Command    Equ    0011D    ; Set the color pallette
  152. Write_Dot_Command    Equ    0012D    ; Write a pixel to a graphics screen
  153. Read_Dot_Command    Equ    0013D    ; Read a pixel from a graphics screen
  154. Write_TTY_Command    Equ    0014D    ; Write a character with automatic
  155.                     ; . processing for LF, CR, Bell & BS
  156. Video_State_Command    Equ    0015D    ; Get the current video state
  157. ;
  158. Read_Keyboard_Command    Equ    0007D    ; Reads character from the keyboard
  159. Flush_Keyboard_Command    Equ    0012D    ; Clears the standard keyboard buffer
  160. Get_DOS_Version_Number    Equ    0030H    ; Gets the current version of PC-DOS
  161. Allocate_Memory        Equ    0048H    ; Allocate a block of memory
  162. Free_Memory        Equ    0049H    ; Free a block of memory
  163. Modify_Memory_Block    Equ    004AH    ; Modify the size of memory block
  164. ;
  165. Default_Drive_Command    Equ    0025D    ; Get PC DOS default drive number
  166. ;
  167. Video_Interrupt        Equ    0010H    ; Interrupt 10H for video calls
  168. Equipment_Interrupt    Equ    0011H    ; Interrupt 11H for equipment
  169. Disk_Interrupt        Equ    0013H    ; Interrupt 13H for disk calls
  170. PC_DOS_Interrupt    Equ    0021H    ; Interrupt 21H for PC DOS calls
  171. ;
  172. Parallel_Ports_Mask    Equ    0C000H    ; Equipment masks
  173. Game_Adapters_Mask    Equ    00100H    ; .
  174. RS232_Ports_Mask    Equ    00E00H    ; .
  175. Disk_Drives_Mask    Equ    000C0H    ; .
  176. Init_Video_Mask        Equ    00030H    ; .
  177. Planar_RAM_Mask        Equ    0000CH    ; .
  178. IPL_Diskette_Mask    Equ    00001H    ; ..End
  179. ;
  180. Page
  181. ;************************************************************************
  182. ;*                                    *
  183. ;*    EQUATES        Page 3                        *
  184. ;*                                    *
  185. ;************************************************************************
  186. ;
  187. Command_Com_Size    Equ    0410D    ; Size of various tables and programs
  188. CHRN_Table_Size        Equ    0180D    ; in 16 byte paragraphs
  189.                     ; .
  190.                     ; .
  191. ESBX_Table_Size        Equ    0020D    ; .
  192.                     ; .
  193.                     ; .
  194. FAT_Sector_Size        Equ    0032D    ; ..End
  195. ;
  196. DMA_Boundary_Mask    Equ    0FFFH    ; Mask to isolate the high nibble of
  197.                     ; . the ES segment address
  198. ;
  199. Invalid_Drive        Equ    0255D    ; Invalid drive parameter
  200. Maximum_Drives        Equ    0003D    ; Maximum number of floppy drives 
  201. Minimum_Drives        Equ    0000D    ; Minimum number of floppy drives
  202. ;
  203. Sector_Size        Equ    0512D    ; Number of bytes per sector
  204. Paragraph_Size        Equ    0016D    ; Number of bytes per paragraph
  205. Number_of_Retries    Equ    0005D    ; Number of attempts to copy 
  206.                     ; . a track before admitting failure
  207. Final_Track        Equ    0039D    ; The last track on a PC DOS diskette
  208. ;
  209. One_Side_Eight_Sectors    Equ    00FEH    ; First entry in the File Allocation
  210. Two_Sides_Eight_Sectors    Equ    00FFH    ; Table (FAT)
  211. One_Side_Nine_Sectors    Equ    00FCH    ; .
  212. Two_Sides_Nine_Sectors    Equ    00FDH    ; .
  213. Fixed_Disk        Equ    00F8H    ; ..End
  214. ;
  215. Keyboard_Buffer_Size    Equ    0080D    ; Maximum number of characters in
  216.                     ; . the keyboard buffer
  217. ;
  218. Minimum_Memory_Size    Equ    0288D    ; Minimum memory size in 16 byte
  219.                     ; . paragraphs to hold a nine
  220.                     ; . sectored track
  221. ;
  222. Blank_Cursor        Equ    0F0FH    ; Blank cursor value
  223. Underline_Cursor    Equ    0D0DH    ; Underline cursor value
  224. ;
  225. False            Equ    0000D    ; Incorrect processing occured
  226. True            Equ Not False    ; Correct processing occured
  227. High_Values        Equ    0FFFFH    ; High values
  228. ;
  229. Page
  230. ;************************************************************************
  231. ;*                                    *
  232. ;*    EQUATES        Page 4                        *
  233. ;*                                    *
  234. ;************************************************************************
  235. ;
  236. NUL            Equ    0000D    ; Null character
  237. SOH            Equ    0001D    ; SOH character
  238. STX            Equ    0002D    ; STX character
  239. ETX            Equ    0003D    ; Control Break character
  240. Bell            Equ    0007D    ; Bell character
  241. BS            Equ    0008D    ; Backspace character
  242. HT            Equ    0009D    ; Horizontal tab character
  243. LF            Equ    0010D    ; Line feed character
  244. CR            Equ    0013D    ; Carriage return character
  245. Space            Equ    0032D    ; Space or blank character
  246. Slash            Equ    0047D    ; Slash character
  247. Zero_Digit        Equ    0048D    ; Digit Zero
  248. One_Digit        Equ    0049D    ; Digit One
  249. Capital_Letter_A    Equ    0065D    ; Capital letter A
  250. Capital_Letter_N    Equ    0078D    ; Capital letter N
  251. Capital_Letter_Y    Equ    0089D    ; Capital letter Y
  252. Small_Letter_n        Equ    0110D    ; Small letter n
  253. Small_Letter_y        Equ    0121D    ; Small letter y
  254. EOT            Equ    0255D    ; End of text character
  255. ;
  256. Minus_One        Equ      -1D    ; Numbers used in FREECOPY
  257. Zero            Equ    0000D    ; .
  258. One            Equ    0001D    ; .
  259. Two            Equ    0002D    ; .
  260. Three            Equ    0003D    ; .
  261. Four            Equ    0004D    ; .
  262. Six            Equ    0006D    ; .
  263. Eight            Equ    0008D    ; .
  264. Nine            Equ    0009D    ; .
  265. Ten            Equ    0010D    ; .
  266. Eleven            Equ    0011D    ; .
  267. Twelve            Equ    0012D    ; .
  268. Fourteen        Equ    0014D    ;.
  269. Fifteen            Equ    0015D    ; .
  270. Twenty_Four        Equ    0024D    ; .
  271. Twenty_Five        Equ    0025D    ; .
  272. Thirty_Four        Equ    0034D    ; .
  273. Thirty_Six        Equ    0036D    ; .
  274. Thirty_Nine        Equ    0039D    ; .
  275. Seventy_Nine        Equ    0079D    ; ..End
  276. ;
  277. Page
  278. ;************************************************************************
  279. ;*                                    *
  280. ;*    CSEG Segment                            *
  281. ;*                                    *
  282. ;*    This segment contains all of the code of the program.  It is    *
  283. ;*    named CSEG because this name conforms with ASM-86.        *
  284. ;*                                    *
  285. ;************************************************************************
  286. ;
  287. CSEG    Segment Para Public 'CSEG'
  288.     Assume CS:CSEG,DS:CSEG,ES:CSEG,SS:Nothing
  289. ;
  290. Page
  291. ;************************************************************************
  292. ;*                                    *
  293. ;*    PROGRAM SEGMENT PREFIX                        *
  294. ;*                                    *
  295. ;*    The first 256 bytes of every program executed under PC DOS    *
  296. ;*    contains a Program Segment Prefix control block.  The data    *
  297. ;*    stored in this block of memory is used by FREECOPY to process    *
  298. ;*    the parameters when invoking the program.            *
  299. ;*                                    *
  300. ;************************************************************************
  301. ;
  302.     Org    05CH
  303. Source_Drive        Label Byte    ; Source diskette drive number
  304.     Org    05DH
  305. Source_Filename        Label Byte    ; Source diskette filename
  306.     Org    068H
  307. Source_Filler_Area    Label Byte
  308.     Org    06CH
  309. Target_Drive        Label Byte    ; Target diskette drive number
  310.     Org    06DH
  311. Target_Filename        Label Byte    ; Target diskette filename
  312.     Org    078H
  313. Target_Filler_Area    Label Byte
  314.     Org    080H
  315. Parameter_Count        Label Byte    ; Number of parameters
  316.     Org    081H
  317. Parameter_String    Label Byte    ; String entered by the user
  318. ;
  319. Page
  320. ;************************************************************************
  321. ;*                                    *
  322. ;*    A1000_MAIN_MODULE                        *
  323. ;*                                    *
  324. ;*    This is the top level of FREECOPY and it controls the flow of    *
  325. ;*    the program.  The first sequence of commands in the routine    *
  326. ;*    preserve the state of the machine.  Next, there is a set of    *
  327. ;*    three (3) calls to sub-modules that control the initial        *
  328. ;*    processing, detail processing and final processing.  Finally,    *
  329. ;*    FREECOPY restores the state of the machine an returns to     *
  330. ;*    PC DOS via INT 20H.                        *
  331. ;*                                    *
  332. ;************************************************************************
  333. ;
  334.     Org    0100H
  335. ;
  336. Public    A1000_Main_Module
  337. ;
  338. A1000_Main_Module Proc Far
  339. ;
  340. A1001:
  341.     Cli                ; Set up the top of the stack
  342.     Mov    SP,Offset MEM04_Top_of_the_Stack
  343.     Sti                ; ..End
  344. ; 
  345.     Push    BP            ; Save the state of the machine
  346.     Push    DS            ; .
  347.     Push    ES            ; .
  348.     Push    SS            ; .
  349.     Push    AX            ; .
  350.     Push    BX            ; .
  351.     Push    CX            ; .
  352.     Push    DX            ; .
  353.     Push    SI            ; .
  354.     Push    DI            ; .
  355.     Pushf                ; ..End
  356. ;
  357.     Cli                ; Save the current stack pointer
  358.     Mov    Word Ptr SYS15_Stack_Pointer,SP
  359.     Add    Word Ptr SYS15_Stack_Pointer,Two            ; .
  360.     Sti                ; ..End
  361. ;
  362.     Call    B1000_Initial_Process    ; Main flow of control
  363.     Cmp    Byte Ptr FLG01_Good_Command,False
  364.     Je    A1002            ; .
  365.     Cmp    Byte Ptr FLG03_Default_Drive,False
  366.     Je    A1002            ; .
  367.     Call    B1100_Detail_Process    ; .
  368. A1002:                    ; .
  369.     Call    B1200_Final_Process    ; ..End
  370. A1090:
  371.     Popf                ; Restore the state of the machine
  372.     Pop    DI            ; .
  373.     Pop    SI            ; .
  374.     Pop    DX            ; .
  375.     Pop    CX            ; .
  376.     Pop    BX            ; .
  377.     Pop    AX            ; .
  378.     Pop    SS            ; .
  379.     Pop    ES            ; .
  380.     Pop    DS            ; .
  381.     Pop    BP            ; ..End
  382. A1099:
  383.     Int    20H            ; Return to PC DOS
  384. ;
  385. A1000_Main_Module Endp
  386. ;
  387. Page
  388. ;************************************************************************
  389. ;*                                    *
  390. ;*    B1000_INITIAL_PROCESS                        *
  391. ;*                                    *
  392. ;*    This module performs the following functions after control    *
  393. ;*    passess to FREECOPY:                        *
  394. ;*                                    *
  395. ;*     1. Sets up the Disk Parameter Table.                *
  396. ;*                                    *
  397. ;*     2. Gets the current PC-DOS version number.            *
  398. ;*                                    *
  399. ;*     3. Initializes various parameters.                *
  400. ;*                                    *
  401. ;*     4. Gets and sets the video mode.                *
  402. ;*                                    *
  403. ;*     5. Displays the intiial message.                *
  404. ;*                                    *
  405. ;*     6. Parses the command line entered by a user.            *
  406. ;*                                    *
  407. ;*     7. Determines the amount of equipment on the machine.        *
  408. ;*                                    *
  409. ;*     8. Validates the number of disk drives on the system.        *
  410. ;*                                    *
  411. ;*     9. Displays the appropriate disk copying message.        *
  412. ;*                                    *
  413. ;*    10. Gets the amount of available memory.            *
  414. ;*                                    *
  415. ;*    11. Calculates the number and position of the entries in the    *
  416. ;*        ES:BX buffer address table.                    *
  417. ;*                                    *
  418. ;************************************************************************
  419. ;
  420. Page
  421. ;
  422. Public    B1000_Initial_Process
  423. ;
  424. B1000_Initial_Process Proc Near
  425. ;
  426. B1001:
  427.     Call    S1000_Setup_Disk_Param_Table
  428.     Call    S1200_Get_Version_Number
  429. ;
  430.     Mov    Byte Ptr FLG01_Good_Command,True
  431.     Mov    Byte Ptr FLG02_Double_Side,True
  432.     Mov    Byte Ptr FLG03_Default_Drive,True
  433.     Mov    Byte Ptr FLG04_Single_Drive,True
  434.     Mov    Byte Ptr FLG07_First_Time,True
  435.     Mov    Byte Ptr FLG16_Free_Memory,True
  436.     Mov    Byte Ptr FLG17_Copy_More_Disks,False
  437. B1002:
  438.     Call    C1000_Get_And_Set_Video    ; Get and set current video state
  439.     Call    C1100_Display_Intro    ; Display the intial screen
  440.     Call    C1200_Parse_Commands    ; Parse the command line entered
  441.                     ; . by the user
  442.     Cmp    Byte Ptr FLG01_Good_Command,False
  443.     Je    B1099            ; If false, go to end of the module
  444.     Call    C1300_Get_Equipment    ; Find out the equipment on the PC
  445.     Call    C1400_Validate_Drives    ; Validate the drive numbers
  446.     Cmp    Byte Ptr FLG03_Default_Drive,False
  447.     Je    B1099            ; If false, go to end of the module
  448.     Call    C1500_Diskette_Messages    ; Display the appropriate messages
  449. ;
  450.     Cmp    Byte Ptr SYS19_Major_Vers_Number,Zero
  451.     Jne    B1003            ; Get available memory in paragraphs
  452.     Call    C1600A_Get_Free_Memory    ; . and create the ES:BX table
  453.     Jmp    B1004            ; .
  454. B1003:                    ; .
  455.     Call    C1600B_Get_Free_Memory    ; .
  456. B1004:                    ; .
  457.     Cmp    Byte Ptr FLG01_Good_Command,False
  458.     Je    B1099            ; .
  459.     Call    C1700_Create_ESBX_Table; ..End
  460. B1099:
  461.     Ret
  462. ;
  463. B1000_Initial_Process Endp
  464. ;
  465. Page
  466. ;************************************************************************
  467. ;*                                    *
  468. ;*    B1100_DETAIL_PROCESS                        *
  469. ;*                                    *
  470. ;*    This module performs the following functions when copying one    *
  471. ;*    or more diskettes:                        *
  472. ;*                                    *
  473. ;*    1. Initializes various parameters.                *
  474. ;*                                    *
  475. ;*    2. Validates the contents of the source diskette.        *
  476. ;*                                    *
  477. ;*    3. Creates all of the entries of the CHRN table used in        *
  478. ;*       formatting the target diskette.                *
  479. ;*                                    *
  480. ;*    4. Reads the tracks of the source diskette.            *
  481. ;*                                    *
  482. ;*    5. If the diskette is being copied on only one drive, the    *
  483. ;*       routines asks the user to enter the target diskette.        *
  484. ;*                                    *
  485. ;*    6. Writes the tracks on the target diskette.            *
  486. ;*                                    *
  487. ;*    7. If FREECOPY is finished copying the source diskette, the    *
  488. ;*       program asks whether to write another target diskette,    *
  489. ;*       provided the source diskette fits completely in memory;    *
  490. ;*       otherwise, the program asks whether to copy a new diskette.    *
  491. ;*       If not, the module returns to A1000_Main_Module.  If so,    *
  492. ;*       control transfers to 1.                    *
  493. ;*                                    *
  494. ;*    8. If FREECOPY is not completed copying the source diskette,    *
  495. ;*       control transfers to 4.                    *
  496. ;*                                    *
  497. ;************************************************************************
  498. ;
  499. Page
  500. ;
  501. Public    B1100_Detail_Process
  502. ;
  503. B1100_Detail_Process Proc Near
  504. ;
  505. B1101:
  506.     Mov    Byte Ptr WRK20_Current_Source_Head,Zero
  507.     Mov    Byte Ptr WRK21_Current_Source_Track,Zero
  508.     Mov    Byte Ptr WRK22_Current_Target_Head,Zero
  509.     Mov    Byte Ptr WRK23_Current_Target_Track,Zero
  510.     Mov    Word Ptr WRK33_CHRN_Table_Address,Offset MEM02_CHRN_Table
  511.     Mov    Byte Ptr FLG13_First_Read_Write,True
  512.     Mov    Byte Ptr FLG14_Copy_Complete,False
  513.     Mov    Byte Ptr FLG15_IO_Error,Three
  514. B1102:
  515.     Call    C1800_Validate_Source_Disk
  516.     Cmp    Byte Ptr FLG08_Good_Read,True
  517.     Je    B1103            ; If it is a valid source, continue
  518.     Mov    SI,Offset MES07_Correct_And_Press_Key
  519.     Call    U1000_Display_Message    ; Display the message on the screen
  520.     Mov    Byte Ptr FLG05_Store_Buffer,False
  521.     Call    U1100_Get_Response    ; Get the user's response
  522.     Jmp    B1101            ; Go back and try again
  523. B1103:
  524.     Call    C1900_Create_CHRN_Table
  525. B1104:
  526.     Call    C2000_Read_Source_Disk
  527.     Cmp    Byte Ptr FLG08_Good_Read,True
  528.     Je    B1105            ; If read disk correctly, continue
  529.     Mov    SI,Offset MES07_Correct_And_Press_Key
  530.     Call    U1000_Display_Message    ; Display the message on the screen
  531.     Mov    Byte Ptr FLG05_Store_Buffer,False
  532.     Call    U1100_Get_Response    ; Get the user's response
  533.     Jmp    B1101            ; Go back and try again
  534. B1105:
  535.     Cmp    Byte Ptr FLG04_Single_Drive,False
  536.     Je    B1106            ; If a single drive copy, continue
  537. B1105A:
  538.     Mov    SI,Offset MES10_Insert_Target
  539.     Mov    AL,Byte Ptr WRK02_Target_Drive
  540.     Add    AL,Capital_Letter_A    ; Put drive letter into AL
  541.     Mov    [SI+Thirty_Four],AL    ; Put the drive letter into the
  542.                     ; . correct position in the message
  543.     Call    U1000_Display_Message    ; Display the message on the screen
  544.     Mov    SI,Offset MES16_Press_Any_Key
  545.     Call    U1000_Display_Message    ; Display the message on the screen
  546.     Mov    Byte Ptr FLG05_Store_Buffer,False
  547.     Call    U1100_Get_Response    ; Get the user's response
  548. B1106:
  549.     Call    C2100_Write_Format_Target_Disk
  550.     Cmp    Byte Ptr FLG09_Good_Write,False
  551.     Je    B1110            ; If bad write, go to bottom of loop
  552.     Cmp    Byte Ptr FLG11_Good_Format,False
  553.     Je    B1110            ; If bad format, go to bottom of loop
  554. B1107:
  555.     Cmp    Byte Ptr FLG14_Copy_Complete,True
  556.     Je    B1109            ; If copy done, go to bottom of loop
  557.     Cmp    Byte Ptr FLG04_Single_Drive,False
  558.     Je    B1108            ; If double drive copy, continue
  559.     Mov    SI,Offset MES09_Insert_Source
  560.     Mov    AL,Byte Ptr WRK01_Source_Drive
  561.     Add    AL,Capital_Letter_A    ; Put the drive letter into AL
  562.     Mov    [SI+Thirty_Four],AL    ; Put the drive letter into the
  563.                     ; . correct position in the message
  564.     Call    U1000_Display_Message    ; Display the message on the screen
  565.     Mov    SI,Offset MES16_Press_Any_Key
  566.     Call    U1000_Display_Message    ; Display the message on the screen
  567.     Mov    Byte Ptr FLG05_Store_Buffer,False
  568.     Call    U1100_Get_Response    ; Get the user's response
  569. B1108:
  570.     Call    C2200_Check_File_Alloc_Table
  571.     Cmp    Byte Ptr FLG12_Good_FAT,False
  572.     Je    B1110            ; If bad FAT, go to bottom of loop
  573.     Mov    Byte Ptr FLG13_First_Read_Write,False
  574.     Jmp    B1104            ; Go back and read some more
  575. B1109:
  576.     Mov    Byte Ptr FLG07_First_Time,False
  577.     Mov    SI,Offset MES02_Copy_Complete
  578.     Call    U1000_Display_Message
  579. B1110:
  580.     Cmp    Byte Ptr FLG17_Copy_More_Disks,False
  581.     Je    B1111
  582.     Mov    SI,Offset MES01A_Write_Another_Diskette
  583.     Call    U1000_Display_Message
  584.     Call    U1200_Get_Yes_or_No
  585.     Cmp    Byte Ptr FLG06_Yes_or_No,False
  586.     Je    B1111            ; Continue
  587.     Mov    Byte Ptr WRK22_Current_Target_Head,Zero
  588.     Mov    Byte Ptr WRK23_Current_Target_Track,Zero
  589.     Mov    Word Ptr WRK33_CHRN_Table_Address,Offset MEM02_CHRN_Table
  590.     Mov    Byte Ptr FLG13_First_Read_Write,True
  591.     Mov    Byte Ptr FLG14_Copy_Complete,False
  592.     Mov    Byte Ptr FLG15_IO_Error,Three
  593.     Jmp    B1105A            ; Start writing a diskette again
  594. B1111:
  595.     Mov    SI,Offset MES01B_Copy_Another_Diskette
  596.     Call    U1000_Display_Message
  597.     Call    U1200_Get_Yes_or_No
  598.     Cmp    Byte Ptr FLG06_Yes_or_No,False
  599.     Je    B1199            ; Go to the end of the module
  600.     Call    C1500_Diskette_Messages    ; Print out the messages on screen
  601.     Jmp    B1101            ; Start copying a diskette again
  602. B1199:
  603.     Ret
  604. ;
  605. B1100_Detail_Process Endp
  606. ;
  607. Page
  608. ;************************************************************************
  609. ;*                                    *
  610. ;*    B1200_FINAL_PROCESS                        *
  611. ;*                                    *
  612. ;*    This module performs the following functions before returning     *
  613. ;*    control to PC DOS:                        *
  614. ;*                                    *
  615. ;*    1. Restores the value of the stack pointer.            *
  616. ;*                                    *
  617. ;*    2. Displays the final message of the program.            *
  618. ;*                                    *
  619. ;*    3. Restores the underline cursor.                *
  620. ;*                                    *
  621. ;*    4. Restores the settings in the Disk Parameter Table.        *
  622. ;*                                    *
  623. ;*    5. Returns control to A1000_Main_Module.            *
  624. ;*                                    *
  625. ;************************************************************************
  626. ;
  627. Page
  628. ;
  629. Public    B1200_Final_Process
  630. ;
  631. B1200_Final_Process Proc Near
  632. ;
  633. B1201:
  634.     Cli                ; Establish the stack pointer
  635.     Mov    SP,Word Ptr SYS15_Stack_Pointer
  636.     Sti                ; ..End
  637. ;
  638.     Call    C2300_Free_Memory    ; Free allocated memory  if necessary
  639. ;
  640.     Mov    SI,Offset MES100_Freecopy_Finished
  641.     Call    U1000_Display_Message    ; Display the message on the screen
  642. ;
  643.     Mov    AH,Set_CType_Command    ; Restore the underline cursor
  644.     Mov    CX,Underline_Cursor    ; .
  645.     Int    Video_Interrupt        ; ..End
  646. ;
  647.     Call    S1100_Restore_Disk_Param_Table
  648. ;
  649.     Mov    AX,Offset A1090        ; Setup to return to the main module
  650.     Push    CS            ; .
  651.     Push    AX            ; ..End
  652. B1299:
  653.     Ret
  654. ;
  655. B1200_Final_Process Endp
  656. ;
  657. Page
  658. ;************************************************************************
  659. ;*                                    *
  660. ;*    C1000_GET_AND_SET_VIDEO                        *
  661. ;*                                    *
  662. ;*    This module gets the current video state and saves this        *
  663. ;*    information in the various SYStem variables.            *
  664. ;*                                    *
  665. ;************************************************************************
  666. ;
  667. Public    C1000_Get_And_Set_Video
  668. ;
  669. C1000_Get_And_Set_Video Proc Near
  670. ;
  671. C1001:
  672.     Push    AX            ; Save the registers
  673.     Push    BX            ; .
  674.     Push    CX            ; ..End
  675. C1002:
  676.     Mov    AH,Video_State_Command    ; Get the current video state
  677.     Int    Video_Interrupt        ; ..End
  678.     Mov    Byte Ptr SYS01_Number_Columns,AH
  679.     Mov    Byte Ptr SYS02_Current_Mode,AL
  680.     Mov    Byte Ptr SYS03_Active_Page,BH
  681. C1003:
  682.     Mov    AH,Set_CType_Command    ; Set the cursor to blanks
  683.     Mov    CX,Blank_Cursor        ; .
  684.     Int    Video_Interrupt        ; ..End
  685. C1090:
  686.     Pop    CX            ; Restore the registers
  687.     Pop    BX            ; .
  688.     Pop    AX            ; ..End
  689. C1099:
  690.     Ret
  691. ;
  692. C1000_Get_And_Set_Video Endp
  693. ;
  694. Page
  695. ;************************************************************************
  696. ;*                                    *
  697. ;*    C1100_DISPLAY_INTRO                        *
  698. ;*                                    *
  699. ;*    This module displays the introductory message to FREECOPY.    *
  700. ;*    Please do not disable this message, since it states the        *
  701. ;*    conditions under which a person may copy this program.        *
  702. ;*                                    *
  703. ;************************************************************************
  704. ;
  705. Public    C1100_Display_Intro
  706. ;
  707. C1100_Display_Intro Proc Near
  708. ;
  709. C1101:
  710.     Mov    SI,Offset MES00_Copy_Notice    ; Display the copy notice
  711.     Call    U1000_Display_Message        ; ..End
  712. C1199:
  713.     Ret
  714. C1100_Display_Intro Endp
  715. ;
  716. Page
  717. ;************************************************************************
  718. ;*                                    *
  719. ;*    C1200_PARSE_COMMANDS                        *
  720. ;*                                    *
  721. ;*    This module parses the command line entered by the user        *
  722. ;*    by checking the following conditions:                *
  723. ;*                                    *
  724. ;*    1. The source and/or the target drives do not exist.        *
  725. ;*                                    *
  726. ;*    2. The command line contains any characters other than two    *
  727. ;*       drive letters (e.g., a filename).                *
  728. ;*                                    *
  729. ;*    3. The /1 (single side) parameter is on the command line.    *
  730. ;*                                    *
  731. ;************************************************************************
  732. ;
  733. Public    C1200_Parse_Commands
  734. ;
  735. C1200_Parse_Commands Proc Near
  736. ;
  737. C1201:
  738.     Cmp    AH,Invalid_Drive    ; Compare for invalid drive parms
  739.     Jne    C1202            ; .
  740.     Mov    Byte Ptr FLG01_Good_Command,False
  741.     Mov    SI,Offset MES14_Invalid_Drive
  742.     Call    U1000_Display_Message
  743.     Jmp    C1299            ; .
  744. C1202:                    ; .
  745.     Cmp    AL,Invalid_Drive    ; .
  746.     Jne    C1203            ; .
  747.     Mov    Byte Ptr FLG01_Good_Command,False
  748.     Mov    SI,Offset MES14_Invalid_Drive
  749.     Call    U1000_Display_Message
  750.     Jmp    C1299            ; ..End
  751. C1203:
  752.     Mov    AL,Byte Ptr Source_Drive
  753.     Mov    Byte Ptr WRK01_Source_Drive,AL
  754.     Mov    AL,Byte Ptr Target_Drive
  755.     Mov    Byte Ptr WRK02_Target_Drive,AL
  756. C1204:
  757.     Mov    SI,Offset Source_Filename
  758.     Mov    DI,Offset WRK03_Valid_Filename
  759.     Mov    CX,Eleven        ; Set CX to compare 11 characters 
  760. C1205:
  761.     Mov    AL,[SI]            ; Compare for valid source diskette
  762.     Mov    AH,[DI]            ; filename in the FCB at 05DH
  763.     Cmp    AH,AL            ; .
  764.     Je    C1206            ; .
  765.     Mov    Byte Ptr FLG01_Good_Command,False
  766.     Mov    SI,Offset MES12_Invalid_Parameter
  767.     Call    U1000_Display_Message
  768.     Jmp    C1299            ; .
  769. C1206:                    ; .
  770.     Inc    SI            ; .
  771.     Inc    DI            ; .
  772.     Loop    C1205            ; ..End
  773. C1207:
  774.     Mov    SI,Offset Target_Filename
  775.     Mov    DI,Offset WRK03_Valid_Filename
  776.     Mov    CX,Eleven        ; Set CX to comapre 11 characters
  777. C1208:
  778.     Mov    AL,[SI]            ; Compare for valid target diskette
  779.     Mov    AH,[DI]            ; . filename in the FCB at 06DH
  780.     Cmp    AH,AL            ; .
  781.     Je    C1209            ; .
  782.     Mov    Byte Ptr FLG01_Good_Command,False
  783.     Mov    SI,Offset MES12_Invalid_Parameter
  784.     Call    U1000_Display_Message
  785.     Jmp    C1299            ; .
  786. C1209:                    ; .
  787.     Inc    SI            ; .
  788.     Inc    DI            ; .
  789.     Loop    C1208            ; ..End
  790. C1210:
  791.     Mov    AL,Byte Ptr Parameter_Count
  792.     Mov    Byte Ptr WRK04_Parameter_Count,AL
  793.     Mov    SI,Offset Parameter_String
  794.     Inc    Byte Ptr WRK04_Parameter_Count
  795. C1211:
  796.     Dec    Byte Ptr WRK04_Parameter_Count
  797.     Jz    C1299            ; Go to the end of the module
  798.     Mov    AL,[SI]            ; Put the character into AL
  799.     Cmp    AL,Slash        ; Compare character with a slash
  800.     Je    C1212            ; If so, then continue processing
  801.     Inc    SI            ; Increment the command string addr
  802.     Jmp    C1211            ; Go back and try again
  803. C1212:
  804.     Inc    SI            ; Increment the command string addr
  805.     Mov    AL,[SI]            ; Get the next char after the slash
  806.     Cmp    AL,One_Digit        ; Compare with the char 1
  807.     Je    C1214            ; Set double side flag to false
  808. C1213:
  809.     Mov    Byte Ptr FLG01_Good_Command,False
  810.     Mov    SI,Offset MES12_Invalid_Parameter
  811.     Call    U1000_Display_Message
  812.     Jmp    C1299            ; Go to the end of the module
  813. C1214:
  814.     Mov    Byte Ptr FLG02_Double_Side,False
  815.     Dec    Byte Ptr WRK04_Parameter_Count
  816.     Jz    C1299            ; Go to the end of the module
  817. C1215:
  818.     Dec    Byte Ptr WRK04_Parameter_Count
  819.     Jz    C1299            ; Go to the end of the module
  820.     Inc    SI            ; Increment the command string addr
  821.     Mov    AL,[SI]            ; Get the next char in command line
  822.     Cmp    AL,HT            ; Check for tabs and spaces
  823.     Je    C1215            ; .
  824.     Cmp    AL,Space        ; .
  825.     Je    C1215            ; ..End
  826. C1216:
  827.     Mov    Byte Ptr FLG01_Good_Command,False
  828.     Mov    SI,Offset MES12_Invalid_Parameter
  829.     Call    U1000_Display_Message
  830. C1299:
  831.     Ret
  832. ;
  833. C1200_Parse_Commands Endp
  834. ;
  835. Page
  836. ;************************************************************************
  837. ;*                                    *
  838. ;*    C1300_GET_EQUIPMENT                        *
  839. ;*                                    *
  840. ;*    This module determines the peripheral devices on the machine.    *
  841. ;*    It invokes the equipment status interrupt and places the    *
  842. ;*    information into the appropriate SYStem parameters.        *
  843. ;*                                    *
  844. ;************************************************************************
  845. ;
  846. Public    C1300_Get_Equipment
  847.  
  848.  
  849. C1300_Get_Equipment Proc Near
  850. ;
  851. C1301:
  852.     Int    Equipment_Interrupt    ; Get the equipment on machine
  853.     Mov    BX,AX            ; Save the result for future use
  854. ;
  855.     And    AX,Parallel_Ports_Mask    ; Get the number of parallel ports
  856.     Mov    CL,Fourteen        ; .
  857.     Shr    AX,CL            ; .
  858.     Mov    Byte Ptr SYS07_No_Parallel_Ports,AL
  859. ;
  860.     Mov    AX,BX            ; Get the game adapter attachments
  861.     And    AX,Game_Adapters_Mask    ; .
  862.     Mov    CL,Twelve        ; .
  863.     Shr    AX,CL            ; .
  864.     Mov    Byte Ptr SYS08_Game_Adapters,AL
  865. ;
  866.     Mov    AX,BX            ; Get the number of RS-232 ports
  867.     And    AX,RS232_Ports_Mask    ; .
  868.     Mov    CL,Nine            ; .
  869.     Shr    AX,CL            ; .
  870.     Mov    Byte Ptr SYS09_No_RS232_Ports,AL
  871. ;
  872.     Mov    AX,BX            ; Get the number of diskette drives
  873.     And    AX,Disk_Drives_Mask    ; .
  874.     Mov    CL,Six            ; .
  875.     Shr    AX,CL            ; .
  876.     Mov    Byte Ptr SYS10_No_Disk_Drives,AL
  877. ;
  878.     Mov    AX,BX            ; Get the initial video mode
  879.     And    AX,Init_Video_Mask    ; .
  880.     Mov    CL,Four            ; .
  881.     Shr    AX,CL            ; .
  882.     Mov    Byte Ptr SYS11_Init_Video_Mode,AL
  883. ;
  884.     Mov    AX,BX            ; Get planar RAM size
  885.     And    AX,Planar_RAM_Mask    ; .
  886.     Mov    CL,Two            ; .
  887.     Shr    AX,CL            ; .
  888.     Mov    Byte Ptr SYS12_Planar_RAM_Size,AL
  889. ;
  890.     Mov    AX,BX            ; Get IPL from diskette flag
  891.     And    AX,IPL_Diskette_Mask    ; .
  892.     Mov    Byte Ptr SYS13_IPL_From_Diskette,AL
  893. ;
  894. C1399:
  895.     Ret
  896. ;
  897. C1300_Get_Equipment Endp
  898. ; 
  899. Page
  900. ;************************************************************************
  901. ;*                                    *
  902. ;*    C1400_VALIDATE_DRIVES                        *
  903. ;*                                    *
  904. ;*    This module determines if the drives specified in the        *
  905. ;*    command line are floppy disk drives or RAM disk drives.        *
  906. ;*    It also checks if copying the source diskette takes place    *
  907. ;*    on a single drive.                        *
  908. ;*                                    *
  909. ;************************************************************************
  910. ;
  911. Public    C1400_Validate_Drives
  912. ;
  913. C1400_Validate_Drives Proc Near
  914. ;
  915. C1401:
  916.     Mov    AH,Default_Drive_Command; Get the PC DOS default drive
  917.     Int    PC_DOS_Interrupt    ; .
  918.     Mov    Byte Ptr SYS14_Default_Drive,AL
  919. C1402:
  920.     Cmp    Byte Ptr SYS10_No_Disk_Drives,Minimum_Drives
  921.     Ja    C1403            ; If not single drive copy, set
  922.                     ; . FLG04 to false
  923.     Mov    Byte Ptr SYS14_Default_Drive,Minimum_Drives
  924.     Mov    Byte Ptr WRK01_Source_Drive,Minimum_Drives
  925.     Mov    Byte Ptr WRK02_Target_Drive,Minimum_Drives
  926.     Jmp    C1499            ; Go to the end of the module
  927. C1403:
  928.     Mov    Byte Ptr FLG04_Single_Drive,False
  929. C1404:
  930.     Cmp    Byte Ptr SYS14_Default_Drive,Maximum_Drives
  931.     Jbe    C1405            ; If below maximum, continue
  932.     Mov    Byte Ptr FLG03_Default_Drive,False
  933.     Mov    SI,Offset MES13_Invalid_Default
  934.     Call    U1000_Display_Message
  935.     Jmp    C1499            ; Go to the end of the module
  936. C1405:
  937.     Dec    Byte Ptr WRK01_Source_Drive
  938.     Cmp    Byte Ptr WRK01_Source_Drive,Minus_One
  939.     Jne    C1406
  940.     Mov    AL,Byte Ptr SYS14_Default_Drive
  941.     Mov    Byte Ptr WRK01_Source_Drive,AL
  942. C1406:
  943.     Dec    Byte Ptr WRK02_Target_Drive
  944.     Cmp    Byte Ptr WRK02_Target_Drive,Minus_One
  945.     Jne    C1407
  946.     Mov    AL,Byte Ptr SYS14_Default_Drive
  947.     Mov    Byte Ptr WRK02_Target_Drive,AL
  948. C1407:
  949.     Mov    AL,Byte Ptr WRK01_Source_Drive
  950.     Mov    AH,Byte Ptr WRK02_Target_Drive
  951.     Cmp    AH,AL            ; Check source drive = target drive
  952.     Jne    C1499            ; If so, then continue
  953.     Mov    Byte Ptr FLG04_Single_Drive,True
  954. C1499:
  955.     Ret
  956. ;
  957. C1400_Validate_Drives Endp
  958. ;
  959. Page
  960. ;************************************************************************
  961. ;*                                    *
  962. ;*    C1500_DISKETTE_MESSAGES                        *
  963. ;*                                    *
  964. ;*    This module displays the appropriate source and target        *
  965. ;*    insertion diskette messages on the screen.            *
  966. ;*                                    *
  967. ;************************************************************************
  968. ;
  969. Public    C1500_Diskette_Messages
  970. ;
  971. C1500_Diskette_Messages Proc Near
  972. ;
  973. C1501:
  974.     Cmp    Byte Ptr FLG07_First_Time,False
  975.     Je    C1502            ; If not first time, continue
  976.     Cmp    Byte Ptr FLG04_Single_Drive,False
  977.     Je    C1502            ; If false, then continue
  978.     Mov    SI,Offset MES15_Single_Drive_Copy
  979.     Call    U1000_Display_Message
  980. C1502:
  981.     Mov    SI,Offset MES09_Insert_Source
  982.     Mov    AL,Byte Ptr WRK01_Source_Drive
  983.     Add    AL,Capital_Letter_A    ; Put the drive letter into AL
  984.     Mov    [SI+Thirty_Four],AL    ; Put the drive letter into the
  985.                     ; . correct position in the message
  986.     Call    U1000_Display_Message    ; Display the message on the screen
  987. C1503:
  988.     Cmp    Byte Ptr FLG04_Single_Drive,True
  989.     Je    C1505            ; If true, go to the message to press
  990.                     ; . any key to continue
  991. C1504:
  992.     Mov    SI,Offset MES10_Insert_Target
  993.     Mov    AL,Byte Ptr WRK02_Target_Drive
  994.     Add    AL,Capital_Letter_A    ; Put the drive letter into AL
  995.     Mov    [SI+Thirty_Four],AL    ; Put the drive letter into the
  996.                     ; . correct position in the message
  997.     Call    U1000_Display_Message    ; Display the message on the screen
  998. C1505:
  999.     Mov    SI,Offset MES16_Press_Any_Key
  1000.     Call    U1000_Display_Message
  1001.     Mov    Byte Ptr FLG05_Store_Buffer,False
  1002.     Call    U1100_Get_Response
  1003. C1599:
  1004.     Ret
  1005. ;
  1006. C1500_Diskette_Messages Endp
  1007. ;
  1008. Page
  1009. ;************************************************************************
  1010. ;*                                    *
  1011. ;*    C1600A_GET_FREE_MEMORY                        *
  1012. ;*                                    *
  1013. ;*    This module calculates the amount of free 16 byte paragraphs    *
  1014. ;*    available on the machine. The segment address of the beginning    *
  1015. ;*    of free memory is obtained by setting DX to:            *
  1016. ;*                                    *
  1017. ;*        1. The contents of the stack segment SS plus        *
  1018. ;*                                    *
  1019. ;*        2. 256 bytes for the Program Segment Prefix plus    *
  1020. ;*                                    *
  1021. ;*        3. 128 bytes for the stack.                *
  1022. ;*                                    *
  1023. ;*    After saving the ES segment register on the stack and        *
  1024. ;*    initializing both the offset register BX and the 16 byte    *
  1025. ;*    counter register CX to zero, the routine begins the looping    *
  1026. ;*    through memory 16 bytes at a time (incrementing the segment    *
  1027. ;*    register ES by one) until either the module encounters one    *
  1028. ;*    of the two (2) conditions:                    *
  1029. ;*                                    *
  1030. ;*        1. The beginning of Video RAM at the segment address    *
  1031. ;*           specified in Video_Address.                *
  1032. ;*                                    *
  1033. ;*        2. The memory pattern defined by the machine that    *
  1034. ;*           indicates no more memory.                *
  1035. ;*                                    *
  1036. ;*    When either of these two (2) conditions occur, CX contains    *
  1037. ;*    the  number of 16 bytes paragraphs of free memory.        *
  1038. ;*                                    *
  1039. ;*    Since we do not know the size of the transient portion of    *
  1040. ;*    COMMAND.COM, FREECOPY makes the worst case assumption that    *
  1041. ;*    all of the bytes in COMMAND.COM reside in high memory.        *
  1042. ;*                                    *
  1043. ;*    This module also allocates space for the ES:BX table, the    *
  1044. ;*    CHRN table, the File Allocation Table (FAT) of the source    *
  1045. ;*    diskette and at least one track (4608 bytes).            *
  1046. ;*                                    *
  1047. ;*    This module executes only when running PC-DOS 1.0 and 1.1!!!    *
  1048. ;*                                    *
  1049. ;************************************************************************
  1050. ;
  1051. Page
  1052. ;
  1053. Public    C1600A_Get_Free_Memory
  1054. ;
  1055. C1600A_Get_Free_Memory Proc Near
  1056. ;
  1057. C1601A:
  1058.     Mov    DX,SS            ; Calculate the segment address for
  1059.                     ; . the beginning of free memory
  1060.     Add    DX,Offset MEM04_Top_of_the_Stack
  1061. ;
  1062.     Push    ES            ; Save ES on the stack for a moment
  1063.     Mov    BX,NUL            ; Initialize BX and CX registers
  1064.     Mov    CX,NUL            ; ..End
  1065. C1602A:
  1066.     Mov    ES,DX            ; Set ES to the appropriate value
  1067.     Cli                ; Turn off interrupts for a moment
  1068.     Mov    AX,ES:[BX]        ; Read a word from memory into AX
  1069.     Mov    Word Ptr ES:[BX],SOH    ; Put the test pattern into memory
  1070.     Cmp    Word Ptr ES:[BX],SOH    ; Compare memory with test pattern
  1071.     Mov    ES:[BX],AX        ; Restore the contents of memory
  1072.     Sti                ; Turn on the interrupts
  1073.     Jne    C1603A            ; If not equal, stop looping
  1074.     Inc    DX            ; Increment DX segment register
  1075.     Cmp    DX,Video_Address    ; Compare for start of Video RAM
  1076.     Jae    C1603A            ; If so, stop looping
  1077.     Inc    CX            ; Increment 16 byte counter CX
  1078.     Jmp    C1602A            ; Go back and try again
  1079. C1603A:
  1080.     Pop    ES            ; Restore the ES register
  1081.     Cmp    CX,Command_Com_Size    ; Compare the paragraph size of
  1082.                     ; . free memory with the paragraph
  1083.                     ; . size of COMMAND.COM.
  1084.     Ja    C1604A            ; If greater, continue
  1085. ;
  1086.     Mov    Byte Ptr FLG01_Good_Command,False
  1087.     Mov    SI,Offset MES11_Insufficient_Memory
  1088.     Call    U1000_Display_Message    ; Display the message on the screen
  1089.     Jmp    C1699A            ; Go to the end of the module
  1090. C1604A:
  1091.     Sub    CX,Command_Com_Size    ; Subtract the size of COMMAND.COM
  1092.     Cmp    CX,ESBX_Table_Size    ; Compare the paragraph size of the
  1093.                     ; . free memory with the paragraph
  1094.                     ; . size of the ES:BX table
  1095.     Ja    C1605A            ; If greater, continue
  1096.     Mov    Byte Ptr FLG01_Good_Command,False
  1097.     Mov    SI,Offset MES11_Insufficient_Memory
  1098.     Call    U1000_Display_Message    ; Display the message on the screen
  1099.     Jmp    C1699A            ; Go to the end of the module
  1100. C1605A:
  1101.     Sub    CX,ESBX_Table_Size    ; Subtract the size of ES:BX table
  1102.     Cmp    CX,CHRN_Table_Size    ; Compare the paragraph size of the
  1103.                     ; . free memory with the paragraph
  1104.                     ; . size of the CHRN table
  1105.     Ja    C1606A            ; If greater, continue
  1106. ;
  1107.     Mov    Byte Ptr FLG01_Good_Command,False
  1108.     Mov    SI,Offset MES11_Insufficient_Memory
  1109.     Call    U1000_Display_Message    ; Display the message on the screen
  1110.     Jmp    C1699A            ; Go to the end of the module
  1111. C1606A:
  1112.     Sub    CX,CHRN_Table_Size    ; Subtract the size of CHRN Table
  1113.     Cmp    CX,FAT_Sector_Size    ; Determine if there is enough memory
  1114.     Jae    C1607A            ; to read the File Allocation Table
  1115.     Mov    Byte Ptr FLG01_Good_Command,False
  1116.     Mov    SI,Offset MES11_Insufficient_Memory
  1117.     Call    U1000_Display_Message    ; Display the message on the screen
  1118.     Jmp    C1699A            ; Go to the end of the module
  1119. C1607A:
  1120.     Sub    CX,FAT_Sector_Size    ; Subtract the size of the source FAT
  1121.     Cmp    CX,Minimum_Memory_Size    ; Determine if the amount of memory
  1122.     Jae    C1608A            ; can hold a nine sectored track
  1123. ;
  1124.     Mov    Byte Ptr FLG01_Good_Command,False
  1125.     Mov    SI,Offset MES11_Insufficient_Memory
  1126.     Call    U1000_Display_Message    ; Display the message on the screen
  1127.     Jmp    C1699A            ; Go to the end of the module
  1128. C1608A:
  1129.     Mov    Word Ptr SYS05_Para_RAM_Size,CX
  1130. C1699A:
  1131.     Ret
  1132. ;
  1133. C1600A_Get_Free_Memory Endp
  1134. ;
  1135. Page
  1136. ;************************************************************************
  1137. ;*                                    *
  1138. ;*    C1600B_GET_FREE_MEMORY                        *
  1139. ;*                                    *
  1140. ;*    This module calcules the amount of available memory.  It    *
  1141. ;*    executes when running PC-DOS versions 2.0 and above.        *
  1142. ;*                                    *
  1143. ;************************************************************************
  1144. ;
  1145. Public    C1600B_Get_Free_Memory
  1146. ;
  1147. C1600B_Get_Free_Memory Proc Near
  1148. ;
  1149. C1601B:
  1150.     Mov    AH,Modify_Memory_Block    ; Allocate enough space for the
  1151.     Mov    BX,Offset MEM00_Bottom_Free_Memory
  1152.     Mov    CL,Four            ; . program and all tables
  1153.     Shr    BX,CL            ; .
  1154.     Inc    BX            ; .
  1155.     Int    PC_DOS_Interrupt    ; .
  1156.     Jnc    C1603B            ; ..End
  1157. C1602B:
  1158.     Mov    Byte Ptr FLG01_Good_Command,False
  1159.     Mov    SI,Offset MES11_Insufficient_Memory
  1160.     Call    U1000_Display_Message    ; Display the message on the screen
  1161.     Jmp    C1699B            ; Go to the end of the module
  1162. C1603B:
  1163.     Mov    AH,Allocate_Memory    ; Get the amount of available memory
  1164.     Mov    BX,High_Values        ; .
  1165.     Int    PC_DOS_Interrupt    ; .
  1166.     Mov    Word Ptr SYS21_Alloc_Segment,AX
  1167.     Mov    Word Ptr SYS05_Para_RAM_Size,BX
  1168.     Jnc    C1699B            ; .
  1169.     Cmp    AL,Eight        ; .
  1170.     Je    C1605B            ; .
  1171. C1604B:
  1172.     Mov    SI,Offset MES97_Return_Linefeed
  1173.     Call    U1000_Display_Message    ; Issue a carriage return/linefeed
  1174.     Mov    SI,Offset MES99_Memory_Block_Destroyed
  1175.     Call    U1000_Display_Message    ; Display the message on the screen
  1176.     Jmp    C1699B            ; Go to the end of the module
  1177. C1605B:
  1178.     Mov    AH,Allocate_Memory    ; .
  1179.     Int    PC_DOS_Interrupt    ; ..End
  1180.     Mov    Word Ptr SYS21_Alloc_Segment,AX
  1181.     Mov    Word Ptr SYS05_Para_RAM_Size,BX
  1182.     Jnc    C1606B            ; Set the allocation flag
  1183.     Jmp    C1604B            ; Go to the error condition
  1184. C1606B:
  1185.     Mov    Byte Ptr FLG16_Free_Memory,False
  1186. C1699B:
  1187.     Ret
  1188. ;
  1189. C1600B_Get_Free_Memory Endp
  1190. ;
  1191. Page
  1192. ;************************************************************************
  1193. ;*                                    *
  1194. ;*    C1700_CREATE_ESBX_TABLE                        *
  1195. ;*                                    *
  1196. ;*    This module creates the correct ES:BX addresses that are    *
  1197. ;*    used when storing tracks read from the source diskette.        *
  1198. ;*    The routine allocates at most 80 entries in the table for    *
  1199. ;*    double sided diskettes.                        *
  1200. ;*                                    *
  1201. ;************************************************************************
  1202. ;
  1203. Public    C1700_Create_ESBX_Table
  1204. ;
  1205. C1700_Create_ESBX_Table Proc Near
  1206. ;
  1207. C1701:
  1208.     Mov    Word Ptr WRK34_DMA_OverFlow_Counter,ZERO
  1209. ;
  1210.     Mov    Word Ptr WRK18_Counter_ESBX_Entries,Zero
  1211.     Mov    AX,Nine            ; Calculate DI = the number of bytes
  1212.     Mov    BX,Sector_Size        ; per track and BX = the number of
  1213.     Mul    BX            ; paragraphs per track
  1214.     Mov    DI,AX            ; .
  1215.     Mov    BX,Paragraph_Size    ; .
  1216.     Mov    DX,Zero            ; .
  1217.     Div    BX            ; .
  1218.     Mov    BX,AX            ; ..End
  1219. ;
  1220.     Cmp    Byte Ptr SYS19_Major_Vers_Number,Zero
  1221.     Je    C1702            ; Compare for PC DOS 1.0 and 1.1
  1222.     Mov    AX,Word Ptr SYS21_Alloc_Segment
  1223.     Jmp    C1703            ; Continue
  1224. C1702:
  1225.     Mov    AX,CS            ; Calculate the address of the 1st
  1226.     Mov    CL,Four            ; that will be copied into memory
  1227.     Shl    AX,CL            ; .
  1228.     Add    AX,Offset MEM00_Bottom_Free_Memory
  1229.     Shr    AX,CL            ; .
  1230.     Inc    AX            ; ..End
  1231. C1703:
  1232.     Mov    SI,Offset MEM03_ESBX_Table
  1233.     Mov    Word Ptr [SI],Zero    ; Put the 1st entry into the table
  1234.     Mov    Word Ptr [SI+Two],AX    ; ..End
  1235. C1704:
  1236.     Cmp    Word Ptr WRK18_Counter_ESBX_Entries,Seventy_Nine
  1237.     Jae    C1707            ; Calculate the ES:BX valid entries
  1238.     Add    SI,Four            ; Get the next ES:BX table address
  1239. ;
  1240.     Mov    AX,[SI-Two]        ; Check for DMA overflow error
  1241.     And    AX,DMA_Boundary_Mask    ; .
  1242.     Shl    AX,CL            ; .
  1243.     Add    AX,DI            ; .
  1244.     Jnc    C1705            ; ..End
  1245. ;
  1246.     Mov    AX,[SI-Two]        ; Correction for DMA overflow
  1247.     Add    AX,BX            ; .
  1248.     Mov    [SI-Two],AX        ; ..End
  1249.     Inc    Word Ptr WRK34_DMA_Overflow_Counter
  1250. C1705:
  1251.     Mov    AX,[SI-Two]        ; Increment the ES segment address
  1252.     Add    AX,BX            ; ..End
  1253. C1706:
  1254.     Mov    Word Ptr [SI],Zero    ; Put the address into the table
  1255.     Mov    Word Ptr [SI+Two],AX    ; ..End
  1256.     Inc    Word Ptr WRK18_Counter_ESBX_Entries
  1257.     Jmp    C1704            ; Go back and find another entry
  1258. C1707:
  1259.     Mov    AX,Word Ptr SYS05_Para_RAM_Size
  1260.     Mov    DX,Zero            ; Divide by the number of paragraphs
  1261.     Div    BX            ; . per track
  1262.     Mov    Word Ptr WRK19_Number_ESBX_Entries,AX
  1263.     Mov    AX,Word Ptr WRK34_DMA_Overflow_Counter
  1264.     Sub    Word Ptr WRK19_Number_ESBX_Entries,AX
  1265.     Cmp    Word Ptr WRK19_Number_ESBX_Entries,Seventy_Nine
  1266.     Jb    C1799            ; If less than 79, continue
  1267.     Mov    Word Ptr WRK19_Number_ESBX_Entries,Seventy_Nine
  1268.     Mov    Byte Ptr FLG17_Copy_More_Disks,True
  1269. C1799:
  1270.     Ret
  1271. ;
  1272. C1700_Create_ESBX_Table Endp
  1273. ;
  1274. Page
  1275. ;************************************************************************
  1276. ;*                                    *
  1277. ;*    C1800_VALIDATE_SOURCE_DISK                    *
  1278. ;*                                    *
  1279. ;*    This module determines if the source diskette is readable    *
  1280. ;*    and whether it was formatted under PC DOS 1.0, 1.1, 2.0 or    *
  1281. ;*    2.1.  The routine also reads the first copy of the File        *
  1282. ;*    Allocation Table (FAT) storing it for future comparisons    *
  1283. ;*    as well as analyzing it first entry.                *
  1284. ;*                                    *
  1285. ;*    A series of comparisons for the number of sectors per track    *
  1286. ;*    is done for the following reasons.  All diskettes formatted    *
  1287. ;*    under PC DOS 2.0 and 2.1 really have nine sectors.  In order    *
  1288. ;*    to obtain an eight sectored diskette, the operating system    *
  1289. ;*    sets the first byte of the File Allocation Table (FAT)        *
  1290. ;*    accordingly.  In contrast, PC DOS 1.0 and 1.1 formats a track    *
  1291. ;*    to have exactly eight sectors.                    *
  1292. ;*                                    *
  1293. ;************************************************************************
  1294. ;
  1295. Public    C1800_Validate_Source_Disk
  1296. ;
  1297. C1800_Validate_Source_Disk Proc Near
  1298. ;
  1299. C1801:
  1300.     Mov    Byte Ptr FLG08_Good_Read,True
  1301. ;
  1302.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1303.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1304.     Mov    Byte Ptr WRK07_Head_Number,Zero
  1305.     Mov    Byte Ptr WRK08_Track_Number,Zero
  1306.     Mov    Byte Ptr WRK09_Sector_Number,Nine
  1307.     Mov    Byte Ptr WRK10_Number_of_Sectors,One
  1308.     Push    CS            ; Establish the address ES:BX
  1309.     Pop    ES            ; ..End
  1310.     Mov    BX,Offset MEM01_File_Allocation_Table
  1311. ;
  1312.     Call    D1000_Read_Diskette
  1313. ;
  1314.     Cli                ; Set the number of sectors to nine
  1315.     Mov    Byte Ptr SYS18_Disk_Parameter_Table[Four],Nine
  1316.     Sti                ; .
  1317.     Mov    Byte Ptr WRK17_Maximum_Sectors,Nine
  1318. ;                
  1319.     Cmp    Byte Ptr FLG08_Good_Read,True
  1320.     Je    C1803            ; Check for good read of sector nine
  1321.     Cmp    Byte Ptr WRK14_Status_Operation,Sector_Error
  1322.     Je    C1802            ; If so, continue
  1323.     Mov    Byte Ptr FLG15_IO_Error,One
  1324.     Call    D1200_Disk_IO_Error    ; Process the error
  1325.     Jmp    C1899            ; ..End
  1326. C1802:
  1327.     Cli                ; Set the number of sectors to eight
  1328.     Mov    Byte Ptr SYS18_Disk_Parameter_Table[Four],Eight
  1329.     Sti                ; .
  1330.     Mov    Byte Ptr WRK17_Maximum_Sectors,Eight
  1331. C1803:                    ; .
  1332.     Mov    Byte Ptr FLG08_Good_Read,True
  1333. ;
  1334.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1335.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1336.     Mov    Byte Ptr WRK07_Head_Number,Zero
  1337.     Mov    Byte Ptr WRK08_Track_Number,Zero
  1338.     Mov    Byte Ptr WRK09_Sector_Number,Two
  1339.     Mov    Byte Ptr WRK10_Number_of_Sectors,One
  1340.     Push    CS            ; Establish the address ES:BX
  1341.     Pop    ES            ; ..End
  1342.     Mov    BX,Offset MEM01_File_Allocation_Table
  1343. ;
  1344.     Call    D1000_Read_Diskette
  1345. ;
  1346.     Cmp    Byte Ptr FLG08_Good_Read,True
  1347.     Je    C1804            ; If the read operation was
  1348.                     ; . successful, continue
  1349.     Mov    Byte Ptr FLG15_IO_Error,One
  1350.     Call    D1200_Disk_IO_Error    ; Display appropriate error message
  1351.     Jmp    C1899            ; Go to the end of the module
  1352. C1804:
  1353.     Mov    AL,Byte Ptr MEM01_File_Allocation_Table[Zero]
  1354. ;
  1355.     Cmp    AL,One_Side_Eight_Sectors
  1356.     Jne    C1805            ; If not, continue
  1357.     Mov    Byte Ptr WRK15_Maximum_Heads,Zero
  1358.     Mov    Byte Ptr WRK16_Maximum_Tracks,Thirty_Nine
  1359.     Mov    SI,Offset MES03_Copy81_Sectors
  1360.     Jmp    C1809            ; Continue the processing
  1361. C1805:
  1362.     Cmp    AL,Two_Sides_Eight_Sectors
  1363.     Jne    C1806            ; If not, continue
  1364.     Mov    Byte Ptr WRK15_Maximum_Heads,One
  1365.     Mov    Byte Ptr WRK16_Maximum_Tracks,Seventy_Nine
  1366.     Mov    SI,Offset MES04_Copy82_Sectors
  1367.     Jmp    C1809            ; Continue the processing
  1368. C1806:
  1369.     Cmp    AL,One_Side_Nine_Sectors
  1370.     Jne    C1807            ; If not, continue
  1371.     Mov    Byte Ptr WRK15_Maximum_Heads,Zero
  1372.     Mov    Byte Ptr WRK16_Maximum_Tracks,Thirty_Nine
  1373.     Mov    SI,Offset MES05_Copy91_Sectors
  1374.     Jmp    C1809            ; Continue the processing
  1375. C1807:
  1376.     Cmp    AL,Two_Sides_Nine_Sectors
  1377.     Jne    C1808            ; If not, continue
  1378.     Mov    Byte Ptr WRK15_Maximum_Heads,One
  1379.     Mov    Byte Ptr WRK16_Maximum_Tracks,Seventy_Nine
  1380.     Mov    SI,Offset MES06_Copy92_Sectors
  1381.     Jmp    C1809            ; Continue the processing
  1382. C1808:
  1383.     Mov    Byte Ptr FLG08_Good_Read,False
  1384.     Mov    SI,Offset MES19_Unrecoverable_Read
  1385.     Call    U1000_Display_Message    ; Display the message on the screen
  1386.     Mov    SI,Offset MES90_Unknown_FAT_Error
  1387.     Call    U1000_Display_Message    ; Display the message on the screen
  1388.     Jmp    C1899            ; Go to display the message
  1389. C1809:
  1390.     Cmp    Byte Ptr WRK15_Maximum_Heads,Zero
  1391.     Je    C1810            ; If the diskette is single sided,
  1392.                     ; . display the diskette message
  1393.     Cmp    Byte Ptr FLG02_Double_Side,True
  1394.     Je    C1810            ; If the flag indicates to copy 
  1395.                     ; . both sides of the diskette,
  1396.                     ; . then continue
  1397.     Mov    Byte Ptr WRK15_Maximum_Heads,Zero
  1398.     Mov    Byte Ptr WRK16_Maximum_Tracks,Thirty_Nine
  1399. C1810:
  1400.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1401.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1402.     Mov    Byte Ptr WRK07_Head_Number,One
  1403.     Mov    Byte Ptr WRK08_Track_Number,Zero
  1404.     Mov    Byte Ptr WRK09_Sector_Number,One
  1405.     Mov    Byte Ptr WRK10_Number_of_Sectors,One
  1406.     Push    CS            ; Establish the ES segment register
  1407.     Pop    ES            ; .
  1408.     Push    ES            ; ..End
  1409.     Mov    BX,Offset MEM00_Bottom_Free_Memory
  1410.     Cmp    SYS19_Major_Vers_Number,Zero
  1411.     Je    C1811            ; If PC DOS 1.0 or 1.1, continue;
  1412.                     ; . otherwise, setup ES:BX a little
  1413.     Mov    ES,Word Ptr SYS21_Alloc_Segment
  1414.     Mov    BX,Zero            ; . differently
  1415. C1811:
  1416.     Call    D1000_Read_Diskette
  1417.     Pop    ES            ; Restore ES in any case
  1418. ;
  1419.     Cmp    Byte Ptr FLG08_Good_Read,True
  1420.     Je    C1813        ; Go to display the message
  1421.     Cmp    Byte Ptr WRK15_Maximum_Heads,One
  1422.     Je    C1812        ; If double sided diskette, error!!!
  1423.     Mov    Byte Ptr FLG08_Good_Read,True
  1424.     Mov    Byte Ptr FLG02_Double_Side,False
  1425.     Jmp    C1813        ; Display the appropriate message
  1426. C1812:
  1427.     Mov    SI,Offset MES19_Unrecoverable_Read
  1428.     Call    U1000_Display_Message    ; Display the message on the screen
  1429.     Mov    SI,Offset MES91_Single_Side_Error
  1430.     Call    U1000_Display_Message    ; Display the message on the screen
  1431.     Jmp    C1899            ; Go to the end of the module
  1432. C1813:
  1433.     Call    U1000_Display_Message    ; Display the message on the screen
  1434. C1899:
  1435.     Ret
  1436. ;
  1437. C1800_Validate_Source_Disk Endp
  1438. ;
  1439. Page
  1440. ;************************************************************************
  1441. ;*                                    *
  1442. ;*    C1900_CREATE_CHRN_TABLE                        *
  1443. ;*                                    *
  1444. ;*    This module creates the CHRN table to be used in case the    *
  1445. ;*    target diskette needs to be formatted.    The abbreviation    *
  1446. ;*    stands for C = track number, H = head number, R = sector    *
  1447. ;*    number and N = a code for the number of bytes per sector.    *
  1448. ;*                                    *
  1449. ;************************************************************************
  1450. ;
  1451. Public    C1900_Create_CHRN_Table
  1452. ;
  1453. C1900_Create_CHRN_Table Proc Near
  1454. ;
  1455. C1901:
  1456.     Mov    BH,Byte Ptr WRK15_Maximum_Heads
  1457.     Mov    BL,Byte Ptr WRK16_Maximum_Tracks
  1458.     Mov    AL,Nine
  1459. ;
  1460.     Mov    CL,BH            ; Establish correct track number
  1461.     Shr    BL,CL            ; ..End
  1462. ;
  1463.     Mov    DL,Two            ; . DL = number of sectors
  1464.     Mov    DH,Zero            ; . DH = head number
  1465.     Mov    CH,Zero            ; . CH = track number
  1466.     Mov    CL,One            ; . CL = sector number
  1467.     Mov    SI,Offset MEM02_CHRN_Table; Set up initial registers
  1468. C1902:
  1469.     Mov    [SI],CH            ; Establish an entry in the CHRN
  1470.     Mov    [SI+One],DH        ; . table
  1471.     Mov    [SI+Two],CL        ; .
  1472.     Mov    [SI+Three],DL        ; ..End
  1473. ;
  1474.     Add    SI,Four            ; Get the addr of next CHRN entry
  1475.     Inc    CL            ; Increment the sector number
  1476.     Cmp    CL,AL            ; Compare for maximum sectors
  1477.     Jbe    C1902            ; If not, go back and try again
  1478. ;
  1479.     Mov    CL,One            ; Initialize sector number
  1480.     Inc    DH            ; Increment the head number
  1481.     Cmp    DH,BH            ; Compare for maximum heads
  1482.     Jbe    C1902            ; If not, go back and try again
  1483. ;
  1484.     Mov    CL,One            ; Initialize sector number
  1485.     Mov    DH,Zero            ; Initialize head number
  1486.     Inc    CH            ; Increment the track number
  1487.     Cmp    CH,BL            ; Compare for maximum tracks
  1488.     Jbe    C1902            ; If not, go back and try again
  1489. C1999:
  1490.     Ret
  1491. ;
  1492. C1900_Create_CHRN_Table Endp
  1493. ;
  1494. Page
  1495. ;************************************************************************
  1496. ;*                                    *
  1497. ;*    C2000_READ_SOURCE_DISK                        *
  1498. ;*                                    *
  1499. ;*    This module reads a diskette track by track until it fills    *
  1500. ;*    all of available memory specified by the ES:BX table.  The    *
  1501. ;*    processing sequence is:                        *
  1502. ;*                                    *
  1503. ;*    1. Initializes the SI resgister to point to the correct entry    *
  1504. ;*       in the ES:BX table.                        *
  1505. ;*                                    *
  1506. ;*    2. Prints the initial read message on the screen.        *
  1507. ;*                                    *
  1508. ;*    3. Compares for the end of the ES:BX table and/or the number    *
  1509. ;*       of tracks on the diskette.  If not, continue.  If so,    *
  1510. ;*       return to B1100_Detail_Processing.                *
  1511. ;*                                    *
  1512. ;*    4. Reads a track from the source diskette.            *
  1513. ;*                                    *
  1514. ;*    5. Displays the track and head numbers on the screen.        *
  1515. ;*                                    *
  1516. ;*    6. Transfers control to 3.                    *
  1517. ;*                                    *
  1518. ;************************************************************************
  1519. ;
  1520. Page
  1521. ;
  1522. Public    C2000_Read_Source_Disk
  1523. ;
  1524. C2000_Read_Source_Disk Proc Near
  1525. ;
  1526. C2001:
  1527.     Mov    Byte Ptr FLG08_Good_Read,True
  1528. ;
  1529.     Mov    SI,Offset MEM03_ESBX_Table
  1530.     Mov    Word Ptr WRK18_Counter_ESBX_Entries,Zero
  1531. ;
  1532.     Cmp    Byte Ptr FLG13_First_Read_Write,False
  1533.     Je    C2002            ; If not first time, continue
  1534.     Mov    Byte Ptr WRK31_Track_Read_Counter,Zero
  1535.     Jmp    C2003            ; Go to display the message
  1536. C2002:
  1537.     Cmp    Byte Ptr FLG04_Single_Drive,False
  1538.     Je    C2004            ; If double drive copy, continue
  1539. C2003:
  1540.     Push    SI            ; Save SI = Addr of ES:BX table
  1541.     Mov    SI,Offset MES97_Return_Linefeed
  1542.     Call    U1000_Display_Message    ; Display a return and linefeed
  1543.     Mov    SI,Offset MES17_Reading_Track
  1544.     Mov    AL,Byte Ptr WRK21_Current_Source_Track
  1545.     Call    U1300_Convert_Binary_to_ASCII
  1546.     Mov    [SI+Fifteen],AX        ; Put the track number into message
  1547.     Mov    AL,Byte Ptr WRK20_Current_Source_Head
  1548.     Call    U1300_Convert_Binary_to_ASCII
  1549.     Mov    [SI+Twenty_Five],AL    ; Put the head number into message
  1550.     Call    U1000_Display_Message    ; Display the message on the screeen
  1551. ;
  1552.     Mov    AH,Read_Cursor_Command    ; Get the current cursor position
  1553.     Mov    BH,Byte Ptr SYS03_Active_Page
  1554.     Int    Video_Interrupt        ; ..End
  1555. ;
  1556.     Dec    DH            ; Save the row of the read track and
  1557.     Mov    Byte Ptr WRK24_Read_Message_Row,DH; . head message
  1558. ;
  1559.     Pop    SI            ; Restore SI = Addr of ES:BX table
  1560. C2004:
  1561.     Mov    AL,Byte Ptr WRK31_Track_Read_Counter
  1562.     Cmp    AL,Byte Ptr WRK16_Maximum_Tracks
  1563.     Jbe    C2005            ; If more tracks, then continue
  1564.     Jmp    C2099            ; Go to the end of the module
  1565. C2005:
  1566.     Mov    AX,Word Ptr WRK18_Counter_ESBX_Entries
  1567.     Cmp    AX,Word Ptr WRK19_Number_ESBX_Entries
  1568.     Jbe    C2006            ; If more memory exists, continue
  1569.     Jmp    C2099            ; Go to the end of the module
  1570. C2006:
  1571. ;                    ; Display the current track and head
  1572.     Mov    AL,Byte Ptr WRK24_Read_Message_Row
  1573.     Mov    Byte Ptr WRK28_Current_Message_Row,AL
  1574.     Mov    AL,Byte Ptr WRK20_Current_Source_Head
  1575.     Mov    Byte Ptr WRK29_Current_Head,AL
  1576.     Mov    AL,Byte Ptr WRK21_Current_Source_Track
  1577.     Mov    Byte Ptr WRK30_Current_Track,AL
  1578. ;
  1579.     Call    U1400_Display_Head_and_Track
  1580. ;
  1581.                     ; Establish the disk parameters
  1582.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1583.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1584.     Mov    AL,Byte Ptr WRK20_Current_Source_Head
  1585.     Mov    Byte Ptr WRK07_Head_Number,AL
  1586.     Mov    AL,Byte Ptr WRK21_Current_Source_Track
  1587.     Mov    Byte Ptr WRK08_Track_Number,AL
  1588.     Mov    Byte Ptr WRK09_Sector_Number,One
  1589.     Mov    AL,Byte Ptr WRK17_Maximum_Sectors
  1590.     Mov    Byte Ptr WRK10_Number_of_Sectors,AL
  1591.     Mov    AX,DS:[SI]        ; .
  1592.     Mov    BX,AX            ; .
  1593.     Mov    AX,DS:[SI+Two]        ; .
  1594.     Mov    ES,AX            ; ..End
  1595. ;
  1596.     Call    D1000_Read_Diskette    ; Read the source diskette
  1597. C2007:
  1598.     Cmp    Byte Ptr FLG08_Good_Read,True
  1599.     Je    C2008            ; If the read operation was 
  1600.                     ; . successful, then continue
  1601.     Mov    Byte Ptr FLG15_IO_Error,One
  1602.     Call    D1200_Disk_IO_Error    ; Display appropriate error message
  1603.     Jmp    C2099            ; Go to the end of the module
  1604. C2008:
  1605.     Inc    Byte Ptr WRK31_Track_Read_Counter
  1606.     Inc    Word Ptr WRK18_Counter_ESBX_Entries
  1607.     Add    SI,Four            ; Increment addr of the ES:BX table
  1608.     Cmp    Byte Ptr FLG02_Double_Side,False
  1609.     Je    C2009            ; If single sided, then continue
  1610.     Inc    Byte Ptr WRK20_Current_Source_Head
  1611.     Cmp    Byte Ptr WRK20_Current_Source_Head,One
  1612.     Jbe    C2010            ; If the head number is less than or
  1613.                     ; . equal to one, then continue
  1614.     Mov    Byte Ptr WRK20_Current_Source_Head,Zero
  1615. C2009:
  1616.     Inc    Byte Ptr WRK21_Current_Source_Track
  1617. C2010:
  1618.     Jmp    C2004            ; Go back and read another track
  1619. C2099:
  1620.     Ret
  1621. ;
  1622. C2000_Read_Source_Disk Endp
  1623. ;
  1624. Page
  1625. ;************************************************************************
  1626. ;*                                    *
  1627. ;*    C2100_WRITE_FORMAT_TARGET_DISK                    *
  1628. ;*                                    *
  1629. ;*    This module formats and writes  a diskette track by track    *
  1630. ;*    until it fills all of available memory specified by the        *
  1631. ;*    ES:BX table.  The processing sequence is:            *
  1632. ;*                                    *
  1633. ;*    1. Initializes the SI resgister to point to the correct entry    *
  1634. ;*       in the ES:BX table.                        *
  1635. ;*                                    *
  1636. ;*    2. Prints the initial write message on the screen.        *
  1637. ;*                                    *
  1638. ;*    3. Compares for the end of the ES:BX table and/or the number    *
  1639. ;*       of tracks on the diskette.  If not, continue.  If so,    *
  1640. ;*       return to B1100_Detail_Processing.                *
  1641. ;*                                    *
  1642. ;*    4. Writes a track from the source diskette.            *
  1643. ;*                                    *
  1644. ;*    5. Displays the track and head numbers on the screen.        *
  1645. ;*                                    *
  1646. ;*    6. Transfers control to 3.                    *
  1647. ;*                                    *
  1648. ;************************************************************************
  1649. ;
  1650. Public    C2100_Write_Format_Target_Disk
  1651. ;
  1652. C2100_Write_Format_Target_Disk Proc Near
  1653. ;
  1654. C2101:
  1655.     Mov    Byte Ptr FLG09_Good_Write,True
  1656.     Mov    Byte Ptr FLG11_Good_Format,True
  1657. ;
  1658.     Mov    Byte Ptr WRK13_Retry_Counter,Number_of_Retries
  1659. ;
  1660.     Mov    SI,Offset MEM03_ESBX_Table
  1661.     Mov    Word Ptr WRK18_Counter_ESBX_Entries,Zero
  1662. ;
  1663.     Cmp    Byte Ptr FLG13_First_Read_Write,False
  1664.     Je    C2102            ; If not first time, continue
  1665.     Mov    Byte Ptr WRK32_Track_Write_Counter,Zero
  1666.     Jmp    C2103            ; Go to display the message
  1667. C2102:
  1668.     Cmp    Byte Ptr FLG04_Single_Drive,False
  1669.     Je    C2104            ; If double drive copy, continue
  1670. C2103:
  1671.     Push    SI            ; Save SI = Addr of ES:BX table
  1672. ;
  1673.     Mov    SI,Offset MES97_Return_Linefeed
  1674.     Call    U1000_Display_Message    ; Display return and line feed
  1675.     Mov    SI,Offset MES23_Writing_Track
  1676.     Call    U1000_Display_Message    ; Display write track message
  1677. ;
  1678.     Mov    AH,Read_Cursor_Command    ; Get the current cursor position
  1679.     Mov    BH,Byte Ptr SYS03_Active_Page
  1680.     Int    Video_Interrupt        ; ..End
  1681. ;
  1682.     Dec    DH            ; Save the row of the I/O track and
  1683.     Mov    Byte Ptr WRK27_Write_Message_Row,DH; . head information
  1684.     Sub    DH,Two            ; .
  1685.     Mov    Byte Ptr WRK24_Read_Message_Row,DH
  1686. ;
  1687.     Pop    SI            ; Restore SI = Addr of ES:BX table
  1688. C2104:
  1689.     Mov    AL,Byte Ptr WRK32_Track_Write_Counter
  1690.     Cmp    AL,Byte Ptr WRK16_Maximum_Tracks
  1691.     Jbe    C2105            ; If more tracks, then continue
  1692.     Mov    Byte Ptr FLG14_Copy_Complete,True
  1693.     Jmp    C2199            ; Go to the end of the module
  1694. C2105:
  1695.     Mov    AX,Word Ptr WRK18_Counter_ESBX_Entries
  1696.     Cmp    AX,Word Ptr WRK19_Number_ESBX_Entries
  1697.     Jbe    C2106            ; If more memory exists, continue
  1698.     Jmp    C2199            ; Go to the end of the module
  1699. C2106:
  1700. ;                    ; Establish the disk parameters
  1701.     Mov    AL,Byte Ptr WRK02_Target_Drive
  1702.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1703.     Mov    AL,Byte Ptr WRK22_Current_Target_Head
  1704.     Mov    Byte Ptr WRK07_Head_Number,AL
  1705.     Mov    AL,Byte Ptr WRK23_Current_Target_Track
  1706.     Mov    Byte Ptr WRK08_Track_Number,AL
  1707.     Mov    Byte Ptr WRK09_Sector_Number,One
  1708.     Mov    AL,Byte Ptr WRK17_Maximum_Sectors
  1709.     Mov    Byte Ptr WRK10_Number_of_Sectors,AL
  1710.     Mov    AX,DS:[SI+Two]        ; .
  1711.     Mov    Word Ptr WRK11_Segment_Address,AX
  1712.     Mov    AX,DS:[SI]        ; .
  1713.     Mov    Word Ptr WRK12_Offset_Address,AX
  1714. ;
  1715.     Call    D1100_Write_Format_Diskette
  1716. ;
  1717.     Cmp    Byte Ptr FLG11_Good_Format,True
  1718.     Je    C2107            ; If a good format, continue
  1719.     Cmp    Byte Ptr FLG09_Good_Write,True
  1720.     Je    C2107            ; If a good write, continue
  1721.     Call    D1200_Disk_IO_Error    ; Display appropriate error message
  1722.     Jmp    C2199            ; Go to the end of the module
  1723. C2107:
  1724.     Inc    Byte Ptr WRK32_Track_Write_Counter
  1725.     Inc    Word Ptr WRK18_Counter_ESBX_Entries
  1726.     Add    SI,Four            ; Increment addr of the ES:BX table
  1727.     Cmp    Byte Ptr FLG02_Double_Side,False
  1728.     Je    C2108            ; If single sided, then continue
  1729.     Inc    Byte Ptr WRK22_Current_Target_Head
  1730.     Cmp    Byte Ptr WRK22_Current_Target_Head,One
  1731.     Jbe    C2109            ; If the head number is less than or
  1732.                     ; . equal to one, then continue
  1733.     Mov    Byte Ptr WRK22_Current_Target_Head,Zero
  1734. C2108:
  1735.     Inc    Byte Ptr WRK23_Current_Target_Track
  1736. C2109:
  1737.     Jmp    C2104            ; Go back and write another track
  1738. C2199:
  1739.     Ret
  1740. ;
  1741. C2100_Write_Format_Target_Disk Endp
  1742. ;
  1743. Page
  1744. ;************************************************************************
  1745. ;*                                    *
  1746. ;*    C2200_CHECK_FILE_ALLOC_TABLE                    *
  1747. ;*                                    *
  1748. ;*    This module checks the File Allocation Table (FAT) of the    *
  1749. ;*    diskette in the source drive and compares it with the File    *
  1750. ;*    Allocation Table (FAT) of the original source diskette.  If    *
  1751. ;*    there are any differences, the program sets the flag        *
  1752. ;*    FLG12_Good_FAT to False; otherwise, the flag is True.        *
  1753. ;*                                    *
  1754. ;************************************************************************
  1755. ;
  1756. Public    C2200_Check_File_Alloc_Table
  1757. ;
  1758. C2200_Check_File_Alloc_Table Proc Near
  1759. ;
  1760. C2201:
  1761.     Mov    Byte Ptr FLG12_Good_FAT,True
  1762. ;
  1763.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1764.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1765.     Mov    Byte Ptr WRK07_Head_Number,Zero
  1766.     Mov    Byte Ptr WRK08_Track_Number,Zero
  1767.     Mov    Byte Ptr WRK09_Sector_Number,Two
  1768.     Mov    Byte Ptr WRK10_Number_of_Sectors,One
  1769.     Push    CS            ; Establish the ES segment register
  1770.     Pop    ES            ; .
  1771.     Push    ES            ; ..End
  1772.     Mov    BX,Offset MEM00_Bottom_Free_Memory
  1773.     Cmp    SYS19_Major_Vers_Number,Zero
  1774.     Je    C2202            ; If PC DOS 1.0 or 1.1, continue;
  1775.                     ; . otherwise, set up ES:BX a little
  1776.     Mov    ES,Word Ptr SYS21_Alloc_Segment
  1777.     Mov    BX,Zero            ; . differently
  1778. C2202:
  1779.     Call    D1000_Read_Diskette    ; Read the File Allocation Table
  1780.     Pop    ES            ; Restore ES in any case
  1781. ;
  1782.     Cmp    Byte Ptr FLG08_Good_Read,True
  1783.     Je    C2203            ; If the read operation was
  1784.                     ; . successful, continue
  1785.     Mov    Byte Ptr FLG15_IO_Error,One
  1786.     Call    D1200_Disk_IO_Error    ; Display appropriate error message
  1787.     Jmp    C2299            ; Go to the end of the module
  1788. C2203:
  1789.     Mov    SI,Offset MEM01_File_Allocation_Table
  1790.     Mov    DI,Offset MEM00_Bottom_Free_Memory
  1791.     Push    ES            ; Save ES for a moment
  1792.     Cmp    Byte Ptr SYS19_Major_Vers_Number,Zero
  1793.     Je    C2204            ; If PC DOS 1.0 or 1.1, continue
  1794.     Mov    ES,Word Ptr SYS21_Alloc_Segment
  1795.     Mov    DI,Zero            ; Set up ES:DI for PC DOS 2.0+
  1796. C2204:
  1797.     Mov    CX,Sector_Size        ; Set counter CX to compare the
  1798.                     ; . sector size in words
  1799.     Shr    CX,1            ; ..End
  1800.     Cld                ; Clear the direction flag
  1801.     Rep    Cmpsw            ; Compare all of the 512 bytes
  1802.     Jne    C2205            ; If there is a discrepancy, go to
  1803.                     ; . the error message routine
  1804.     Jmp    C2206            ; Go to the end of the module
  1805. C2205:
  1806.     Pop    ES            ; Restore the ES register
  1807.     Mov    Byte Ptr FLG12_Good_FAT,False
  1808.     Mov    SI,Offset MES19_Unrecoverable_Read
  1809.     Call    U1000_Display_Message    ; Display the message on the screen
  1810.     Mov    SI,Offset MES90_Unknown_FAT_Error
  1811.     Call    U1000_Display_Message    ; Display the message on the screen
  1812.     Jmp    C2299            ; Go to the end of the module
  1813. C2206:
  1814.     Pop    ES            ; Restore the ES register
  1815. C2299:
  1816.     Ret
  1817. ;
  1818. C2200_Check_File_Alloc_Table Endp
  1819. ;
  1820. Page
  1821. ;************************************************************************
  1822. ;*                                    *
  1823. ;*    C2300_FREE_MEMORY                        *
  1824. ;*                                    *
  1825. ;*    This module free up allocated memory, provided that a user    *
  1826. ;*    is running PC DOS 2.0 or greater; otherwise, it does nothing.    *
  1827. ;*                                    *
  1828. ;************************************************************************
  1829. ;
  1830. Public    C2300_Free_Memory
  1831. ;
  1832. C2300_Free_Memory Proc Near
  1833. ;
  1834. C2301:
  1835.     Cmp    Byte Ptr SYS19_Major_Vers_Number,Zero
  1836.     Je    C2399            ; If PC DOS 1.0 or 1.1, go to the
  1837.                     ; . end of the module
  1838.     Cmp    Byte Ptr FLG16_Free_Memory,True
  1839.     Je    C2399            ; If memory was not allocated, go
  1840.                     ; . to the end of the module
  1841. ;
  1842.     Mov    AH,Free_Memory        ; Free allocated memory
  1843.     Push    ES            ; .
  1844.     Mov    ES,Word Ptr SYS21_Alloc_Segment
  1845.     Int    PC_DOS_Interrupt    ; .
  1846.     Pop    ES            ; .
  1847.     Jnc    C2399            ; ..End
  1848. ;
  1849.     Mov    SI,Offset MES97_Return_Linefeed
  1850.     Call    U1000_Display_Message    ; Issue a carriage return/linefeed
  1851.     Mov    SI,Offset MES99_Memory_Block_Destroyed
  1852.     Call    U1000_Display_Message    ; Display the message on the screen
  1853. C2399:
  1854.     Ret
  1855. ;
  1856. C2300_Free_Memory Endp
  1857. ;
  1858. Page
  1859. ;************************************************************************
  1860. ;*                                    *
  1861. ;*    D1000_READ_DISKETTE                        *
  1862. ;*                                    *
  1863. ;*    This module reads a track at a time from a diskette. If it    *
  1864. ;*    fails to read the diskette it tries Number_of_Retries = 5    *
  1865. ;*    times.                                *
  1866. ;*                                    *
  1867. ;************************************************************************
  1868. ;
  1869. Public    D1000_Read_Diskette
  1870. ;
  1871. D1000_Read_Diskette Proc Near
  1872. ;
  1873. D1001:
  1874.     Mov    Byte Ptr WRK13_Retry_Counter,Number_of_Retries
  1875. D1002:
  1876.     Clc                ; Clear the carry flag
  1877.     Mov    AH,Read_Command        ; Read the data on the diskette
  1878.     Mov    DL,Byte Ptr WRK06_Drive_Number
  1879.     Mov    DH,Byte Ptr WRK07_Head_Number
  1880.     Mov    CH,Byte Ptr WRK08_Track_Number
  1881.     Mov    CL,Byte Ptr WRK09_Sector_Number
  1882.     Mov    AL,Byte Ptr WRK10_Number_of_Sectors
  1883.     Int    Disk_Interrupt        ; ..End
  1884. ;
  1885.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1886.     Jnc    D1099            ; Go to the end of the module
  1887. D1003:
  1888.     Dec    Byte Ptr WRK13_Retry_Counter
  1889.     Jz    D1004            ; Could not read the diskette
  1890.     Clc                ; Clear the carry flag
  1891.     Mov    AH,Reset_Command    ; Initialize the disk controller
  1892.     Int    Disk_Interrupt        ; .
  1893.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1894.     Jnc    D1002            ; .
  1895.     Jmp    D1003            ; ..End
  1896. D1004:
  1897.     Mov    Byte Ptr FLG08_Good_Read,False
  1898. D1099:
  1899.     Ret
  1900. ;
  1901. D1000_Read_Diskette Endp
  1902. ;
  1903. Page
  1904. ;************************************************************************
  1905. ;*                                    *
  1906. ;*    D1100_WRITE_FORMAT_DISKETTE                    *
  1907. ;*                                    *
  1908. ;*    This module formats and writes a track at a time to a         *
  1909. ;*    diskette.  If it fails to format or a write a track, it tries    *
  1910. ;*    Number_of_Retries = 5 times.                    *
  1911. ;*                                    *
  1912. ;************************************************************************
  1913. ;
  1914. Public    D1100_Write_Format_Diskette
  1915. ;
  1916. D1100_Write_Format_Diskette Proc Near
  1917. ;
  1918. D1101:
  1919.     Mov    Byte Ptr WRK13_Retry_Counter,Number_of_Retries
  1920. D1102:
  1921.     Clc                ; Clear the carry flag
  1922.     Mov    AH,Format_Command    ; Format the diskette
  1923.     Mov    DL,Byte Ptr WRK06_Drive_Number
  1924.     Mov    DH,Byte Ptr WRK07_Head_Number
  1925.     Mov    CH,Byte Ptr WRK08_Track_Number
  1926.     Mov    CL,Byte Ptr WRK09_Sector_Number
  1927.     Mov    AL,Byte Ptr WRK10_Number_of_Sectors
  1928.     Push    CS            ; .
  1929.     Pop    ES            ; .
  1930.     Mov    BX,Word Ptr WRK33_CHRN_Table_Address
  1931.     Int    Disk_Interrupt        ; ..End
  1932.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1933.     Jnc    D1105            ; Formatted the diskette
  1934. D1103:
  1935.     Dec    Byte Ptr WRK13_Retry_Counter
  1936.     Jz    D1104            ; Go to format error processing
  1937.     Clc                ; Clear the carry flag
  1938.     Mov    AH,Reset_Command    ; Initialize the disk controller
  1939.     Int    Disk_Interrupt        ; .
  1940.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1941.     Jnc    D1102            ; Try to format the disk again
  1942.     Jmp    D1103            ; Try to initialize the disk again
  1943. D1104:
  1944.     Mov    Byte Ptr FLG15_IO_Error,Zero
  1945.     Mov    Byte Ptr FLG11_Good_Format,False
  1946.     Jmp    D1199            ; Go to the end of the module
  1947. D1105:
  1948.     Mov    Byte Ptr WRK13_Retry_Counter,Number_of_Retries
  1949. D1106:
  1950.     Clc                ; Clear the carry flag
  1951.     Mov    AH,Write_Command    ; Write the diskette
  1952.     Mov    ES,Word Ptr WRK11_Segment_Address
  1953.     Mov    BX,Word Ptr WRK12_Offset_Address
  1954.     Mov    AL,Byte Ptr WRK10_Number_of_Sectors
  1955.     Int    Disk_Interrupt        ; .
  1956.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1957.     Jnc    D1109            ; ..End
  1958. D1107:
  1959.     Dec    Byte Ptr WRK13_Retry_Counter
  1960.     Jz    D1108            ; Go to write error processing
  1961.     Clc                ; Clear the carry flag
  1962.     Mov    AH,Reset_Command    ; Initialize the disk controller
  1963.     Int    Disk_Interrupt        ; .
  1964.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1965.     Jnc    D1106            ; .
  1966.     Jmp    D1107            ; ..End
  1967. D1108:
  1968.     Mov    Byte Ptr FLG15_IO_Error,Two
  1969.     Mov    Byte Ptr FLG09_Good_Write,False
  1970.     Jmp    D1199            ; Go to the end of the module
  1971. D1109:
  1972.     Add    Word Ptr WRK33_CHRN_Table_Address,Thirty_Six
  1973. ;
  1974.     Mov    AL,Byte Ptr WRK27_Write_Message_Row
  1975.     Mov    Byte Ptr WRK28_Current_Message_Row,AL
  1976.     Mov    AL,Byte Ptr WRK22_Current_Target_Head
  1977.     Mov    Byte Ptr WRK29_Current_Head,AL
  1978.     Mov    AL,Byte Ptr WRK23_Current_Target_Track
  1979.     Mov    Byte Ptr WRK30_Current_Track,AL
  1980.     Call    U1400_Display_Head_and_Track
  1981. D1199:
  1982.     Ret
  1983. ;
  1984. D1100_Write_Format_Diskette Endp
  1985. ;
  1986. Page
  1987. ;************************************************************************
  1988. ;*                                    *
  1989. ;*    D1200_DISK_IO_ERROR                        *
  1990. ;*                                    *
  1991. ;*    This module fans out a disk error.  It tells a user if it    *
  1992. ;*    occured on a read, format or write operation.  If it cannot    *
  1993. ;*    determine the nature of the error, the routine displays an    *
  1994. ;*    unknown disk error message.                    *
  1995. ;*                                    *
  1996. ;************************************************************************
  1997. ;
  1998. Public    D1200_Disk_IO_Error
  1999. ;
  2000. D1200_Disk_IO_Error Proc Near
  2001. ;
  2002. D1201:
  2003.     Cmp    Byte Ptr WRK14_Status_Operation,Time_Out_Error
  2004.     Jne    D1202            ; If not time out error, continue
  2005.     Mov    SI,Offset MES08_Drive_Not_Ready
  2006.     Mov    AL,Byte Ptr WRK06_Drive_Number
  2007.     Add    AL,Capital_Letter_A    ; Convert drive number to a letter
  2008.     Mov    [SI+Twenty_Four],AL    ; Put the drive letter into position
  2009.     Call    U1000_Display_Message
  2010.     Jmp    D1299            ; Go to the end of the module
  2011. D1202:
  2012.     Cmp    Byte Ptr FLG15_IO_Error,Zero
  2013.     Jne    D1203            ; If not a format error, continue
  2014.     Mov    SI,Offset MES18_Unrecoverable_Format
  2015.     Jmp    D1206            ; Continue processing
  2016. D1203:
  2017.     Cmp    Byte Ptr FLG15_IO_Error,One
  2018.     Jne    D1204            ; If not a read error, continue
  2019.     Mov    SI,Offset MES19_Unrecoverable_Read
  2020.     Jmp    D1206            ; Continue processing
  2021. D1204:
  2022.     Cmp    Byte Ptr FLG15_IO_Error,Two
  2023.     Jne    D1205            ; If not a write error, continue
  2024.     Mov    SI,Offset MES21_Unrecoverable_Write
  2025.     Jmp    D1206            ; Continue processing
  2026. D1205:
  2027.     Mov    SI,Offset MES22_Unrecoverable_IO
  2028. D1206:
  2029.     Call    U1000_Display_Message    ; Display the message on the screen
  2030. D1207:
  2031.     Cmp    Byte Ptr WRK14_Status_Operation,Seek_Error
  2032.     Jne    D1208            ; If not a seek error, continue
  2033.     Mov    SI,Offset MES80_Seek_Error
  2034.     Jmp    D1217            ; Continue processing
  2035. D1208:
  2036.     Cmp    Byte Ptr WRK14_Status_Operation,Controller_Error
  2037.     Jne    D1209            ; If not a controller error, continue
  2038.     Mov    SI,Offset MES81_Controller_Error
  2039.     Jmp    D1217            ; Continue processing
  2040. D1209:
  2041.     Cmp    Byte Ptr WRK14_Status_Operation,CRC_Error
  2042.     Jne    D1210            ; If not a CRC error, continue
  2043.     Mov    SI,Offset MES82_CRC_Error
  2044.     Jmp    D1217            ; Continue processing
  2045. D1210:
  2046.     Cmp    Byte Ptr WRK14_Status_Operation,DMA_Boundary_Error
  2047.     Jne    D1211            ; If not DMA boundary error, continue
  2048.     Mov    SI,Offset MES83_DMA_Boundary_Error
  2049.     Jmp    D1217            ; Continue processing
  2050. D1211:
  2051.     Cmp    Byte Ptr WRK14_Status_Operation,DMA_Error
  2052.     Jne    D1212            ; If not a DMA error, continue
  2053.     Mov    SI,Offset MES84_DMA_Error
  2054.     Jmp    D1217            ; Continue processing
  2055. D1212:
  2056.     Cmp    Byte Ptr WRK14_Status_Operation,Sector_Error
  2057.     Jne    D1213            ; If not a sector error, continue
  2058.     Mov    SI,Offset MES85_Sector_Error
  2059.     Jmp    D1217            ; Continue processing
  2060. D1213:
  2061.     Cmp    Byte Ptr WRK14_Status_Operation,Write_Protect_Error
  2062.     Jne    D1214            ; If not write protected, continue
  2063.     Mov    SI,Offset MES86_Write_Protect_Error
  2064.     Jmp    D1217            ; Continue processing
  2065. D1214:
  2066.     Cmp    Byte Ptr WRK14_Status_Operation,Address_Mark_Error
  2067.     Jne    D1215            ; If not addr mark error, continue
  2068.     Mov    SI,Offset MES87_Address_Mark_Error
  2069.     Jmp    D1217            ; Continue processing
  2070. D1215:
  2071.     Cmp    Byte Ptr WRK14_Status_Operation,Command_Error
  2072.     Jne    D1216            ; If not a command error, continue
  2073.     Mov    SI,Offset MES88_Command_Error
  2074.     Jmp    D1217            ; Continue processing
  2075. D1216:
  2076.     Mov    SI,Offset MES89_Unknown_Error
  2077. D1217:
  2078.     Call    U1000_Display_Message    ; Display the message on the screen
  2079. D1299:
  2080.     Ret
  2081. ;
  2082. D1200_Disk_IO_Error Endp
  2083. ;
  2084. Page
  2085. ;************************************************************************
  2086. ;*                                    *
  2087. ;*    S1000_SETUP_DISK_PARAM_TABLE                    *
  2088. ;*                                    *
  2089. ;*    This module sets up the Disk Parameter Table (Int 1EH) so that    *
  2090. ;*    it points to the disk parameters for PC DOS 2.1 contained in    *
  2091. ;*    this program.                            *
  2092. ;*                                    *
  2093. ;************************************************************************
  2094. ;
  2095. Public    S1000_Setup_Disk_Param_Table
  2096. ;
  2097. S1000_Setup_Disk_Param_Table Proc Near
  2098. ;
  2099. S1001:
  2100.     Push    AX            ; Save the registers
  2101.     Push    BX            ; .
  2102.     Push    DS            ; ..End
  2103. ;
  2104.     Cli                ; Turn off the interrupts
  2105.  
  2106. ;
  2107.     Sub    AX,AX            ; Initialize DS to Absolute Zero
  2108.     Mov    DS,AX            ; ..End
  2109. ;
  2110.     Mov    BX,Disk_Parameter_Addr    ; Save and redirect the address
  2111.     Mov    AX,[BX]            ; .
  2112.     Mov    Word Ptr CS:SYS16_Save_DPT_Offset,AX
  2113.     Mov    AX,[BX+Two]        ; .
  2114.     Mov    Word Ptr CS:SYS17_Save_DPT_Segment,AX
  2115.                     ; .
  2116.     Mov    AX,Offset SYS18_Disk_Parameter_Table
  2117.     Mov    [BX],AX            ; .
  2118.     Mov    AX,CS            ; .
  2119.     Mov    [BX+Two],AX        ; ..End
  2120. ;
  2121.     Sti                ; Turn on interrupts
  2122. ;
  2123.     Pop    DS            ; Restore the registers
  2124.     Pop    BX            ; .
  2125.     Pop    AX            ; ..End
  2126. S1099:
  2127.     Ret
  2128. ;
  2129. S1000_Setup_Disk_Param_Table Endp
  2130. ;
  2131. Page
  2132. ;************************************************************************
  2133. ;*                                    *
  2134. ;*    S1100_RESTORE_DISK_PARAM_TABLE                    *
  2135. ;*                                    *
  2136. ;*    This module restores the Disk Parameter Table to its original    *
  2137. ;*    address in PC DOS.                        *
  2138. ;*                                    *
  2139. ;************************************************************************
  2140. ;
  2141. Public    S1100_Restore_Disk_Param_Table
  2142. ;
  2143. S1100_Restore_Disk_Param_Table Proc Near
  2144. ;
  2145. S1101:
  2146.     Push    AX            ; Save the registers
  2147.     Push    BX            ; .
  2148.     Push    DS            ; ..End
  2149. ;
  2150.     Cli                ; Turn off the interrupts
  2151. ;
  2152.     Sub    AX,AX            ; Initialize DS to Absolute Zero
  2153.     Mov    DS,AX            ; ..End
  2154. ;
  2155.     Mov    BX,Disk_Parameter_Addr    ; Restore Disk Parameter Address
  2156.     Mov    AX,Word Ptr CS:SYS16_Save_DPT_Offset
  2157.     Mov    [BX],AX            ; .
  2158.     Mov    AX,Word Ptr CS:SYS17_Save_DPT_Segment
  2159.     Mov    [BX+Two],AX        ; ..End
  2160. ;
  2161.     Sti                ; Turn on the interrupts
  2162. ;
  2163.     Pop    DS            ; Restore the registers
  2164.     Pop    BX            ; .
  2165.     Pop    AX            ; ..End
  2166. S1199:
  2167.     Ret
  2168. ;
  2169. S1100_Restore_Disk_Param_Table Endp
  2170. ;
  2171. Page
  2172. ;************************************************************************
  2173. ;*                                    *
  2174. ;*    S1200_GET_VERSION_NUMBER                    *
  2175. ;*                                    *
  2176. ;*    This module gets the current version number of PC DOS and    *
  2177. ;*    stores the information in determining whether to allocate    *
  2178. ;*    memory using the PC DOS 2.0 function calls.            *
  2179. ;*                                    *
  2180. ;************************************************************************
  2181. ;
  2182. Public    S1200_Get_Version_Number
  2183. ;
  2184. S1200_Get_Version_Number Proc Near
  2185. ;
  2186. S1201:
  2187.     Push    AX            ; Save the registers and flags
  2188.     Pushf                ; ..End
  2189. ;
  2190.     Mov    AH,Get_DOS_Version_Number
  2191.     Int    PC_DOS_Interrupt
  2192.     Mov    Byte Ptr SYS19_Major_Vers_Number,AL
  2193.     Mov    Byte Ptr SYS20_Minor_Vers_Number,AH
  2194. ;
  2195.     Popf                ; Restore the registers and flags
  2196.     Pop    AX            ; ..End
  2197. S1299:
  2198.     Ret
  2199. ;
  2200. S1200_Get_Version_Number Endp
  2201. ;
  2202. Page
  2203. ;************************************************************************
  2204. ;*                                    *
  2205. ;*    U1000_DISPLAY_MESSAGE                        *
  2206. ;*                                    *
  2207. ;*    This module displays a message on the screen. Before calling    *
  2208. ;*    this module, the offset of the message should be in SI         *
  2209. ;*    relative to the DS register.  This routine preserves the    *
  2210. ;*    registers and the flags.                    *
  2211. ;*                                    *
  2212. ;************************************************************************
  2213. ;
  2214. Public    U1000_Display_Message
  2215. ;
  2216. U1000_Display_Message Proc Near
  2217. ;
  2218. U1001:
  2219.     Push    AX            ; Save the registers and flags
  2220.     Push    BX            ; .
  2221.     Push    SI            ; .
  2222.     Pushf                ; ..End
  2223. U1002:
  2224.     Mov    AL,[SI]            ; Put the character into AL
  2225.     Cmp    AL,EOT            ; Compare for the end of the string
  2226.     Je    U1090            ; If so, go to end of the module
  2227.     Mov    AH,Write_TTY_Command    ; Write the Character
  2228.     Mov    BH,Byte Ptr SYS03_Active_Page
  2229.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2230.     Int    Video_Interrupt        ; ..End
  2231.     Inc    SI            ; Increment the SI counter
  2232.     Jmp    U1002            ; Go back and try again
  2233. U1090:
  2234.     Popf                ; Restore the registers and flags
  2235.     Pop    SI            ; .
  2236.     Pop    BX            ; .
  2237.     Pop    AX            ; ..End
  2238. U1099:
  2239.     Ret
  2240. ;
  2241. U1000_Display_Message Endp
  2242. ;
  2243. Page
  2244. ;************************************************************************
  2245. ;*                                    *
  2246. ;*    U1100_GET_RESPONSE                        *
  2247. ;*                                    *
  2248. ;*    This module gets the response from the keyboard and displays    *
  2249. ;*    the information on the video display unit.  The keyboard    *
  2250. ;*    buffer is WRK05_Keyboard_Buffer.  The first byte of this    *
  2251. ;*    buffer contains the length of the buffer and must be less    *
  2252. ;*    than or equal to 80 characters.  The next 80 characters are    *
  2253. ;*    the acutal buffer. The character EOT denotes the end of the    *
  2254. ;*    buffer and can occur in any one of the 80 characters.        *
  2255. ;*                                    *
  2256. ;************************************************************************
  2257. ;
  2258. Public    U1100_Get_Response
  2259. ;
  2260. U1100_Get_Response Proc Near
  2261. ;
  2262. U1101:
  2263.     Push    AX            ; Save the registers and flags
  2264.     Push    BX            ; .
  2265.     Push    CX            ; .
  2266.     Push    SI            ; .
  2267.     Pushf                ; ..End
  2268. U1102:
  2269.     Mov    SI,Offset WRK05_Keyboard_Buffer+1
  2270.     Mov    CX,NUL            ; Initialize the CX counter register
  2271. U1103:
  2272.     Mov    AH,Flush_Keyboard_Command; Read the character from keyboard
  2273.     Mov    AL,Read_Keyboard_Command; .
  2274.     Int    PC_DOS_Interrupt    ; ..End
  2275.     Cmp    AL,ETX            ; Compare for a control break
  2276.     Jne    U1104            ; If not, then continue
  2277.     Mov    SI,Offset MES98_Control_Break
  2278.     Call    U1000_Display_Message    ; Display the message on the screen
  2279.     Jmp    A1002            ; Go to B1200_Final_Process
  2280. U1104:
  2281.     Cmp    Byte Ptr FLG05_Store_Buffer,True
  2282.     Je    U1105            ; If store keyboard entries, continue
  2283.     Jmp    U1190            ; If not, go to end of the module
  2284. U1105:
  2285.     Cmp    AL,BS            ; Is AL a backspace character???
  2286.     Jne    U1106            ; If not, continue processing AL
  2287.     Cmp    CX,NUL            ; Is the cursor at column zero????
  2288.     Je    U1103            ; Yes, so get another character
  2289.     Dec    CX            ; Decrement CX to point to the
  2290.                     ; . previous cursor location
  2291.     Dec    SI            ; Decrement SI to go back to the
  2292.                     ; . previos buffer location
  2293. ;
  2294.     Mov    AH,Write_TTY_Command    ; Write a backspace to the screen
  2295.     Mov    AL,BS            ; .
  2296.     Mov    BH,Byte Ptr SYS03_Active_Page
  2297.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2298.     Int    Video_Interrupt        ; ..End
  2299. ;
  2300.     Mov    AH,Write_TTY_Command    ; Write a space to the screen
  2301.     Mov    AL,Space        ; .
  2302.     Mov    BH,Byte Ptr SYS03_Active_Page
  2303.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2304.     Int    Video_Interrupt        ; ..End
  2305. ;
  2306.     Mov    AH,Write_TTY_Command    ; Write a backspace to the screen
  2307.     Mov    AL,BS            ; .
  2308.     Mov    BH,Byte Ptr SYS03_Active_Page
  2309.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2310.     Int    Video_Interrupt        ; ..End
  2311. ;
  2312.     Jmp    U1103            ; Go back and get another character
  2313. U1106:
  2314.     Cmp    AL,CR            ; Compare char for a carriage return
  2315.     Je    U1108            ; If so, insert an EOT into buffer
  2316.     Cmp    CX,Keyboard_Buffer_Size    ; Check for keyboard buffer full
  2317.     Jae    U1107            ; If so, sound bell and get new char
  2318.     Mov    [SI],AL            ; Put the character into the buffer
  2319.     Inc    SI            ; Increment the keyboard address
  2320.     Inc    CX            ; Increment the CX character counter
  2321.     Jmp    U1103            ; Go back and get another character
  2322. U1107:
  2323.     Mov    AH,Write_TTY_Command    ; Sound the beep from the screen
  2324.     Mov    AL,Bell            ; .
  2325.     Mov    BH,Byte Ptr SYS03_Active_Page
  2326.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2327.     Int    Video_Interrupt        ; ..End
  2328.     Jmp    U1103            ; Go back and get another character
  2329. U1108:
  2330.     Mov    AL,EOT            ; Put an EOT into the buffer
  2331.     Mov    [SI],AL            ; ..End
  2332. ;
  2333.     Mov    AH,Write_TTY_Command    ; Write a carriage return to the
  2334.     Mov    AL,CR            ; . screen
  2335.     Mov    BH,Byte Ptr SYS03_Active_Page
  2336.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2337.     Int    Video_Interrupt        ; ..End
  2338. ;
  2339.     Mov    AH,Write_TTY_Command    ; Write a line feed to the screen
  2340.     Mov    AL,LF            ; .
  2341.     Mov    BH,Byte Ptr SYS03_Active_Page
  2342.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2343.     Int    Video_Interrupt        ; ..End
  2344. ;
  2345.     Mov    WRK05_Keyboard_Buffer[0],CL; Set the length accrodingly
  2346. U1190:
  2347.     Popf                ; Restore the registers and flags
  2348.     Pop    SI            ; .
  2349.     Pop    CX            ; .
  2350.     Pop    BX            ; .
  2351.     Pop    AX            ; ..End
  2352. U1199:
  2353.     Ret
  2354. U1100_Get_Response Endp
  2355. ;
  2356. Page
  2357. ;************************************************************************
  2358. ;*                                    *
  2359. ;*    U1200_GET_YES_OR_NO                        *
  2360. ;*                                    *
  2361. ;*    This module asks for a [Yy]es or [Nn]o answer from a user.  The    *
  2362. ;*    routine accepts only a [Yy] or [Nn] and exists with the flag    *
  2363. ;*    FLG06_Yes_or_No set to True for YES and False for NO.        *
  2364. ;*                                    *
  2365. ;************************************************************************
  2366. ;
  2367. Public    U1200_Get_Yes_or_No
  2368. ;
  2369. U1200_Get_Yes_or_No Proc Near
  2370. ;
  2371. U1201:
  2372.     Push    AX            ; Save the registers and flags
  2373.     Push    SI            ; .
  2374.     Pushf                ; ..End
  2375. U1202:
  2376.     Mov    AH,Flush_Keyboard_Command; Read the character from keyboard
  2377.     Mov    AL,Read_Keyboard_Command; .
  2378.     Int    PC_DOS_Interrupt    ; ..End
  2379.     Cmp    AL,ETX            ; Compare for control break
  2380.     Jne    U1203            ; If not, then continue
  2381.     Mov    SI,Offset MES98_Control_Break
  2382.     Call    U1000_Display_Message    ; Display the message on the screen
  2383.     Jmp    A1002            ; Go to B1200_Final_Process
  2384. U1203:
  2385.     Cmp    AL,Capital_Letter_Y    ; Check for capital letter Y
  2386.     Jne    U1204            ; ..End
  2387.     Mov    Byte Ptr FLG06_Yes_or_No,True
  2388.     Mov    SI,Offset MES24_Yes    ; Display YES on the screen
  2389.     Call    U1000_Display_Message    ; ..End
  2390.     Jmp    U1290            ; Go to the end of the module
  2391. U1204:
  2392.     Cmp    AL,Small_Letter_y    ; Check for small letter y
  2393.     Jne    U1205            ; ..End
  2394.     Mov    Byte Ptr FLG06_Yes_or_No,True
  2395.     Mov    SI,Offset MES24_Yes    ; Display YES on the screen
  2396.     Call    U1000_Display_Message    ; ..End
  2397.     Jmp    U1290            ; Go to the end of the module
  2398. U1205:
  2399.     Cmp    AL,Capital_Letter_N    ; Check for capital letter N
  2400.     Jne    U1206            ; ..End
  2401.     Mov    Byte Ptr FLG06_Yes_or_No,False
  2402.     Mov    SI,Offset MES25_No    ; Display NO on the screen
  2403.     Call    U1000_Display_Message    ; ..End
  2404.     Jmp    U1290            ; Go to the end of the module
  2405. U1206:
  2406.     Cmp    AL,Small_Letter_n    ; Check for small letter n
  2407.     Jne    U1207            ; ..End
  2408.     Mov    Byte Ptr FLG06_Yes_or_No,False
  2409.     Mov    SI,Offset MES25_No    ; Display NO on the screen
  2410.     Call    U1000_Display_Message    ; ..End
  2411.     Jmp    U1290            ; Go to the end of the module
  2412. U1207:
  2413.     Jmp    U1202            ; Go back and get another character
  2414. U1290:
  2415.     Popf                ; Restore the registers and flags
  2416.     Pop    SI            ; .
  2417.     Pop    AX            ; ..End
  2418. U1299:
  2419.     Ret
  2420. ;
  2421. U1200_Get_Yes_or_No Endp
  2422. ;
  2423. Page
  2424. ;************************************************************************
  2425. ;*                                    *
  2426. ;*    U1300_CONVERT_BINARY_TO_ASCII                    *
  2427. ;*                                    *
  2428. ;*    This module BCD contained in the AL register into an ASCII    *
  2429. ;*    character.  The output is returned in the AX register.        *
  2430. ;*                                    *
  2431. ;************************************************************************
  2432. ;
  2433. Public    U1300_Convert_Binary_to_ASCII
  2434. ;
  2435. U1300_Convert_Binary_to_ASCII Proc Near
  2436. ;
  2437. U1301:
  2438.     Push    DX            ; Save the registers
  2439.     Pushf                ; ..End
  2440. ;
  2441.     Cbw                ; Perform sign extension for division
  2442.     Mov    DL,Ten            ; Set DL disvisor to 10D
  2443.     Div    DL            ; Divide AL by 10D remainder in AH
  2444.     Add    AL,Zero_Digit        ; Setup the characters in AL & AH
  2445.     Add    AH,Zero_Digit        ; ..End
  2446. ;
  2447.     Popf                ; Restore the registers
  2448.     Pop    DX            ; ..End
  2449. U1399:
  2450.     Ret
  2451. ;
  2452. U1300_Convert_Binary_to_ASCII Endp
  2453. ;
  2454. Page
  2455. ;************************************************************************
  2456. ;*                                    *
  2457. ;*    U1400_DISPLAY_HEAD_AND_TRACK                    *
  2458. ;*                                    *
  2459. ;*    This module displays the current track and head number that    *
  2460. ;*    is being read from the source diskette or written to the     *
  2461. ;*    target diskette.                        *
  2462. ;*                                    *
  2463. ;************************************************************************
  2464. ;
  2465. Public    U1400_Display_Head_and_Track
  2466. ;
  2467. U1400_Display_Head_and_Track Proc Near
  2468. ;
  2469. U1401:
  2470.     Push    AX            ; Save the registers
  2471.     Push    BX            ; .
  2472.     Push    DX            ; .
  2473.     Pushf                ; ..End
  2474. ;
  2475.     Mov    AH,Set_CPos_Command    ; Set cursor to track position
  2476.     Mov    BH,Byte Ptr SYS03_Active_Page
  2477.     Mov    DH,Byte Ptr WRK28_Current_Message_Row
  2478.     Mov    DL,Fifteen        ; .
  2479.     Int    Video_Interrupt        ; ..End
  2480. ;
  2481.                     ; Write the current track number
  2482.     Mov    AL,Byte Ptr WRK30_Current_Track
  2483.     Call    U1300_Convert_Binary_to_ASCII
  2484.     Push    AX            ; .
  2485.     Mov    AH,Write_TTY_Command    ; .
  2486.     Mov    BH,Byte Ptr SYS03_Active_Page
  2487.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2488.     Int    Video_Interrupt        ; .
  2489.     Pop    AX            ; .
  2490.     Mov    AL,AH            ; .
  2491.     Mov    AH,Write_TTY_Command    ; .
  2492.     Mov    BH,Byte Ptr SYS03_Active_Page
  2493.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2494.     Int    Video_Interrupt        ; ..End
  2495. ;
  2496.     Mov    AH,Set_CPos_Command    ; Set cursor to head position
  2497.     Mov    BH,Byte Ptr SYS03_Active_Page
  2498.     Mov    DH,Byte Ptr WRK28_Current_Message_Row
  2499.     Mov    DL,Twenty_Five        ; .
  2500.     Int    Video_Interrupt        ; ..End
  2501. ;                    ; Write the current head number
  2502.     Mov    AL,Byte Ptr WRK29_Current_Head
  2503.     Call    U1300_Convert_Binary_to_ASCII
  2504.     Mov    AL,AH            ;.
  2505.     Mov    AH,Write_TTY_Command    ;.
  2506.     Mov    BH,Byte Ptr SYS03_Active_Page
  2507.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2508.     Int    Video_Interrupt        ; ..End
  2509. ;
  2510.     Mov    AH,Set_CPos_Command    ; Set cursor to the next line
  2511.     Mov    BH,Byte Ptr SYS03_Active_Page
  2512.     Mov    DH,Byte Ptr WRK28_Current_Message_Row
  2513.     Inc    DH            ; .
  2514.     Mov    DL,Zero            ; .
  2515.     Int    Video_Interrupt        ; ..End
  2516. U1490:
  2517.     Popf                ; Restore the registers
  2518.     Pop    DX            ; 
  2519.     Pop    BX            ; .
  2520.     Pop    AX            ; ..End
  2521. U1499:
  2522.     Ret
  2523. ;
  2524. U1400_Display_Head_and_Track Endp
  2525. ;
  2526. Page
  2527. ;************************************************************************
  2528. ;*                                    *
  2529. ;*    FLAGS                                *
  2530. ;*                                    *
  2531. ;*    This portion of FREECOPY contains the definitions of all of    *
  2532. ;*    flags defined in the program.                    *
  2533. ;*                                    *
  2534. ;************************************************************************
  2535. ;
  2536. FLG01_Good_Command    DB (?)        ; Establishes any errors in the
  2537.                     ; . command line entered by a user
  2538. FLG02_Double_Side    DB (?)        ; Points out whether the user wants
  2539.                     ; . to copy only the top side of a
  2540.                     ; . floppy diskette
  2541. FLG03_Default_Drive    DB (?)        ; Shows if the default drive is a
  2542.                     ; . valid floppy disk drive
  2543. FLG04_Single_Drive    DB (?)        ; Determines if the machine is a
  2544.                     ; . single drive system
  2545. FLG05_Store_Buffer    DB (?)        ; Establishes whether to put the
  2546.                     ; . characters entered from the
  2547.                     ; . keyboard into the buffer
  2548. FLG06_Yes_or_No        DB (?)        ; Points out the user's response
  2549.                     ; . NO = False   YES = True
  2550. FLG07_First_Time    DB (?)        ; Shows the number of times the user
  2551.                     ; . copies a diskette
  2552.                     ; . ONCE = True  MORE = False
  2553. FLG08_Good_Read        DB (?)        ; Flags establish whether the
  2554. FLG09_Good_Write    DB (?)        ; . operation was performed correctly
  2555. FLG10_Good_Verify      DB (?)        ; . YES = True    NO = False
  2556. FLG11_Good_Format    DB (?)        ; ..End
  2557. FLG12_Good_FAT        DB (?)        ; Establishes a good FAT when reading
  2558.                     ; . source diskette more than once
  2559. FLG13_First_Read_Write    DB (?)        ; Shows if a diskette is being read
  2560.                     ; . or written for the first time
  2561.                     ; . YES = True    NO  = False
  2562. FLG14_Copy_Complete    DB (?)        ; Points out if a diskette has been
  2563.                     ; . copied completely
  2564.                     ; . YES = True    NO = False
  2565. FLG15_IO_Error        DB (?)        ; Establishes the type of IO error
  2566.                     ; . Zero = Format error
  2567.                     ; . One  = Read error
  2568.                     ; . Two  = Write error
  2569.                     ; ..End
  2570. FLG16_Free_Memory    DB (?)        ; Determines whether memory should
  2571.                     ; . using the PC DOS function calls
  2572. FLG17_Copy_More_Disks    DB (?)        ; Indicates whether to ask a user to
  2573.                     ; . write the same disk over again
  2574. ;
  2575. Page
  2576. ;************************************************************************
  2577. ;*                                    *
  2578. ;*    MESSAGES                            *
  2579. ;*                                    *
  2580. ;*    This portion of FREECOPY contains the definitions of all of    *
  2581. ;*    messages defined in the program.                *
  2582. ;*                                    *
  2583. ;************************************************************************
  2584. ;
  2585. MES00_Copy_Notice        Label Byte
  2586.     DB    CR,LF
  2587.     DB    'FREECOPY Disk Utility',CR,LF
  2588.     DB    'IBM Personal Computer/Jr.',CR,LF
  2589.     DB    'Version 1.13 (C)Copyright 1984, 1985',CR,LF
  2590.     DB    CR,LF
  2591.     DB    'Squire Buresh Assoc., Inc.',CR,LF
  2592.     DB    'Post Office Box 112',CR,LF
  2593.     DB    'Millbury, MA 01527',CR,LF
  2594.     DB    CR,LF
  2595.     DB    '$25.00 requested contribution.',CR,LF,EOT
  2596. MES01A_Write_Another_Diskette    Label Byte
  2597.     DB    CR,LF
  2598.     DB    'Write source diskette again (Y/N)? ',EOT
  2599. MES01B_Copy_Another_diskette    Label Byte
  2600.     DB    CR,LF
  2601.     DB    'Copy another diskette (Y/N)? ',EOT
  2602. MES02_Copy_Complete        Label Byte
  2603.     DB    CR,LF
  2604.     DB    'Copy complete.',CR,LF,EOT
  2605. MES03_Copy81_Sectors        Label Byte
  2606.     DB    CR,LF
  2607.     DB    'Copying 8 sectors per track, 1 side.',CR,LF,EOT
  2608. MES04_Copy82_Sectors        Label Byte
  2609.     DB    CR,LF
  2610.     DB    'Copying 8 sectors per track, 2 sides.',CR,LF,EOT
  2611. MES05_Copy91_Sectors        Label Byte
  2612.     DB    CR,LF
  2613.     DB    'Copying 9 sectors per track, 1 side.',CR,LF,EOT
  2614. MES06_Copy92_Sectors        Label Byte
  2615.     DB    CR,LF
  2616.     DB    'Copying 9 sectors per track, 2 sides.',CR,LF,EOT
  2617. MES07_Correct_And_Press_Key    Label Byte
  2618.     DB    CR,LF
  2619.     DB    'Correct, and press any key to continue',CR,LF,EOT
  2620. MES08_Drive_Not_Ready        Label Byte
  2621.     DB    CR,LF
  2622.     DB    'Diskette not in drive  :.',CR,LF,EOT
  2623. MES09_Insert_Source        Label Byte
  2624.     DB    CR,LF
  2625.     DB    'Insert source diskette in drive  :.',CR,LF,EOT
  2626. MES10_Insert_Target        Label Byte
  2627.     DB    CR,LF
  2628.     DB    'Insert target diskette in drive  :.',CR,LF,EOT
  2629. MES11_Insufficient_Memory    Label Byte
  2630.     DB    CR,LF
  2631.     DB    'Insufficient memory.',Bell,CR,LF,EOT
  2632. MES12_Invalid_Parameter        Label Byte
  2633.     DB    CR,LF
  2634.     DB    'Invalid parameter(s) specified.',CR,LF,EOT
  2635. MES13_Invalid_Default        Label Byte
  2636.     DB    CR,LF
  2637.     DB    'Invalid default floppy disk drive',CR,LF,EOT
  2638. MES14_Invalid_Drive        Label Byte
  2639.     DB    CR,LF
  2640.     DB    'Invalid drive specification.',CR,LF,EOT
  2641. MES15_Single_Drive_Copy        Label Byte
  2642.     DB    CR,LF
  2643.     DB    'NOTE: Copying diskette on single drive.',Bell,CR,LF,EOT
  2644. MES16_Press_Any_Key        Label Byte
  2645.     DB    CR,LF
  2646.     DB    'Press any key when ready.',CR,LF,EOT
  2647. MES17_Reading_Track        Label Byte
  2648.     DB    'Reading track (  ) head ( ).',CR,LF,EOT
  2649. MES18_Unrecoverable_Format    Label Byte
  2650.     DB    CR,LF
  2651.     DB    'Unrecoverable format error on target.',CR,LF,EOT
  2652. MES19_Unrecoverable_Read    Label Byte
  2653.     DB    CR,LF
  2654.     DB    'Unrecoverable read error on source.',CR,LF,EOT
  2655. MES20_Unrecoverable_Verify    Label Byte
  2656.     DB    CR,LF
  2657.     DB    'Unrecoverable verify error on target.',CR,LF,EOT
  2658. MES21_Unrecoverable_Write    Label Byte
  2659.     DB    CR,LF
  2660.     DB    'Unrecoverable write error on target.',CR,LF,EOT
  2661. MES22_Unrecoverable_IO        Label Byte
  2662.     DB    CR,LF
  2663.     DB    'Unrecoverable IO error.',CR,LF,EOT
  2664. MES23_Writing_Track        Label Byte
  2665.     DB    'Writing track (  ) head ( ).',CR,LF,EOT
  2666. MES24_Yes            Label Byte
  2667.     DB    'YES',CR,LF,EOT
  2668. MES25_No            Label Byte
  2669.     DB    'NO',CR,LF,EOT
  2670. MES80_Seek_Error        Label Byte
  2671.     DB    'Seek operation has failed.',CR,LF,EOT
  2672. MES81_Controller_Error        Label Byte
  2673.     DB    'Disk controller has failed.',CR,LF,EOT
  2674. MES82_CRC_Error            Label Byte
  2675.     DB    'Cyclic redundancy check (CRC) error.',CR,LF,EOT
  2676. MES83_DMA_Boundary_Error    Label Byte
  2677.     DB    'Attempted to DMA across a 64K boundary.',CR,LF,EOT
  2678. MES84_DMA_Error            Label Byte
  2679.     DB    'DMA overrun on I/O operation.',CR,LF,EOT
  2680. MES85_Sector_Error        Label Byte
  2681.     DB    'Requested sector not found.',CR,LF,EOT
  2682. MES86_Write_Protect_Error    Label Byte
  2683.     DB    'Output diskette is write protected.',CR,LF,EOT
  2684. MES87_Address_Mark_Error    Label Byte
  2685.     DB    'Address mark was not found.',CR,LF,EOT
  2686. MES88_Command_Error        Label Byte
  2687.     DB    'Bad command passed to the disk interrupt 13H.',CR,LF,EOT
  2688. MES89_Unknown_Error        Label Byte
  2689.     DB    'Unknown diskette error encountered.',CR,LF,EOT
  2690. MES90_Unknown_FAT_Error        Label Byte
  2691.     DB    'First byte of the FAT does not',CR,LF
  2692.     DB    'match any known diskette type.',CR,LF,EOT
  2693. MES91_Single_Side_Error        Label byte
  2694.     DB    'Double sided diskette in a',CR,LF
  2695.     DB    'single sided disk drive.',CR,LF,EOT
  2696. MES97_Return_Linefeed        Label Byte
  2697.     DB    CR,LF,EOT
  2698. MES98_Control_Break        Label Byte
  2699.     DB    '^C',CR,LF,EOT
  2700. MES99_Memory_Block_Destroyed    Label Byte
  2701.     DB    'Memory control block destroyed.',CR,LF,EOT
  2702. MES100_Freecopy_Finished    Label Byte
  2703.     DB    CR,LF
  2704.     DB    'Returning to PC DOS.',CR,LF,EOT
  2705. ;
  2706. Page
  2707. ;************************************************************************
  2708. ;*                                    *
  2709. ;*    WORK VARIABLES                            *
  2710. ;*                                    *
  2711. ;*    This portion of FREECOPY contains the definitions of the work    *
  2712. ;*    variables that are used by the program.                *
  2713. ;*                                    *
  2714. ;************************************************************************
  2715. ;
  2716. WRK01_Source_Drive        DB (?)    ; Source diskette drive number
  2717. WRK02_Target_Drive        DB (?)    ; Target diskette drive number
  2718. WRK03_Valid_Filename        DB 11 Dup (32D); Valid diskette file name
  2719. WRK04_Parameter_Count        DB (?)    ; Valid diskette filler area
  2720. ;
  2721. WRK05_Keyboard_Buffer        Label Byte
  2722.                 DB 80D    ; Length of the keyboard buffer
  2723.                 DB 80 Dup (?); Actual keyboard buffer
  2724.                 DB EOT    ; Last char denotes the end of text
  2725. ;
  2726. WRK06_Drive_Number        DB (?)    ; Drive number of a disk drive
  2727. WRK07_Head_Number        DB (?)    ; Head number of a disk drive
  2728. WRK08_Track_Number        DB (?)    ; Track number of a diskette
  2729. WRK09_Sector_Number        DB (?)    ; Sector number of a diskette
  2730. WRK10_Number_of_Sectors        DB (?)    ; Number of sectors on a track
  2731. WRK11_Segment_Address        DW (?)    ; ES segment address
  2732. WRK12_Offset_Address        DW (?)    ; BX offset address
  2733. WRK13_Retry_Counter        DB (?)    ; Number of retrys to make
  2734. WRK14_Status_Operation        DB (?)    ; Result of the operation
  2735. ;
  2736. WRK15_Maximum_Heads        DB (?)    ; Maximum heads, tracks and sectors
  2737. WRK16_Maximum_Tracks        DB (?)    ; .
  2738. WRK17_Maximum_Sectors        DB (?)    ; ..End
  2739. ;
  2740. WRK18_Counter_ESBX_Entries    DW (?)    ; Counter to calculate ES:BX entries
  2741. WRK19_Number_ESBX_Entries    DW (?)    ; Maximum ES:BX table entires
  2742. ;
  2743. Page
  2744. ;************************************************************************
  2745. ;*                                    *
  2746. ;*    WORK VARIABLES    Page 2                        *
  2747. ;*                                    *
  2748. ;************************************************************************
  2749. ;
  2750. WRK20_Current_Source_Head    DB (?)    ; Current source head & track number
  2751. WRK21_Current_Source_Track    DB (?)    ; ..End
  2752. WRK22_Current_Target_Head    DB (?)    ; Current target head & track number
  2753. WRK23_Current_Target_Track    DB (?)    ; . End
  2754. ;
  2755. WRK24_Read_Message_Row        DB (?)    ; Cursor row of read, verify, format
  2756. WRK25_Verify_Message_Row    DB (?)    ; and write message
  2757. WRK26_Format_Message_Row    DB (?)    ; .
  2758. WRK27_Write_Message_Row        DB (?)    ; .
  2759. WRK28_Current_Message_Row    DB (?)    ; ..End
  2760. ;
  2761. WRK29_Current_Head        DB (?)    ; Current head and track to display
  2762. WRK30_Current_Track        DB (?)    ; . on the screen
  2763. ;
  2764. WRK31_Track_Read_Counter        DB (?)    ; Counter of tracks processed
  2765. WRK32_Track_Write_Counter       DB (?)  ; ..End
  2766. ;
  2767. WRK33_CHRN_Table_Address    DW (?)    ; Current address of the CHRN table
  2768. ;
  2769. WRK34_DMA_Overflow_Counter    DW (?)    ; Counts how many times FREECOPY
  2770.                     ; . adjusted for DMA overflow
  2771. ;
  2772. Page
  2773. ;************************************************************************
  2774. ;*                                    *
  2775. ;*    SYSTEM VARIABLES                        *
  2776. ;*                                    *
  2777. ;*    This portion of FREECOPY contains the definitions of all of    *
  2778. ;*    the system variables used by the program.            *
  2779. ;*                                    *
  2780. ;************************************************************************
  2781. ;
  2782. SYS01_Number_Columns    DB (?)        ; Number of columns in current mode
  2783. SYS02_Current_Mode    DB (?)        ; Current video mode
  2784. SYS03_Active_Page    DB (?)        ; Active display page
  2785. SYS04_Foreground_Color    DB (?)        ; Foreground color number
  2786. SYS05_Para_RAM_Size    DW (?)        ; Number of free 16 byte paragraphs
  2787. SYS06_Monitor_Flag    DB (?)        ; 0 = monochrome  1 = graphics
  2788. SYS07_No_Parallel_Ports    DB (?)        ; Number of parallel ports
  2789. SYS08_Game_Adapters    DB (?)        ; Number of RS-232 ports
  2790. SYS09_No_RS232_Ports    DB (?)        ; 0 = no adapter  1 = has adapter
  2791. SYS10_No_Disk_Drives    DB (?)        ; Number of floppy disk drives
  2792. SYS11_Init_Video_Mode    DB (?)        ; Initial video mode when powering
  2793.                     ; up the machine
  2794. SYS12_Planar_RAM_Size    DB (?)        ; Planar RAM size
  2795. SYS13_IPL_From_Diskette    DB (?)        ; Location of initial program load
  2796. SYS14_Default_Drive    DB (?)        ; Default disk drive
  2797. ;
  2798. SYS15_Stack_Pointer    DW (?)        ; Stack pointer value when entering
  2799.                     ; . FREECOPY from PC DOS
  2800. SYS16_Save_DPT_Offset    DW (?)        ; Address of Disk Parameter Table
  2801. SYS17_Save_DPT_Segment    DW (?)        ; ..End
  2802. ;
  2803. SYS18_Disk_Parameter_Table    Label Byte
  2804.             DB 11011111B    ; SRT = 0D & Head Unload = 0FH
  2805.             DB 002H        ; Head Load = 1 Mode = DMA
  2806.             DB 025H        ; Wait to turn the motor off
  2807.             DB 002H        ; 512 bytes per sector
  2808.             DB 009H        ; 9 sectors per track
  2809.             DB 02AH        ; PC DOS gap length for I/O
  2810.             DB 0FFH        ; Data length parameter
  2811.             DB 050H        ; PC DOS gap length for format
  2812.             DB 0F6H        ; Fille byte for format
  2813.             DB 00FH        ; Head Settle time in milliseconds
  2814.             DB 002H        ; Motor start-up time (1/8 sec.)
  2815. ;
  2816. SYS19_Major_Vers_Number DB (?)        ; Major and minor version number
  2817. SYS20_Minor_Vers_Number DB (?)        ; . of the operating system
  2818. ;
  2819. SYS21_Alloc_Segment    DW (?)        ; Beginning segment address of
  2820.                     ; . free memory
  2821. ;
  2822. Page
  2823. ;************************************************************************
  2824. ;*                                    *
  2825. ;*    SETUP STACK POINTER AND MEMORY                    *
  2826. ;*                                    *
  2827. ;*    This portion of FREECOPY is contains the stack and the label    *
  2828. ;*    that indicates the beginning of available memory.        *
  2829. ;*                                    *
  2830. ;************************************************************************
  2831. ;
  2832. MEM05_Bottom_of_the_Stack    Label Word
  2833.             DW 64 Dup (?)
  2834. MEM04_Top_of_the_Stack        Label Word
  2835. ;
  2836. MEM03_ESBX_Table        Equ MEM04_Top_of_the_Stack+2
  2837. ;
  2838. MEM02_CHRN_Table        Equ MEM03_ESBX_Table+320
  2839. ;
  2840. MEM01_File_Allocation_Table    Equ MEM02_CHRN_Table+2880
  2841. ;
  2842. MEM00_Bottom_Free_Memory    Equ MEM01_File_Allocation_Table+512
  2843. ;
  2844. Page
  2845. ;************************************************************************
  2846. ;*                                    *
  2847. ;*    END OF THE PROGRAM                        *
  2848. ;*                                    *
  2849. ;************************************************************************
  2850. ;
  2851. CSEG    Ends
  2852.     End   A1000_Main_Module
  2853.  
  2854.  
  2855.