home *** CD-ROM | disk | FTP | other *** search
/ Set of Apple II Hard Drive Images / eric.hdv / ANNMIDI / MAKECONCERT.bas < prev    next >
BASIC Source File  |  2020-08-13  |  2KB  |  47 lines
  1. 1  HOME : PRINT "READING /MIDI DIRECTORY...": PRINT 
  2. 5  DIM F$(50),LI(50)
  3. 10 D$ =  CHR$(4)
  4. 15  ONERR  GOTO 100
  5. 20  PRINT D$"OPEN /MIDI,TDIR"
  6. 25  PRINT D$"READ /MIDI"
  7. 30  INPUT L$
  8. 33  IF  MID$ (L$,18,3) < >"$D7"  THEN 50
  9. 35 F$ =  MID$ (L$,2,15)
  10. 40 W =  LEN(F$)
  11. 41  IF  MID$ (F$,W,1) = " "  THEN W = W -1: GOTO 41
  12. 42 F$ =  LEFT$(F$,W)
  13. 45 F$(I) = F$:I = I +1
  14. 50  GOTO 30
  15. 100  PRINT D$"CLOSE"
  16. 101  POKE 216,0
  17. 110  FOR J = 0 TO I -1
  18. 120  PRINT J +1;") ";F$(J)
  19. 130  NEXT 
  20. 140  PRINT : PRINT "SELECT SONGS (TYPE 0 WHEN DONE)"
  21. 200 N = 0
  22. 210  INPUT CH
  23. 220  IF CH = 0  THEN 300
  24. 230  IF CH >I  THEN  PRINT "TOO BIG": GOTO 210
  25. 240 N = N +1:LI(N) = CH -1
  26. 250  GOTO 210
  27. 300  IF N = 0  THEN 999
  28. 305  PRINT : PRINT "YOUR SELECTIONS ARE:": PRINT 
  29. 310  FOR K = 1 TO N: PRINT F$(LI(K)): NEXT 
  30. 315  PRINT 
  31. 320  INPUT "IS THIS CORRECT (Y/N):";Y$: IF  LEFT$(Y$,1) < >"Y"  AND  LEFT$(Y$,1) < >"y"  THEN 200
  32. 330  INPUT "ENTER OPTION STRING:";OP$
  33. 340  INPUT "PLAY CONCERT NOW (Y/N):";CO$:CN = 1
  34. 350  IF  LEFT$(CO$,1) < >"Y"  AND  LEFT$(CO$,1) < >"y"  THEN CN = 0
  35. 400  PRINT  CHR$(4)"OPEN CONCERT,D1": PRINT  CHR$(4)"CLOSE": PRINT  CHR$(4)"DELETE CONCERT,D1"
  36. 410  PRINT  CHR$(4)"OPEN CONCERT,D1": PRINT  CHR$(4)"WRITE CONCERT"
  37. 420  PRINT "-INT0PLAY.BAS,D1"
  38. 430  FOR K = 1 TO N
  39. 440  PRINT F$(LI(K))
  40. 450  PRINT OP$
  41. 460  IF K <N  THEN  PRINT "Y"
  42. 470  IF K = N  THEN  PRINT "N"
  43. 480  NEXT K
  44. 490  PRINT  CHR$(4)"CLOSE CONCERT"
  45. 500  IF CN = 0  THEN  PRINT "OK, TYPE -CONCERT TO PLAY IT YOURSELF": GOTO 999
  46. 520  PRINT  CHR$(4)"-CONCERT,D1"
  47. 999  END