home *** CD-ROM | disk | FTP | other *** search
/ Sams Cobol 24 Hours / Sams_Cobol_24_Hours.iso / source / ch15 / chapt15a.cob next >
Text File  |  1998-10-05  |  6KB  |  128 lines
  1. 000010 @OPTIONS MAIN,TEST
  2. 000020 Identification Division.
  3. 000030 Program-Id.  Chapt15a.
  4. 000031* Sequentially Read An Indexed File
  5. 000041 Environment Division.
  6. 000050 Configuration Section.
  7. 000051 Source-Computer.  IBM-PC.
  8. 000055 Object-Computer.  IBM-PC.
  9. 000056 Input-Output Section.
  10. 000057 File-Control.
  11. 000058     Select Dealer-File Assign To "Dealer.Dat"
  12. 000059            Organization Indexed
  13. 000060            Access Sequential
  14. 000061            Record Key Dealer-Number
  15. 000062            Alternate Record Key Dealer-Name
  16. 000063            File Status Dealer-Status.
  17. 000065 Data Division.
  18. 000066 File Section.
  19. 000067 Fd  Dealer-File.
  20. 000068 01  Dealer-Record.
  21. 000069     03  Dealer-Number         Pic X(8).
  22. 000070     03  Dealer-Name.
  23. 000071         05  Last-Name   Pic X(25).
  24. 000072         05  First-Name  Pic X(15).
  25. 000073         05  Middle-Name Pic X(10).
  26. 000083     03  Address-Line-1      Pic X(50).
  27. 000085     03  Address-Line-2      Pic X(50).
  28. 000086     03  City                Pic X(40).
  29. 000087     03  State-Or-Country    Pic X(20).
  30. 000088     03  Postal-Code         Pic X(15).
  31. 000089     03  Home-Phone          Pic X(20).
  32. 000090     03  Work-Phone          Pic X(20).
  33. 000091     03  Other-Phone         Pic X(20).
  34. 000092     03  Start-Date          Pic 9(8).
  35. 000093     03  Last-Rent-Paid-Date Pic 9(8).
  36. 000094     03  Next-Rent-Due-Date  Pic 9(8).
  37. 000095     03  Rent-Amount         Pic 9(4)v99.
  38. 000096     03  Consignment-Percent Pic 9(3).
  39. 000097     03  Filler              Pic X(50).
  40. 000098 Working-Storage Section.
  41. 000116 01  Dealer-Status     Pic X(2) Value Spaces.
  42. 000240     88  Dealer-Success Value "00".
  43. 000276 01  Show-Next-Record  Pic X Value "Y".
  44. 000277 01  Process-Flag      Pic X Value Spaces.
  45. 000278     88  End-Process   Value "Y".
  46. 000279 Screen Section.
  47. 000321 01  Data-Entry-Screen
  48. 000322     Blank Screen, Auto
  49. 000323     Foreground-Color Is 7,
  50. 000324     Background-Color Is 1.
  51. 000325*
  52. 000326     03  Screen-Literal-Group.
  53. 000327         05  Line 01 Column 30 Value "Darlene's Treasures"
  54. 000328             Highlight Foreground-Color 4 Background-Color 1.
  55. 000329         05  Line 03 Column 30 Value "Tenant Display Program"
  56. 000330             Highlight.
  57. 000331         05  Line 4  Column 01  Value "Number: ".
  58. 000332         05  Line 5  Column 01  Value "Name, Last: ".
  59. 000333         05  Line 5  Column 39  Value "First: ".
  60. 000334         05  Line 5  Column 62  Value "Middle: ".
  61. 000335         05  Line 6  Column 01  Value "Address 1: ".
  62. 000336         05  Line 7  Column 01  Value "Address 2: ".
  63. 000337         05  Line 8  Column 01  Value "City: ".
  64. 000338         05  Line 9  Column 01  Value "Country/State: ".
  65. 000339         05  Line 9  Column 36  Value "Postal Code: ".
  66. 000340         05  Line 11 Column 01  Value "Phone/Home: ".
  67. 000341         05  Line 11 Column 34  Value "Work: ".
  68. 000342         05  Line 12 Column 06  Value "Other: ".
  69. 000343         05  Line 14 Column 01  Value "Start Date: ".
  70. 000344         05  Line 14 Column 24  Value "Last Paid Date: ".
  71. 000345         05  Line 14 Column 51  Value "Next Rent Due on: ".
  72. 000346         05  Line 15 Column 01  Value "Rent Amount: ".
  73. 000348         05  Line 16 Column 01  Value "Consignment Percent: ".
  74. 000349         05  Line 22 Column 01
  75. 000350             Value "Display next Record? (Y/N):".
  76. 000351*
  77. 000352     03  Required-Reverse-Group Reverse-Video.
  78. 000353         05  Line 4 Column 13  Pic X(8)  From Dealer-Number.
  79. 000354         05  Line 5 Column 13  Pic X(25) From Last-Name.
  80. 000355         05  Line 5 Column 46  Pic X(15) From First-Name.
  81. 000356         05  Line 5  Column 70 Pic X(10) From Middle-Name.
  82. 000359         05  Line 6  Column 15 Pic X(50) From Address-Line-1.
  83. 000361         05  Line 7  Column 15 Pic X(50) From Address-Line-2.
  84. 000363         05  Line 8  Column 15 Pic X(40) From City.
  85. 000365         05  Line 9  Column 15 Pic X(20) From State-Or-Country.
  86. 000367         05  Line 9  Column 50 Pic X(15) From Postal-Code.
  87. 000369         05  Line 11 Column 13 Pic X(20) From Home-Phone.
  88. 000371         05  Line 11 Column 41 Pic X(20) From Work-Phone.
  89. 000373         05  Line 12 Column 13 Pic X(20) From Other-Phone.
  90. 000375         05  Line 14 Column 13 Pic 99/99/9999 From Start-Date.
  91. 000377         05  Line 14 Column 40 Pic 99/99/9999
  92. 000378             From Last-Rent-Paid-Date.
  93. 000379         05  Line 14 Column 69 Pic 99/99/9999
  94. 000380             From Next-Rent-Due-Date.
  95. 000381         05  Line 15 Column 14 Pic Z,ZZZ.99 From Rent-Amount.
  96. 000382         05  Line 16 Column 22 Pic ZZ9 From Consignment-Percent.
  97. 000383         05  Line 22 Column 29 Pic X Using Show-Next-Record.
  98. 000386*
  99. 000387
  100. 000388 Procedure Division.
  101. 000389 Chapt15a-Start.
  102. 000408     Perform Open-File
  103. 000411     If Dealer-Success
  104. 000412        Perform Process-Screen Until Show-Next-Record = "N" Or
  105. 000413                                     Show-Next-Record = "n" Or
  106. 000414                                     End-Process
  107. 000415        Perform Close-File
  108. 000416     End-If
  109. 000417     Stop Run
  110. 000418     .
  111. 000419  Process-Screen.
  112. 000420     Read Dealer-File
  113. 000421       At End Set End-Process To True
  114. 000422       Not At End
  115. 000423           Perform Display-And-Accept
  116. 000424     End-Read
  117. 000425     .
  118. 000451 Display-And-Accept.
  119. 000452     Display Data-Entry-Screen
  120. 000453     Accept Data-Entry-Screen
  121. 000456     .
  122. 000457 Open-File.
  123. 000458     Open Input Dealer-File
  124. 000459     .
  125. 000460 Close-File.
  126. 000461     Close Dealer-File
  127. 000462     .
  128.