home *** CD-ROM | disk | FTP | other *** search
/ Power Programming / powerprogramming1994.iso / progtool / ega / egaepsn1.arc / EPSON.ASM next >
Assembly Source File  |  1989-10-28  |  15KB  |  579 lines
  1.     page    60,132
  2.     title Graphics Module for Print Screen with the EGA
  3. Epson    segment para public 'code'
  4.     assume CS:Epson,DS:Epson,ES:Epson
  5.  
  6. comment #
  7.  
  8. This routine is for public domain for those of you who bought an
  9. EGA and enhanced monitor and determined that you could no longer
  10. do a Shf_Prt_Scn in mode 10h (16).  If you have an IBM compatible
  11. and an Epson FX series printer then this routine will replace the
  12. Graphics.com routine. I also have routines for Radio Shack DMP 
  13. printers with 8 pins (but only 7 usable for graphics) and for HP
  14. LaserJet printers when used with an EGA. Enjoy...
  15.  
  16. Dr. R. Brooks Van Horn, Jr.
  17. 701 Fall Place
  18. Herndon, VA. 22070
  19.  
  20. Toad Hall tweak:
  21.     Made "proper" near and far procedures so this would
  22.     compile under MASM 5.0
  23.     (Kept getting an "IP NOT 0" error when converting from
  24.     .EXE to .COM.)
  25.     Tabified, formatted to a "proper" .ASM file.
  26.  
  27.     Original .COM program was weird .. had an extra 100 bytes
  28.     of miscellaneous code at the end (some sort of compiled
  29.     C math routines from the looks of it).  Suspicion was
  30.     a virus appended to original code, but no such thing.
  31.     Dr Van Horn has a VERY weird compiler/linker/exe2bin
  32.     package!
  33.     So .. I just recompiled with MASM .. and got the same
  34.     size as his (with the garbage stripped off the end).
  35.     What we have now is a clean EPSON.COM and source that'll
  36.     compile, link, etc. with MASM, LINK, and several EXE2COM
  37.     converters.
  38.  
  39.     This code is in MAJOR need of a rewrite.  Almost ALL the
  40.     segment overrides are unnecessary, and more.
  41.     I'm almost done with a rewrite, but (1) I can't test it
  42.     (no EGA card or graphics printer) and (2) My hack broke
  43.     the code!  Maybe one of these days.
  44.  
  45. David Kirschbaum
  46. Toad Hall
  47. kirsch@arsocomvax.socom.mil
  48. #
  49.  
  50. CSEG    SEGMENT PUBLIC PARA 'CODE'
  51.     ASSUME    CS:CSEG, DS:CSEG, ES:CSEG
  52.  
  53.     ORG    100H
  54.  
  55. Epson    proc    near
  56.     jmp    Setup
  57.  
  58. Mlen    db    'EGA Graphics Ver 1.0'
  59. Cmp_Str    dw    $-mlen
  60. Epson    endp
  61.  
  62. ;    normal int 5 entry point
  63.  
  64. Begin    proc    far
  65.     pushf            ; enable further interrupts
  66.     push    ax
  67.     push    bx
  68.     push    bp
  69.     push    di
  70.     push    si
  71.     mov    ah,15        ; setup a function call to dos to
  72.     int    10h        ; get the video mode
  73.     and    ax,007fh    ; mask off unwanted data
  74.     mov    CS:[mode],ax    ; and save it for future use
  75.     cmp    al,7        ; is this a mono card?
  76.     jz    Go_Out        ; yes, exit - when in text mode
  77.      cmp    al,3         ; see if we are in the graphics mode?
  78.      jg    Cont         ; yes, go around using dos
  79. Go_Out:    pop    si        ; restore the registers saved
  80.     pop    di
  81.     pop    bp
  82.     pop    bx
  83.     pop    ax
  84.     popf
  85. ;-----    jump far to Dos
  86.     db    0EAh        ; jump far segment to Print
  87. dos    dw    0        ; offset of jump
  88. dos2    dw    0        ; segment of jump
  89.  
  90. Cont:    push    cx            ; and save all the registers
  91.     push    dx
  92.     push    DS
  93.     push    ES
  94.     push    CS            ; now put code seg register into
  95.     pop    ES            ; the extra segment register
  96.     xor    ax,ax
  97.     mov    DS,ax
  98.     inc    al            ; see if we are already being done
  99.     mov    al,Byte Ptr DS:[500h]    ; get the current mode and also set it
  100.     or    al,al
  101.     jnz    Getout            ; if 550h was not zero then exit
  102.     push    CS
  103.     pop    DS
  104.     xchg    al,Byte Ptr CS:switch
  105.     or    al,al
  106.     jnz    GetOut
  107.      sti
  108.      mov    CS:[sp_save],sp
  109.      jmp    Process
  110.  
  111. Return:    mov    si,Offset restore
  112.     mov    cl,CS:[si]        ; get number of bytes to print
  113.     xor    ch,ch
  114.     inc    si
  115.     call    Tabptr            ; restore printer to original state
  116. Exit:    mov    sp,CS:[sp_save]
  117.     xor    ax,ax
  118.     mov    Byte Ptr CS:switch,al    ; set value to zero
  119. Getout:    pop    ES            ; restore registers and exit
  120.     pop    DS
  121.     pop    dx
  122.     pop    cx
  123.     pop    si
  124.     pop    di
  125.     pop    bp
  126.     pop    bx
  127.     pop    ax
  128.     popf
  129.     sti
  130.     iret        ; bye...............
  131. Begin    endp
  132.  
  133. ;--------------------------------------------------------------------
  134. ;    Epson FX Printer with IBM-PC
  135. ;--------------------------------------------------------------------
  136. line_sp    db    3,27,51,24    ; Control Codes for 24/216" line spacing
  137. set_graf db    4,27,76        ; Cntrl Code for each graphics line printed
  138. col_2_do dw    0        ; last column number to be printed
  139. restore  db    2,27,48,12    ; change count to 3 if you want a form feed
  140.  
  141. line_buf db    960 dup (?)    ; line buffer
  142. eight    dw    8
  143. four    dw    4
  144. switch    db    0
  145. sp_save    dw    0
  146. mode    dw    0        ; Current Video Mode
  147. rows    dw    0        ; Number of rows for this mode
  148. cols    dw    0        ; Number of columns for this mode
  149.  
  150. ;    Modes =   4   5   6   7   8   9   A   B   C   D   E   F  10
  151. col_mode dw    320,320,640,  0,  0,320,640,  0,720,320,640,640,640
  152. row_mode dw    200,200,200,  0,  0,200,200,  0,348,200,200,350,350
  153.  
  154. ;--------------------------------------------------------------------
  155.  
  156. ;    Print a Table of Control Values
  157. ;    ===============================
  158. ;
  159. Tabptr    proc    near
  160.     mov    al,CS:[si]
  161.     call    Printer
  162.     inc    si
  163.     loop    Tabptr
  164.     nop
  165.     ret
  166. Tabptr    endp
  167.  
  168. ;
  169. ;    Send an alarm bell sound
  170. ;    ========================
  171. ;
  172. Bell    proc    near
  173.     mov    al,7
  174.     mov    ah,14
  175.     int    10h
  176.     ret
  177. Bell    endp
  178.  
  179. ;    Send the character in AL to the printer
  180. ;    =======================================
  181. ;
  182. Printer    proc    near
  183.     push    dx
  184.     sub    dx,dx
  185.     xor    ah,ah
  186.     int    17h
  187.     pop    dx
  188.     test    ah,25h
  189.     jnz    Error
  190.     ret
  191. Printer    endp
  192.  
  193. ;
  194. ;    Error returns on printer commands
  195. ;    =================================
  196. ; 
  197. Error    proc    near
  198.     call    Bell
  199.     call    Bell
  200.     jmp    Exit
  201. Error    endp
  202. ;
  203. ;    Send a form feed to the Printer
  204. ;    ===============================
  205. ;
  206. Cr_Lf    proc    near
  207.     push    dx
  208.     sub    dx,dx
  209.     mov    ax,0dh
  210.     int    17h
  211.     mov    ax,0ah
  212.     int    17h
  213.     pop    dx
  214.     test    ah,25h
  215.     jnz    Error
  216.     ret
  217. Cr_Lf    endp
  218.  
  219. ;---------------------------------------------------------------------
  220. ;
  221. ;        Graphics Processing Section
  222. ;
  223. ;---------------------------------------------------------------------
  224.  
  225. Process    proc    near
  226.     mov    bp,CS:[mode]
  227.     sub    bp,4
  228.     sal    bp,1
  229.  
  230.     mov    ax,CS:row_mode[bp]    ; save rows-1 and cols-1
  231.     dec    ax
  232.     mov    CS:rows,ax
  233.     mov    ax,CS:col_mode[bp]
  234.     dec    ax
  235.     mov    CS:cols,ax
  236.  
  237.     mov    ah,1            ; initialize the printer
  238.     xor    dx,dx
  239.     int    17h
  240.  
  241.     mov    si,Offset CS:line_sp    ; setup for correct interline spacing
  242.     mov    cl,CS:[si]        ; get length
  243.     xor    ch,ch
  244.     inc    si
  245.     call    TabPtr
  246.     
  247.     mov    ax,CS:[cols]    ; decide to do graphics by row or column mode
  248.     cmp    ax,320
  249.     jg    By_Rows
  250.      jmp    By_Cols
  251.  
  252. ;--------------------------------------------------------------------
  253. ;    for By_Rows calls we have usually 640 x 200 type, so do 200
  254. ;    across and 640 down the page.  This means that we can only 
  255. ;    single dot to get lines to connect on the printer paper.
  256. ;--------------------------------------------------------------------
  257.  
  258. By_Rows: mov    cx,0            ; start the column index at zero
  259.  
  260. Br_Strt:
  261.     push    cx            ; save the current column index
  262.     mov    dx,CS:[rows]        ; initialize the row count to max
  263.     mov    bh,Byte Ptr CS:[eight]
  264.     xor    si,si            ; max characters to print
  265.     mov    CS:[col_2_do],si
  266.     mov    di,Offset CS:line_buf
  267.     xor    bl,bl
  268.  
  269. ;    do for a count of 'Eight'
  270.  
  271. Br_Cont:
  272.     call    Read            ; read the next dot at (row,col)
  273.     and    al,07fh            ; check if any thing is there
  274.     jz    Br_Fill            ; and skip if nothing there
  275.      mov    al,1            ; else fill the byte 
  276. Br_Fill: shl    bl,1            ; move reg left one bit 
  277.     or    bl,al            ; and or in the next value
  278.     inc    cx            ; increment the column count
  279.     dec    bh            ; and the loop index
  280.     jnz    Br_Cont            ; continue loop for 8 times
  281.  
  282. ;    undo
  283.  
  284.     add    si,2            ; add two to the column counter
  285.     mov    Byte Ptr CS:[di],bl    ; save filled byte
  286.     mov    Byte Ptr CS:[di+1],bl    ; twice for filling
  287.     cmp    CS:[rows],199        ; check for less than 200 rows
  288.     jg    Br_Two
  289.      mov    Byte Ptr CS:[di+2],bl    ; and 3 times for low resolution
  290.      inc    di
  291.      inc    si
  292. Br_Two:    add    di,2            ; up the buffer ptr
  293.     or    bl,bl            ; do we have anything to print?
  294.     jz    Br_Skp            ; no, skip
  295.  
  296.      mov    CS:[col_2_do],si    ; save index
  297.  
  298. Br_Skp:    mov    bh,Byte Ptr CS:[eight]    ; set loop for 8 more cols per row
  299.     dec    dx            ; delete one from the row index
  300.     pop    cx            ; restore the column count
  301.     push    cx            ; and save it again for this row
  302.     cmp    dx,0            ; and test to see if we are finished
  303.     jge    Br_Cont            ; loop
  304.  
  305.     mov    cx,CS:[col_2_do]    ; get the number of bytes to print
  306.     or    cx,cx
  307.     jz    Br_NoP            ; skip if didn't get anything
  308.  
  309.     push    cx            ; save number to do
  310.     mov    si,Offset CS:set_graf    ; setup for graphics
  311.     mov    cl,CS:[si]        ; get length
  312.     xor    ch,ch
  313.     inc    si            ; point past length field
  314.     call    TabPtr            ; perform the setup
  315.     pop    cx            ; now get the real characters to do
  316.     mov    si,Offset CS:line_buf    ; get print line pointer
  317.     call    TabPtr            ; and print the line
  318.  
  319. Br_NoP:    call    Cr_Lf        ; do carriage return and line feed at end
  320.  
  321.     pop    cx
  322.     add    cx,CS:[eight]        ; add 8 to column count
  323.     cmp    cx,CS:[cols]        ; compare to max to do
  324.  
  325.     jg    Br_Ret
  326.      jmp    Br_Strt            ; continue until fini
  327.  
  328. Br_Ret:    jmp    Return    ; restore printer and exit
  329.  
  330. ;--------------------------------------------------------------------
  331. ;    for By_Cols calls we have usually 320 x 200 type, so do 320
  332. ;    across and 200 down the page.  This means that we must double
  333. ;    dot to get lines to connect on the printer paper.
  334. ;--------------------------------------------------------------------
  335.  
  336. By_Cols: mov    dx,0            ; start the row index at zero
  337.  
  338. ;    for each row do all the columns
  339. Bc_Strt:
  340.     push    dx            ; save the current row index
  341.     mov    cx,0            ; initialize the col count to start
  342.     mov    bh,Byte Ptr CS:[four]
  343.     xor    si,si            ; max characters to print
  344.     mov    CS:[col_2_do],si
  345.     mov    di,Offset CS:line_buf
  346.  
  347. ;    for each column in the row, do
  348. Bc_Cont:
  349.     call    Read            ; read the next dot at (row,col)
  350.     and    al,07fh            ; check if any thing is there
  351.     jz    Bc_Fill            ; and skip if nothing there
  352.      mov    al,3            ; else fill the byte from the bottom
  353. Bc_Fill:
  354.     shl    bl,1            ; move reg left one bit 
  355.     shl    bl,1            ; and repeat
  356.     or    bl,al            ; and 'or' in the next value
  357.     inc    dx            ; increment the row count
  358.     dec    bh            ; and the loop index
  359.     jnz    Bc_Cont            ; continue loop for 4 times
  360.  
  361.     add    si,3            ; add three to the column counter
  362.     mov    Byte Ptr CS:[di],bl    ; save filled byte
  363.     mov    Byte Ptr CS:[di+1],bl    ; twice for filling
  364.     mov    Byte Ptr CS:[di+2],bl    ; and three times for a lady
  365.     add    di,3            ; up the buffer ptr
  366.     or    bl,bl            ; see if anything is there
  367.     jz    Bc_Skp            ; skip if we have nothing to plot
  368.  
  369.      mov    CS:[col_2_do],si    ; save index
  370.  
  371. Bc_Skp:    mov    bh,Byte Ptr CS:[four]    ; set loop for 8 more cols per row
  372.     inc    cx            ; add one to the col index
  373.     pop    dx            ; restore the row count
  374.     push    dx            ; and save it again for this row
  375.     cmp    cx,CS:[cols]        ; and test to see if we are finished
  376.     jle    Bc_Cont            ; loop
  377.  
  378.     mov    cx,CS:[col_2_do]    ; get the number of bytes to print
  379.     or    cx,cx
  380.     jz    Bc_NoP            ; skip if didn't get anything
  381.  
  382.     push    cx            ; save number to do
  383.     mov    si,Offset CS:set_graf    ; setup for graphics
  384.     mov    cl,CS:[si]        ; get length
  385.     xor    ch,ch
  386.     inc    si            ; point past length field
  387.     call    TabPtr            ; perform the setup
  388.  
  389.     pop    cx            ; now get the real characters to do
  390.     mov    si,Offset CS:line_buf    ; get print line pointer
  391.     call    TabPtr            ; print the line
  392.  
  393. Bc_NoP:    call    Cr_Lf
  394.  
  395.     pop    dx
  396.     add    dx,CS:[four]        ; add to column count
  397.     cmp    dx,CS:[rows]        ; compare to max to do
  398.  
  399.     jg    Bc_Ret            ; if fini then exit
  400.      jmp    Bc_Strt            ; else go do next row
  401.  
  402. Bc_Ret:    jmp    Return            ; restore printer and exit
  403.  
  404. Process    endp
  405.  
  406. ;--------------------------------------------------------------------
  407. ;
  408. ;    Read Dot Routine Using DOS/BIOS or VDI interface for int 10h
  409. ;
  410. ;-------------------------------------------------------------------
  411. Read    proc    near
  412.     xor    al,al
  413.      cmp    dx,0            ; see if all is ok
  414.      jl    Read_Ret
  415.      cmp    cx,CS:[cols]        ; also check on overdoing it
  416.      jg    Read_Ret
  417.      cmp    CS:[mode],10h
  418.      je    Read_Dot        ; if mode = 10 then do special I/O
  419.  
  420.      mov    ah,13
  421.      push    bx
  422.      push    cx
  423.      push    dx
  424.      int    10h
  425.      pop    dx
  426.      pop    cx
  427.      pop    bx
  428.      xor    ah,ah            ; clear the high byte for testing
  429. Read_Ret:
  430.     ret
  431.  
  432. ;---------------------------------------------------------------
  433. ;
  434. ;    Read a Pixel (Dot) from the EGA using Read Mode 0
  435. ;
  436. ;----------------------------------------------------------------
  437.  
  438. Read_Dot: push bx
  439.     push    cx
  440.     push    dx
  441.     mov    ax,dx            ; save column value
  442.     mov    bx,cx            ; and row value
  443.     mov    dx,0a000h        ; Video ram address
  444.     mov    DS,dx            ; into segment register
  445.     mov    dx,80
  446.     mul    dx            ; column * 80
  447.     shr    bx,1
  448.     shr    bx,1
  449.     shr    bx,1            ; row / 8
  450.     add    bx,ax            ; actual data byte address
  451.     and    cl,7            ; row mod 8
  452.     xor    cl,7            ; bit mask 7 - (row mod 8)
  453.     mov    ch,1
  454.     shl    ch,cl            ; 2^mask
  455.     mov    ah,3            ; initialize bit plane number
  456. Plane_Loop:
  457.     mov    dx,03CEh        ; EGA Controller
  458.     mov    al,4            ; map select register
  459.     out    dx,al
  460.     mov    dx,03CFh        ; data register
  461.     mov    al,ah            ; select bit planes 3,2,1,0
  462.     out    dx,al
  463.     mov    al,DS:[bx]        ; read bit plane
  464.     shl    cl,1
  465.     and    al,ch
  466.     jz    Not_On
  467.      or    cl,1
  468. Not_On:    dec    ah
  469.     jge    Plane_Loop
  470.  
  471.     and    cl,0fh
  472.     mov    al,cl
  473.     pop    dx
  474.     pop    cx
  475.     pop    bx
  476.     ret
  477. Read    endp
  478.  
  479.     dw    -1            ; fense
  480.     
  481. ;--------------------------------------------------------------------
  482. ;
  483. ;    Initialization Routine for Graphics.Com
  484. ;
  485. ;--------------------------------------------------------------------
  486. Setup    proc    near
  487.     xor    ax,ax
  488.     mov    ES,ax            ; setup to address segment zero
  489.     mov    cx,ES:[0016h]        ; get current segment
  490.     mov    bx,ES:[0014h]        ; and offset
  491.     mov    DS,cx            ; make that the data segment
  492.     mov    cx,CS:[Cmp_Str]        ; setup to check bytes for same
  493.     mov    si,Offset CS:mlen    ; data field "Graphic..."
  494.     mov    bx,si
  495.  
  496. Check:    mov    ax,CS:[si]        ; get a byte in accum
  497.     cmp    ax,DS:[bx]        ;is it the same
  498.     jne    Ok            ; no, then we are ok
  499.     inc    si            ; otherwise, increment pointers
  500.     inc    bx            ; to both fields
  501.     loop    Check            ; and loop for 7 checks
  502.  
  503.     mov    ax,CS
  504.     mov    DS,ax
  505.     mov    ah,09h
  506.     mov    dx,Offset Message1
  507.     int    21h
  508.     int    20h            ; if same then don't overlay but exit
  509.  
  510. Ok:    mov    bx,ES:[0014h]        ; get the current offset in int vector
  511.     mov    ax,CS            ; now setup to display a message
  512.     mov    DS,ax
  513.     mov    Word Ptr dos,bx        ; and save it locally
  514.     mov    bx,ES:[0016h]        ; get the segment location of item too
  515.     mov    Word Ptr dos2,bx    ; and save it also
  516.     mov    ax,CS            ; save our entry at int vector
  517.     mov    ES:[0016h],ax        ; segment
  518.     mov    bx,Offset CS:Begin    ; define entry point to routine
  519.     mov    ES:[0014h],bx        ; offset
  520.     mov    di,Offset Field1
  521.     call    Convert            ; convert starting address
  522.     mov    di,Offset Field2
  523.     mov    bx,Offset Setup
  524.     add    bx,15            ; convert to next paragraph addr
  525.     mov    cl,4
  526.     shr    bx,cl
  527.     add    ax,bx
  528.     call    Convert            ; and the new ending address
  529.     mov    ah,09h            ; now do our message
  530.     mov    dx,Offset Message2
  531.     int    21h
  532.     mov    dx,Offset CS:Setup
  533.     int    27h            ; terminate but stay resident
  534. Setup    endp
  535.  
  536. Convert    proc    near
  537. ;
  538. ;    ax = number to be converted 
  539. ;    di = address of field in which to put the hex characters 
  540. ;
  541.     push    ax
  542.     push    bx
  543.     push    cx
  544.     push    dx
  545.     lea    bx,Ascii
  546.     mov    cl,4
  547.     mov    dx,ax
  548.     mov    al,ah
  549.     shr    al,cl
  550.     xlat    Ascii
  551.     mov    Byte Ptr CS:[di],al
  552.     mov    al,dh
  553.     and    al,0fh
  554.     xlat    Ascii
  555.     mov    Byte Ptr CS:[di+1],al
  556.     mov    al,dl
  557.     shr    al,cl
  558.     xlat    Ascii
  559.     mov    Byte Ptr CS:[di+2],al
  560.     mov    al,dl
  561.     and    al,0fh
  562.     xlat    Ascii
  563.     mov    Byte Ptr CS:[di+3],al
  564.     pop    dx
  565.     pop    cx
  566.     pop    bx
  567.     pop    ax
  568.     ret
  569. Convert    endp
  570.  
  571. Message1 db    'EGA Graphics routine is already resident',13,10,'$'
  572. Message2 db    'EGA Graphics routine is now resident ('
  573. Field1    db    '0000-'
  574. Field2    db    '0000)',13,10,'$'
  575. Ascii    db    '0123456789abcdef'
  576.  
  577. CSEG    ENDS
  578.     END    Epson
  579.