home *** CD-ROM | disk | FTP | other *** search
/ Power Programming / powerprogramming1994.iso / progtool / asmutl / tsrdemo.arc / TSRDEMO2.ASM
Assembly Source File  |  1980-04-10  |  45KB  |  1,494 lines
  1. ;==============================================================================
  2. ; TSRDEMO2.ASM
  3. ; Thomas Brandenborg
  4. ; 87.02.11
  5. ;
  6. ; Sample demonstration of a safe approach for writing TSR programmes.
  7. ;
  8. ;------------------------------------------------------------------------------
  9. ; Copyright 1987 by Thomas Brandenborg. All Rights Reserved
  10. ; Written for uploading to Compuserve Forums by
  11. ; 
  12. ;    Thomas Brandenborg
  13. ;    Lundbyesgade 11
  14. ;    DK-8000 Aarhus C
  15. ;    DENMARK
  16. ;
  17. ; This code is intended as a reference to users on Compuserve Forums
  18. ; on how to write Terminate-And-Stay resident programmes for Personal
  19. ; Cumputers running under DOS versions 2.00 and newer.
  20. ;
  21. ; The code is not part of any proprietary product, but is rather a
  22. ; demonstration of such techniques that may be used to write safe TSR
  23. ; programmes.
  24. ;
  25. ; All or part of it may, however, be used in other software products
  26. ; or otherwise distributed assuming the copyright holders Name & Address
  27. ; as listed above are included clearly and visibly in the documentation
  28. ; for such product.
  29. ;
  30. ; The copyright holder offers no warranty with this code whatsoever,
  31. ; including its fitness for any particular purpose. Neither shall he
  32. ; be liable for damages of any kind that may arise from its use.
  33. ;
  34. ;
  35. ; IF YOU THINK THIS CODE IS USEFUL:
  36. ;
  37. ; If you think this code has had some value to you, and in particular
  38. ; if you consider using all or parts of it in your own product, you
  39. ; may want to consider a smaller or larger donation to the author
  40. ; (Name & Address above) who spend his late night hours putting
  41. ; it together.
  42. ;
  43. ; As to the size of a such donation this is entirely up to your own
  44. ; judgement. It is suggested that you simply consider the value this
  45. ; code has had to you, the time you saved not having to write it your
  46. ; self... that should help you determine the right amount.
  47. ;
  48. ; Please notice that such donations are an entirely voluntary contribution.
  49. ; This holds true whatever your purpose is for using this code, and whatever
  50. ; the type of product and distribution you work with. The author has nothing
  51. ; against commercial software distribution and does not have any reason
  52. ; to restrict developers of commercial products in their use of this code.
  53. ;------------------------------------------------------------------------------
  54. ; COMPILING:    masm tsrdemo2;
  55. ; LINKING:    link tsrdemo2;
  56. ;         exe2bin tsrdemo2 tsrdemo2.com
  57. ;------------------------------------------------------------------------------
  58. ; Revisions
  59. ; Brandenborg 87.02.14    Added copyright notice & checked comments
  60. ; Brandenborg 87.02.17    Added full AX value in Set Ext Err call
  61. ; Brandenborg 87.02.25    Went through to optimize things
  62. ; Brandenborg 87.02.28    Added auto INT28 invocation in INT16 handler
  63. ; Brandenborg 87.03.01    Added INT21 filter for recursion onto console stack
  64. ; Brandenborg 87.03.02    Final cleanup of comments etc.
  65. ;==============================================================================
  66.  
  67. ;==============================================================================
  68. ; DEFINE BIOS DATA SEGMENT OFFSETS
  69. ;==============================================================================
  70.  
  71. BiosData    segment at 40h
  72.         org    17h
  73. KbFlag        label    byte        ;current shift status bits
  74.         org    18h
  75. KbFlag1        label    byte        ;current key status of toggle keys
  76. BiosData    ends
  77.  
  78. ;==============================================================================
  79. ; DEFINE OFFSETS WITHIN BIOS EXTRA DATA SEGMENT
  80. ;==============================================================================
  81.  
  82. BiosXX        segment at 50h
  83.         org    0
  84. StatusByte    label    byte        ;PrtSc status
  85. BiosXX        ends
  86.  
  87. ErrPrtSc    equ    -1        ;err during last PrtSc
  88. InPrtSc        equ    1        ;PrtSc in progress
  89.  
  90. ;==============================================================================
  91. ; DEFINE OFFSETS WITHIN OUR PSP
  92. ;==============================================================================
  93.  
  94. Cseg        segment byte public
  95.         org    2
  96. TopSeg        label    word        ;last seg in alloc block
  97.         org    2ch
  98. EnvSeg        label    word        ;seg of our environment copy
  99. Cseg        ends
  100.  
  101. ;==============================================================================
  102. ; DOS COM-FILE ENTRY POINT
  103. ;==============================================================================
  104.  
  105. Cseg        segment public byte
  106.         assume    cs:Cseg, ds:nothing, es:nothing, ss:nothing
  107.         org    100h
  108. ComEntry:    jmp    Init        ;JMP to init at bottom of seg
  109.  
  110. ;==============================================================================
  111. ; IDENTIFICATION CODES FOR THIS TSR (MUST BE UNIQUE FOR EACH CO-EXISTING TSR)
  112. ; HIGH BYTE OF GetId MUST NOT MATCH ANY AH REQUEST CODES FOR INT16H.
  113. ;==============================================================================
  114.  
  115. GetId        equ    'tc'            ;INT16h AX val to get MyId
  116. MyId        equ    'TC'            ;ID of this TSR
  117.  
  118. ;==============================================================================
  119. ; FLAGS AND PTRS FOR RESIDENT HANDLING
  120. ;==============================================================================
  121.  
  122. TsrMode        db    0            ;bits for various modes
  123. InInt08        equ    1 SHL 0            ;timer0 tick handler
  124. InInt09        equ    1 SHL 1            ;keyboard handler
  125. InInt13        equ    1 SHL 2            ;BIOS disk I/O
  126. InInt28        equ    1 SHL 3            ;INT28 handler
  127. In28Call    equ    1 SHL 4            ;we have issued INT28
  128. InPopup        equ    1 SHL 5            ;popup routine activated
  129. NewDos        equ    1 SHL 6            ;DOS 2.x in use
  130. InDosClr    equ    1 SHL 7            ;InDos=0 at popup time
  131.  
  132. KeyMode        db    0            ;bits for hotkey status
  133. HotIsShift    equ    1 SHL 0            ;hotkey is shift state
  134. InHotMatch    equ    1 SHL 1            ;so far keys match hotkey seq
  135. HotKeyOn    equ    1 SHL 2            ;full hotkey pressed
  136.  
  137. InDosPtr    label    dword            ;seg:off of InDos flag
  138. InDosOff    dw    0
  139. InDosSeg    dw    0
  140.  
  141. CritErrPtr    label    dword            ;seg:off of CritErr flag
  142. CritErrOff    dw    0
  143. CritErrSeg    dw    0
  144.  
  145. ;==============================================================================
  146. ; DATA FOR INT09H HANDLER TO CHECK FOR HOTKEY COMBINATION
  147. ;==============================================================================
  148.  
  149. ; ------------    EQU'S FOR BIT SHIFTS WITHIN KEYBOARD FLAGS
  150.  
  151. InsState    equ    80h
  152. CapsState    equ    40h
  153. NumState    equ    20h
  154. ScrollState    equ    10h
  155. AltShift    equ    08h
  156. CtlShift    equ    04h
  157. LeftShift    equ    02h
  158. RightShift    equ    01h
  159.  
  160. InsShift    equ    80h
  161. CapsShift    equ    40h
  162. NumShift    equ    20h
  163. ScrollShift    equ    10h
  164. HoldState    equ    08h
  165.  
  166. ; ------------    SCAN CODES FOR VARIOUS SHIFT KEYS
  167.  
  168. LeftDown    equ    42            ;scan code of left shift key
  169. LeftUp        equ    LeftDown OR 80h
  170. RightDown    equ    54            ;scan code of right shift key
  171. RightUp        equ    RightDown OR 80h
  172. AltDown        equ    56            ;scan code of alt key
  173. AltUp        equ    AltDown OR 80h
  174. CtlDown        equ    29            ;scan code of ctrl key
  175. CtlUp        equ    CtlDown OR 80h
  176.  
  177. ; ------------    MISC KEYBOARD DATA
  178.  
  179. KbData        equ    60h            ;keyboard data input
  180.  
  181. ;==============================================================================
  182. ; TO USE A SHIFT KEY COMBINATION AS HOT KEY:
  183. ;  -    SET THE FLAG HotIsShift IN KeyMode
  184. ;  -    DEFINE THE SHIFT STATUS BITS IN THE VARIABLE HotKeyShift
  185. ;
  186. ; TO USE A SERIES OF SCAN CODES AS HOT KEY:
  187. ;    CLEAR THE FLAG HotIsShift IN KeyMode
  188. ;  -    INSERT THE MAKE AND BREAK SCAN CODES IN THE HotKeySeq STRING
  189. ;    NOTE:    WITH THIS DEMO IMPLEMENTATION YOU SHOULD NOT USE A HOT KEY
  190. ;        SEQUENCE WHICH PRODUCES A KEY IN THE BIOS KEYBOARD QUEUE,
  191. ;        SINCE THE KEY IS NOT REMOVED BEFORE CALLING THE POPUP ROUTINE.
  192. ;
  193. ; NOTE:    HOTKEY TYPE AND CONTENTS OF HOTKEY VARIABLES MAY BE CHANGED AT RUN TIME
  194. ;==============================================================================
  195.  
  196. HotKeyShift    db    LeftShift OR RightShift    ;shift state IF HotIsShift=FF
  197.  
  198. HotKeySeq    db    LeftDown,LeftUp,LeftDown,LeftUp
  199. HotKeyLen    equ    $-HotKeySeq
  200. HotIndex    db    0            ;# key in seq to compare next
  201. BetweenKeys    db    0            ;timeout count between keys
  202. KeyTimeOut    equ    10            ;more ticks means not a hotkey
  203.  
  204. ;==============================================================================
  205. ; DATA FOR INT08H HANDLER TO CHECK FOR POPUP
  206. ;==============================================================================
  207.  
  208. SafeWait    db    0            ;count-down for safe popup
  209. MaxWait        equ    8            ;wait no more 8/18 sec
  210.  
  211. ;==============================================================================
  212. ; PROCESS & SYSTEM DATA
  213. ;==============================================================================
  214.  
  215. OurSS        dw    0            ;stack for popup routine
  216. OurSP        dw    0
  217. StackSize    equ    512            ;bytes to reserve for stack
  218.  
  219. OldSS        dw    0            ;old stack seg
  220. OldSP        dw    0            ;old stack off
  221.  
  222. OurPSP        dw    0            ;our PSP seg
  223. OldPSP        dw    0            ;old PSP seg
  224.  
  225. OldDTA        label    dword            ;seg:off of old DTA area
  226. OldDTAOff    dw    0
  227. OldDTASeg    dw    0
  228.  
  229. OurDTA        label    dword            ;seg:off of our DTA
  230. OurDTAOff    dw    0
  231. OurDTASeg    dw    0
  232.  
  233. OldBreak    db    0            ;old ctrl-break state
  234. OldExtErr    dw    3 dup (0)        ;AX,BX,CX of ext err
  235.  
  236. ;==============================================================================
  237. ; LOCATIONS FOR SAVED INTERRUPT VECTORS
  238. ;==============================================================================
  239.  
  240. OldInt08    label    dword            ;Timer0 loaded before this
  241. OldInt08Off    dw    0
  242. OldInt08Seg    dw    0
  243.  
  244. OldInt09    label    dword            ;Kb handler loadde before this
  245. OldInt09Off    dw    0
  246. OldInt09Seg    dw    0
  247.  
  248. OldInt13    label    dword            ;BIOS diskette I/O
  249. OldInt13Off    dw    0
  250. OldInt13Seg    dw    0
  251.  
  252. OldInt16    label    dword            ;BIOS kb Q-handler
  253. OldInt16Off    dw    0
  254. OldInt16Seg    dw    0
  255.  
  256. OldInt1B    label    dword            ;^break of process we steal
  257. OldInt1BOff    dw    0
  258. OldInt1BSeg    dw    0
  259.  
  260. OldInt1C    label    dword            ;timer tick of process we steal
  261. OldInt1COff    dw    0
  262. OldInt1CSeg    dw    0
  263.  
  264. OldInt21    label    dword            ;DOS function dispatcher
  265. OldInt21Off    dw    0
  266. OldInt21Seg    dw    0
  267.  
  268. OldInt23    label    dword            ;^C of process we steal
  269. OldInt23Off    dw    0
  270. OldInt23Seg    dw    0
  271.  
  272. OldInt24    label    dword            ;crit err of process we steal
  273. OldInt24Off    dw    0
  274. OldInt24Seg    dw    0
  275.  
  276. OldInt28    label    dword            ;DOS idles loaded before this
  277. OldInt28Off    dw    0
  278. OldInt28Seg    dw    0
  279.  
  280. ;==============================================================================
  281. ; SPEAKER/TONE GENERATION DATA
  282. ;==============================================================================
  283.  
  284. PB0port        equ    61h            ;port for speaker bit
  285. ErrLen1        equ    10            ;# outer err beep cycles
  286. ErrLen2        equ    80            ;# inner err beep cycles
  287. ErrLow        equ    100            ;low tone wait in err beep
  288. ErrHi        equ    40            ;hi tone wait in err beep
  289.  
  290. ;==============================================================================
  291. ; ErrBeep - PRODUCE ERROR-INDICATING SOUND ON SPEAKER
  292. ;==============================================================================
  293.  
  294. ErrBeep        proc    near
  295.         assume    ds:nothing, es:nothing, ss:nothing
  296.  
  297.         push    ax            ;save regs used
  298.         push    bx
  299.         push    cx
  300.         push    dx
  301.  
  302.         mov    cx,ErrLen1        ;# mix-cycles for beep
  303.  
  304. ErrBeep1:    mov    dx,ErrLow        ;wait time for half-cycle
  305.         mov    bx,ErrLen2        ;len of one tone
  306.         call    DoTone            ;output low err tone
  307.         mov    dx,ErrHi        ;wait time for half-cycle
  308.         mov    bx,ErrLen2        ;len of one tone
  309.         call    DoTone            ;output low err tone
  310.  
  311.         loop    ErrBeep1        ;loop for some time
  312.  
  313.         pop    dx
  314.         pop    cx            ;restore regs
  315.         pop    bx
  316.         pop    ax
  317.         ret
  318. ErrBeep        endp
  319.  
  320. ;==============================================================================
  321. ; DoTone - OUTPUT ONE TONE ON THE SPEAKER
  322. ;
  323. ; INPUT:    DX:    LOOP WAIT TIME FOR HALF CYCLE IN TONE
  324. ;        BX:    NUMBER OF CYCLES FOR TONE DURATION
  325. ; OUTPUT:    NONE
  326. ; REGS:        ALL PRESERVED
  327. ;==============================================================================
  328.  
  329. DoTone        proc    near
  330.         assume    ds:nothing, es:nothing, ss:nothing
  331.  
  332.         push    ax            ;save regs used
  333.         push    bx
  334.         push    cx
  335.         in    al,PB0port        ;get PB0 reg pattern
  336.         mov    ah,al            ;save it
  337.  
  338. DoTone1:    and    al,0fch            ;mask off speaker bit
  339.         out    PB0port,al        ;pull!
  340.         mov    cx,dx            ;half cycle in counter
  341. DoTone2:    loop    DoTone2            ;leave there for half a cycle
  342.         or    al,2            ;turn on speaker bit
  343.         out    PB0port,al        ;push!
  344.         mov    cx,dx            ;half cycle in counter
  345. DoTone3:    loop    DoTone3            ;leave there for half a cycle
  346.  
  347.         dec    bx            ;count down tone duration
  348.         jnz    DoTone1            ;go through full tone
  349.  
  350.         mov    al,ah            ;AL=original PB0 reg value
  351.         out    PB0port,al        ;restore
  352.  
  353.         pop    cx            ;restore regs
  354.         pop    bx
  355.         pop    ax
  356.         ret
  357. DoTone        endp
  358.  
  359. ;==============================================================================
  360. ; TestSafe - CHECK IF THIS IS A SAFE TIME TO DO A POP UP
  361. ; 
  362. ; RETURN CLC IF SAFE TO POP UP, CY IF NOT SAFE.
  363. ;
  364. ; CHECK IF ANY INTs ARE IN CRITICAL AREAS (InInt09 & InInt13)
  365. ; CHECK IF WE ARE IN AN OUR OWN INT28 CALL (In28Call)
  366. ; CHECK 8259A PIC ISR REGISTER FOR MISSING EOIs
  367. ; CHECK IF DOS IS STABLE FOR POP UP
  368. ; CHECK IF A PRINT SCREEN IS IN PROGRESS
  369. ;==============================================================================
  370.  
  371. TestSafe    proc    near
  372.         assume    ds:nothing, es:nothing
  373.  
  374.         push    ax            ;save regs used
  375.         push    bx
  376.         push    ds
  377.  
  378. ; ------------    CHECK INTs TO SEE IF THEY WERE INTERRUPTED AT BAD TIMES
  379.  
  380.         test    TsrMode,InInt09 OR InInt13 OR In28Call
  381.         jnz    NotSafe            ;jump if any INTs are chopped
  382.  
  383. ; ------------    CHECK THE 8259A PIC ISR REGISTER FOR NON-EOIed HW INTs
  384.  
  385.         mov    al,00001011b        ;tell 8259A we want the ISR
  386.         out    20h,al            ;8259A command reg
  387.         nop
  388.         nop
  389.         nop                ;now, ISR should be ready
  390.         in    al,20h            ;AL=mask of active INTs
  391.         or    al,al            ;test all (IRQ0 *did* EOI)
  392.         jnz    NotSafe            ;jump if active INTs
  393.  
  394. ; ------------    NOW, ENSURE THAT DOS WAS NOT INTERRUPTED
  395.  
  396.         assume    ds:nothing
  397.  
  398.         lds    bx,InDosPtr        ;now, DS:BX=InDos
  399.         mov    al,byte ptr [bx]    ;get InDos to AL
  400.         lds    bx,CritErrPtr        ;now, DS:BX=CritErr
  401.         or    al,byte ptr [bx]    ;both flags zero?
  402.         jz    DosSafe            ;YES - DOS is really idle
  403.         test    TsrMode,InInt28        ;is this an INT28h
  404.         jz    NotSafe            ;NO - not safe, should be idle
  405.         cmp    al,1            ;YES - one InDos entry only?
  406.         ja    NotSafe            ;NO - jump if more than one
  407. DosSafe:
  408.  
  409. ; ------------    CHECK TO SEE IF A PRINT SCREEN IS IN PROGRESS
  410.  
  411.         mov    ax,BiosXX
  412.         mov    ds,ax            ;move DS to BIOS extra data seg
  413.         assume    ds:BiosXX
  414.  
  415.         cmp    StatusByte,InPrtSc    ;print screen in progress?
  416.         je    NotSafe            ;YES - jump if prtsc
  417.  
  418. ; ------------    SEEMS TO BE A SAFE TIME FOR POPUP
  419.  
  420. IsSafe:        clc                ;CLC=safe to popup
  421.         jmp    short ExitSafe        ;end this then
  422.  
  423. ; ------------    APPARENTLY THIS IS JUST NOT THE TIME TO DO A POPUP
  424.  
  425. NotSafe:    stc                ;CY=don't popup now
  426.  
  427. ; ------------    RETURN TO CALLER WITH CARRY SET/CLEAR
  428.  
  429. ExitSafe:    pop    ds            ;restore regs
  430.         pop    bx
  431.         pop    ax
  432.         ret
  433. TestSafe    endp
  434.  
  435. ;==============================================================================
  436. ; OurInt08 - TSR INT08H HANDLER TO WATCH FOR HOTKEY AND SAFE POPUP TIMES
  437. ;
  438. ; CALL OldInt08
  439. ; CHECK FOR RE-ENTRANCE INTO CRITICAL INT08 CODE
  440. ; SET InInt08 FLAG
  441. ; CHECK FOR TIMEOUT BETWEEN KEYS IN HOTKEY SEQUENCE
  442. ; CHECK IF HOTKEY WAS PRESSED
  443. ; CHECK IF ALREADY InPopup OR InInt28
  444. ; CHECK IF SAFE TIME FOR SYSTEM TO POPUP
  445. ; UPDATE FLAGS AND CALL POPUP IF SAFE
  446. ; GIVE ERROR BEEP IF POPUP WAS UNSAFE FOR A LONG TIME
  447. ; RESET InInt08 FLAG
  448. ; DO IRET
  449. ;==============================================================================
  450.  
  451. ; ------------    NEAR JUMP DESTINATION FOR FAST IRET'S
  452.  
  453. Exit08:        iret                ;IRET (!)
  454.  
  455. ; ------------    ACTUAL INT08 ENTRY POINT
  456.  
  457. OurInt08    proc    far
  458.         assume    ds:nothing, es:nothing, ss:nothing
  459.  
  460.         pushf                ;simulate INT08
  461.         cli                ;in case others forgot it
  462.         call    OldInt08        ;call TSRs loaded before us
  463.  
  464. ; ------------    ENSURE NO RECURSION INTO CRITICAL INT08 CODE
  465.  
  466.         sti                ;we'll manage INTs
  467.  
  468.         test    TsrMode,InInt08        ;already in here somewhere?
  469.         jnz    Exit08            ;YES - don't re-enter
  470.         or    TsrMode,InInt08        ;tell people we are here
  471.  
  472.         push    ax            ;need a few regs in this code
  473.  
  474. ; ------------    COUNT DOWN TIME-OUT BETWEEN KEYS IN HOTKEY SEQUENCE
  475.  
  476.         test    KeyMode,InHotMatch    ;are we in a key match?
  477.         jz    TestHot08        ;NO - don't care then
  478.         dec    BetweenKeys        ;count down timeout val
  479.         jnz    TestHot08        ;jump if no timeout yet
  480.         mov    HotIndex,0        ;start match from beginning
  481.         and    KeyMode,not InHotMatch    ;just so we know it next time
  482.  
  483. ; ------------    CHECK FOR POSSIBLE POPUP ACTIONS
  484.  
  485. TestHot08:    test    KeyMode,HotKeyOn    ;has hotkey been pressed?
  486.         jz    ExitInt08        ;NO - jump if no fun here
  487.  
  488.         test    TsrMode,InInt28 OR InPopup
  489.         jnz    ExitInt08        ;jmp if not alr in business
  490.  
  491. ; ------------    HOTKEY PRESSED, CHECK TO SEE IF IT IS SAFE TO POPUP
  492.  
  493.         cmp    SafeWait,0        ;first time we find hotkey?
  494.         ja    TestSafe08        ;NO - wait has alr been set
  495.         mov    SafeWait,MaxWait    ;# ticks to wait at most
  496.  
  497. TestSafe08:    call    TestSafe        ;now, CY clear if popup is safe
  498.         jc    NotSafe08        ;jump if popup is bad idea
  499.  
  500. ; ------------    SEEMS SAFE TO POPUP AT THIS TIME, SO DO!
  501.  
  502.         xor    al,al            ;fast zero
  503.         mov    SafeWait,al        ;don't count any more
  504.         and    KeyMode,not HotKeyOn    ;clear hotkey status
  505.         or    TsrMode,InPopup        ;tell'em we enter popup routine
  506.         and    TsrMode,not InInt08    ;OK to enter critical INT08
  507.         call    InitPopup        ;do actual popup
  508.         or    TsrMode,InInt08        ;back in INT08 code here
  509.         and    TsrMode,not InPopup    ;not in popup code any more
  510.         mov    SafeWait,al        ;in case of hotkey during popup
  511.         and    KeyMode,not HotKeyOn    ;clear hotkey status
  512.  
  513.         jmp    short ExitInt08        ;finally done
  514.  
  515. ; ------------    UNSAFE POPUP TIME, COUNT DOWN SafeWait
  516.  
  517. NotSafe08:    dec    SafeWait        ;count down waiter
  518.         jnz    ExitInt08         ;jump if still no timeout
  519.  
  520. ; ------------    NO SAFE TIMES FOUND FOR QUITE SOME TIME, ERROR
  521.  
  522.         and    KeyMode,not HotKeyOn    ;might as well clear hotkey
  523.         call    ErrBeep            ;do an error beep
  524.  
  525. ; ------------    NORMAL INT08H EXIT, RESET InInt08
  526.  
  527. ExitInt08:    pop    ax            ;restore regs used
  528.         and    TsrMode,not InInt08    ;clear that flag
  529.         iret                ;straight back
  530. OurInt08    endp
  531.  
  532. ;==============================================================================
  533. ; OurInt09 - TSR INT09H HANDLER TO WATCH FOR HOTKEY
  534. ;
  535. ; SAVE SCAN CODE
  536. ; CALL OldInt09
  537. ; CHECK FOR RECURSION INTO CRITICAL INT09 CODE
  538. ; SET InInt09 FLAG
  539. ; CHECK IF HOTKEY ALREADY SET
  540. ; DETERMINE HOTKEY TYPE (SHIFT STATE OR KEY SEQENCE)
  541. ; CHECK SHIFT STATE IF HotIsShift
  542. ; COMPARE FOR KEY MATCH IF (NOT HotIsShift)
  543. ; SET HotKeyOn IF HOTKEY PRESSED
  544. ; RESET InInt09 FLAG
  545. ; DO IRET
  546. ;==============================================================================
  547.  
  548. ; ------------    NEAR JUMP DESTINATION FOR EARLY EXITS
  549.  
  550. Exit09:        pop    bx            ;restore regs
  551.         pop    ax
  552.         iret                ;flags restored from stack
  553.  
  554. ; ------------    ACTUAL INT09 ENTRY POINT
  555.  
  556. OurInt09    proc    far
  557.         assume    ds:nothing, es:nothing, ss:nothing
  558.  
  559.         push    ax            ;save regs used
  560.         push    bx
  561.  
  562. ; ------------    READ SCAN CODE, IN CASE SEQUENCE MATCHING SELECTED
  563.  
  564.         in    al,KbData        ;Al=key, preserved by BIOS
  565.  
  566. ; ------------    CALL BIOS TO PERFORM IT'S DUTIES
  567.  
  568.         pushf                ;simulate INT (CLI alr set)
  569.         cli                ;in case others forgot it
  570.         call    OldInt09        ;call BIOS/earlier TSRs
  571.  
  572. ; ------------    ENSURE NO RECURSION INTO CRITICAL INT09 CODE
  573.  
  574.         sti                ;we'll manage INTs
  575.  
  576.         test    TsrMode,InInt09        ;alr in business?
  577.         jnz    Exit09            ;YES - skip test till clear
  578.         or    TsrMode,InInt09        ;tell them we arrived here
  579.  
  580. ; ------------    DETERMINE HOT KEY TYPE SELECTED
  581.  
  582.         test    KeyMode,HotKeyOn    ;already hotkey there?
  583.         jnz    ExitInt09        ;YES - no double hotkeys here
  584.  
  585.         test    KeyMode,HotIsShift    ;shift state type hotkey?
  586.         jz    CompSeq09        ;NO - go compare sequence
  587.  
  588. ; ------------    COMPARE CURRENT SHIFT STATUS AGAINST HOTKEY
  589.  
  590.         push    ds            ;save current ds
  591.         mov    ax,BiosData        ;move DS to BIOS data seg
  592.         mov    ds,ax            ;DS can now access keyb vars
  593.         assume    ds:BiosData        ;tell MASM about our DS
  594.         mov    al,KbFlag        ;get BIOS shift state bits
  595.         pop    ds            ;restore
  596.         assume    ds:nothing        ;last thing we know about him
  597.  
  598.         and    al,HotKeyShift        ;isolate relevant bits
  599.         cmp    al,HotKeyShift        ;our shift state in effect?
  600.         jne    ExitInt09        ;NO - not that shift state
  601.         or    KeyMode,HotKeyOn    ;YES - flag hotkey
  602.         jmp    short ExitInt09        ;now we can be proud to leave
  603.  
  604. ; ------------    MATCH KEY IN SCAN CODE SEQUENCE
  605.  
  606. CompSeq09:    mov    bl,HotIndex        ;next scan code to match
  607.         xor    bh,bh            ;must be word
  608.         cmp    al,HotKeySeq[bx]    ;does key match?
  609.         je    HotMatch09        ;YES - jump if match
  610.         mov    HotIndex,bh        ;search from start next time
  611.         and    KeyMode,not InHotMatch    ;current no match
  612.         jmp    short ExitInt09        ;now end this
  613.  
  614. ; ------------    KEY MACTHED NEXT SCAN CODE IN HotKeySeq
  615.  
  616. HotMatch09:    inc    bl            ;new code at next pass
  617.         cmp    bl,HotKeyLen        ;did we match whole sequence?
  618.         jae    HotHit09         ;YES - jump if full sequence
  619.         mov    HotIndex,bl        ;NO - save new count
  620.         mov    BetweenKeys,KeyTimeOut    ;reset counter between keys
  621.         or    KeyMode,InHotMatch    ;we are in a match now
  622.         jmp    short ExitInt09        ;time to end this
  623.  
  624. ; ------------    KEY MATCHED ALL SCAN CODES IN HOTKEY SEQUENCE
  625.  
  626. HotHit09:    or    KeyMode,HotKeyOn    ;say hotkey was pressed
  627.         mov    HotIndex,bh        ;match 1st code next time
  628.         and    KeyMode,not InHotMatch    ;that's the end of a match
  629.  
  630. ; ------------    EXIT FROM INT09H, RESET InInt09 FLAG
  631.  
  632. ExitInt09:    and    TsrMode,not InInt09    ;tell'em we left this code
  633.         pop    bx            ;restore regs
  634.         pop    ax
  635.         iret                ;flags restored from stack
  636. OurInt09    endp
  637.  
  638. ;==============================================================================
  639. ; OurInt13 - SET InInt13 FLAG TO SAY THAT WE ARE IN AN INT13H
  640. ;==============================================================================
  641.  
  642. OurInt13    proc    far
  643.         assume    ds:nothing, es:nothing, ss:nothing
  644.  
  645.         pushf                ;save flags we use
  646.         or    TsrMode,InInt13        ;remember we are in BIOS now
  647.         popf                ;restore flags
  648.  
  649.         pushf                ;simulate INT13
  650.         cli                ;just in case others forgot
  651.         call    OldInt13        ;let BIOS handle it all
  652.  
  653.         pushf                ;BIOS uses flag return
  654.         and    TsrMode, not InInt13    ;tell people we left INT13h
  655.         popf
  656.  
  657.         ret    2            ;throw flags off stack
  658. OurInt13    endp
  659.  
  660. ;==============================================================================
  661. ; OurInt16 - TSR INT16H HANDLER, INT28 CHAIN INTERFACE
  662. ;
  663. ; INPUT:    AX = GetId
  664. ; OUTPUT:    AX = MyId
  665. ; REGS:        AX LOST, ALL OTHERS PRESERVED
  666. ; DESCRIPTION:    DETERMINE IF TSR WITH THIS ID IS ALREADY IN MEMORY
  667. ;
  668. ; INPUT:    AH = 00
  669. ; OUTPUT:    AX = NEXT KEY FROM BUFFER
  670. ; REGS;        AX LOST, ALL OTHERS PRESERVED
  671. ; DESCRIPTION:    RETURN A KEY FROM KEYBOARD BUFFER, WAIT TILL KEY IS PRESSED
  672. ;
  673. ; INPUT:    AH = 02
  674. ; OUTPUT:    AX = KEY FROM BUFFER IN ANY
  675. ;        ZF = NO KEYS IN BUFFER (AX PRESERVED)
  676. ;        NZ = KEY IN BUFFER (RETURNED IN AX, KEY STILL IN BUFFER)
  677. ; DESCRIPTION:    CHECK BUFFER FOR ANY PENDING KEYS, RETURN KEY IF ANY
  678. ;
  679. ; NOTE:    ALL OTHER AX REQUEST CODES ARE PASSED ON TO BIOS INT16H HANDLER.
  680. ;
  681. ; NOTE:    DURING INT28 POPUP (InPopup AND NOT InDosClr) FUNCTIONS AH=0 AND
  682. ;    AH=1 WILL ISSUE INT28, UNLESS InDos HAS FROM VALUE AT POPUP OR
  683. ;    CritErr HAS BEEN SET.
  684. ;==============================================================================
  685.  
  686. OurInt16    proc    far
  687.         assume    ds:nothing, es:nothing, ss:nothing
  688.  
  689.         sti                ;we'll manage INTs
  690.         pushf                ;save callers flags
  691.         cmp    ax,GetId        ;return ID request?
  692.         jne    NotId16            ;NO - jump if not
  693.  
  694. ; ------------    TSR DIAGNOSTIC REQUEST, RETURN SPECIAL VALUE TO SAY WE ARE HERE
  695.  
  696.         mov    ax,MyId            ;ID val returned in AX
  697.         popf                ;restore flags
  698.         iret                ;return to caller
  699.  
  700. ; ------------    PASS CONTROL TO BIOS, FLAGS ON STACK
  701.  
  702. GoBios16:    popf                ;restore flags at INT time
  703.         jmp    OldInt16        ;continue in the woods
  704.  
  705. ; ------------    REGULAR BIOS INT16 REQUEST, CHECK FOR ANY FANCY ACTIONS
  706.  
  707. NotId16:    test    TsrMode,InPopup        ;are we in a popup?
  708.         jz    GoBios16        ;NO - leave rest with BIOS
  709.         test    TsrMode,InDosClr    ;InDos clear at popup?
  710.         jnz    GoBios16        ;YES - no need to signal INT28
  711.  
  712.         popf                ;restore original flags
  713.         push    bx            ;we need a few regs here
  714.         push    cx
  715.         push    si
  716.         push    ds
  717.         pushf                ;original flags back on stack
  718.  
  719. ; ------------    GET REQUEST CODE TO BH ENHANCED BIT TO BL
  720.  
  721.         mov    bh,ah            ;BH=function request code
  722.         and    bh,not 10h        ;zap enhanced kybd bit
  723.         cmp    bh,1            ;any function above 1?
  724.         ja    ExitBios16        ;YES - leave rest with BIOS
  725.  
  726.         mov    bl,ah            ;BL used for enhanced bit
  727.         and    bl,10h            ;BL=value of enhanced bit
  728.  
  729. ; ------------    GET InDos To CL, CritErr to CH, SETUP REGS
  730.  
  731.         assume    ds:nothing
  732.  
  733.         lds    si,InDosPtr        ;DS:[SI]=InDos
  734.         mov    cl,byte ptr [si]    ;CL=InDos value
  735.         lds    si,CritErrPtr        ;ES:[SI]=CritErr
  736.         mov    ch,byte ptr [si]    ;CH=CritErr value
  737.  
  738.         mov    si,ax            ;save AX call value
  739.  
  740.         mov    ax,cs            ;move DS here, now we got it
  741.         mov    ds,ax
  742.         assume    ds:Cseg            ;everybody should know
  743.  
  744. ; ------------    CHECK KEYBOARD BUFFER, ORIGINAL FLAGS ON STACK
  745.  
  746. Wait16:        mov    ah,1            ;AH=1=test buffer status
  747.         or    ah,bl            ;maintain enhanced bit value
  748.  
  749.         popf                ;restore original flags
  750.         pushf                ;simulate INT
  751.         cli                ;in case others forgot
  752.         call    OldInt16        ;now, ZF set if no keys
  753.         pushf                ;save result flags
  754.         jnz    TestSkip16        ;jump if a key was found
  755.  
  756. ; ------------    NO KEY FOUND, CALL INT28 IF DOS InDos ALLOWS
  757.  
  758.         cmp    cx,0001h        ;CritErr=0, InDos=1 ?
  759.         jne    NextKey16        ;NO - wait for next key
  760.         or    TsrMode,In28Call    ;tell people we called this INT
  761.         int    28h            ;now take your chance
  762.         and    TsrMode,not In28Call    ;end of that call
  763.  
  764. ; ------------    TEST BUFFER AGAIN IF INT16.00, IRET IF INT16.01
  765.  
  766. NextKey16:    or    bh,bh            ;is this a wait for key?
  767.         jz    Wait16            ;YES - then go wait for it!
  768.         mov    ax,si            ;restore original AX contents
  769.         jmp    short Exit16        ;NO - exit with status we got
  770.  
  771. ; ------------    KEY IN BUFFER, IF CTRL-C WE MAY HAVE TO SKIP IT, FLAGS ON STACK
  772.  
  773. TestSkip16:    cmp    al,3            ;is this Ctrl-C?
  774.         jne    TestExit16        ;NO - determine exit method
  775.         test    cx,not 0001h        ;anything but InDos=1?
  776.         jz    TestExit16        ;NO - determine exit method
  777.  
  778. ; ------------    SKIP CTRL-C IN KEYBOARD BUFFER
  779.  
  780.         mov    ah,bl            ;AH=0 + enhanced bit
  781.         popf                ;restore original INTs
  782.         pushf                ;save again
  783.         pushf                ;simulate INT
  784.         cli                ;simulate properly!
  785.         call    OldInt16        ;now, key should be gone
  786.         jmp    short Wait16        ;do as if nothing had happened
  787.  
  788. ; ------------    KEY IN AX, IRET IF INT16.01, LEAVE WITH BIOS IF INT16.00
  789.  
  790. TestExit16:    or    bh,bh            ;is this a wait for key?
  791.         jnz    Exit16            ;NO - do fast return
  792.         mov    ax,si            ;YES - restore AX code
  793.  
  794. ; ------------    PASS CONTROL TO BIOS, FLAGS & REGS ON STACK
  795.  
  796.         assume    ds:nothing
  797.  
  798. ExitBios16:    popf                ;restore work flags
  799.         pop    ds            ;restore regs
  800.         pop    si
  801.         pop    cx
  802.         pop    bx
  803.         cli                ;should look like an INT
  804.         jmp    OldInt16        ;leave rest with BIOS
  805.  
  806. ; ------------    RETURN FROM INT16, FLAGS & REGS ON STACK
  807.  
  808.         assume    ds:nothing
  809.  
  810. Exit16:        popf                ;restore proper flags
  811.         pop    ds            ;restore regs
  812.         pop    si
  813.         pop    cx
  814.         pop    bx
  815.         ret    2            ;IRET, without flags restore
  816.  
  817. OurInt16    endp
  818.  
  819. ;==============================================================================
  820. ; OurInt21 - INT21 FILTER TO THROW DANGEROUS DOS CALLS ON CRITICAL STACK
  821. ;
  822. ; CHECK IF InPopup AND InDosClr
  823. ; CHECK FUNCTION USES CONSOLE STACK
  824. ; SET CritErr IN DOS IF CONSOLE STACK USED
  825. ; CALL OldInt21
  826. ; RESTORE CritErr IF CRITICAL STACK USED
  827. ;==============================================================================
  828.  
  829. OurInt21    proc    far
  830.         assume    ds:nothing, es:nothing
  831.  
  832.         pushf                ;save calling flags
  833.         sti
  834.  
  835.         test    TsrMode,InPopup        ;are we in a popup?
  836.         jz    GoDos21            ;NO - don't worry then
  837.         test    TsrMode,InDosClr    ;console stack idle?
  838.         jnz    GoDos21            ;YES - nothing fancy then
  839.  
  840. ; ------------    THIS IS 2ND CALL INTO DOS, SEE IF USING CONSOLE STACK
  841.  
  842.         cmp    ah,0ch            ;any function 00-0C?
  843.         jbe    UseCrit21        ;YES - use critical stack
  844.         test    TsrMode,NewDos        ;NO - is this DOS 3.x?
  845.         jnz    GoDos21            ;YES - no other to worry about
  846.         cmp    ah,50h            ;set PSP function?
  847.         je    UseCrit21        ;YES - use critical stack
  848.         cmp    ah,51h            ;get PSP function?
  849.         jne    GoDos21            ;NO - leave it with DOS
  850.  
  851. ; ------------    FORCE USE OF CRITICAL STACK FOR THIS CALL
  852.  
  853. UseCrit21:    assume    ds:nothing        ;nothing to say about DS
  854.  
  855.         push    si            ;save regs
  856.         push    ds
  857.         lds    si,CritErrPtr        ;now, DS:[SI]=InDos
  858.         mov    byte ptr [si],-1    ;FF=use crit stack now
  859.         pop    ds            ;restore regs
  860.         pop    si
  861.  
  862.         popf                ;retsore flags setting
  863.         pushf                ;simulate INT
  864.         cli                ;in case others forgot
  865.         call    OldInt21        ;flags already on stack
  866.  
  867.         push    si            ;save regs
  868.         push    ds
  869.         lds    si,CritErrPtr        ;now, DS:[SI]=InDos
  870.         mov    byte ptr [si],0        ;0=back to default stack
  871.         pop    ds            ;restore regs
  872.         pop    si
  873.  
  874.         ret    2            ;IRET throw old flags
  875.  
  876. ; ------------    PASS CONTROL TO DOS, FLAGS ON STACK
  877.  
  878. GoDos21:    popf                ;restore original flags
  879.         cli                ;just in case someone forgot
  880.         jmp    OldInt21        ;let DOS handle the rest
  881. OurInt21    endp
  882.  
  883. ;==============================================================================
  884. ; OurInt24 - SAFE DOS CRITICAL ERROR HANDLER
  885. ; 
  886. ; IF DOS 3.X, FAIL THE SYSTEM CALL
  887. ; IF NOT DOS 3.X, IGNORE ERROR
  888. ;==============================================================================
  889.  
  890. OurInt24    proc    far
  891.         assume    ds:nothing, es:nothing, ss:nothing
  892.         mov    al,3            ;AL=3=fail system call
  893.         test    TsrMode,NewDos        ;are we using DOS 3.x?
  894.         jnz    Exit24            ;YES - OK to use AL=3
  895.         xor    al,al            ;NO - have to ignore err then
  896. Exit24:        iret                ;return to DOS
  897. OurInt24    endp
  898.  
  899. ;==============================================================================
  900. ; OurInt28 - TSR INT28H HANDLER, ALLOWS POPUP DURING DOS IDLE CALLS
  901. ;
  902. ; CALL OldInt28
  903. ; CHECK FOR RECURSION INTO CRITICAL INT28 CODE (& OTHER INTs AS WELL)
  904. ; SET InInt28 FLAG
  905. ; CHECK FOR HOTKEY
  906. ; CHECK IF SAFE TO POPUP
  907. ; DO POPUP IF SAFE AT THIS TIME
  908. ; RESET InInt28 FLAG
  909. ; DO IRET
  910. ;==============================================================================
  911.  
  912. ; ------------    NEAR JUMP DESTINATION FOR FAST IRET'S
  913.  
  914. Exit28:        iret                ;IRET (!)
  915.  
  916. ; ------------    ACTUAL INT28 ENTRY POINT
  917.  
  918. OurInt28    proc    far
  919.         assume    ds:nothing, es:nothing, ss:nothing
  920.  
  921.         pushf
  922.         cli                ;in case others forgot it
  923.         call    OldInt28        ;call TSRs loaded before this
  924.  
  925. ; ------------    ENSURE NO RECURSION ON CRITICAL INT28 CODE
  926.  
  927.         sti                ;we'll manage INT's after this
  928.         test    TsrMode,InInt08 OR InInt28 OR In28Call OR InPopup
  929.         jnz    Exit28            ;exit fast if already going
  930.         or    TsrMode,InInt28        ;tell'em we are here
  931.  
  932. ; ------------    CHECK FOR POSSIBLE POPUP ACTIONS
  933.  
  934.         test    KeyMode,HotKeyOn    ;any hotkeys pressed?
  935.         jz    ExitInt28        ;NO - don't check any more then
  936.  
  937. ; ------------    HOTKEY WAS PRESSED, ENSURE IT'S SAFE TO DO POPUP
  938.  
  939.         call    TestSafe        ;now, CY clear if popup is OK
  940.         jc    ExitInt28        ;jump if not to popup
  941.  
  942. ; ------------    SEEMS OK TO DO POPUP, SO DO!
  943.  
  944.         and    KeyMode,not HotKeyOn    ;clear hotkey status
  945.         or    TsrMode,InPopup        ;tell'em we enter popup routine
  946.         and    TsrMode,not InInt28    ;OK to enter critical INT28
  947.         call    InitPopup        ;then do popup
  948.         or    TsrMode,InInt28        ;back in INT28 code here
  949.         and    TsrMode,not InPopup    ;not in popup code any more
  950.         and    KeyMode,not HotKeyOn    ;clear hotkeys during popup
  951.  
  952. ; ------------    NORMAL INT28H EXIT, RESET InInt28 FLAG
  953.  
  954. ExitInt28:    and    TsrMode,not InInt28    ;tell'em we left this code
  955.         iret                ;we have nothing more to say
  956. OurInt28    endp
  957.  
  958. ;==============================================================================
  959. ; NopInt - DUMMY IRET INSTRUCTION USED BY EMPTY INT HANDLERS
  960. ;==============================================================================
  961.  
  962. NopInt:        iret                ;immediate return
  963.  
  964. ;==============================================================================
  965. ; InitPopup - PREPARES SYSTEM FOR POPUP, THEN CALLS Popup, THEN RESTORES
  966. ;
  967. ; ESTABLISH INTERNAL WORK STACK
  968. ; SAVE CPU REGS
  969. ; UPDATE InDosClr FLAG WITH CURRENT VALUE OF InDos
  970. ; SAVE PROCESS RELATED SYSTEM INFO
  971. ; SAVE USER INTERRUPT VECTORS
  972. ; INSERT SAFE USER INTERRUPT VECTORS
  973. ; CALL POPUP ROUTINE
  974. ; RESTORE USER INTERRUPT VECTORS
  975. ; RESTORE PROCESS AND SYSTEM INFO
  976. ; CLEAR InDosClr FLAG TO PREVENT UNSAFE INT28 CALLs
  977. ; RESTORE CPU REGS
  978. ;==============================================================================
  979.  
  980. InitPopup    proc    near
  981.         assume    ds:nothing, es:nothing, ss:nothing
  982.  
  983. ; ------------    SWITCH TO PSP INTERNAL STACK
  984.  
  985.         mov    OldSS,ss        ;save current stack frame
  986.         mov    OldSP,sp
  987.  
  988.         cli                ;always CLI for the old chips
  989.         mov    ss,OurSS        ;move SS here
  990.         mov    sp,OurSP        ;move SP into position
  991.         sti                ;OK guys
  992.  
  993. ; ------------    SAVE ALL REGS
  994.  
  995.         push    ax
  996.         push    bx
  997.         push    cx
  998.         push    dx
  999.         push    bp
  1000.         push    si
  1001.         push    di
  1002.         push    ds
  1003.         push    es
  1004.  
  1005.         mov    ax,cs
  1006.         mov    ds,ax            ;mov DS here
  1007.         assume    ds:Cseg            ;tell MASM that
  1008.  
  1009. ; ------------    TAG VALUE OF InDos FLAG AT TIME OF POPUP
  1010.  
  1011.         or    TsrMode,InDosClr    ;assume InDos=0
  1012.         les    si,InDosPtr        ;now, ES:[SI]=InDos
  1013.         cmp    byte ptr es:[si],1    ;InDos set? (>2 impossible)
  1014.         jb    InDosSaved        ;NO - jump if all clear DOS
  1015.         and    TsrMode,not InDosClr    ;clear flag for popup InDos
  1016. InDosSaved:
  1017.  
  1018. ; ------------    SAVE DOS 3.X EXTENDED ERROR INFO
  1019.  
  1020.         test    TsrMode,NewDos        ;really DOS 3.x?
  1021.         jz    Dos3Saved        ;NO - jump if not 3.x
  1022.  
  1023.         mov    ah,59h            ;to get err info from DOS
  1024.         xor    bx,bx            ;BX must be zero
  1025.         push    ds            ;save DS (killed by DOS)
  1026.         int    21h            ;ext err info in AX,BX,CX
  1027.         pop    ds            ;restore
  1028.         mov    OldExtErr[0],ax        ;save
  1029.         mov    OldExtErr[2],bx
  1030.         mov    OldExtErr[4],cx
  1031.  
  1032. Dos3Saved:
  1033.  
  1034. ; ------------    SAVE CURRENT BREAK STATE, RELAX BREAK CHECKING
  1035.  
  1036.         mov    ax,3302h        ;to swap DL with BREAK value
  1037.         xor    dl,dl            ;DL=0=relax checking
  1038.         int    21h            ;current level in DL
  1039.         mov    OldBreak,dl        ;save current level
  1040.  
  1041. ; ------------    SAVE CURRENT USER INT VECTORS
  1042.  
  1043.         mov    ax,351bh        ;BIOS ctrl-break int
  1044.         int    21h            ;ES:BX=vector
  1045.         mov    OldInt1BOff,bx        ;save it
  1046.         mov    OldInt1BSeg,es
  1047.  
  1048.         mov    ax,351ch        ;BIOS timer tick
  1049.         int    21h            ;ES:BX=vector
  1050.         mov    OldInt1COff,bx        ;save it
  1051.         mov    OldInt1CSeg,es
  1052.  
  1053.         mov    ax,3523h        ;DOS ctrl-C
  1054.         int    21h            ;ES:BX=vector
  1055.         mov    OldInt23Off,bx        ;save it
  1056.         mov    OldInt23Seg,es
  1057.  
  1058.         mov    ax,3524h        ;DOS crit err handler
  1059.         int    21h            ;ES:BX=vector
  1060.         mov    OldInt24Off,bx        ;save it
  1061.         mov    OldInt24Seg,es
  1062.  
  1063. ; ------------    INSERT DUMMY IRET INTO DANGEROUS VECTORS
  1064.  
  1065.         mov    dx,offset NopInt    ;now, DS:DX=dunny iret
  1066.         mov    ax,251bh        ;BIOS ctrlk-break handler
  1067.         int    21h            ;set to IRET
  1068.         mov    ax,251ch        ;BIOS timer tick
  1069.         int    21h            ;set to IRET
  1070.         mov    ax,2523h        ;DOS ctrl-C handler
  1071.         int    21h            ;set to IRET
  1072.  
  1073. ; ------------    ESTABLISH SAFE CRITICAL ERROR HANDLER
  1074.  
  1075.         mov    dx,offset OurInt24    ;now, DS:DX=safe crit err
  1076.         mov    ax,2524h        ;to set crit err handler
  1077.         int    21h
  1078.  
  1079. ; ------------    SAVE CURRENT DTA AREA, SET OUR DEFAULT DTA
  1080.  
  1081.         mov    ah,2fh            ;to obtain current DTA from DOS
  1082.         int    21h            ;DTA addr now in ES:BX
  1083.         mov    OldDTAOff,bx        ;save it
  1084.         mov    OldDTASeg,es
  1085.  
  1086.         push    ds            ;save DS for a while
  1087.         lds    dx,OurDTA        ;DS:DX=our DTA addr
  1088.         mov    ah,1ah            ;to set DTA via DOS
  1089.         int    21h            ;set that addr
  1090.         pop    ds            ;restore DS
  1091.  
  1092. ; ------------    SAVE CURRENT PSP, ESTABLISH OURS INSTEAD
  1093.  
  1094.         mov    ax,5100h        ;to get PSP from DOS
  1095.         int    21h            ;current PSP now in BX
  1096.         mov    OldPSP,bx        ;save it
  1097.         mov    bx,OurPSP        ;het our PSP instead
  1098.         mov    ax,5000h        ;to set our PSP
  1099.         int    21h
  1100.  
  1101. ; ------------    CALL USER POPUP ROUTINE
  1102.  
  1103.         call    Popup            ;finally!
  1104.  
  1105. ; ------------    RESTORE TO SAVED CURRENT PROCESS
  1106.  
  1107.         mov    bx,OldPSP        ;new current process in BX
  1108.         mov    ax,5000h        ;to set PSP via DOS
  1109.         int    21h            ;restore original PSP
  1110.  
  1111. ; ------------    RESTORE SAVED DTA
  1112.  
  1113.         push    ds            ;save DS for a while
  1114.         lds    dx,OldDTA        ;DS:DX=our DTA addr
  1115.         mov    ah,1ah            ;to set DTA via DOS
  1116.         int    21h            ;set that addr
  1117.         pop    ds            ;restore DS
  1118.  
  1119. ; ------------    RESTORE SAVED INTERRUPT VECTORS
  1120.  
  1121.         push    ds            ;save for a while
  1122.         assume    ds:nothing        ;be careful about MASM
  1123.  
  1124.         lds    dx,OldInt1B        ;BIOS ctrl-break handler
  1125.         mov    ax,251bh
  1126.         int    21h
  1127.  
  1128.         lds    dx,OldInt1C        ;BIOS timer tick
  1129.         mov    ax,251ch
  1130.         int    21h
  1131.  
  1132.         lds    dx,OldInt23        ;DOS ctrl-C
  1133.         mov    ax,2523h
  1134.         int    21h
  1135.  
  1136.         lds    dx,OldInt24        ;DOS crit err handler
  1137.         mov    ax,2524h
  1138.         int    21h
  1139.  
  1140.         pop    ds            ;restore data seg DS
  1141.         assume    ds:Cseg
  1142.  
  1143. ; ------------    RESTORE SAVED BREAK CHECKING LEVEL
  1144.  
  1145.         mov    ax,3301h        ;to set break check level
  1146.         mov    dl,OldBreak        ;get saved break state
  1147.         int    21h
  1148.  
  1149. ; ------------    RESTORE DOS 3.X SPECIFIC SYSTEM INFO
  1150.  
  1151.         test    TsrMode,NewDos        ;using DOS 3.x
  1152.         jz    Dos3Restored        ;NO - jump if old DOS 2
  1153.         mov    dx,offset OldExtErr    ;DS:DX=3 words of ext err
  1154.         mov    ax,5d0ah        ;to set ext err info
  1155.         int    21h
  1156. Dos3Restored:
  1157.  
  1158. ; ------------    RESET InDosSet FLAG VALUE TO PREVENT UNSAFE INT28
  1159.  
  1160.         or    TsrMode,InDosClr    ;now we only care that InDos=0
  1161.  
  1162. ; ------------    RESTORE USER REGS
  1163.  
  1164.         pop    es
  1165.         pop    ds
  1166.         pop    di
  1167.         pop    si
  1168.         pop    bp
  1169.         pop    dx
  1170.         pop    cx
  1171.         pop    bx
  1172.         pop    ax
  1173.         assume    ds:nothing
  1174.  
  1175. ; ------------    RETURN TO USER STACK
  1176.  
  1177.         cli                ;always CLI for the old chips
  1178.         mov    ss,OldSS        ;restore SS
  1179.         mov    sp,OldSP        ;restore SP
  1180.         sti                ;OK guys
  1181.  
  1182.         ret
  1183. InitPopup    endp
  1184.  
  1185. ;==============================================================================
  1186. ; DATA FOR POPUP ROUTINE
  1187. ;==============================================================================
  1188.  
  1189. DosReadMsg    db    13,10,'Reading DOS CON (press <Enter> to terminate)',13,10
  1190. DosReadLen    equ    $-DosReadMsg
  1191.  
  1192. BiosReadMsg    db    'Reading BIOS keyboard (press any key... )',8,8
  1193. BiosReadLen    equ    $-BiosReadMsg
  1194.  
  1195. DoneMsg        db    ' key pressed, exit from TSR DEMO)',13,10
  1196. DoneLen        equ    $-DoneMsg
  1197.  
  1198. Scratch        db    80 dup (?)
  1199.  
  1200. ;==============================================================================
  1201. ; Popup - POPUP USER ROUTINE
  1202. ;
  1203. ; ALL REGISTERS EXCEPT SS:SP AND DS MAY BE CHANGED.
  1204. ; DS IS PRESET TO THE TSR DATA SEGMENT.
  1205. ;
  1206. ; NOTE:    UPON ENTRY TO THIS ROUTINE ALL DOS FUNCTIONS MAY BE CALLED.
  1207. ;    IF POPUP WAS DONE ON INT28, WITH CritErr==1, ALL DOS FUNCTIONS
  1208. ;    THAT WOULD NORMALLY USE THE CONSOLE STACK, WILL GO TO THE CRITICAL
  1209. ;    STACK, HENCE PREVENTING FURTHER POPUP DURING THE DOS CALL.
  1210. ;    (HOWEVER, MOST TSRs WOULD NOT POPUP ANYWAY, SINCE InDos==2).
  1211. ;
  1212. ;    ADDRESSES OF THE InDos AND CritErr ARE STORED IN THE DOUBLE WORDS
  1213. ;    InDosPtr AND CritErrPtr.
  1214. ;
  1215. ;    AT ENTRY CritErr FLAG IS 0 (ZERO), InDos NO GREATER THAN 1 (ONE).
  1216. ;==============================================================================
  1217.  
  1218. Popup        proc    near
  1219.         assume    ds:Cseg, es:nothing, ss:nothing
  1220.  
  1221.         mov    ah,40h            ;DOS write handle
  1222.         mov    bx,1            ;standard output handle
  1223.         mov    dx,offset DosReadMsg    ;DS:DX=str to write
  1224.         mov    cx,DosReadLen        ;CX=# chars to write
  1225.         int    21h            ;output that string
  1226.  
  1227.         mov    ah,3fh            ;DOS read handle
  1228.         xor    bx,bx            ;standard input handle
  1229.         mov    dx,offset Scratch    ;scratch buf for key
  1230.         mov    cx,80            ;read till CR hit
  1231.         int    21h
  1232.  
  1233.         mov    ah,40h            ;read from BIOS msg
  1234.         mov    bx,1
  1235.         mov    dx,offset BiosReadMsg
  1236.         mov    cx,BiosReadLen
  1237.         int    21h
  1238.  
  1239.         xor    ah,ah            ;to let BIOS wait for key
  1240.         int    16h            ;now, key was pressed
  1241.  
  1242.         mov    ah,40h            ;write confirm msg
  1243.         mov    bx,1
  1244.         mov    dx,offset DoneMsg
  1245.         mov    cx,DoneLen
  1246.         int    21h
  1247.  
  1248.         ret
  1249. Popup        endp
  1250.  
  1251. ;==============================================================================
  1252. ; TSR IRON CURTAIN - HE WHO CROSSES THIS CURTAIN WILL BE GONE AFTER TSR!
  1253. ;==============================================================================
  1254.  
  1255. TsrCurtain:                    ;TSR memory break
  1256.  
  1257. ;==============================================================================
  1258. ; NON-RESIDENT MESSAGES FOR INIT
  1259. ;==============================================================================
  1260.  
  1261. BannerMsg    label    byte
  1262. db    13,10
  1263. db    '<<<<<<  TSR DEMO  >>>>>>',13,10
  1264. db    '   Thomas Brandenborg',13,10
  1265. db    '      Version 2.00',13,10,10
  1266. db    '$'
  1267.  
  1268. FirstMsg    label    byte
  1269. db    'Pop up routine installed resident.',13,10
  1270. db    '$'
  1271.  
  1272. SecondMsg    label    byte
  1273. db    'TSR DEMO already loaded.',13,10
  1274. db    '$'
  1275.  
  1276. HotKeyMsg    label    byte
  1277. db    'Hit <Left Shift> twice to pop up!',13,10,10
  1278. db    '$'
  1279.  
  1280. Dos1Msg    label    byte
  1281. db    'OOPS!',7,13,10
  1282. db    'Must use DOS release 2.00 or later!',13,10,10
  1283. db    '$'
  1284.  
  1285. BadDosMsg    label    byte
  1286. db    'OOPS!',7,13,10
  1287. db    'Did not recognize DOS version!',13,10,10
  1288. db    '$'
  1289.  
  1290. ; ------------    DOS ERROR LEVEL EXIT CODES
  1291.  
  1292. xOk        equ    0            ;normal, OK exit
  1293. xSecond        equ    1            ;TSR already loaded
  1294. xBadDos        equ    2            ;CritErr flag not found
  1295.  
  1296. ;==============================================================================
  1297. ; Init - INITIALIZE TSR APPLICATION, ENTERED UPON DOS LOAD
  1298. ; 
  1299. ; DISPLAY BANNER, INITIALIZE SYSTEM DATA, CHECK IF ALREADY LOADED,
  1300. ; HOOK INTO INTERRUPT CHAIN, TERMINATE, BUT STAY RESIDENT.
  1301. ;==============================================================================
  1302.  
  1303. Init        proc    near
  1304.         assume    ds:Cseg, es:nothing, ss:nothing
  1305.  
  1306.         mov    dx,offset BannerMsg
  1307.         mov    ah,9
  1308.         int    21h            ;display programme banner
  1309.  
  1310. ; ------------    USE INT16H DIAGNOSTIC TO SEE IF TSR ALREADY INSTALLED
  1311.  
  1312.         mov    ax,GetId        ;INT16h diagnostic request
  1313.         int    16h            ;now, AX=MyId if installed
  1314.         cmp    ax,MyId            ;TSR already installed?
  1315.         jne    CheckDos        ;NO - jump if not installed
  1316.  
  1317. ; ------------    TSR ALREADY INSTALLED, DISPLAY MSG, EXIT
  1318.  
  1319.         mov    dx,offset SecondMsg
  1320.         mov    ah,9
  1321.         int    21h                ;display alr installed msg
  1322.         mov    dx,offset HotKeyMsg
  1323.         mov    ah,9
  1324.         int    21h            ;be kind & disp hot key
  1325.         mov    ax,4c00h + xSecond    ;error level in AL
  1326.         int    21h            ;abot now
  1327.  
  1328. ; ------------    IDIOT IS RUNNING DOS 1, LEAVE THE OLD FASHION WAY!
  1329.  
  1330. Dos1:        mov    dx,offset Dos1Msg
  1331.         mov    ah,9
  1332.         int    21h            ;display msg about DOS 1
  1333.         int    20h            ;no err level for DOS 1
  1334.  
  1335. ; ------------    ENSURE DOS VERSION IS NEWER THAN 2.00
  1336.  
  1337. CheckDos:    or    TsrMode,NewDos        ;assume suing DOS 3.x
  1338.         mov    ah,30h            ;to get DOS version number
  1339.         int    21h            ;version is AL.AH
  1340.         cmp    al,2            ;release 2 or newer?
  1341.         jb    Dos1            ;NO - jump if DOS 1 in use
  1342.         ja    DosFlags        ;jump if DOS 3.x
  1343.         and    TsrMode,not NewDos    ;now, say we use DOS 2.x
  1344.  
  1345. ; ------------    INITIALIZE PTRS TO DOS FLAGS - 1ST InDos
  1346.  
  1347. DosFlags:    mov    ax,3400h        ;to get InDos ptr
  1348.         int    21h            ;ES:BX=seg:off of InDos
  1349.         mov    InDosOff,bx        ;save ptr
  1350.         mov    InDosSeg,es
  1351.  
  1352. ; ------------    WE NEED CritErr TO USE PSP FUNCTIONS IN DOS 2.X (CHIPs WAY)
  1353.  
  1354.         xor    dl,dl            ;DL=0=this is 1st scan
  1355.         mov    CritErrSeg,es        ;DOS seg still in ES
  1356. CritScan:    mov    di,bx            ;start search at InDos
  1357.         mov    cx,2000h        ;search max 1000h words
  1358.         mov    ax,3e80h        ;opcode CMP BYTE PTR [CritErr]
  1359.         cld                ;better serach forward
  1360.  
  1361. CritScan2:    repne    scasw            ;search till found or end
  1362.         jne    NoCritFound        ;jump if CMP not found
  1363.                         ;ES:[DI-2] at:
  1364.                         ;    CMP BYTE PTR [CritErr]
  1365.                         ;    JNZ ...
  1366.                         ;    MOV SP,stack addr
  1367.         cmp    byte ptr es:[di][5],0bch ;really CMP SP there?
  1368.         jne    CritScan2        ;NO - scan again if not
  1369.         mov    ax,word ptr es:[di]    ;now, AX=CritErr offset
  1370.         mov    CritErrOff,ax        ;save it
  1371.         jmp    short InitData        ;OK to end this now
  1372.  
  1373. NoCritFound:    or    dl,dl            ;was this1 st scan?
  1374.         jnz    BadDos            ;NO - CritErr not founbd at all
  1375.         inc    dl            ;DL=1=this is 2nd scan
  1376.         inc    bx            ;try scan at odd/even offset
  1377.         jmp    CritScan        ;scan again
  1378.         
  1379. ; ------------    COULD NOT LOCATE DOS CritErr FLAG - THAT'S AN ERROR
  1380.  
  1381. BadDos:        mov    dx,offset BadDosMsg
  1382.         mov    ah,9
  1383.         int    21h            ;display msg about that
  1384.         mov    ax,4c00h + xBadDos    ;err level in AL
  1385.         int    21h            ;OK to use 4C (DOS >= 2)
  1386.  
  1387. ; ------------    INITIALIZE SYSTEM DATA VARIABLES
  1388.  
  1389. InitData:                    ;store position for stack
  1390.         mov    OurSP,TsrCurtain - ComEntry + 100h + StackSize
  1391.         mov    OurSS,cs        ;stack seg is code seg
  1392.  
  1393.         mov    ax,5100h        ;to get current PSP from DOS
  1394.         int    21h            ;PSP now in BX
  1395.         mov    OurPSP,bx        ;save our PSP
  1396.  
  1397.         mov    ah,2fh            ;to get current DTA from DOS
  1398.         int    21h            ;now, ES:BX=current DTA
  1399.         mov    OurDTAOff,bx        ;save it
  1400.         mov    OurDTASeg,es
  1401.  
  1402.         and    KeyMode,not HotIsShift    ;hotkey is not shift state
  1403.         or    TsrMode,InDosClr    ;will prevent unsafe INT28s
  1404.  
  1405. ; ------------    SAVE VECTORS FOR OUR MONITOR INTERRUPTS
  1406.  
  1407.         mov    ax,3508h        ;BIOS timer0 tick handler
  1408.         int    21h            ;ES:BX=vector
  1409.         mov    OldInt08Off,bx
  1410.         mov    OldInt08Seg,es
  1411.  
  1412.         mov    ax,3509h        ;BIOS kb HW handler
  1413.         int    21h            ;ES:BX=vector
  1414.         mov    OldInt09Off,bx
  1415.         mov    OldInt09Seg,es
  1416.  
  1417.         mov    ax,3513h        ;BIOS disk I/O service
  1418.         int    21h            ;ES:BX=vector
  1419.         mov    OldInt13Off,bx
  1420.         mov    OldInt13Seg,es
  1421.  
  1422.         mov    ax,3516h        ;BIOS kb read
  1423.         int    21h            ;ES:BX=vector
  1424.         mov    OldInt16Off,bx
  1425.         mov    OldInt16Seg,es
  1426.  
  1427.         mov    ax,3521h        ;DOS functions dispatcher
  1428.         int    21h            ;ES:BX=vector
  1429.         mov    OldInt21Off,bx
  1430.         mov    OldInt21Seg,es
  1431.  
  1432.         mov    ax,3528h        ;DOS idle hook
  1433.         int    21h            ;ES:BX=vector
  1434.         mov    OldInt28Off,bx
  1435.         mov    OldInt28Seg,es
  1436.  
  1437. ; ------------    ESTABLISH IRET INT23 TO PREVENT BREAK DURING VECTOR FIX
  1438.  
  1439.         mov    dx,offset NopInt    ;DS:DX=dummy vector to set
  1440.         mov    ax,2523h        ;to set ^C handler through DOS
  1441.         int    21h            ;now, no break will occur
  1442.  
  1443. ; ------------    SAVE VECTORS FOR OUR MONITOR INTERRUPTS
  1444.  
  1445.         mov    ax,2508h        ;to set our INT08h handler
  1446.         mov    dx,offset OurInt08    ;DS:DX=new vector
  1447.         int    21h            ;let DOS set vector
  1448.  
  1449.         mov    ax,2509h        ;to set our INT09h handler
  1450.         mov    dx,offset OurInt09    ;DS:DX=new vector
  1451.         int    21h            ;let DOS set vector
  1452.  
  1453.         mov    ax,2513h        ;to set our INT13h handler
  1454.         mov    dx,offset OurInt13    ;DS:DX=new vector
  1455.         int    21h            ;let DOS set vector
  1456.  
  1457.         mov    ax,2516h        ;to set our INT16h handler
  1458.         mov    dx,offset OurInt16    ;DS:DX=new vector
  1459.         int    21h            ;let DOS set vector
  1460.  
  1461.         mov    ax,2521h        ;to set our INT21h handler
  1462.         mov    dx,offset OurInt21    ;DS:DX=new vector
  1463.         int    21h            ;let DOS set vector
  1464.  
  1465.         mov    ax,2528h        ;to set our INT28h handler
  1466.         mov    dx,offset OurInt28    ;DS:DX=new vector
  1467.         int    21h            ;let DOS set vector
  1468.  
  1469. ; ------------    DISLAY MSG ABOUT HOW WELL THIS IS ALL RUNNING
  1470.  
  1471.         mov    dx,offset FirstMsg
  1472.         mov    ah,9
  1473.         int    21h            ; display confirm msg
  1474.         mov    dx,offset HotKeyMsg
  1475.         mov    ah,9
  1476.         int    21h            ;disp hot key
  1477.  
  1478. ; ------------    EXIT, SAY GOOD BYE TO FRIENDS BEHIND CURTAIN!
  1479.  
  1480.         mov    es,EnvSeg        ;ES=our environment copy
  1481.         mov    ah,49h            ;to let DOS free block
  1482.         int    21h            ;environment copy freed
  1483.  
  1484.         mov    dx,(TsrCurtain-ComEntry+100h+StackSize+15) SHR 4
  1485.         mov    ax,3100h + xOk        ;TSR, AL=err level
  1486.         int    21h
  1487. Init        endp
  1488.  
  1489. ;==============================================================================
  1490.  
  1491. Cseg        ends
  1492.         end    ComEntry
  1493.  
  1494.