home *** CD-ROM | disk | FTP | other *** search
/ SPACE 2 / SPACE - Library 2 - Volume 1.iso / music / 194 / pascal / newdial.pas < prev    next >
Encoding:
Pascal/Delphi Source File  |  1987-11-19  |  7.4 KB  |  176 lines
  1. PROGRAM TestDialogRoutines;
  2.  
  3. { 
  4.   Replacement routines for Center_Dialog, Do_Dialog, Redo_Dialog, 
  5.   End_Dialog in Personal Pascal v 2.0, 2.01. Apparently the programmer
  6.   thought that dialogs look better without the ouline, so SOMEHOW he
  7.   chose not to display it (he probably altered the clip values in the
  8.   Obj_Draw call). He must have REALLY GONE OUT OF HIS WAY to do this!
  9.   Anyway, enough hazing. This code implements the following AES routines
  10.   as described in Abacus GEM Prog. Ref. to fix this problem: 
  11.      1. Form_Center 2. Form_Dial 3. Form_Do.
  12.   Note that Form_Dial(3,...) can force a redraw of ALL windows, including
  13.   the desktop window. Useful, for instance, when you draw a "marquee box"
  14.   by the file selector to indicate the action more definitely. If you don't
  15.   do this, and the marquee overlays a window not associated with your
  16.   program, such as an acc or desktop, it doesn't know to redraw itself. So
  17.   you can use Form_Dial(3,...) w/ the dimensions of your marquee, and it
  18.   will get the message (no pun intended). Form_Dial can be used AT ANY TIME
  19.   in this manner. These routines are probably also found in Tackle Box, 
  20.   if you have that (I don't). Incidentally, using this code IN PLACE of the
  21.   library routines shouldn't increase code size. 
  22.   
  23.   If you have any questions, I'm Doug Harrison, PPN 72277,2315.
  24. }
  25.  
  26. (*************************************************************************)
  27. (* Mandatory global declarations; change path as necessary               *) 
  28. (*************************************************************************)
  29.  
  30. {$I d:\pascal\gemsubs}
  31.  
  32. VAR
  33.     fo_x,fo_y,fo_w,fo_h,alert : INTEGER; 
  34.     button,
  35.     ok_btn,
  36.     cancel_btn,
  37.     prompt_item,
  38.     date_item           : integer ;
  39.     dialog              : Dialog_Ptr ;
  40.     int_in              : Int_In_Parms;
  41.     int_out             : Int_Out_Parms;
  42.     addr_in             : Addr_In_Parms;
  43.     addr_out            : Addr_Out_Parms;
  44.  
  45. { The following procedures can be compiled in a module, and declared as
  46.   externals in your main program, with caveats as noted }
  47.  
  48. PROCEDURE Obj_Draw ( dial                        : Dialog_Ptr; 
  49.                      index,depth,
  50.                      x_clip,y_clip,w_clip,h_clip : INTEGER     );
  51.    EXTERNAL;
  52.  
  53. FUNCTION CHANGE_PTR ( tree_ptr : Dialog_Ptr ) : Pointer;
  54.    { Note none of the new AUXSUBS routines will do this! }
  55.    VAR change : RECORD
  56.                      CASE byte OF
  57.                         1 : ( original : Dialog_Ptr );
  58.                         2 : ( final    : Pointer );
  59.                      END;
  60.    BEGIN
  61.        change.original := tree_ptr;
  62.        change_ptr := change.final
  63.    END; { CHANGE_PTR }
  64.  
  65. PROCEDURE Form_Center ( box                     : Dialog_Ptr;
  66.                         VAR fo_x,fo_y,fo_w,fo_h : INTEGER );
  67.    { Like Center_Dialog, but returns the actual screen coordinates of the
  68.      tree when drawn }                     
  69.    BEGIN
  70.        addr_in[0] := change_ptr(box);
  71.        AES_Call(54,int_in,int_out,addr_in,addr_out);
  72.        fo_x := int_out[1];
  73.        fo_y := int_out[2];
  74.        fo_w := int_out[3];
  75.        fo_h := int_out[4]
  76.    END; { Form_Center }
  77.  
  78. PROCEDURE Form_Dial ( fn,little_x,little_y,little_w,little_h,
  79.                          big_x,big_y,big_w,big_h              : INTEGER );
  80.    { fn = 0, reserve memory for window border components;
  81.      fn = 1, draw expanding zoom box;
  82.      fn = 2, draw shrinking zoom box;
  83.      fn = 3, force redraw of ALL workstations under GEM that intersect
  84.              the x,y,w,h values, which should be equal (little_x=big_x,
  85.              etc.). }
  86.    BEGIN
  87.        int_in[0] := fn;
  88.        int_in[1] := little_x;
  89.        int_in[2] := little_y;
  90.        int_in[3] := little_w;
  91.        int_in[4] := little_h;
  92.        int_in[5] := big_x;
  93.        int_in[6] := big_y;
  94.        int_in[7] := big_w;
  95.        int_in[8] := big_h;
  96.        AES_Call(51,int_in,int_out,addr_in,addr_out)
  97.    END; { Form_Dial }
  98.  
  99. FUNCTION Form_Do ( box   : Dialog_Ptr; 
  100.                    index : Tree_Index  ) : Tree_Index;
  101.    { used by FORM_BEGIN and is functionally the same as Redo_Dialog and may
  102.      be used in its place }
  103.    BEGIN
  104.        int_in[0] := index;
  105.        addr_in[0] := change_ptr(box);
  106.        AES_Call(50,int_in,int_out,addr_in,addr_out);
  107.        Form_Do := int_out[0]
  108.    END; { Form_Do }
  109.  
  110. (*************************************************************************)
  111. (*                    Interface to Pascal program                        *)
  112. (*************************************************************************)
  113.  
  114. FUNCTION FORM_BEGIN ( box   : Dialog_Ptr; 
  115.                       index : Tree_Index  ) : Tree_Index;
  116.    { Routine to replace Do_Dialog, should be part of main program. To
  117.      make this an EXTERNAL, you would have to add parms as in Form_Dial
  118.      above }
  119.    BEGIN
  120.        Hide_Mouse;
  121.        { Center the dialog, note this returns the actual x,y,w,h coords
  122.          for the box, as opposed to the OSS Center_Dialog which does not. }
  123.        Form_Center(box,fo_x,fo_y,fo_w,fo_h); 
  124.        { Now reserve some memory for window border components which may be 
  125.          overwritten }
  126.        Form_Dial(0,fo_x,fo_y,fo_w,fo_h,fo_x,fo_y,fo_w,fo_h);
  127.        { OPTIONALLY, you may use Form_Dial(1,...) here to draw the 
  128.          "zoom-box." 
  129.          In high rez, Form_Dial(1,320,200,0,0,fo_x,fo_y,fo_w,fo_h) will
  130.          zoom from the center of the screen to the form margins }
  131.        { draw the tree... }
  132.        Obj_Draw(box,Root,Max_Depth,fo_x,fo_y,fo_w,fo_h);
  133.        Show_Mouse;
  134.        { and pass control to the AES form manager }
  135.        form_begin := Form_Do(box,index)
  136.    END; { FORM_BEGIN }
  137.    
  138. PROCEDURE FORM_END;
  139.    { Same as End_Dialog, except no parms are needed.
  140.      Again can be compiled in a module as long as you pass it Form_Dial
  141.      parms }
  142.    BEGIN
  143.        Hide_Mouse;
  144.        { OPTIONALLY you may call Form_Dial(2,...) to draw the shrinking
  145.          zoom box.
  146.          In high rez, Form_Dial(2,fo_x,fo_y,fo_w,fo_h,320,200,0,0) zooms
  147.          from tree margins to the center of the screen. }
  148.        { Tell GEM I'm through and screen needs to be redrawn }   
  149.        Form_Dial(3,fo_x,fo_y,fo_w,fo_h,fo_x,fo_y,fo_w,fo_h);
  150.        Show_Mouse
  151.    END; { FORM_END }
  152.  
  153. BEGIN { main program }
  154.     IF Init_Gem >= 0 THEN BEGIN
  155.        { the following appears in the GEMDEMOS as DIALOG.PAS }
  156.        dialog := New_Dialog( 4, 0, 0, 26, 8 ) ;
  157.        prompt_item := Add_DItem( dialog, G_String, None, 2, 1, 0, 0, 0, 0 ) ;
  158.        Set_DText( dialog, prompt_item, 'Please enter the date:',
  159.                        System_Font, TE_Left ) ;
  160.        date_item := Add_DItem( dialog, G_FText, None, 2, 3, 10, 1, 0, $1180 );
  161.        Set_DEdit( dialog, date_item, '__/__/__', '999999', '090187',
  162.                        System_Font, TE_Center ) ;
  163.        ok_btn := Add_DItem( dialog, G_Button, Selectable|Exit_Btn|Default,
  164.                        2, 5, 8, 2, 2, $1180 ) ;
  165.        Set_DText( dialog, ok_btn, 'OK', System_Font, TE_Center ) ;
  166.        cancel_btn := Add_DItem( dialog, G_Button, Selectable|Exit_Btn,
  167.                        16, 5, 8, 2, 2, $1180 ) ;
  168.        Set_DText( dialog, cancel_btn, 'Cancel', System_Font, TE_Center ) ;
  169.        button := form_begin(dialog,date_item) ; { = Do_Dialog }
  170.        Obj_SetState(dialog,button,Normal,TRUE);
  171.        alert := Do_Alert('[1][Now I''ll use Form_Do.][ OK ]',1);
  172.        button := Form_Do(dialog,date_item); { = Redo_Dialog }
  173.        Exit_Gem
  174.     END
  175. END.       
  176.