home *** CD-ROM | disk | FTP | other *** search
/ Sams Cobol 24 Hours / Sams_Cobol_24_Hours.iso / source / ch14 / CHAPT14B.COB < prev    next >
Text File  |  1998-09-14  |  8KB  |  200 lines
  1. 000010 @OPTIONS MAIN,TEST
  2. 000020 Identification Division.
  3. 000030 Program-Id.  Chapt14b.
  4. 000031* Dealer Data Entry
  5. 000041 Environment Division.
  6. 000050 Configuration Section.
  7. 000051 Special-Names.
  8. 000052       Crt Status Is Keyboard-Status
  9. 000053       Cursor Is Cursor-Position.
  10. 000054 Source-Computer.  IBM-PC.
  11. 000055 Object-Computer.  IBM-PC.
  12. 000056 Input-Output Section.
  13. 000057 File-Control.
  14. 000058     Select Dealer-File Assign To "Dealer.Dat"
  15. 000059            Organization Indexed
  16. 000060            Access Sequential
  17. 000061            Record Key Dealer-Number Of Dealer-Record
  18. 000062            Alternate Record Key Dealer-Name Of Dealer-Record
  19. 000063            File Status Dealer-Status.
  20. 000065 Data Division.
  21. 000066 File Section.
  22. 000067 Fd  Dealer-File.
  23. 000068 01  Dealer-Record.
  24. 000069     03  Dealer-Number         Pic X(8).
  25. 000070     03  Dealer-Name.
  26. 000071         05  Last-Name   Pic X(25).
  27. 000072         05  First-Name  Pic X(15).
  28. 000073         05  Middle-Name Pic X(10).
  29. 000083     03  Address-Line-1      Pic X(50).
  30. 000085     03  Address-Line-2      Pic X(50).
  31. 000086     03  City                Pic X(40).
  32. 000087     03  State-Or-Country    Pic X(20).
  33. 000088     03  Postal-Code         Pic X(15).
  34. 000089     03  Home-Phone          Pic X(20).
  35. 000090     03  Work-Phone          Pic X(20).
  36. 000091     03  Other-Phone         Pic X(20).
  37. 000092     03  Start-Date          Pic 9(8).
  38. 000093     03  Last-Rent-Paid-Date Pic 9(8).
  39. 000094     03  Next-Rent-Due-Date  Pic 9(8).
  40. 000095     03  Rent-Amount         Pic 9(4)v99.
  41. 000096     03  Consignment-Percent Pic 9(3).
  42. 000097     03  Filler              Pic X(50).
  43. 000098 Working-Storage Section.
  44. 000099 01  Keyboard-Status.
  45. 000100     03  Accept-Status Pic 9.
  46. 000101     03  Function-Key  Pic X.
  47. 000102         88  F1-Pressed Value X"01".
  48. 000103         88  F2-Pressed Value X"02".
  49. 000104     03  System-Use    Pic X.
  50. 000105 01  Cursor-Position.
  51. 000106     03  Cursor-Row    Pic 9(2) Value 1.
  52. 000107     03  Cursor-Column Pic 9(2) Value 1.
  53. 000116 01  Dealer-Status     Pic X(2) Value Spaces.
  54. 000240     88  Dealer-Success Value "00".
  55. 000250 01  Error-Message     Pic X(60) Value Spaces.
  56. 000251 01  Open-Error.
  57. 000252     03  Filler        Pic X(26)
  58. 000253         Value "Error Opening Dealer File ".
  59. 000254     03  Open-Error-Status  Pic X(2).
  60. 000255 01  Write-Error.
  61. 000256     03  Filler        Pic X(26)
  62. 000257         Value "Error Writing Dealer File ".
  63. 000258     03  Write-Error-Status Pic X(2).
  64. 000259 01  Work-Record.
  65. 000260     03  Dealer-Number         Pic X(8).
  66. 000261     03  Dealer-Name.
  67. 000262         05  Last-Name   Pic X(25).
  68. 000263         05  First-Name  Pic X(15).
  69. 000264         05  Middle-Name Pic X(10).
  70. 000265     03  Address-Line-1      Pic X(50).
  71. 000266     03  Address-Line-2      Pic X(50).
  72. 000267     03  City                Pic X(40).
  73. 000268     03  State-Or-Country    Pic X(20).
  74. 000269     03  Postal-Code         Pic X(15).
  75. 000270     03  Home-Phone          Pic X(20).
  76. 000271     03  Work-Phone          Pic X(20).
  77. 000272     03  Other-Phone         Pic X(20).
  78. 000273     03  Start-Date          Pic 9(8).
  79. 000274     03  Last-Rent-Paid-Date Pic 9(8).
  80. 000275     03  Next-Rent-Due-Date  Pic 9(8).
  81. 000276     03  Rent-Amount         Pic 9(4)v99.
  82. 000277     03  Consignment-Percent Pic 9(3).
  83. 000278
  84. 000279 Screen Section.
  85. 000321 01  Data-Entry-Screen
  86. 000322     Blank Screen, Auto
  87. 000323     Foreground-Color Is 7,
  88. 000324     Background-Color Is 1.
  89. 000325*
  90. 000326     03  Screen-Literal-Group.
  91. 000327         05  Line 01 Column 30 Value "Darlene's Treasures"
  92. 000328             Highlight Foreground-Color 4 Background-Color 1.
  93. 000329         05  Line 03 Column 30 Value "Tenant Entry Program"
  94. 000330             Highlight.
  95. 000331         05  Line 4  Column 01  Value "Number: ".
  96. 000332         05  Line 5  Column 01  Value "Name, Last: ".
  97. 000333         05  Line 5  Column 39  Value "First: ".
  98. 000334         05  Line 5  Column 62  Value "Middle: ".
  99. 000335         05  Line 6  Column 01  Value "Address 1: ".
  100. 000336         05  Line 7  Column 01  Value "Address 2: ".
  101. 000337         05  Line 8  Column 01  Value "City: ".
  102. 000338         05  Line 9  Column 01  Value "Country/State: ".
  103. 000339         05  Line 9  Column 36  Value "Postal Code: ".
  104. 000340         05  Line 11 Column 01  Value "Phone/Home: ".
  105. 000341         05  Line 11 Column 34  Value "Work: ".
  106. 000342         05  Line 12 Column 06  Value "Other: ".
  107. 000343         05  Line 14 Column 01  Value "Start Date: ".
  108. 000344         05  Line 14 Column 24  Value "Last Paid Date: ".
  109. 000345         05  Line 14 Column 51  Value "Next Rent Due on: ".
  110. 000346         05  Line 15 Column 01  Value "Rent Amount: ".
  111. 000347         05  Line 16 Column 01  Value "Consignment Percent: ".
  112. 000348         05  Line 22 Column 01  Value "F1-Exit    F2-Save".
  113. 000349*
  114. 000350     03  Required-Reverse-Group Reverse-Video Required.
  115. 000351         05  Line 4 Column 13  Pic X(8)  Using Dealer-Number
  116. 000352             Of Work-Record.
  117. 000353         05  Line 5 Column 13  Pic X(25) Using Last-Name
  118. 000354             Of Work-Record.
  119. 000355         05  Line 5 Column 46  Pic X(15) Using First-Name
  120. 000356             Of Work-Record.
  121. 000357*
  122. 000358     03  Reverse-Video-Group Reverse-Video.
  123. 000359         05  Line 5  Column 70 Pic X(10) Using Middle-Name
  124. 000360             Of Work-Record.
  125. 000361         05  Line 6  Column 15 Pic X(50) Using Address-Line-1
  126. 000362             Of Work-Record.
  127. 000363         05  Line 7  Column 15 Pic X(50) Using Address-Line-2
  128. 000364             Of Work-Record.
  129. 000365         05  Line 8  Column 15 Pic X(40) Using City
  130. 000366             Of Work-Record.
  131. 000367         05  Line 9  Column 15 Pic X(20) Using State-Or-Country
  132. 000368             Of Work-Record.
  133. 000369         05  Line 9  Column 50 Pic X(15) Using Postal-Code
  134. 000370             Of Work-Record.
  135. 000371         05  Line 11 Column 13 Pic X(20) Using Home-Phone
  136. 000372             Of Work-Record.
  137. 000373         05  Line 11 Column 41 Pic X(20) Using Work-Phone
  138. 000374             Of Work-Record.
  139. 000375         05  Line 12 Column 13 Pic X(20) Using Other-Phone
  140. 000376             Of Work-Record.
  141. 000377         05  Line 14 Column 13 Pic 99/99/9999 Using Start-Date
  142. 000378             Of Work-Record.
  143. 000379         05  Line 14 Column 40 Pic 99/99/9999
  144. 000380             Using Last-Rent-Paid-Date Of Work-Record.
  145. 000382         05  Line 14 Column 69 Pic 99/99/9999
  146. 000383             Using Next-Rent-Due-Date Of Work-Record.
  147. 000385         05  Line 15 Column 14 Pic Z,ZZZ.99 Using Rent-Amount
  148. 000386             Of Work-Record.
  149. 000387         05  Line 16 Column 22 Pic ZZ9 Using Consignment-Percent
  150. 000388             Of Work-Record.
  151. 000389     03  Blink-Group Highlight Blink.
  152. 000390         05  Line 20 Column 01 Pic X(60) From Error-Message.
  153. 000391*
  154. 000392
  155. 000393 Procedure Division.
  156. 000394 Chapt14b-Start.
  157. 000395     Perform Open-File
  158. 000396     If Dealer-Success
  159. 000397        Initialize Work-Record
  160. 000398        Perform Process-Screen Until F1-Pressed Or
  161. 000399                                 Not Dealer-Success
  162. 000400        Perform Close-File
  163. 000401     End-If
  164. 000402     Stop Run
  165. 000403     .
  166. 000404  Process-Screen.
  167. 000405     Display Data-Entry-Screen
  168. 000406     Accept Data-Entry-Screen
  169. 000407     If F2-Pressed
  170. 000408        Perform Save-Record
  171. 000409     End-If
  172. 000410     .
  173. 000411 Save-Record.
  174. 000412     Move Corresponding Work-Record To Dealer-Record
  175. 000413     Write Dealer-Record
  176. 000414     If Not Dealer-Success
  177. 000415        Move Dealer-Status To Write-Error-Status
  178. 000416        Move Write-Error To Error-Message
  179. 000417        Perform Display-And-Accept-Error
  180. 000418     Else
  181. 000419        Initialize Work-Record
  182. 000420        Move 1 To Cursor-Row
  183. 000421                  Cursor-Column
  184. 000422     End-If
  185. 000423     .
  186. 000424 Open-File.
  187. 000425     Open Output Dealer-File
  188. 000426     If Not Dealer-Success
  189. 000427        Move Dealer-Status To Open-Error-Status
  190. 000428        Move Open-Error To Error-Message
  191. 000429        Perform Display-And-Accept-Error
  192. 000430     End-If
  193. 000431     .
  194. 000432 Close-File.
  195. 000433     Close Dealer-File
  196. 000434     .
  197. 000435 Display-And-Accept-Error.
  198. 000436     Display Data-Entry-Screen
  199. 000437     Accept Data-Entry-Screen
  200. 000438     .