home *** CD-ROM | disk | FTP | other *** search
/ Power Programming / powerprogramming1994.iso / progtool / pctech / pctj1188.arc / SPLITSCR.ASM < prev    next >
Assembly Source File  |  1988-09-06  |  4KB  |  101 lines
  1. ; Microsoft C: 
  2. ;       void SplitScreen( n ); 
  3. ;               int     n;      /* scan line at which */ 
  4. ;                               /*  to split screen */ 
  5. ; 
  6.  
  7.  
  8. _TEXT           SEGMENT byte public 'CODE' 
  9.                 ASSUME  cs:_TEXT 
  10.  
  11.                 PUBLIC  _SplitScreen 
  12. _SplitScreen    PROC    near 
  13.  
  14.                 push    bp              ; preserve BP 
  15.                 mov     bp,sp 
  16.  
  17.                 mov     ax,40h 
  18.                 mov     es,ax           ; ES -> video BIOS data area 
  19.                 mov     dx,es:[63h]     ; DX = port for CRTC index reg 
  20.  
  21. ; wait for vertical retrace 
  22.  
  23.                 add     dl,6            ; DX = 3BAH or 3DAH (CRT status port) 
  24. L01:            in      al,dx           ; wait for end of vertical retrace 
  25.                 test    al,8 
  26.                 jnz     L01 
  27.  
  28. L02:            in      al,dx           ; wait for start of vertical retrace 
  29.                 test    al,8 
  30.                 jz      L02 
  31.                 sub     dl,6            ; DX = port for CRTC index reg 
  32.  
  33. ; isolate bits 0-7, bit 8, and bit 9 of the Line Compare value 
  34.  
  35.                 mov     ax,[bp+4]       ; AX = scan line value 
  36.                 mov     bh,ah           ; BH bits 0-1 = bits 8-9 of 
  37.                                         ;  Line Compare value 
  38.                  
  39.                 mov     bl,bh 
  40.                 and     bx,0201h        ; BH bit 1 = Line Compare bit 9 
  41.                                         ; BL bit 0 = Line Compare bit 0 
  42.  
  43.                 mov     cl,4 
  44.                 shl     bx,cl           ; BH bit 5 = Line Compare bit 9 
  45.                                         ; BL bit 4 = Line Compare bit 8 
  46.                 shl     bh,1            ; BH bit 6 = Line Compare bit 9 
  47.  
  48. ; update the CRTC registers 
  49.  
  50.                 mov     ah,al           ; AH = low-order 8 bits of value 
  51.                 mov     al,18h          ; AL = Line Compare register number 
  52.                 out     dx,ax           ; update Line Compare register 
  53.  
  54.                 mov     al,7            ; AL = Overflow register number 
  55.                 cli 
  56.                 out     dx,al 
  57.                 inc     dx 
  58.                 in      al,dx           ; AL = current Overflow reg value 
  59.                 sti 
  60.                 dec     dx 
  61.  
  62.                 mov     ah,al 
  63.                 and     ah,11101111b    ; AH bit 4 = 0 
  64.                 or      ah,bl           ; AH bit 4 = Line Compare bit 8 
  65.                 mov     al,7            ; AL = Overflow register number 
  66.                 out     dx,ax           ; update Overflow register 
  67.  
  68.                 mov     al,9            ; AL = Max Scan Line register number 
  69.                 cli 
  70.                 out     dx,al 
  71.                 inc     dx 
  72.                 in      al,dx           ; AL = current Max Scan Line reg value 
  73.                 sti 
  74.                 dec     dx 
  75.  
  76.                 mov     ah,al 
  77.                 and     ah,10111111b    ; AH bit 6 = 0 
  78.                 or      ah,bh           ; AH bit 6 = Line Compare bit 9 
  79.                 mov     al,9            ; AL = Max Scan Line reg number 
  80.                 out     dx,ax           ; update Max Scan Line register 
  81.  
  82. ; set bit 5 of the Attribute Controller Mode Control register 
  83.  
  84.                 mov     ax,1007h        ; AH = 10h (int 10H function number) 
  85.                                         ; AL = 7 (subfunction number) 
  86.                 mov     bl,10h          ; BL = Mode Control reg number 
  87.                 int     10h             ; BH = Mode Control reg value 
  88.                 or      bh,20h          ; set bit 5 
  89.  
  90.                 mov     ax,1000h        ; AH = 10h 
  91.                                         ; AL = 0 
  92.                 mov     bl,10h 
  93.                 int     10h             ; update Mode Control register 
  94.  
  95.                 pop     bp              ; restore BP and exit 
  96.                 ret 
  97.  
  98. _SplitScreen    ENDP 
  99.  
  100. _TEXT           ENDS 
  101.