home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Professional / OS2PRO194.ISO / os2 / prgramer / rcs / rcsfile.man < prev    next >
Text File  |  1992-02-19  |  6KB  |  152 lines
  1. NAME
  2.      rcsfile - format of RCS file
  3.  
  4. DESCRIPTION
  5.      An RCS file's contents are described by the grammar below.
  6.  
  7.      The text is free format: space, backspace, tab, newline,
  8.      vertical tab, form feed, and carriage return (collectively,
  9.      white space) have no significance except in strings.
  10.      However, an RCS file must end in a newline character.
  11.  
  12.      Strings are enclosed by @.  If a string contains a @, it
  13.      must be doubled; otherwise, strings may contain arbitrary
  14.      binary data.
  15.  
  16.      The meta syntax uses the following conventions: `|' (bar)
  17.      separates alternatives; `{' and `}' enclose optional
  18.      phrases; `{' and `}*' enclose phrases that may be repeated
  19.      zero or more times; `{' and '}+' enclose phrases that must
  20.      appear at least once and may be repeated; Terminal symbols
  21.      are in boldface; nonterminal symbols are in italics.
  22.  
  23.      rcstext    ::=  admin {delta}* desc {deltatext}*
  24.  
  25.      admin      ::=  head       {num};
  26.                      { branch   {num}; }
  27.                      access     {id}*;
  28.                      symbols    {id : num}*;
  29.                      locks      {id : num}*;  {strict  ;}
  30.                      { comment  {string}; }
  31.                      { expand   {string}; }
  32.                      { newphrase }*
  33.  
  34.      delta      ::=  num
  35.                      date       num;
  36.                      author     id;
  37.                      state      {id};
  38.                      branches   {num}*;
  39.                      next       {num};
  40.                      { newphrase }*
  41.  
  42.      desc       ::=  desc       string
  43.  
  44.      deltatext  ::=  num
  45.                      log        string
  46.                      { newphrase }*
  47.                      text       string
  48.  
  49.      num        ::=  {digit{.}}+
  50.  
  51.      digit      ::=  0 | 1 | ... | 9
  52.  
  53.      id         ::=  letter{idchar}*
  54.  
  55.      letter     ::=  any letter
  56.  
  57.      idchar     ::=  any visible graphic character except special
  58.  
  59.      special    ::=  $ | , | . | : | ; | @
  60.  
  61.      string     ::=  @{any character, with @ doubled}*@
  62.  
  63.      newphrase  ::=  id word* ;
  64.  
  65.      word       ::=  id | num | string | :
  66.  
  67.      Identifiers are case sensitive.  Keywords are in lower case
  68.      only.  The sets of keywords and identifiers may overlap.  In
  69.      most environments RCS uses the ISO 8859/1 encoding: letters
  70.      are octal codes 101-132, 141-172, 300-326, 330-366 and 370-
  71.      377, visible graphic characters are codes 041-176 and
  72.      240-377, and white space characters are codes 010-015 and
  73.      040.
  74.  
  75.      The newphrase productions in the grammar are reserved for
  76.      future extensions to the format of RCS files.  No newphrase
  77.      will begin with any keyword already in use.
  78.  
  79.      The delta nodes form a tree.  All nodes whose numbers
  80.      consist of a single pair (e.g., 2.3, 2.1, 1.3, etc.) are on
  81.      the trunk, and are linked through the next field in order of
  82.      decreasing numbers.  The head field in the admin node points
  83.      to the head of that sequence (i.e., contains the highest
  84.      pair).  The branch node in the admin node indicates the
  85.      default branch (or revision) for most RCS operations.  If
  86.      empty, the default branch is the highest branch on the
  87.      trunk.
  88.  
  89.      All delta nodes whose numbers consist of 2n fields (n_2)
  90.      (e.g., 3.1.1.1, 2.1.2.2, etc.) are linked as follows.  All
  91.      nodes whose first 2n-1 number fields are identical are
  92.      linked through the next field in order of increasing
  93.      numbers.  For each such sequence, the delta node whose
  94.      number is identical to the first 2n-2 number fields of the
  95.      deltas on that sequence is called the branchpoint.  The
  96.      branches field of a node contains a list of the numbers of
  97.      the first nodes of all sequences for which it is a
  98.      branchpoint.  This list is ordered in increasing numbers.
  99.  
  100.  
  101.      Example:
  102.  
  103.                                 Head
  104.                                   |
  105.                                   |
  106.                                   v                        / \
  107.                               ---------                   /   \
  108.         / \          / \      |       |      / \         /     \
  109.        /   \        /   \     |  2.1  |     /   \       /       \
  110.       /     \      /     \    |       |    /     \     /         \
  111.      /1.2.1.3\    /1.3.1.1\   |       |   /1.2.2.2\   /1.2.2.1.1.1\
  112.      ---------    ---------   ---------   ---------   -------------
  113.          ^            ^           |           ^             ^
  114.          |            |           |           |             |
  115.          |            |           v           |             |
  116.         / \           |       ---------      / \            |
  117.        /   \          |       \  1.3  /     /   \           |
  118.       /     \         ---------\     /     /     \-----------
  119.      /1.2.1.1\                  \   /     /1.2.2.1\
  120.      ---------                   \ /      ---------
  121.          ^                        |           ^
  122.          |                        |           |
  123.          |                        v           |
  124.          |                    ---------       |
  125.          |                    \  1.2  /       |
  126.          ----------------------\     /---------
  127.                                 \   /
  128.                                  \ /
  129.                                   |
  130.                                   |
  131.                                   v
  132.                               ---------
  133.                               \  1.1  /
  134.                                \     /
  135.                                 \   /
  136.                                  \ /
  137.  
  138.                        Fig. 1: A revision tree
  139.  
  140. IDENTIFICATION
  141.      Author: Walter F. Tichy, Purdue University, West Lafayette,
  142.      IN, 47907.
  143.      Revision Number: 5.2; Release Date: 1992/02/17.
  144.      Copyright 1982, 1988, 1989 by Walter F. Tichy.
  145.      Copyright 1990, 1991, 1992 by Paul Eggert.
  146.  
  147. SEE ALSO
  148.      ci(1), co(1), ident(1), rcs(1), rcsdiff(1), rcsmerge(1),
  149.      rlog(1),
  150.      Walter F. Tichy, RCS--A System for Version Control,
  151.      Software--Practice & Experience 15, 7 (July 1985), 637-654.
  152.