home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / assemblr / library / nor_asm / video_13.asm < prev    next >
Assembly Source File  |  1989-05-04  |  3KB  |  103 lines
  1. .MODEL    SMALL
  2. .CODE
  3.  
  4.     PUBLIC    WRITE_HEX
  5. ;-----------------------------------------------------------------------;
  6. ; This procedure converts the byte in the DL register to hex and writes    ;
  7. ; the two hex digits at the current cursor position.            ;
  8. ;                                    ;
  9. ; On entry:    DL    Byte to convert to hex.                ;
  10. ;                                    ;
  11. ; Uses:        WRITE_HEX_DIGIT                        ;
  12. ;-----------------------------------------------------------------------;
  13. WRITE_HEX    PROC            ;Entry point
  14.     PUSH    CX            ;Save registers used in this procedure
  15.     PUSH    DX
  16.     MOV    DH,DL            ;Make a copy of byte
  17.     MOV    CX,4            ;Get the upper nibble in DL
  18.     SHR    DL,CL
  19.     CALL    WRITE_HEX_DIGIT        ;Display first hex digit
  20.     MOV    DL,DH            ;Get lower nibble into DL
  21.     AND    DL,0Fh            ;Remove the upper nibble
  22.     CALL    WRITE_HEX_DIGIT        ;Display second hex digit
  23.     POP    DX
  24.     POP    CX
  25.     RET
  26. WRITE_HEX    ENDP
  27.  
  28.     PUBLIC    WRITE_HEX_DIGIT
  29. ;-----------------------------------------------------------------------;
  30. ; This procedure converts the lower 4 bits of DL to a hex digit and    ;
  31. ; writes it to the screen.                        ;
  32. ;                                    ;
  33. ; On entry:    DL    Lower 4 bits contain number to be printed    ;
  34. ;            in hex.                        ;
  35. ;                                    ;
  36. ; Uses:        WRITE_CHAR                        ;
  37. ;-----------------------------------------------------------------------;
  38. WRITE_HEX_DIGIT        PROC
  39.     PUSH    DX            ;Save registers used
  40.     CMP    DL,10            ;Is this nibble <10?
  41.     JAE    HEX_LETTER        ;No, convert to a letter
  42.     ADD    DL,"0"            ;Yes, convert to a digit
  43.     JMP    Short WRITE_DIGIT    ;Now write this character
  44. HEX_LETTER:
  45.     ADD    DL,"A"-10        ;Convert to hex letter
  46. WRITE_DIGIT:
  47.     CALL    WRITE_CHAR        ;Display the letter on the screen
  48.     POP    DX            ;Restore old value of DX
  49.     RET
  50. WRITE_HEX_DIGIT        ENDP
  51.  
  52.     PUBLIC    WRITE_CHAR
  53. ;-----------------------------------------------------------------------;
  54. ; This procedure prints a character on the screen using the DOS        ;
  55. ; function call.                            ;
  56. ;                                    ;
  57. ; On entry:    DL    Byte to print on screen.            ;
  58. ;-----------------------------------------------------------------------;
  59. WRITE_CHAR    PROC
  60.     PUSH    AX    
  61.     MOV    AH,2            ;Call for character output
  62.     INT    21h            ;Output character in DL register
  63.     POP    AX            ;Restore old value in AX
  64.     RET                ;And return
  65. WRITE_CHAR    ENDP
  66.  
  67.     PUBLIC    WRITE_DECIMAL
  68. ;-----------------------------------------------------------------------;
  69. ; This procedure writes a 16-bit, unsigned number in decimal notation.    ;
  70. ;                                    ;
  71. ; On entry:    DX    N : 16-bit, unsigned number.            ;
  72. ;                                    ;
  73. ; Uses:        WRITE_HEX_DIGIT                        ;
  74. ;-----------------------------------------------------------------------;
  75. WRITE_DECIMAL    PROC
  76.     PUSH    AX            ;Save registers used here
  77.     PUSH    CX
  78.     PUSH    DX
  79.     PUSH    SI
  80.     MOV    AX,DX
  81.     MOV    SI,10            ;Will divide by 10 using SI
  82.     XOR    CX,CX            ;Count of digits placed on stack
  83. NON_ZERO:
  84.     XOR    DX,DX            ;Set upper word of N to 0
  85.     DIV    SI            ;Calculate N/10 and (N mod 10)
  86.     PUSH    DX            ;Push one digit onto the stack
  87.     INC    CX            ;One more digit added
  88.     OR    AX,AX            ;N = 0 yet?
  89.     JNE    NON_ZERO        ;Nope, continue
  90. WRITE_DIGIT_LOOP:
  91.     POP    DX            ;Get the digits in reverse order
  92.     CALL    WRITE_HEX_DIGIT
  93.     LOOP    WRITE_DIGIT_LOOP
  94. END_DECIMAL:
  95.     POP    SI
  96.     POP    DX
  97.     POP    CX
  98.     POP    AX
  99.     RET
  100. WRITE_DECIMAL    ENDP
  101.  
  102.     END
  103.