home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / assemblr / library / nor_asm / editor22.asm < prev    next >
Assembly Source File  |  1989-05-17  |  2KB  |  81 lines
  1. .MODEL    SMALL
  2.  
  3. .CODE
  4.  
  5. .DATA
  6.     EXTRN    SECTOR:BYTE
  7.     EXTRN    SECTOR_OFFSET:WORD
  8.     EXTRN    PHANTOM_CURSOR_X:BYTE
  9.     EXTRN    PHANTOM_CURSOR_Y:BYTE
  10. .CODE
  11. ;-----------------------------------------------------------------------;
  12. ; This procedure writes one byte to SECTOR, at the memory location    ;
  13. ; pointed to by the phantom cursor.                    ;
  14. ;                                    ;
  15. ; On entry:    DL    Byte to write to SECTOR                ;
  16. ;                                    ;
  17. ; The offset is calculated by                        ;
  18. ;   OFFSET = SECTOR_OFFSET + (16 * PHANTOM_CURSOR_Y) + PHANTOM_CURSOR_X    ;
  19. ;                                    ;
  20. ; Reads:    PHANTOM_CURSOR_X, PHANTOM_CURSOR_Y, SECTOR_OFFSET    ;
  21. ; Writes:    SECTOR                            ;
  22. ;-----------------------------------------------------------------------;
  23. WRITE_TO_MEMORY    PROC
  24.     PUSH    AX
  25.     PUSH    BX
  26.     PUSH    CX
  27.     MOV    BX,SECTOR_OFFSET
  28.     MOV    AL,PHANTOM_CURSOR_Y
  29.     XOR    AH,AH
  30.     MOV    CL,4            ;Multiply PHANTOM_CURSOR_Y by 16
  31.     SHL    AX,CL
  32.     ADD    BX,AX            ;BX = SECTOR_OFFSET + (16 * Y)
  33.     MOV    AL,PHANTOM_CURSOR_X
  34.     XOR    AH,AH
  35.     ADD    BX,AX            ;That's the address!
  36.     MOV    SECTOR[BX],DL        ;Now, store the byte
  37.     POP    CX
  38.     POP    BX
  39.     POP    AX
  40.     RET
  41. WRITE_TO_MEMORY        ENDP
  42.  
  43.     PUBLIC    EDIT_BYTE
  44.     EXTRN    SAVE_REAL_CURSOR:PROC, RESTORE_REAL_CURSOR:PROC
  45.     EXTRN    MOV_TO_HEX_POSITION:PROC, MOV_TO_ASCII_POSITION:PROC
  46.     EXTRN    WRITE_PHANTOM:PROC, WRITE_PROMPT_LINE:PROC
  47.     EXTRN    CURSOR_RIGHT:PROC, WRITE_HEX:PROC, WRITE_CHAR:PROC
  48. .DATA
  49.     EXTRN    EDITOR_PROMPT:BYTE
  50. .CODE
  51. ;-----------------------------------------------------------------------;
  52. ; This procedure changes a byte in memory and on the screen.        ;
  53. ;                                    ;
  54. ;    DL    Byte to write into SECTOR, and change on screen        ;
  55. ;                                    ;
  56. ; Uses:        SAVE_REAL_CURSOR, RESTORE_REAL_CURSOR            ;
  57. ;        MOV_TO_HEX_POSITION, MOV_TO_ASCII_POSITION        ;
  58. ;        WRITE_PHANTOM, WRITE_PROMPT_LINE, CURSOR_RIGHT        ;
  59. ;        WRITE_HEX, WRITE_CHAR, WRITE_TO_MEMORY            ;
  60. ; Reads:    EDITOR_PROMPT                        ;
  61. ;-----------------------------------------------------------------------;
  62. EDIT_BYTE    PROC
  63.     PUSH    DX
  64.     CALL    SAVE_REAL_CURSOR
  65.     CALL    MOV_TO_HEX_POSITION    ;Move to the hex number in the
  66.     CALL    CURSOR_RIGHT        ; hex window
  67.     CALL    WRITE_HEX        ;Write the new number
  68.     CALL    MOV_TO_ASCII_POSITION    ;Move to the char. in the ASCII window
  69.     CALL    WRITE_CHAR        ;Write the new character
  70.     CALL    RESTORE_REAL_CURSOR    ;Move cursor back where it belongs
  71.     CALL    WRITE_PHANTOM        ;Rewrite the phantom cursor
  72.     CALL    WRITE_TO_MEMORY        ;Save this new byte in SECTOR
  73.     LEA    DX,EDITOR_PROMPT
  74.     CALL    WRITE_PROMPT_LINE
  75.     POP    DX
  76.     RET
  77. EDIT_BYTE    ENDP
  78.  
  79.  
  80.     END
  81.