home *** CD-ROM | disk | FTP | other *** search
/ No Fragments Archive 12: Textmags & Docs / nf_archive_12.iso / MAGS / SOURCES / ATARI_SRC.ZIP / atari source / PART_F / VIEWMAN / MOVE.S < prev    next >
Encoding:
Text File  |  2001-02-10  |  56.9 KB  |  2,931 lines
  1. *
  2. *    MOVE.S
  3. *
  4.     .include    "equates.s"
  5. *
  6.     .text
  7. *
  8. *
  9. ***********************************************
  10. ;
  11. ; d0 - x mouse position
  12. ; d1 - y mouse position
  13. *
  14. DaveButton:
  15. *
  16.     bclr.b    #1,BUT_STATE+1
  17.     bne    lib_sel
  18.     bclr.b    #0,BUT_STATE+1
  19.     bne    wor_sel
  20. nolfbut:
  21.     rts
  22. *
  23. *
  24. *
  25. *   We call this every time we start with a down mouse button..
  26. *
  27. butninit:
  28.     clr.w    keyz
  29.     clr.w    grid        ;start out of grid mode
  30. *
  31.     move.w    #MouseOff,d0
  32.     bsr    Graf_Mouse        ;turn off the mouse
  33. *
  34.     move.l    mouseptr,a0        ;get mouse ptr
  35.     movem.w    (a0),d0-d1        ;d0 = xpos, d1 = ypos
  36.     movem.w    d0-d1,mousex        ;save when we restore
  37. clipinit:
  38.     lea    wstruct+xoffset,a5
  39.     movem.w    wx(a5),d0-d1
  40.     move.w    d0,d2
  41.     move.w    d1,d3
  42. *
  43.     add.w    wwidth(a5),d2
  44.     subq.w    #1,d2        ;check window right-edge beyond screen
  45.     cmp.w    form_width,d2
  46.     ble    butixok
  47.     move.w    form_width,d2
  48. butixok:
  49.     addq.w    #1,d2
  50. *
  51.     add.w    wheight(a5),d3
  52.     subq.w    #1,d3        ;check window bottom-edge beyond screen
  53.     cmp.w    form_height,d3
  54.     ble    butiyok
  55.     move.w    form_height,d3
  56. butiyok:
  57.     addq.w    #1,d3
  58.     movem.w    d0-d3,xmin_clp
  59.     movem.w    d0-d3,Mclpxmn    ;init motion clip variables to window
  60. *
  61.     movem.w    wwidth(a5),d0-d1
  62.     lsr.w    #1,d0
  63.     lsr.w    #1,d1
  64.     add.w    wx(a5),d0    ;mouse relative positioning
  65.     add.w    wy(a5),d1    ;needs a safe place--
  66.     movem.w    d0-d1,relcentx    ;put it smack in the center of window
  67.     move.l    mouseptr,a0
  68.     move.l    relcentx,(a0)    ;put rel mouse at a nice place
  69. *    
  70.     movem.w    mousex,d0-d1
  71. *
  72.     rts
  73. *
  74. *
  75. *
  76. *  Left button has gone down--select an existing item from the world
  77. *
  78. wor_sel:
  79.     movem.l    a0-a6/d0-d7,-(sp)
  80. *
  81.     bsr    butninit
  82. *
  83. *  d0 = mousex, d1 = mousey on screen..
  84. *
  85.     sub.w    wx(a5),d0
  86.     add.w    xoffset(a5),d0    ;adjust for world co-ords
  87.     sub.w    wy(a5),d1
  88.     add.w    yoffset(a5),d1
  89. *
  90. *  Search the worldblk for the highest priority object
  91. *   whose rectangle falls within the mouse position
  92. *
  93.     cmp.w    w_wid(a5),d0    ;are we right of the world
  94.     bge    wor_selx    ;br if so
  95.     cmp.w    w_hite(a5),d1
  96.     bge    wor_selx    ;br if below world
  97. *
  98.     move.l    wblkptr,a0        ;get pointer to end +1
  99.     move.l    #worldblk,a1        ; & ptr to beginning
  100.     lea    bshblock,a2
  101.     bra    findreci
  102. findlp:
  103.     move.w    -(a0),d3    ;get vpos
  104.     move.w    -(a0),d2    ;hpos
  105.     subq.l    #2,a0        ;skip special effects
  106.     move.w    -(a0),d4    ;brush #
  107. *
  108.     cmp.w    d0,d2        ;are we entirely to left?
  109.     bgt    findreci    ;br if so
  110. *
  111.     cmp.w    d1,d3        ;are we entirely above?
  112.     bgt    findreci    ;br if yes
  113. *
  114. *  we may have found our boy--check width & height
  115. *
  116.     move.w    d4,d5
  117.     swap    d5        ;save possible curbrush in upper word
  118. *
  119.     lsl.w    #4,d4        ;get offset into bshblock
  120.     move.w    (a2,d4.w),d5    ;get width
  121.     move.w    2(a2,d4.w),d6    ; & height
  122.     add.w    d2,d5
  123.     add.w    d3,d6
  124. *
  125.     cmp.w    d0,d5
  126.     ble    findreci
  127. *
  128.     cmp.w    d1,d6
  129.     ble    findreci    ;br if outside rect
  130. *
  131. *  we're inside a rectangle--check mask for pixel level match
  132. *
  133.     move.l    4(a2,d4.w),a3    ;get graphics s_form
  134.     move.l    a3,a5
  135.     adda.w    12(a2,d4.w),a5    ;get mono mask s_form
  136.     move.l    a5,a6
  137.     move.w    14(a2,d4.w),d5    ;get bytes/line
  138.     beq    hitnail        ;br if filled rect
  139.     lsr.w    #2,d5
  140.     move.w    d0,d6
  141.     sub.w    d2,d6        ;d6 = horz offset into mask form
  142.     move.w    d1,d7
  143.     sub.w    d3,d7        ;d7 = # rows down the form
  144.     mulu    d5,d7
  145.     add.l    d7,a5
  146.     move.w    d6,d7
  147.     asr.w    #3,d7
  148.     adda.w    d7,a5
  149.     not.w    d6
  150.     andi.w    #7,d6        ;d6 = dot address    
  151.     btst.b    d6,(a5)        ;do we have a hit, or miss
  152.     beq    findreci
  153. *
  154. *
  155. *  we have hit the nail on the head
  156. *
  157. hitnail:
  158.     swap    d5
  159.     move.w    d5,curbrush
  160.     swap    d5
  161. *
  162. *   convert world co-ords to screen ones
  163. *
  164.     lea    wstruct+xoffset,a5    ;restore structure ptr
  165. *
  166.     sub.w    xoffset(a5),d2
  167.     add.w    wx(a5),d2
  168.     sub.w    yoffset(a5),d3
  169.     add.w    wy(a5),d3
  170. *
  171.     movem.w    d2-d3,bsh_x    ;select this brush
  172.     move.w    d5,bsh_monoln    ;save bytes/line in form
  173.     lea    (a2,d4.w),a2
  174.     movem.w    (a2),d5-d6    ;get width & height
  175.     movem.w    d5-d6,bsh_wid
  176. *
  177. *   Delete it from worldblk
  178. *
  179.     movem.l    a3/a5-a6,-(sp)
  180. *
  181.     move.l    a0,wblkcur    ;save in current
  182.     lea    8(a0),a3
  183.     move.l    wblkptr,a4    ;get end +1
  184.     bra    delei
  185. dele:
  186.     move.l    (a3)+,(a0)+
  187.     move.l    (a3)+,(a0)+
  188. delei:
  189.     cmp.l    a4,a3
  190.     bcs    dele
  191. *
  192.     subq.l    #8,a4
  193.     move.l    a4,wblkptr
  194.     bsr    makewld        ;rebuild the world
  195.     bsr    makemsk        ;  & the mask
  196. *
  197. *  Blit a patch of the world buffer to the screen
  198. *
  199.     bsr    brushpat
  200. *
  201.     movem.l    (sp)+,a3/a5-a6
  202.     move.l    a6,a0
  203. *
  204. *  enter here from cluster code to put up a unit
  205. *
  206. bckdoorm:
  207.     movem.w    bsh_x,d0-d4
  208.     bsr    bdisplay
  209. *
  210.     movem.l    a0/d0,-(sp)
  211.     lea    bshblock,a0
  212.     move.w    curbrush,d0
  213.     bsr    upname            ;put up the name
  214.     movem.l    (sp)+,a0/d0
  215. *
  216.     bra    lib_m            ;make her animate!
  217. *
  218. findreci:
  219.     cmp.l    a0,a1            ;any more items left
  220.     bcs    findlp            ;br if so
  221. *
  222. wor_selx:
  223.     movem.l    mousex,d0
  224.     moveq    #0,d1
  225.     movem.l    d0-d1,bsh_x
  226.     bra    but_xit            ;exit thru right button stuff
  227. *
  228. *
  229. *
  230. *  Select a stamp from the library
  231. *
  232. lib_sel:
  233.     movem.l    a0-a6/d0-d7,-(sp)
  234. *
  235.     bsr    butninit
  236. *
  237. *
  238. newstamp:
  239. *
  240.     movem.w    mousex,d0-d1        ;get xpos, ypos
  241. *
  242.     lea    bshblock,a1        ;get brush data block base
  243.     move.w    curbrush,d2        ;get desired brush #
  244.     lsl.w    #4,d2
  245. *
  246.     adda.w    d2,a1
  247.     move.w    (a1)+,d2        ;get block width
  248.     move.w    d2,bsh_wid        ;save for use by move
  249.     beq    lib_sel1        ;br if null entry
  250. *
  251. *
  252.     move.w    d2,d5            ;copy width
  253.     lsr.w    #1,d5
  254.     sub.w    d5,d0            ;adjust xpos by 1/2 width
  255. *
  256.     move.w    d0,bsh_x        ;we allow bsh_x < 0
  257. *
  258. *
  259.     move.w    (a1)+,d3        ;get block height
  260.     move.w    d3,bsh_hite        ;save for use by move
  261. *
  262.     move.w    d3,d6
  263.     lsr.w    #1,d6
  264.     sub.w    d6,d1
  265. *
  266.     move.w    d1,bsh_y
  267. *
  268.     move.l    (a1)+,a3    ;a3 -> s_form
  269.     move.l    (a1)+,a2    ;object name string
  270. *
  271. *  is this an intrinsic object?
  272. *
  273.     move.w    curbrush,d6
  274.     cmp.w    maxintrins,d6
  275.     bls    strcpyx        ;br if intrinsic
  276.     move.l    (a2),a2        ;else, derived
  277. strcpyx:
  278. *
  279.     lea    brshfile,a0    ;use this to copy brush name
  280.     move.l    a0,-(sp)
  281. strcopy:
  282.     move.b    (a2)+,d6
  283.     move.b    d6,(a0)+
  284.     cmpi.b    #" ",d6
  285.     bhi    strcopy
  286.     clr.b    -(a0)
  287. *
  288.     move.l    (sp)+,a0
  289.     movem.l    a1-a3/d0-d3,-(sp)    
  290.     move.w    #LIBRARY,d0
  291.     bsr    DaveInfo    ;put brush name on the info bar
  292.     movem.l    (sp)+,a1-a3/d0-d3
  293. *
  294.     move.w    (a1)+,d4    ;get mask_offset
  295.     lea    (a3,d4.w),a0    ;get mono mask src_form
  296. *
  297.     move.w    (a1)+,d4    ;s_nxln for 4-plane brush
  298.     lsr.w    #2,d4        ;d4 = mono scr_nxln
  299.     move.w    d4,bsh_monoln
  300. *
  301. *
  302. *    d0 = DST x
  303. *    d1 = DST y
  304. *    d2 = width
  305. *    d3 = height
  306. *    d4 = mono mask scr_nxln
  307. *
  308. *    a0 -> mono mask s_form
  309. *    a3 -> 4-plane graphics s_form
  310. *
  311. *
  312.     bsr    bdisplay    ;display brush, clipped to screen
  313. *
  314. *    This loop is entered when a right button is down--
  315. *        exit loop when button released
  316. *
  317. lib_sel1:
  318.     bsr    getmouse
  319. *
  320.     bsr    CaryKey        ;check for user ctrl-keys
  321. *
  322. *  the following code allows function keys to be programmed
  323. *   during right-mouse button brush select mode
  324. *
  325.     tst.w    d4        ;any keyboard input?
  326.     beq    lib_sel0    ;br if not
  327.  
  328.     ror.w    #8,d4
  329.     cmpi.b    #FUNC_1,d4
  330.     bcs    lib_sel0
  331.     cmpi.b    #FUNC_10+1,d4
  332.     bcc    lib_sel0x
  333. *
  334. *  we want the brush from the function key
  335. *
  336.     moveq    #0,d0
  337.     move.b    d4,d0
  338.     subi.b    #FUNC_1,d0
  339.     lsl.w    #8,d0
  340.     bsr    Func_Key
  341.     move.w    curbrush,d1
  342.     bra    lib_sel4
  343. lib_sel0x:
  344.     cmpi.b    #SH_FUNC_1,d4
  345.     bcs    lib_sel0
  346.     cmpi.b    #SH_FUNC_10+1,d4
  347.     bcc    lib_sel0
  348. *
  349.     moveq    #0,d0
  350.     move.b    d4,d0
  351.     subi.b    #SH_FUNC_1,d0
  352.     lsl.w    #8,d0
  353.     bsr    Shift_Func_Key
  354. *
  355. lib_sel0:
  356.     move.l    mouseptr,a1
  357.     movem.w    (a1),d0-d1
  358.     and    #1,d3
  359.     bne    lib_sel1x
  360.     tst.w    bsh_wid        ;if null brush is selected, exit
  361.     beq    lib_xit
  362.     bra    lib_move    ;else, move this guy
  363. lib_sel1x:
  364.     sub.w    relcentx,d0    ;how far did mouse travel x-wise?
  365.     move.w    d0,d3
  366.     bpl    lib_sel2
  367.     neg.w    d3
  368. lib_sel2:
  369.     cmpi.w    #4,d3
  370.     bcs    lib_sel1
  371.     move.l    relcentx,(a1)    ;restore fake mouse to center position
  372. *
  373. *  We assume there exists at least one good brush..
  374. *
  375. nxt_bsh:
  376.     move.w    curbrush,d1
  377.     tst.w    d0        ;check sign
  378.     bmi    lib_sel3
  379.     addq.w    #1,d1
  380.     cmp.w    maxderivd,d1
  381. *
  382.     bls    lib_sel4
  383.     moveq    #0,d1
  384.     bra    lib_sel4    
  385. lib_sel3:
  386.     subq.w    #1,d1
  387.     bpl    lib_sel4
  388.     move.w    maxderivd,d1
  389. lib_sel4:
  390.     move.w    d1,curbrush
  391. *
  392.     lea    bshblock,a1
  393.     lsl.w    #4,d1
  394.     tst.w    (a1,d1.w)    ;are we a real brush?
  395.     beq    nxt_bsh        ;loop until we get a real one
  396. *
  397. *  the following screens out H & V flipped cache images
  398. *
  399.     move.l    8(a1,d1.w),a1    ;get ptr to derived entry
  400.     lsr.w    #4,d1
  401.     cmp.w    maxintrins,d1    ;are we intrinsic?
  402.     bls    lib_sel5    ;br if so--we'll take it
  403.     tst.w    4(a1)        ;are we a primary cluster?
  404.     bne    lib_sel5    ;br if so
  405.     move.w    8(a1),d1    ;get effects
  406.     andi.w    #Hflip+Vflip,d1    ;any flips?
  407.     bne    nxt_bsh        ;if so, skip display
  408. lib_sel5:
  409. *
  410.     bsr    pastund
  411.     bra    newstamp
  412. *
  413. lib_move:
  414.     move.l    relcentx,(a1)
  415. *
  416. lib_m:
  417.     clr.w    forceupd
  418.  
  419.     bsr    fat
  420. *
  421.     bsr    getmouse
  422. *
  423.     bsr    CaryKey
  424. *
  425.     bsr    ctrlkey        ;process cntrl keys
  426. *
  427.     tst.w    d4        ;any keyboard input?
  428.     beq    lib_m0
  429.     bsr    checkpri    ;check keyboard for re-prioritization
  430. lib_m0:
  431.     and.w    #1,d3        ;check for no buttons down
  432.     beq    lib_mx
  433. *
  434.     bclr.b    #1,BUT_STATE+1
  435.     bne    lib_xita    ;exit if right button down
  436. *
  437.     bclr.b    #0,BUT_STATE+1    ;check for left down
  438.     beq    lib_mx        ;br if left not down
  439. *
  440. *   A brush is stamped into the world..
  441. *
  442.     bsr    pastund        ;erase display brush
  443.     movem.w    xmin_clp,d4-d7    ;get window clipping rectangle
  444.     movem.w    d4-d7,-(sp)    ;save
  445. *
  446.     lea    wstruct+xoffset,a5
  447.     move.w    d4,d0
  448.     sub.w    xoffset(a5),d0
  449.     add.w    w_wid(a5),d0    ;comput world clip rectangle
  450.     cmp.w    d0,d6        ;take the smaller of world/window
  451.     ble    xclpok
  452.     move.w    d0,d6
  453. xclpok:
  454.     move.w    d5,d0
  455.     sub.w    yoffset(a5),d0
  456.     add.w    w_hite(a5),d0
  457.     cmp    d0,d7
  458.     ble    yclpok
  459.     move.w    d0,d7
  460. yclpok:
  461.     movem.w    d4-d7,xmin_clp    ;save new clip rect
  462. *
  463.     movem.w    bsh_x,d0-d4
  464.  
  465.     cmp.w    d6,d0        ;are we totally right of clip?
  466.     bge    skipstmp
  467. *
  468.     cmp.w    d7,d1
  469.     bge    skipstmp
  470. *
  471.     bsr    bdisplay    ;put up a world-clipped brush
  472. *
  473. *  now blit to world buffer as well
  474. *
  475.     movem.l    a0/a3/a5,-(sp)    ;save s_forms ptrs
  476.     movem.w    bsh_x,d0-d4    ;get screen brush position
  477. *
  478. *  put entry into world object list
  479. *
  480.     move.l    wblkptr,a0    ;open up a hole in world object list
  481.     lea    8(a0),a3    ;open up a hole in world object list
  482.     move.l    a3,wblkptr
  483.     move.l    wblkcur,a2
  484.     bra    holelpi
  485. holelp:
  486.     move.l    -(a0),-(a3)
  487.     move.l    -(a0),-(a3)
  488. holelpi:
  489.     cmp.l    a0,a2
  490.     bcs    holelp
  491. *
  492.     move.w    curbrush,(a2)+    ;save brush #
  493.     clr.w    (a2)+        ;special effect (not used yet)
  494. *
  495.     sub.w    wx(a5),d0
  496.     add.w    xoffset(a5),d0    ;d0 = world relative x_min
  497.     move.w    d0,(a2)+    ;
  498. *    
  499.     sub.w    wy(a5),d1
  500.     add.w    yoffset(a5),d1    ;d1 = world relative y_min
  501.     move.w    d1,(a2)+    ;
  502.     move.l    a2,wblkcur    ;adjust priority ptr
  503. *    
  504.     lea    grafbsh,a3
  505.     lea    grafmsk,a0
  506.     bsr    wldblit        ;blit to world buffer too
  507.     movem.l    (sp)+,a0/a3/a5    ;restore old brush s_forms    
  508.  
  509. *
  510. skipstmp:
  511.     lea    bitblock,a6
  512.     bsr    copyund
  513. *
  514. *
  515.     movem.w    (sp)+,d0-d3
  516.     movem.w    d0-d3,xmin_clp    ;put back world clip
  517. *  fake a move
  518. *    movem.w    bsh_x,d2-d3
  519. *    addq.w    #1,d2
  520. *    move.w    #$7f,d0
  521. *    move.w    #$80,d1
  522.     moveq    #1,d4
  523.     bra    lib_cheat
  524. *
  525. *
  526. lib_mx:
  527.     move.w    grid,d4
  528. lib_cheat:
  529.     movem.w    bsh_x,d2-d3    ;pick up current positions
  530.     move.l    mouseptr,a1
  531.     movem.w    (a1),d0-d1
  532.     move.l    relcentx,(a1)
  533. *
  534.     sub.w    relcentx,d0    ;check x move
  535.     beq    lib_mov1    ;br if no x move
  536.     moveq    #-1,d4        ;indicate a move
  537.     add.w    d2,d0        ;get proposed new x position
  538.     cmp.w    Mclpxmx,d0    ;does it go beyond our clip?
  539.     blt    clp_mov1    ;br if ok on right
  540.     move.w    Mclpxmx,d0
  541.     subq.w    #1,d0        ;anchor at right maximum
  542. clp_mov1:
  543.     move.w    d0,d5
  544.     add.w    bsh_wid,d5
  545.     subq.w    #1,d5
  546.     cmp.w    Mclpxmn,d5
  547.     bge    clp_mov2
  548.     move.w    Mclpxmn,d0
  549.     sub.w    bsh_wid,d0
  550.     addq.w    #1,d0
  551. clp_mov2:
  552.     move.w    d0,d2
  553. *
  554. *  Check on vert movement
  555. *
  556. lib_mov1:
  557.     sub.w    relcenty,d1    ;check y move
  558.     beq    lib_mov2    ;br if no y move
  559.     moveq    #-1,d4        ;indicate a move
  560.     add.w    d3,d1        ;get proposed new y position
  561.     cmp.w    Mclpymx,d1    ;does it go beyond our clip?
  562.     blt    clp_mov3    ;br if ok on bottom
  563.     move.w    Mclpymx,d1
  564.     subq.w    #1,d1        ;anchor at bottom maximum
  565. clp_mov3:
  566.     move.w    d1,d5
  567.     add.w    bsh_hite,d5
  568.     subq.w    #1,d5
  569.     cmp.w    Mclpymn,d5
  570.     bge    clp_mov4
  571.     move.w    Mclpymn,d1
  572.     sub.w    bsh_hite,d1
  573.     addq.w    #1,d1
  574. clp_mov4:
  575.     move.w    d1,d3
  576. lib_mov2:
  577.     movem.w    bsh_x,d0-d1    ;check old position
  578.  
  579.     cmpi.w    #1,d4
  580.     beq    do_mov        ;br if this a grid init
  581. *
  582.     tst.w    forceupd    ;is this a forced update?
  583.     bne    lib_mov5    ;br if so
  584. *    
  585.     tst.w    d4
  586.     beq    lib_m        ;br if no move
  587. *
  588. *
  589.     cmp.w    d2,d0
  590.     bne    do_movx
  591.     cmp.w    d3,d1
  592.     beq    lib_m        ;br if new position same as old
  593. lib_mov5:
  594. *
  595. *   Here's some constrain stuff
  596. *
  597. do_movx:
  598.     move.w    constrain,d6    ;check contrain status
  599.     beq    do_mov        ;0=none,1=horz,2=vert,-1=init
  600.     cmpi.w    #-1,d6        ;is it init?
  601.     bne    cstrain4    ;br if not
  602.     move.w    d0,d4
  603.     sub.w    d2,d4
  604.     bpl    cstrain1
  605.     neg.w    d4
  606. cstrain1:
  607.     move.w    d1,d5
  608.     sub.w    d3,d5
  609.     bpl    cstrain2
  610.     neg.w    d5
  611. cstrain2:
  612.     moveq    #1,d6
  613.     cmp.w    d4,d5
  614.     beq    lib_m        ;no move if both the same
  615.     bls    cstrain3
  616.     moveq    #2,d6
  617. cstrain3:
  618.     move.w    d6,constrain
  619. cstrain4:
  620.     cmp.w    #1,d6        ;horz constrain?
  621.     bne    cstrain5
  622.     move.w    d1,d3
  623.     bra    do_mov
  624. cstrain5:
  625.     move.w    d0,d2
  626. *
  627. *    
  628. do_mov:
  629. *
  630. *   check grid
  631. *
  632.     move.w    grid,d4
  633.     beq    nogrid        ;skip if grid isn't on
  634. *
  635.     bmi    do_grid        ;br if grid-continue
  636. *
  637. *  grid init
  638. *
  639.     movem.w    d2-d3,bsh_x
  640. *
  641.     move.w    #-1,grid
  642. *
  643.     movem.w    bsh_x,d0-d1    ;get current brush position
  644. *
  645.     lea    wstruct+xoffset,a5
  646.     sub.w    wx(a5),d0
  647.     add.w    xoffset(a5),d0    ;d0= world xpos
  648. *
  649.     sub    wy(a5),d1
  650.     add.w    yoffset(a5),d1
  651. *
  652. *  We're in world co-ords now
  653. *  enforce grid position NOW!
  654. *
  655.     movem.w    d0-d1,-(sp)
  656.     movem.w    Grid,d2-d5    ;get grid co-ords
  657. *
  658.     tst.w    d4        ;convert 0's to 1's
  659.     bne    grid0
  660.     moveq    #1,d4
  661. grid0:
  662.     tst.w    d5
  663.     bne    grid1
  664.     moveq    #1,d5
  665. grid1:
  666.     sub.w    d2,d0
  667.     sub.w    d3,d1
  668.     ext.l    d0
  669.     ext.l    d1
  670.     divs    d4,d0
  671.     divs    d5,d1
  672.     swap    d0    ;get signed remainder for x (dividend has same sign) 
  673.     tst.w    d0
  674.     bpl    grid2
  675.     add.w    d4,d0    ;make positive
  676. grid2:
  677.     swap    d1        ; & for y
  678.     tst.w    d1
  679.     bpl    grid3
  680.     add.w    d5,d1
  681. grid3:
  682.     movem.w    (sp)+,d2-d3    ;get original world x & y
  683. *
  684.     move.w    d4,d6
  685.     lsl.w    #1,d0        ;x remainder *2
  686.     cmp.w    d0,d4        ;less than 1/2 way to next grid point?
  687.     bhi    grid4        ;br if so
  688. *
  689. *  more than 1/2 way--compute amount to add
  690. *
  691.     lsr.w    #1,d0
  692.     sub.w    d0,d6
  693.     add.w    d6,d2
  694.     neg.w    d6        ;d6 = offset
  695.     bra    grid5
  696. *
  697. *  less than 1/2 way--use d0 to subtract
  698. *
  699. grid4:    
  700.     lsr.w    #1,d0
  701.     sub.w    d0,d2
  702.     move.w    d0,d6
  703. grid5:
  704.     move.w    d6,xgridoff
  705. *
  706. *
  707.     move.w    d5,d7
  708.     lsl.w    #1,d1        ;y remainder *2
  709.     cmp.w    d1,d5        ;less than 1/2 way to next grid point?
  710.     bhi    grid6        ;br if so
  711. *
  712. *  more than 1/2 way--compute amount to add
  713. *
  714.     lsr.w    #1,d1
  715.     sub.w    d1,d7
  716.     add.w    d7,d3
  717.     neg.w    d7        ;d7 = offset
  718.     bra    grid7
  719. *
  720. *  less than 1/2 way--use d1 to subtract
  721. *
  722. grid6:    
  723.     lsr.w    #1,d1
  724.     sub.w    d1,d3
  725.     move.w    d1,d7
  726. grid7:
  727.     move.w    d7,ygridoff
  728. *
  729. *  Restore to screen co-ords..
  730. *
  731.     add.w    wx(a5),d2
  732.     sub.w    xoffset(a5),d2
  733.     add.w    wy(a5),d3
  734.     sub.w    yoffset(a5),d3
  735. *
  736. *  Make sure new position is on window..
  737. *
  738.     moveq    #0,d7
  739.     movem.w    bsh_wid,d0-d1
  740.     add.w    d2,d0        ;get brush right edge
  741.     move.w    wx(a5),d6
  742.     cmp.w    d0,d6        ;is new brush position too far left?
  743.     blt    ritechk        ;br if not
  744.     add.w    d4,d2        ;else, just position one notch to right
  745.     addq.w    #1,d7
  746. ritechk:
  747.     add.w    wwidth(a5),d6    ;get window xmax (+1)
  748. *
  749.     subq.w    #1,d6
  750.     cmp.w    form_width,d6    ;window exceeds screen?
  751.     ble    notxscre
  752.     move.w    form_width,d6
  753. notxscre:
  754.     addq.w    #1,d6
  755. *
  756.     cmp.w    d2,d6
  757.     bgt    topchk
  758.     sub.w    d4,d2
  759.     addq.w    #1,d7
  760. topchk:
  761.     cmpi.w    #2,d7
  762.     beq    cantwind    ;br if can't find any anchor point on window
  763. *
  764.     moveq    #0,d6
  765.     add.w    d3,d1        ;get brush bottom edge
  766.     move.w    wy(a5),d7
  767.     cmp.w    d1,d7
  768.     blt    botchk
  769.     add.w    d5,d3
  770.     addq.w    #1,d6
  771. botchk:
  772.     add.w    wheight(a5),d7    ;get window ymax +1
  773. *
  774.     subq.w    #1,d7
  775.     cmp.w    form_height,d7    ;window exceeds screen?
  776.     ble    notyscre
  777.     move.w    form_height,d7
  778. notyscre:
  779.     addq.w    #1,d7
  780. *
  781.     cmp.w    d3,d7
  782.     bgt    owind
  783.     sub.w    d5,d3
  784.     add.w    #1,d6
  785. owind:
  786.     cmpi.w    #2,d6
  787.     bne    goodwin
  788. cantwind:
  789.     movem.w    bsh_x,d2-d3    ;just got to use the old values
  790. *
  791. goodwin:
  792.     movem.w    d2-d3,bsh_x
  793. *
  794. offworld:
  795.     bra    nogrid        ;skip this grid thang if just entered
  796. *
  797. *  we're griddin'
  798. *
  799. do_grid:
  800.     moveq    #0,d7        ;indicate no move
  801. *
  802. *    movem.w    gridw,d4-d5    ;get grid width & height
  803.     movem.w    Grid+4,d4-d5
  804. *
  805.     tst.w    d4
  806.     bne    grdx
  807.     moveq    #1,d4
  808. grdx:
  809.     tst.w    d5
  810.     bne    grdy
  811.     moveq    #1,d5
  812. grdy:
  813.     sub.w    d2,d0
  814.     sub.w    d3,d1
  815. *
  816.     neg.w    d0
  817.     neg.w    d1
  818. *
  819.     sub.w    d0,d2        ;undo the move for now
  820. *
  821.     add.w    xgridoff,d0    ;add xaccum to delta
  822.     move.w    d0,d6
  823.     bpl    grd0
  824.     neg.w    d6
  825.     add.w    d6,d6
  826.     cmp.w    d4,d6        ;more than 1/2 way to the goal line?
  827.     bcs    grd1        ;br if no grid jump yet
  828. grd0a:
  829.     sub.w    d4,d2        ;adjust xpos
  830.     add.w    d4,d0        ;adjust new xgridoff till it goes positive
  831.     bmi    grd0a
  832. *
  833.     bra    grd1a
  834. grd0:
  835.     add.w    d6,d6
  836.     cmp.w    d4,d6
  837.     bcs    grd1        ;br if no grid jump yet
  838. grd0b:
  839.     add.w    d4,d2        ;adjust xpos
  840.     sub.w    d4,d0
  841.     bpl    grd0b        ;adjust new xgridoff till it goes negative
  842. grd1a:
  843.     moveq    #-1,d7
  844. grd1:
  845.     move.w    d0,xgridoff
  846. *
  847. *  Now do y
  848. *
  849.     sub.w    d1,d3        ;undo the move for now
  850.     add.w    ygridoff,d1    ;add yaccum to delta
  851.     move.w    d1,d6
  852.     bpl    grd2
  853.     neg.w    d6
  854.     add.w    d6,d6
  855.     cmp.w    d5,d6        ;more than 1/2 way to the goal line?
  856.     bcs    grd3        ;br if no grid jump yet
  857. grd2a:
  858.     sub.w    d5,d3        ;adjust ypos
  859.     add.w    d5,d1        ;adjust new ygridoff till it goes positive
  860.     bmi    grd2a
  861.     bra    grd3a
  862. grd2:
  863.     add.w    d6,d6
  864.     cmp.w    d5,d6
  865.     bcs    grd3        ;br if no grid jump yet
  866. grd2b:
  867.     add.w    d5,d3        ;adjust ypos
  868.     sub.w    d5,d1
  869.     bpl    grd2b    
  870. grd3a:
  871.     moveq    #-1,d7
  872. grd3:
  873.     move.w    d1,ygridoff
  874.     tst.w    forceupd    ;check for forced update
  875.     bne    grd4
  876.     tst.w    d7
  877.     beq    lib_m        ;don't flash if we haven't grid-moved
  878. grd4:
  879. *
  880. *  Check for outside window (we don't permit outside window)
  881. *
  882.     bsr    offwind
  883.     beq    nogrid        ;br if on window
  884. *
  885.     movem.w    bsh_x,d2-d3    ;else, just use previous
  886. *
  887. *  End of grid maddness
  888. *
  889. nogrid:
  890.     movem.w    d2-d3,bsh_x
  891. *
  892.     sub.w    wx(a5),d2
  893.     add.w    xoffset(a5),d2
  894.     move.w    d2,d0
  895. *
  896.     lea    infox,a1
  897.     bsr    decitpad
  898. *
  899.     move.w    bsh_y,d0
  900.     sub.w    wy(a5),d0
  901.     add.w    yoffset(a5),d0
  902. *
  903.     lea    infoy,a1
  904.     bsr    decitpad
  905. *
  906.  
  907.     move.l    a0,-(sp)
  908.     move.w    #WORLD,d0
  909.     lea    infostrng,a0
  910.     bsr    DaveInfo
  911.     move.l    (sp)+,a0
  912. *
  913.     bsr    pastund
  914. *
  915. *
  916.     movem.w    bsh_x,d0-d4
  917.     bsr    bdisplay
  918. *
  919. *
  920.     bra    lib_m
  921. *
  922. *
  923. lib_xita:
  924.     bsr    wtritup
  925. *
  926. lib_xit:
  927.     bsr    pastund
  928. *
  929. *
  930. but_xit:
  931.     bsr    bsh2curs
  932. but_xit0:
  933.     move.w    #MouseOn,d0
  934.     bsr    Graf_Mouse
  935. *
  936.     bsr    Back2G        ;check for curbrush = cluster
  937. *
  938.     lea    world_ID,a0
  939.     move.w    #WORLD,d0
  940.     bsr    DaveName    ;put world name back on title bar
  941. *
  942.     bsr    fatquit
  943.     bsr    wtritup
  944. *
  945. *    lea    Mrets,a0
  946. *    bsr    Graf_mkstate    ;clean up AES
  947. *
  948.     movem.l    (sp)+,a0-a6/d0-d7
  949.  
  950.     rts
  951. *
  952. *  Put system cursor at about the center of the brush
  953. *
  954. bsh2curs:
  955.     movem.l    a1/d0-d3,-(sp)
  956.     move.l    mouseptr,a1
  957.     movem.w    bsh_x,d0-d3
  958.     lsr.w    #1,d2
  959.     lsr.w    #1,d3
  960.     add.w    d2,d0
  961.     add.w    d3,d1
  962. *
  963. *  clip new x,y mouse position to the screen
  964. *
  965.     tst.w    d0
  966.     bpl    mxok
  967.     moveq    #0,d0
  968. mxok:
  969.     cmp.w    form_width,d0
  970.     bcs    mxok1
  971.     move.w    form_width,d0
  972. mxok1:
  973.     tst.w    d1
  974.     bpl    myok
  975.     moveq    #0,d1
  976. myok:
  977.     cmp.w    form_height,d1
  978.     bcs    myok1
  979.     move.w    form_height,d1
  980. myok1:
  981. *
  982.     movem.w    d0-d1,(a1)
  983.     movem.l    (sp)+,a1/d0-d3
  984.     rts
  985. *
  986. *
  987. *   Wait for right button to come up
  988. *
  989. wtritup:
  990.     bsr    getmouse
  991.     and.w    #1,d3
  992.     bne    wtritup
  993. *
  994.     bclr.b    #1,BUT_STATE+1
  995.     bne    wtritup
  996.     bclr.b    #0,BUT_STATE+1
  997.     bne    wtritup
  998.     rts
  999. *
  1000. *
  1001. *   Let Cary call this to display xoffset/yoffset
  1002. *
  1003. DisplayXY:
  1004.     movem.l    a0-a6/d0-d7,-(sp)
  1005.     move.w    wstruct+xoffset,d0
  1006.     lea    infox,a1
  1007.     bsr    decitpad
  1008. *
  1009.     move.w    wstruct+yoffset,d0
  1010.     lea    infoy,a1
  1011.     bsr    decitpad
  1012. *
  1013.     move.w    #WORLD,d0
  1014.     lea    infostrng,a0
  1015.     bsr    DaveInfo
  1016.     movem.l    (sp)+,a0-a6/d0-d7
  1017.     rts
  1018. *
  1019. *
  1020. *  Check for outside window (we don't permit outside window)
  1021. *
  1022. *  assume d2-d3 is bsh_x, bsh_y
  1023. *  a5 -> wstruct
  1024. *
  1025. offwind:
  1026.     movem.w    bsh_wid,d0-d1
  1027.     add.w    d2,d0        ;get brush right edge +1
  1028.     move.w    wx(a5),d6    ;get window x-minimum
  1029.     cmp.w    d0,d6
  1030.     bge    offwx
  1031. *
  1032.     add.w    wwidth(a5),d6    ;get window x-max +1
  1033. *
  1034.     subq.w    #1,d6
  1035.     cmp.w    form_width,d6    ;window exceeds screen?
  1036.     ble    nxscre
  1037.     move.w    form_width,d6
  1038. nxscre:
  1039.     addq.w    #1,d6
  1040. *
  1041.     cmp.w    d2,d6
  1042.     ble    offwx
  1043. *
  1044.     add.w    d3,d1        ;get brush bot edge +1
  1045.     move.w    wy(a5),d7
  1046.     cmp.w    d1,d7
  1047.     bge    offwx
  1048. *
  1049.     add.w    wheight(a5),d7
  1050.  
  1051.     subq.w    #1,d7
  1052.     cmp.w    form_height,d7    ;window exceeds screen?
  1053.     ble    nyscre
  1054.     move.w    form_height,d7
  1055. nyscre:
  1056.     addq.w    #1,d7
  1057. *
  1058.     cmp.w    d3,d7
  1059.     bgt    onwind
  1060. offwx:
  1061.     moveq    #-1,d0        ;indicate off window
  1062.     rts
  1063. onwind:
  1064.     moveq    #0,d0        ;indicate on window
  1065.     rts
  1066. *
  1067. *
  1068. ********************************************************
  1069. *
  1070. *   This comes from Cary when a key is hit
  1071. *
  1072. *    d0 = shift keys
  1073. *    d1 = scan code + ASCII code of a key
  1074. *    d2 = topped window (-1 if not one of ours)
  1075. *
  1076. DaveKey:
  1077.     cmpi.w    #WORLD,d2    ;is world window topped?
  1078.     bne    Dky1        ;br if not topped        
  1079.     cmpi.b    #"a",d1        ;force upper case
  1080.     bcs    Dky0
  1081.     subi.b    #$20,d1        
  1082. Dky0:
  1083.     cmpi.b    #"C",d1        ;enter "cluster" mode?
  1084.     beq    docluster    ;br if so
  1085. *
  1086.     cmpi.b    #"B",d1        ;enter "bridge" mode?
  1087.     beq    dobridge
  1088. *
  1089.     cmpi.b    #"R",d1        ;enter filled Rectangle mode?
  1090.     beq    dorect
  1091. Dky1:
  1092.     rts            ;exit to ignore any other key
  1093. *
  1094. *
  1095. *
  1096. docluster:
  1097.     movem.l    a0-a6/d0-d7,-(sp)
  1098.     move.w    #$8001,aggreg    ;indicate a cluster aggregate
  1099.     bra    aggregate
  1100. *
  1101. *
  1102. dobridge:
  1103.     movem.l    a0-a6/d0-d7,-(sp)
  1104.     move.w    #1,aggreg    ;indicate bridge aggregate
  1105. *
  1106. *  Enter CLUSTER/BRIDGE select mode
  1107. *
  1108. aggregate:
  1109.     moveq    #outlnx,d0
  1110.     bsr    Graf_Mouse
  1111. *
  1112.     clr.w    butt        ;init button edge shadow
  1113. *
  1114.     lea    tempbuf,a3    ;start cluster list here
  1115.  
  1116.     move.w    #$7fff,d0    ;largest 16-bit signed
  1117.     move.w    d0,d1
  1118.     move.w    #$8000,d2    ;smallest 16-bit signed
  1119.     move.w    d2,d3
  1120.     movem.w    d0-d3,xmin_clust    ;init min/max stuff
  1121. *
  1122. aggrcnt:
  1123.     lea    bridg_msg,a0
  1124.     move.w    aggreg,d0
  1125.     cmpi.w    #4,d0        ;reached end of a bridge?
  1126.     beq    brid_xit    ;br if so
  1127. *
  1128.     bclr.l    #15,d0
  1129.     beq    aggr0
  1130.     lea    clust_msg,a0
  1131. aggr0:
  1132.     lea    17(a0),a1
  1133.     bsr    decitpad
  1134. *
  1135.     move.w    #WORLD,d0
  1136.     move.l    a3,-(sp)    ;save the cluster list ptr
  1137.     bsr    DaveInfo    ;tell 'em our mode
  1138.     move.l    (sp)+,a3
  1139. *
  1140. aggrlp:
  1141.     bsr    getmouse    ;let GEM have control for a while
  1142.     andi.w    #1,d3        ;any mouse buttons?
  1143.     beq    aggr3        ;br if none
  1144. *
  1145.     move.w    BUT_STATE,d6    ;get left & right
  1146.     clr.w    BUT_STATE    
  1147.     move.w    butt,d5
  1148.     move.w    d3,butt
  1149.     eor.w    d3,d5
  1150.     bne    aggrbut        ;br if positive edge on button
  1151. aggr3:
  1152.     move.w    d3,butt
  1153. *
  1154.     tst.w    d4        ;any keyboard?
  1155.     beq    aggrlp        ;br if not
  1156. *
  1157. *  we got a key
  1158. *
  1159.     tst.b    d4        ;ASCII code?
  1160.     beq    aggrlp        ;br if not
  1161. *
  1162.     cmpi.b    #"a",d4
  1163.     bcs    aggr1
  1164.     subi.b    #$20,d4        ;force upper case
  1165. aggr1:
  1166.     cmpi.b    #esc,d4        ;are we escape?
  1167.     beq    ag_abort    ;br if so
  1168. *
  1169.     bra    aggrlp        ;go for more user input
  1170. *
  1171. *  Button was pressed--find sprite selected
  1172. *
  1173. aggrbut:
  1174.     btst.l    #1,d6        ;check for right button
  1175.     bne    aggr_xit    ;exit if right button
  1176. *
  1177.     lea    wstruct,a5
  1178.     move.l    mouseptr,a0
  1179.     movem.w    (a0),d0-d1    ;get mouse screen cursor x/y
  1180. *
  1181. *   Gotta be on the world window
  1182. *
  1183.     movem.w    wx(a5),d2-d3
  1184.     cmp.w    d2,d0    ;
  1185.     blt    aggrlp        ;exit if off window
  1186.     cmp.w    d3,d1
  1187.     blt    aggrlp
  1188. *
  1189.     add.w    wwidth(a5),d2
  1190.     cmp.w    d2,d0
  1191.     bge    aggrlp
  1192. *
  1193.     add.w    wheight(a5),d3
  1194.     cmp.w    d3,d1
  1195.     bge    aggrlp
  1196. *
  1197. *  mouse is on the world window work area
  1198. *
  1199.     sub.w    wx(a5),d0
  1200.     add.w    xoffset(a5),d0    ;adjust for world co-ords
  1201.     sub.w    wy(a5),d1
  1202.     add.w    yoffset(a5),d1
  1203. *
  1204. *  Search the worldblk for the highest priority object
  1205. *   whose rectangle falls within the mouse position
  1206. *
  1207.     cmp.w    w_wid(a5),d0    ;are we right of the world
  1208.     bge    aggrlp        ;br if so
  1209.     cmp.w    w_hite(a5),d1
  1210.     bge    aggrlp        ;br if below world
  1211. *
  1212.     move.l    wblkptr,a0        ;get pointer to end +1
  1213.     move.l    #worldblk,a1        ; & ptr to beginning
  1214.     lea    bshblock,a2
  1215.     bra    aggrreci
  1216. aggreclp:
  1217.     move.w    -(a0),d3    ;get vpos
  1218.     move.w    -(a0),d2    ;hpos
  1219.     subq.l    #2,a0        ;skip special effects
  1220.     move.w    -(a0),d4    ;brush #
  1221. *
  1222.     cmp.w    d0,d2        ;are we entirely to left?
  1223.     bgt    aggrreci    ;br if so
  1224. *
  1225.     cmp.w    d1,d3        ;are we entirely above?
  1226.     bgt    aggrreci    ;br if yes
  1227. *
  1228. *  we may have found our boy--check width & height
  1229. *
  1230.     move.w    d4,d5
  1231.     swap    d5        ;save possible curbrush in upper word
  1232. *
  1233.     lsl.w    #4,d4        ;get offset into bshblock
  1234.     move.w    (a2,d4.w),d5    ;get width
  1235.     move.w    2(a2,d4.w),d6    ; & height
  1236.     add.w    d2,d5
  1237.     add.w    d3,d6
  1238. *
  1239.     cmp.w    d0,d5
  1240.     ble    aggrreci
  1241. *
  1242.     cmp.w    d1,d6
  1243.     ble    aggrreci    ;br if outside rect
  1244. *
  1245.     move.w    d5,a4
  1246.     move.w    d6,a6        ;save in case we need
  1247. *
  1248. *  we're inside a rectangle--check mask for pixel level match
  1249. *
  1250.     move.l    4(a2,d4.w),a5    ;get graphics s_form
  1251.     adda.w    12(a2,d4.w),a5    ;get mono mask s_form
  1252.     move.w    14(a2,d4.w),d5    ;get bytes/line
  1253.     lsr.w    #2,d5
  1254.     move.w    d0,d6
  1255.     sub.w    d2,d6        ;d6 = horz offset into mask form
  1256.     move.w    d1,d7
  1257.     sub.w    d3,d7        ;d7 = # rows down the form
  1258.     mulu    d5,d7
  1259.     add.l    d7,a5
  1260.     move.w    d6,d7
  1261.     asr.w    #3,d7
  1262.     adda.w    d7,a5
  1263.     not.w    d6
  1264.     andi.w    #7,d6        ;d6 = dot address    
  1265.     btst.b    d6,(a5)        ;do we have a hit, or miss
  1266.     beq    aggrreci
  1267. *
  1268. *  we have hit the nail on the head
  1269. *
  1270.     swap    d5
  1271.     move.w    d5,d0        ;brush # to d0
  1272. *
  1273.     move.w    a4,d5
  1274.     move.w    a6,d6
  1275. *
  1276. *  d2 - xmin
  1277. *  d3 - ymin
  1278. *  d5 - xmax +1
  1279. *  d6 - ymax +1
  1280. *
  1281. *  accumulate cluster-wide min/max info
  1282. *
  1283.     cmp.w    xmin_clust,d2
  1284.     bge    aggr5
  1285.     move.w    d2,xmin_clust
  1286. aggr5:
  1287.     cmp.w    ymin_clust,d3
  1288.     bge    aggr6
  1289.     move.w    d3,ymin_clust
  1290. aggr6:
  1291.     cmp.w    xmax_clust,d5
  1292.     ble    aggr7
  1293.     move.w    d5,xmax_clust
  1294. aggr7:
  1295.     cmp.w    ymax_clust,d6
  1296.     ble    aggr8
  1297.     move.w    d6,ymax_clust
  1298. aggr8:
  1299. *
  1300. *  we got one--see if we got it already
  1301. *
  1302.     movem.l    a1/a3,-(sp)    ;keep our place on list
  1303.     cmp.l    #tempbuf+100,a3    ;have we gone beyond capacity here?
  1304.     bcc    xistskip
  1305. *
  1306.     lea    tempbuf,a1
  1307.     bra    xistchki
  1308. xistchk:
  1309.     cmp.l    -(a3),a0
  1310.     bne    xistchki
  1311. *
  1312. *  we've already selected this item--skip it this time
  1313. *
  1314. xistskip:
  1315.     movem.l    (sp)+,a1/a3
  1316.     bra    aggrcnt    
  1317. xistchki:
  1318.     cmp.l    a3,a1        ;reached beginning?
  1319.     bcs    xistchk        ;br if not
  1320. *
  1321. *  else, our new one hasn't been picked already..
  1322. *    
  1323.     movem.l    (sp)+,a1/a3    ;end exist check
  1324.     
  1325.     move.l    a0,(a3)+    ;save cluster ptr
  1326. *
  1327.     move.l    a3,-(sp)
  1328.     lea    bshblock,a0
  1329.     bsr    upname        ;put up the name
  1330.     move.l    (sp)+,a3
  1331. *
  1332.     addq.w    #1,aggreg
  1333. *
  1334.     bra    aggrcnt        ;count up next one
  1335. *    
  1336. aggrreci:
  1337.     cmp.l    a0,a1
  1338.     bcs    aggreclp    ;look for next item in world
  1339. *
  1340. *  no more items, air-ball click here..
  1341. *
  1342.     bra    aggrlp        ;get next user input
  1343. *
  1344. *  We finished a bridge (always 3 elements)..
  1345. *
  1346. brid_xit:
  1347. *
  1348. *  see if horz or vert bridge..
  1349. *
  1350.     lea    tempbuf,a0
  1351.     lea    bshblock,a5
  1352. *
  1353. *  see if any of the three are aggregates..
  1354. *
  1355.     moveq    #2,d1        ;check all three
  1356.     moveq    #0,d2        ;count of aggregates found
  1357. aggr3lp:
  1358.     move.l    (a0)+,a1    ;get next item
  1359. aggr3lp0:
  1360.     move.w    (a1)+,d0    ;check derived
  1361.     cmp.w    maxintrins,d0    ;are we intrinsic or derived?
  1362.     bls    aggrno        ;br if intrinsic
  1363. *
  1364.     lsl.w    #4,d0
  1365.     move.l    8(a5,d0.w),a1    ;look at derived info block
  1366.     addq.l    #4,a1        ;skip over string ptr
  1367.     tst.w    (a1)+        ;multiple elements here?
  1368.     beq    aggr3lp0    ;br if not--recheck for intrinsic
  1369.     move.l    -(a0),d3    ;put root of this aggregate in d3
  1370.     addq.l    #4,a0
  1371.     addq.w    #1,d2        ;inc the agg count
  1372. aggrno:
  1373.     dbra    d1,aggr3lp    ;search rest of 'em
  1374. *
  1375.     lea    tempbuf,a0
  1376.     movem.l    (a0),a1-a3    ;a1, a2, a3 -> three element entries
  1377.     lea    brshfile,a4
  1378. *
  1379. *
  1380. *******temp test
  1381. *    bra    aggrnox        ;just jump into normal aggregate
  1382. *    tst.w    d2
  1383. *    bne    ag_abort    ;abort if ANY aggregates
  1384. *** end test
  1385. *
  1386. *
  1387.     cmpi.w    #1,d2
  1388.     bhi    ag_abort    ;abort if more than 1 aggregate
  1389.     tst.w    d2
  1390.     beq    aggrnox        ;do normal if no aggregates
  1391. *
  1392. *  we have 1 aggregate--look at other two for orientation..
  1393. *
  1394.     cmp.l    d3,a1
  1395.     bne    aggrchk
  1396.     exg    a3,a1
  1397.     bra    aggrx1
  1398. aggrchk:
  1399.     cmp.l    d3,a2
  1400.     bne    aggrx1
  1401.     exg    a3,a2
  1402. *
  1403. *  a1 & a2 are singles, a3 is aggregate
  1404. *
  1405. aggrx1:
  1406.  
  1407.     movem.w    4(a1),d0-d1    ;get hpos/vpos of one 
  1408.     movem.w    4(a2),d6-d7    ; & hpos/vpos of the other
  1409.     sub.w    d0,d6
  1410.     bpl    aggrx2        ;get absolute value of horz delta
  1411.     neg.w    d6
  1412. aggrx2:
  1413.     sub.w    d1,d7
  1414.     bpl    aggrx3        ;get vert delta
  1415.     neg.w    d7
  1416. aggrx3:
  1417.     cmp.w    d7,d6        ;which is greater, horz or vert?
  1418.     ble    v2big        ;br if vertical
  1419. *
  1420. *  a1, a2 -> intrinsics
  1421. *
  1422.     move.w    4(a1),d0
  1423.     cmp.w    4(a2),d0
  1424.     bcs    aggrx4
  1425.     exg    a1,a2        ;a1 -> leftmost intrinsic
  1426. aggrx4:
  1427. *
  1428. *  we're horz--which end of compound bridge to bridge to?
  1429. *
  1430. *  check 1st endbrush and eliminate if:
  1431. *
  1432. *    Endbrush horizontally between intrinsics
  1433. *    Endbrush face needed for new bridge is bridged already
  1434. *    Mean intrinsics vpos alignment with endbrush exceeds height
  1435. *
  1436. *
  1437.     move.w    (a3),d0
  1438.     lsl.w    #4,d0
  1439.     move.l    8(a5,d0.w),a6    
  1440.     movem.w    4(a3),d2-d3    ;get base hpos/vpos of compound bridge
  1441. *
  1442.     moveq    #0,d0        ;assume both endbrushes OK
  1443. *
  1444.     movem.w    10(a6),d4-d5    ;get relative hpos/vpos of 1st endbrush
  1445.     add.w    d2,d4        ;form absolute hpos
  1446.     add.w    d3,d5        ; & vpos
  1447.     move.w    d4,d6
  1448.     move.w    d4,d1
  1449.     sub.w    4(a1),d6
  1450.     sub.w    4(a2),d1
  1451.     eor.w    d6,d1        ;check endbrush between intrinsics
  1452.     bmi    must2        ;br if must reject 1st
  1453. *
  1454.     move.w    10(a6),d1    ;get relative hpos 1st endbrush
  1455.     sub.w    22(a6),d1    ;find delta with previous bridge
  1456.     beq    vbridg        ;br if its a vertical--face is avail
  1457.     eor.w    d6,d1        ;check for available face
  1458.     bpl    must2        ;br if face not avail, must select other or none
  1459. vbridg:
  1460.     move.w    6(a1),d1
  1461.     add.w    6(a2),d1
  1462.     lsr.w    #1,d1        ;d1 = average vpos of intrinsics
  1463.     sub.w    d5,d1        ;get delta with vpos of this endbrush
  1464.     bpl    hcheck
  1465.     neg.w    d1        ;get positive delta
  1466. hcheck:
  1467.     move.w    6(a6),d5    ;find 1st endbrush height
  1468.     lsl.w    #4,d5
  1469.     cmp.w    2(a5,d5.w),d1    ;1st endbrush height >= delta?
  1470.     bhi    must2        ;br if vertical alignment not good enough
  1471. *
  1472. *  we pass the 3 tests for 1st endbrush, now check last
  1473. *
  1474.     bra    mustchk2
  1475. must2:
  1476.     ori.w    #1,d0        ;indicate 1st endbrush rejected
  1477. mustchk2:
  1478.     move.w    d4,-(sp)    ;save hpos of 1st endbrush
  1479. *
  1480. *  Last endbrush must pass three tests
  1481. *
  1482.     move.w    4(a6),d7    ;get compound item count
  1483.     mulu    #12,d7
  1484.     movem.w    10(a6,d7.w),d4-d5 ;get relative hpos/vpos of last endbrush
  1485.     add.w    d2,d4        ;form absolute hpos
  1486.     add.w    d3,d5        ; & vpos
  1487.     move.w    d4,d6
  1488.     move.w    d4,d1
  1489.     sub.w    4(a1),d6
  1490.     sub.w    4(a2),d1
  1491.     eor.w    d6,d1        ;check endbrush between intrinsics
  1492.     bmi    must1        ;br if must select first or none
  1493. *
  1494.     move.w    10(a6,d7.w),d1    ;get relative hpos 1st endbrush
  1495.     sub.w    -2(a6,d7.w),d1    ;find delta with previous bridge
  1496.     beq    vbridg0        ;br if its a vertical--face is avail
  1497.     eor.w    d6,d1        ;check for available face
  1498.     bpl    must1        ;br if face not avail, must select other or none
  1499. vbridg0:
  1500.     move.w    6(a1),d1
  1501.     add.w    6(a2),d1
  1502.     lsr.w    #1,d1        ;d1 = average vpos of intrinsics
  1503.     sub.w    d5,d1        ;get delta with vpos of this endbrush
  1504.     bpl    hcheck0
  1505.     neg.w    d1        ;get positive delta
  1506. hcheck0:
  1507.     move.w    6(a6,d7.w),d5    ;find last endbrush height
  1508.     lsl.w    #4,d5
  1509.     cmp.w    2(a5,d5.w),d1    ;1st endbrush height >= delta?
  1510.     bhi    must1        ;br if vertical alignment not good enough
  1511. *
  1512. *  we pass the 3 tests
  1513. *
  1514.     bra    mustchk
  1515. must1:
  1516.     ori.w    #2,d0        ;reject last brush
  1517. mustchk:
  1518.     move.w    (sp)+,d5    ;reget 1st endbrush hpos
  1519. *
  1520.     cmpi.w    #3,d0        ;rejected both?
  1521.     beq    ag_abort    ;br if so
  1522. *
  1523.     cmpi.w    #2,d0        ;selected 1st & rejected last?
  1524.     beq    dohfirst    ;br to do 1st
  1525. *
  1526.     cmpi.w    #1,d0        ;selected last & rejected first?
  1527.     beq    dohlast        ;br to do last
  1528. *
  1529. *  both brushes are eligible--choose the one closest
  1530. * 
  1531. *  d4.w = last endbrush hpos, d5.w = 1st endbrush hpos
  1532. *
  1533.     move.w    d4,d1
  1534.     sub.w    4(a1),d1
  1535.     bpl    hcheck1
  1536.     neg.w    d1
  1537. hcheck1:
  1538.     sub.w    4(a2),d4
  1539.     bpl    hcheck2
  1540.     neg.w    d4
  1541. hcheck2:
  1542.     cmp.w    d4,d1
  1543.     bcc    hcheck3
  1544.     move.w    d1,d4
  1545. hcheck3:
  1546. *
  1547. *   d4 = minimum abs horz delta for last endbrush
  1548. *
  1549.     move.w    d5,d1
  1550.     sub.w    4(a1),d1
  1551.     bpl    hcheck4
  1552.     neg.w    d1
  1553. hcheck4:
  1554.     sub.w    4(a2),d5
  1555.     bpl    hcheck5
  1556.     neg.w    d5
  1557. hcheck5:
  1558.     cmp.w    d5,d1
  1559.     bcc    hcheck6
  1560.     move.w    d1,d5
  1561. hcheck6:
  1562. *
  1563. *   d5 = minimum abs horz delta for 1st endbrush
  1564. *
  1565.     cmp.w    d4,d5        ;which is closer?
  1566.     bcc    dohlast 
  1567. *
  1568. *  we picked 1st or last endbrush..
  1569. *
  1570. dohfirst:
  1571.     moveq    #0,d1
  1572.     bra    comphorz
  1573. dohlast:
  1574.     moveq    #-1,d1
  1575. comphorz:
  1576.     move.w    d1,tempbuf+26
  1577. *
  1578.     move.w    (a3),d0
  1579.     lsl.w    #4,d0
  1580.     move.l    8(a5,d0.w),a6
  1581.     movem.w    4(a3),d2-d3
  1582.     tst.w    d1
  1583.     beq    cphorz0
  1584.     move.w    4(a6),d1    ;get last index
  1585. cphorz0:
  1586.     mulu    #12,d1
  1587.     add.w    10(a6,d1.l),d2    ;add relative h/v positions to 
  1588.     add.w    12(a6,d1.l),d3    ;  get absolute hpos/vpos of endbrush
  1589.     move.w    6(a6,d1.l),d1    ;  & get endbrush #
  1590. *
  1591. *  check horz position-order amongst the three
  1592. *
  1593.     cmp.w    4(a1),d2    ;is left intrinsic left of endbrush?
  1594.     bge    h123        ;br if so
  1595. *
  1596. *  else, we do a3,a1,a2 order
  1597. *
  1598.     move.l    a0,(a4)+
  1599.     move.l    (a3)+,(a0)+    ;copy brush & effects
  1600.     move.l    (a3)+,(a0)+    ;use hpos/vpos
  1601. *
  1602. *  now a1 & a2 must use vpos in d3, a1 must use xpos at left side of endbrush
  1603. *
  1604.     move.l    a0,(a4)+
  1605.     move.l    (a1)+,(a0)+
  1606.     lsl.w    #4,d1
  1607.     add.w    (a5,d1.w),d2
  1608.     move.w    d2,(a0)+
  1609.     move.w    d3,(a0)+
  1610. *
  1611.     move.l    a0,(a4)+
  1612.     move.l    (a2)+,(a0)+
  1613.     move.w    (a2)+,(a0)+
  1614.     move.w    d3,(a0)+
  1615. *    
  1616.     move.w    #$8000,(a0)    ;indicate stretch destination is intrinsic
  1617.     bra    wehclust
  1618. *
  1619. *  do a1,a2,a3 order
  1620. *    
  1621. h123:
  1622.     move.l    a0,(a4)+
  1623.     move.l    (a1)+,(a0)+
  1624.     move.w    (a1),(a0)+
  1625.     move.w    d3,(a0)+
  1626. *
  1627.     move.l    a0,(a4)+
  1628.     move.w    -8(a0),d1
  1629.     lsl.w    #4,d1
  1630.     move.w    (a5,d1.w),d1
  1631.     add.w    (a1),d1
  1632.     move.l    (a2)+,(a0)+
  1633.     move.w    d1,(a0)+
  1634.     move.w    d3,(a0)+
  1635. *
  1636.     move.l    a0,(a4)+
  1637.     move.l    (a3)+,(a0)+
  1638.     move.l    (a3)+,(a0)+
  1639. *
  1640.     move.w    d2,(a0)    ;save stretch destination into complex bridge
  1641.     bra    wehclust
  1642. *
  1643. *
  1644. ***************************************************
  1645. *
  1646. *    We're going for the vertical orientation
  1647. *
  1648. *
  1649. v2big:
  1650.     move.w    6(a1),d0
  1651.     cmp.w    6(a2),d0
  1652.     bcs    v2bigx4
  1653.     exg    a1,a2        ;a1 -> topmost intrinsic
  1654. v2bigx4:
  1655. *
  1656. *  we're vert--which end of compound bridge to bridge to?
  1657. *
  1658. *  check 1st endbrush and eliminate if:
  1659. *
  1660. *    Endbrush vertically between intrinsics
  1661. *    Endbrush face needed for new bridge is bridged already
  1662. *    Mean intrinsics hpos alignment with endbrush exceeds width
  1663. *
  1664. *
  1665.     move.w    (a3),d0
  1666.     lsl.w    #4,d0
  1667.     move.l    8(a5,d0.w),a6
  1668.     movem.w    4(a3),d2-d3    ;get base hpos/vpos of compound bridge
  1669. *
  1670.     moveq    #0,d0        ;assume both endbrushes OK
  1671. *
  1672.     movem.w    10(a6),d4-d5    ;get relative hpos/vpos of 1st endbrush
  1673.     add.w    d2,d4        ;form absolute hpos
  1674.     add.w    d3,d5        ; & vpos
  1675.     move.w    d5,d6
  1676.     move.w    d5,d1
  1677.     sub.w    6(a1),d6
  1678.     sub.w    6(a2),d1
  1679.     eor.w    d6,d1        ;check endbrush between intrinsics
  1680.     bmi    mustv2        ;br if must reject 1st
  1681. *
  1682.     move.w    12(a6),d1    ;get relative vpos 1st endbrush
  1683.     sub.w    24(a6),d1    ;find delta with previous bridge
  1684.     beq    hbridg        ;br if its a horz--face is avail
  1685.     eor.w    d6,d1        ;check for available face
  1686.     bpl    mustv2        ;br if must reject 1st (face unavail)
  1687. hbridg:
  1688.     move.w    4(a1),d1
  1689.     add.w    4(a2),d1
  1690.     lsr.w    #1,d1        ;d1 = average hpos of intrinsics
  1691.     sub.w    d4,d1        ;get delta with hpos of this endbrush
  1692.     bpl    vcheck
  1693.     neg.w    d1        ;get positive delta
  1694. vcheck:
  1695.     move.w    6(a6),d4    ;get 1st endbrush #
  1696.     lsl.w    #4,d4
  1697.     cmp.w    (a5,d4.w),d1    ;1st endbrush width >= delta?
  1698.     bhi    mustv2        ;br if vertical alignment not good enough
  1699. *
  1700. *  we pass the 3 tests for 1st endbrush, now check last
  1701. *
  1702.     bra    mustcvk2
  1703. mustv2:
  1704.     ori.w    #1,d0        ;indicate 1st endbrush rejected
  1705. mustcvk2:
  1706.     move.w    d5,-(sp)    ;save vpos of 1st endbrush
  1707. *
  1708. *  Last endbrush must pass three tests
  1709. *
  1710.     move.w    4(a6),d7    ;get compound item count
  1711.     mulu    #12,d7
  1712.     movem.w    10(a6,d7.w),d4-d5 ;get relative hpos/vpos of last endbrush
  1713.     add.w    d2,d4        ;form absolute hpos
  1714.     add.w    d3,d5        ; & vpos
  1715.     move.w    d5,d6
  1716.     move.w    d5,d1
  1717.     sub.w    6(a1),d6
  1718.     sub.w    6(a2),d1
  1719.     eor.w    d6,d1        ;check endbrush between intrinsics
  1720.     bmi    mustv1        ;br if must reject last
  1721. *
  1722.     move.w    12(a6,d7.w),d1    ;get relative vpos 1st endbrush
  1723.     sub.w    (a6,d7.w),d1    ;find delta with previous bridge
  1724.     beq    hbridg0        ;br if its a vertical--face is avail
  1725.     eor.w    d6,d1        ;check for available face
  1726.     bpl    mustv1        ;br if face not avail, must select other or none
  1727. hbridg0:
  1728.     move.w    4(a1),d1
  1729.     add.w    4(a2),d1
  1730.     lsr.w    #1,d1        ;d1 = average hpos of intrinsics
  1731.     sub.w    d4,d1        ;get delta with hpos of this endbrush
  1732.     bpl    vcheck0
  1733.     neg.w    d1        ;get positive delta
  1734. vcheck0:
  1735.     move.w    6(a6,d7.w),d4    ;find last endbrush #
  1736.     lsl.w    #4,d4
  1737.     cmp.w    (a5,d4.w),d1    ;1st endbrush width >= delta?
  1738.     bhi    mustv1        ;br if vertical alignment not good enough
  1739. *
  1740. *  we pass the 3 tests
  1741. *
  1742.     bra    mustcvk
  1743. mustv1:
  1744.     ori.w    #2,d0        ;reject last brush
  1745. mustcvk:
  1746.     move.w    (sp)+,d4    ;reget 1st endbrush hpos
  1747. *
  1748.     cmpi.w    #3,d0        ;rejected both?
  1749.     beq    ag_abort    ;br if so
  1750. *
  1751.     cmpi.w    #2,d0        ;selected 1st & rejected last?
  1752.     beq    dovfirst    ;br to do 1st
  1753. *
  1754.     cmpi.w    #1,d0        ;selected last & rejected first?
  1755.     beq    dovlast        ;br to do last
  1756. *
  1757. *  both brushes are eligible--choose the one closest
  1758. * 
  1759. *  d4.w = first endbrush vpos, d5.w = last endbrush vpos
  1760. *
  1761.     move.w    d4,d1
  1762.     sub.w    6(a1),d1
  1763.     bpl    vcheck1
  1764.     neg.w    d1
  1765. vcheck1:
  1766.     sub.w    6(a2),d4
  1767.     bpl    vcheck2
  1768.     neg.w    d4
  1769. vcheck2:
  1770.     cmp.w    d4,d1
  1771.     bcc    vcheck3
  1772.     move.w    d1,d4
  1773. vcheck3:
  1774. *
  1775. *   d4 = minimum abs vert delta for last endbrush
  1776. *
  1777.     move.w    d5,d1
  1778.     sub.w    6(a1),d1
  1779.     bpl    vcheck4
  1780.     neg.w    d1
  1781. vcheck4:
  1782.     sub.w    6(a2),d5
  1783.     bpl    vcheck5
  1784.     neg.w    d5
  1785. vcheck5:
  1786.     cmp.w    d5,d1
  1787.     bcc    vcheck6
  1788.     move.w    d1,d5
  1789. vcheck6:
  1790. *
  1791. *   d5 = minimum abs vert delta for 1st endbrush
  1792. *
  1793.     cmp.w    d5,d4        ;which is closer?
  1794.     bcc    dovlast 
  1795. *
  1796. *  we picked 1st or last endbrush..
  1797. *
  1798. dovfirst:
  1799.     moveq    #0,d1
  1800.     bra    compvert
  1801. dovlast:
  1802.     moveq    #-1,d1
  1803. compvert:
  1804.     move.w    d1,tempbuf+26
  1805. *
  1806.     move.w    (a3),d0
  1807.     lsl.w    #4,d0
  1808.     move.l    8(a5,d0.w),a6
  1809.     movem.w    4(a3),d2-d3
  1810.     tst.w    d1
  1811.     beq    cpvert0
  1812.     move.w    4(a6),d1    ;get last index
  1813. cpvert0:
  1814.     mulu    #12,d1
  1815.     add.w    10(a6,d1.l),d2    ;add relative h/v positions to 
  1816.     add.w    12(a6,d1.l),d3    ;  get absolute hpos/vpos of endbrush
  1817.     move.w    6(a6,d1.l),d1    ;  & get endbrush #
  1818. *
  1819. *  check vert position-order amongst the three
  1820. *
  1821.     cmp.w    6(a1),d3    ;is top intrinsic above endbrush?
  1822.     bge    v123        ;br if so
  1823. *
  1824. *  else, we do a3,a1,a2 order
  1825. *
  1826.     move.l    a0,(a4)+
  1827.     move.l    (a3)+,(a0)+    ;copy brush & effects
  1828.     move.l    (a3)+,(a0)+    ;use hpos/vpos
  1829. *
  1830. *  now a1 & a2 must use hpos in d2, a1 must use ypos at bottom of endbrush
  1831. *
  1832.     move.l    a0,(a4)+
  1833.     move.l    (a1)+,(a0)+
  1834.     lsl.w    #4,d1
  1835.     add.w    2(a5,d1.w),d3
  1836.     move.w    d2,(a0)+
  1837.     move.w    d3,(a0)+
  1838. *
  1839.     move.l    a0,(a4)+
  1840.     move.l    (a2)+,(a0)+
  1841.     move.w    d2,(a0)+
  1842.     addq.l    #2,a2
  1843.     move.w    (a2)+,(a0)+
  1844. *    
  1845.     move.w    #$8000,(a0)    ;indicate stretch destination is intrinsic
  1846.     bra    wevclust
  1847. *
  1848. *  do a1,a2,a3 order
  1849. *    
  1850. v123:
  1851.     move.l    a0,(a4)+
  1852.     move.l    (a1)+,(a0)+
  1853.     move.w    d2,(a0)+
  1854.     addq.l    #2,a1
  1855.     move.w    (a1),(a0)+
  1856. *
  1857.     move.l    a0,(a4)+
  1858.     move.w    -8(a0),d1
  1859.     lsl.w    #4,d1
  1860.     move.w    2(a5,d1.w),d1
  1861.     add.w    (a1),d1
  1862.     move.l    (a2)+,(a0)+
  1863.     move.w    d2,(a0)+
  1864.     move.w    d1,(a0)+
  1865. *
  1866.     move.l    a0,(a4)+
  1867.     move.l    (a3)+,(a0)+
  1868.     move.l    (a3)+,(a0)+
  1869. *
  1870.     move.w    d3,(a0)    ;save stretch destination into complex bridge
  1871.     bra    wevclust
  1872. *
  1873. ***************************************************
  1874. *
  1875. *  All three are intrinsics--either left edge or top edge
  1876. *    
  1877. aggrnox:
  1878. *
  1879.     moveq    #4,d5        ;check hpos
  1880.     bsr    chepsort
  1881. *
  1882.     movem.l    a1-a3,(a0)    ;save horz sort order
  1883.     move.w    d3,d0
  1884.     sub.w    d1,d0        ;d0 = max horz displacement
  1885. *
  1886.     moveq    #6,d5
  1887.     bsr    chepsort
  1888. *
  1889.     move.w    d3,d4
  1890.     sub.w    d1,d4        ;d4 = max vert displacement
  1891. *
  1892.     cmp.w    d4,d0        ;vert:horz max?
  1893.     ble    vertbrg        ;br if this will be vert bridge
  1894. *
  1895. *  Horz bridge
  1896. *
  1897.     movem.l    (a0),a1-a3
  1898. *
  1899.     move.l    a0,(a4)+
  1900.     move.l    (a1)+,(a0)+    ;copy brush/effects
  1901.     move.w    (a1)+,d0    ;get xpos
  1902.     move.w    d0,(a0)+
  1903.     move.w    d0,xmin_clust    ;adjust cluster xmin
  1904.     move.w    (a1)+,d0    ;get ypos
  1905.     move.w    d0,(a0)+
  1906.     move.w    d0,ymin_clust    ;adjust cluster ymin
  1907. *
  1908.     move.w    -8(a0),d1
  1909.     lsl.w    #4,d1
  1910.     move.w    2(a5,d1.w),d2    ;get brush height
  1911.     add.w    d0,d2
  1912.     move.w    d2,ymax_clust
  1913.     move.w    (a5,d1.w),d2    ;get 1st brush width
  1914.     add.w    -4(a0),d2
  1915. *
  1916. *
  1917.     move.l    a0,(a4)+
  1918.     move.l    (a2)+,(a0)+
  1919.     move.w    d2,(a0)+
  1920.     move.w    d0,(a0)+
  1921. *
  1922.     move.w    -8(a0),d1
  1923.     lsl.w    #4,d1
  1924.     move.w    2(a5,d1.w),d1    ;get brush height
  1925.     add.w    d0,d1
  1926.     cmp.w    ymax_clust,d1
  1927.     ble    hbrid0
  1928.     move.w    d1,ymax_clust
  1929. hbrid0:
  1930. *
  1931. *
  1932.     move.l    a0,(a4)+
  1933.     move.l    (a3)+,(a0)+
  1934.     move.w    (a3)+,(a0)+
  1935.     move.w    d0,(a0)+
  1936. *
  1937.     move.w    -8(a0),d1
  1938.     lsl.w    #4,d1
  1939.     move.w    2(a5,d1.w),d1    ;get brush height
  1940.     add.w    d0,d1
  1941.     cmp.w    ymax_clust,d1
  1942.     ble    hbrid1
  1943.     move.w    d1,ymax_clust
  1944. hbrid1:
  1945.     move.w    #$8000,(a0)    ;indicate stretch destination is intrinsic
  1946. wehclust:
  1947.     bsr    clustit
  1948. *
  1949.     bsr    hstretch    ;h-stretch the middle elemnt of 3-item cluster
  1950. *
  1951.     bsr    reclumsk    ;rebuild cluster mask    
  1952. *
  1953. *  unwrap bridge d'bridges here..
  1954. *
  1955. *   We have three items bridged--expand deriveds
  1956. *
  1957. brid_unw:
  1958.     move.w    curbrush,d0
  1959.     lea    bshblock,a2
  1960.     lsl.w    #4,d0
  1961.     move.l    8(a2,d0.w),a3
  1962.     move.w    6(a3),d0    ;get first endbrush
  1963.     cmp.w    maxintrins,d0    ;is it derived
  1964.     bls    brid_un0    ;br if not
  1965. *
  1966. *  1st endbrush is derived--check for cluster/bridge
  1967. *
  1968.     lsl.w    #4,d0
  1969.     move.l    8(a2,d0.w),a4
  1970.     move.w    4(a4),d1    ;is this derived made up of multiples
  1971.     beq    brid_un0    ;br if not
  1972. *
  1973.     add.w    d1,4(a3)    ;increase cluster count
  1974. *
  1975.     movem.w    10(a3),d4-d6    ;retain hpos/vpos base offset
  1976. *
  1977.     move.w    d1,d2
  1978.     mulu    #12,d2        ;here's how much we need to add
  1979. *
  1980.     move.l    derblkend,a5
  1981.     lea    (a5,d2.l),a6
  1982.     move.l    a6,derblkend
  1983. *
  1984.     moveq    #5,d3
  1985. dervexp:
  1986.     move.l    -(a5),-(a6)    ;move 2 intrinsics to end of list
  1987.     dbra    d3,dervexp
  1988. *
  1989.     suba.w    #12,a5        ;go to head of (1st) derived entry
  1990.     lea    6(a4),a6    ; & to head of corresponding cluster list
  1991.     moveq    #0,d3        ;assume no adjust
  1992.     tst.w    tempbuf+26    ;check first/last link endbrush
  1993.     bmi    dervx        ;br if last was connect
  1994.     adda.l    d2,a6        ;go to tail of cluster list
  1995.     move.w    #24,d3        ;here's a new decrement value
  1996. dervx:
  1997.     move.l    (a6)+,(a5)+    ;put in brush # & effects
  1998.     move.w    (a6)+,d2
  1999.     add.w    d4,d2
  2000.     move.w    d2,(a5)+
  2001.     move.w    (a6)+,d2
  2002.     add.w    d5,d2
  2003.     move.w    d2,(a5)+
  2004.     move.l    (a6)+,(a5)+
  2005.     suba.w    d3,a6
  2006.     dbra    d1,dervx
  2007. *
  2008.     bra    brid_unx    ;we're all set
  2009. *
  2010. *   check for derived at last endbrush of this bridge
  2011. *
  2012. brid_un0:
  2013.     move.w    30(a3),d0    ;get last endbrush
  2014.     cmp.w    maxintrins,d0
  2015.     bls    brid_unx    ;exit if not derived
  2016. *
  2017.     lsl.w    #4,d0
  2018.     move.l    8(a2,d0.w),a4
  2019.     move.w    4(a4),d1    ;is this derived made up of multiples
  2020.     beq    brid_unx    ;br if not
  2021. *
  2022.     add.w    d1,4(a3)    ;increase cluster count
  2023. *
  2024.     movem.w    34(a3),d4-d6    ;retain hpos/vpos base offset
  2025. *
  2026.     move.w    d1,d2
  2027.     mulu    #12,d2        ;here's how much we need to add
  2028. *
  2029.     move.l    derblkend,a5
  2030.     lea    (a5,d2.l),a6
  2031.     move.l    a6,derblkend
  2032. *
  2033.     suba.w    #12,a5        ;go to head of (1st) derived entry
  2034.     lea    6(a4),a6    ; & to head of corresponding cluster list
  2035.     moveq    #0,d3        ;assume no adjust
  2036.     tst.w    tempbuf+26    ;check first/last link endbrush
  2037.     bpl    dervxx        ;br if first was connect
  2038.     adda.l    d2,a6        ;go to tail of cluster list
  2039.     move.w    #24,d3        ;here's a new decrement value
  2040. dervxx:
  2041.     move.l    (a6)+,(a5)+    ;put in brush # & effects
  2042.     move.w    (a6)+,d2
  2043.     add.w    d4,d2
  2044.     move.w    d2,(a5)+
  2045.     move.w    (a6)+,d2
  2046.     add.w    d5,d2
  2047.     move.w    d2,(a5)+
  2048.     move.l    (a6)+,(a5)+
  2049.     suba.w    d3,a6
  2050.     dbra    d1,dervxx
  2051. *
  2052. brid_unx:
  2053.     bra    aggr_i
  2054. *
  2055. *
  2056. *
  2057. ********************************************************
  2058. *  Horz stretch the middle item of a three item cluster
  2059. *
  2060. *    a0 -> base of graphics buffer
  2061. *
  2062. *   curbrush = derived brush of a 3 element cluster
  2063. *
  2064. hstretch:
  2065.     movem.l    a0-a1/d0-d3/d5,-(sp)
  2066.  
  2067.     move.w    curbrush,d0
  2068.     lea    bshblock,a2
  2069.     lsl.w    #4,d0
  2070.     move.w    14(a2,d0.w),d7    ;cluster s_nxln
  2071.     move.l    8(a2,d0.w),a3    ;get cluster elements ptr
  2072.     adda.w    #18,a3        ;go for 2nd (bridging) element
  2073.     move.w    (a3),d0        ;get bridge brush #
  2074.     move.w    #Hbridge,2(a3)    ;stuff in a special effect
  2075.     lsl.w    #4,d0
  2076.     move.w    2(a2,d0.w),d5    ;d5 = bridge height
  2077.     lsl.w    #2,d5
  2078.     move.w    6(a3),d1    ;vpos of bridge element
  2079.     mulu    d7,d1
  2080.     adda.l    d1,a0
  2081.     move.w    (a2,d0.w),d0    ;d0 = bridge intrinsic width
  2082.     move.w    d0,d4        ;save in d4
  2083.  
  2084.     move.w    tempbuf+24,d1    ;check for complex destination
  2085.     cmpi.w    #$8000,d1    ;should we just use intrinsic?
  2086.     beq    hintrz
  2087.     sub.w    xmin_clust,d1
  2088.     bra    hintrz0
  2089. hintrz:    
  2090.     move.w    16(a3),d1    ;d1 = hpos of last element
  2091. hintrz0:
  2092.     move.w    4(a3),d3    ;d3 = hpos of bridge element
  2093.     add.w    d3,d4        ;get dot addr +1 of rite bridge column
  2094.     move.w    d1,d2
  2095.     sub.w    d3,d2        ;d2 = desired width
  2096.     swap    d0        ;intrinsic width * 65536
  2097.     clr.w    d0
  2098.     divu    d2,d0        ;get frac for DDA
  2099.     subq.w    #1,d0        ;inc value
  2100.     move.w    d0,d3
  2101.     lsr.w    #1,d3        ;d3 = initial DDA value
  2102. *
  2103.     subq.w    #1,d4        ;adjust dot addr to ritemost bridge
  2104.     move.w    d4,d6
  2105.     lsr.w    #3,d6
  2106.     andi.w    #$fffe,d6
  2107.     lea    (a0,d6.w),a3    ;SRC ptr
  2108.     not.w    d4
  2109.     andi.w    #$f,d4        ;SRC bit # in word
  2110. *
  2111.     subq.w    #1,d1        ;DST dot addr
  2112.     move.w    d1,d6
  2113.     lsr.w    #3,d6
  2114.     andi.w    #$fffe,d6
  2115.     lea    (a0,d6.w),a4    ;DST ptr
  2116.     not.w    d1
  2117.     andi.w    #$f,d1        ;DST bit # in word
  2118.     lsr.w    #2,d7        ;get s_nxpl
  2119.     move.w    d0,a2
  2120. *
  2121. *
  2122. *    d0 =  <unused> 
  2123. *    d1 =  DST bit # in word
  2124. *    d2 =  desired (stretched) width
  2125. *    d3 =  DDA accum
  2126. *    d4 =  SRC bit # in word
  2127. *    d5 =  # of plane-lines to expand
  2128. *    d6 = <unused>
  2129. *    d7 =  s_nxpl
  2130. *
  2131. *    a2 = DDA inc
  2132. *    a3 -> SRC in form
  2133. *    a4 -> DST in form
  2134. *
  2135.     bra    hexpandi
  2136. hexpand:
  2137.     movem.l    a3-a4/d1-d4,-(sp)
  2138.     move.w    (a4),d6        ; & DST word
  2139.     move.w    (a3),d0        ;pick up SRC word
  2140. hexp:
  2141.     btst.l    d4,d0
  2142.     bne    hex2
  2143. hex0:
  2144.     subq.w    #1,d2
  2145.     bmi    hexi
  2146.     bclr.l    d1,d6
  2147.     addq.w    #1,d1
  2148.     andi.w    #$f,d1
  2149.     bne    hex1
  2150.     move.w    d6,(a4)
  2151.     move.w    -(a4),d6
  2152. hex1:
  2153.     add.w    a2,d3
  2154.     bcc    hex0
  2155.     addq.w    #1,d4
  2156.     andi.w    #$f,d4
  2157.     bne    hexp
  2158.     move.w    -(a3),d0
  2159.     bra    hexp
  2160. hex2:
  2161.     subq.w    #1,d2
  2162.     bmi    hexi
  2163.     bset.l    d1,d6
  2164.     addq.w    #1,d1
  2165.     andi.w    #$f,d1
  2166.     bne    hex3
  2167.     move.w    d6,(a4)
  2168.     move.w    -(a4),d6
  2169. hex3:
  2170.     add.w    a2,d3
  2171.     bcc    hex2
  2172.     addq.w    #1,d4
  2173.     andi.w    #$f,d4
  2174.     bne    hexp
  2175.     move.w    -(a3),d0
  2176.     bra    hexp
  2177. hexi:
  2178.     move.w    d6,(a4)
  2179.     movem.l    (sp)+,a3-a4/d1-d4
  2180.     adda.w    d7,a3
  2181.     adda.w    d7,a4
  2182. hexpandi:
  2183.     dbra    d5,hexpand
  2184. *
  2185.     movem.l    (sp)+,a0-a1/d0-d3/d5
  2186.     rts
  2187. *
  2188. *
  2189. *
  2190. *
  2191. *
  2192. *
  2193. *  Vert bridge
  2194. *
  2195. *    a1,a2 & a3 are the sorted element ptr's
  2196. *
  2197. vertbrg:
  2198. *
  2199.     move.l    a0,(a4)+
  2200.     move.l    (a1)+,(a0)+
  2201.     move.w    (a1)+,d0
  2202.     move.w    d0,xmin_clust
  2203.     move.w    d0,(a0)+
  2204.     move.w    (a1)+,d1
  2205.     move.w    d1,(a0)+
  2206.     move.w    d1,ymin_clust
  2207. *
  2208.     move.w    -8(a0),d1
  2209.     lsl.w    #4,d1
  2210.     move.w    (a5,d1.w),d2    ;get brush width
  2211.     add.w    d0,d2
  2212.     move.w    d2,xmax_clust
  2213.     move.w    2(a5,d1.w),d2    ;get height
  2214.     add.w    -2(a0),d2    ;get vpos of next item
  2215. *
  2216. *
  2217.     move.l    a0,(a4)+
  2218.     move.l    (a2)+,(a0)+
  2219.     move.w    d0,(a0)+
  2220.     addq.l    #4,a2
  2221.     move.w    d2,(a0)+    ;vpos of second just below 1st
  2222. *
  2223.     move.w    -8(a0),d1
  2224.     lsl.w    #4,d1
  2225.     move.w    (a5,d1.w),d1    ;get brush width
  2226.     add.w    d0,d1
  2227.     cmp.w    xmax_clust,d1
  2228.     ble    vbrid0
  2229.     move.w    d1,xmax_clust
  2230. vbrid0:
  2231. *
  2232. *
  2233.     move.l    a0,(a4)+
  2234.     move.l    (a3)+,(a0)+
  2235.     move.w    d0,(a0)+
  2236.     addq.l    #2,a3
  2237.     move.w    (a3)+,(a0)+
  2238. *
  2239.     move.w    -8(a0),d1
  2240.     lsl.w    #4,d1
  2241.     move.w    (a5,d1.w),d1    ;get brush width
  2242.     add.w    d0,d1
  2243.     cmp.w    xmax_clust,d1
  2244.     ble    vbrid1
  2245.     move.w    d1,xmax_clust
  2246. vbrid1:
  2247.     move.w    #$8000,(a0)
  2248. wevclust:
  2249.     bsr    clustit        ;build it like any cluster
  2250. *
  2251. * preserve a0-a1/d0-d3/d5 here
  2252. *
  2253.     bsr    vstretch    ;v-stretch the middle elemnt of 3-item cluster
  2254. *
  2255.     bsr    reclumsk    ;rebuild cluster mask
  2256.  
  2257.     bra    brid_unw    ;perform the bridge unwrap
  2258. *
  2259. *
  2260. ********************************************************
  2261. *  Vert stretch the middle item of a three item cluster
  2262. *
  2263. *
  2264. *   curbrush = derived brush of a 3 element cluster
  2265. *
  2266. *
  2267. *  Must be called right after clustit
  2268. *
  2269. vstretch:
  2270.     movem.l    a0-a1/a6/d0-d3/d5,-(sp)
  2271. *
  2272.     move.w    curbrush,d0
  2273.     lea    bshblock,a2
  2274.     lsl.w    #4,d0
  2275.     move.l    8(a2,d0.w),a3    ;get cluster elements ptr
  2276.     adda.w    #18,a3        ;go for 2nd (bridging) element
  2277.     move.w    (a3),d0        ;get bridge brush #
  2278.     move.w    #Vbridge,2(a3)    ;stuff in a special effect
  2279.     movem.w    4(a3),d2-d3
  2280.     move.w    d3,d5
  2281.     lsl.w    #4,d0
  2282.     move.w    2(a2,d0.w),d4    ;d4 = intrinsic height of bridge
  2283.     add.w    d4,d3        ;d3 = vpos 1 line below bottom of bridge
  2284.     subq.w    #1,d3        ;d3 = vpos of last line
  2285.     movem.w    d2-d3,d_xmin(a6)
  2286.     lea    s_xmin(a6),a0
  2287.     lea    d_xmin(a6),a1
  2288.     moveq    #6,d2
  2289. vstret0:
  2290.     move.w    (a1)+,(a0)+
  2291.     dbra    d2,vstret0
  2292. *
  2293.     move.l    #$03030303,op_tab(a6)
  2294. *
  2295.     move.w    (a2,d0.w),b_width(a6)    ;set width of bridge element
  2296.     move.w    #1,b_height(a6)    ;do 1 line at a time
  2297. *
  2298.     move.w    tempbuf+24,d1
  2299.     cmpi.w    #$8000,d1
  2300.     beq    vintrz
  2301.     sub.w    ymin_clust,d1
  2302.     bra    vintrz0    
  2303. vintrz:
  2304.     move.w    18(a3),d1    ;d1 = vpos of last element, d3 = vpos bridge
  2305. vintrz0:
  2306.     move.w    d1,d0
  2307.     sub.w    d5,d0        ;d0 = desired height
  2308.     subq.w    #1,d1
  2309.     move.w    d1,d_ymin(a6)
  2310. *
  2311.     swap    d4        ;intrinsic height * 65536
  2312.     clr.w    d4
  2313.     divu    d0,d4        ;get frac for DDA
  2314.     subq.w    #1,d4        ;inc value
  2315.     move.w    d4,d3
  2316.     lsr.w    #1,d3        ;d3 = initial DDA value
  2317.  
  2318.     bra    movslini
  2319. movslin:
  2320.     move.w    #4,plane_ct(a6)
  2321.     movem.l    a0-a6/d0-d7,-(sp)    
  2322.     .dc.w    bitblt
  2323.     movem.l    (sp)+,a0-a6/d0-d7
  2324.     subq.w    #1,d_ymin(a6)
  2325.     add.w    d4,d3        ;check DDA
  2326.     bcc    movslini
  2327.     subq.w    #1,s_ymin(a6)
  2328. movslini:
  2329.     dbra    d0,movslin
  2330. *
  2331. *
  2332.     movem.l    (sp)+,a0-a1/a6/d0-d3/d5
  2333.     rts
  2334. *
  2335. ********************************************
  2336. *
  2337. *
  2338. chepsort:
  2339.     move.w    (a1,d5.w),d1
  2340.     move.w    (a2,d5.w),d2
  2341.     move.w    (a3,d5.w),d3
  2342. *
  2343.     cmp.w    d2,d1
  2344.     ble    brid0
  2345.     exg    d1,d2
  2346.     exg    a1,a2
  2347. brid0:
  2348.     cmp.w    d3,d1
  2349.     ble    brid1
  2350.     exg    d1,d3
  2351.     exg    a1,a3
  2352. brid1:
  2353.     cmp.w    d3,d2
  2354.     ble    brid2
  2355.     exg    d3,d2
  2356.     exg    a3,a2
  2357. brid2:
  2358.     rts
  2359. *    
  2360. *
  2361. *  Hit escape key--abort
  2362. *
  2363. ag_abort:
  2364.     lea    cxit_msg,a0    ;"Abort"
  2365.     bra    agxit
  2366. *
  2367. *  Close cluster select--& build the sucker
  2368. *
  2369. aggr_xit:
  2370.     move.w    aggreg,d7
  2371.     cmpi.b    #2,d7        ;check for 1 or less selected
  2372.     bls    ag_abort    ;abort if so
  2373.     cmpi.w    #3,d7        ;check for 2 or less selected (bridge)
  2374.     bls    ag_abort    ;abort if so
  2375. *    
  2376.     clr.l    brshfile    ;tell 'em we need to sort painter's order
  2377. *
  2378.     bsr    clustit        ;build a new cluster entry in derived
  2379. *
  2380. aggr_i:
  2381.     movem.l    a0/a1,-(sp)
  2382.  
  2383.     bsr    butninit
  2384. *
  2385.     bsr    makemsk
  2386. *
  2387.     moveq    #Arrow,d0
  2388.     bsr    Graf_Mouse
  2389. *
  2390.     movem.l    (sp)+,a0/a1
  2391. *
  2392.     move.l    a0,a3
  2393.     move.l    a1,a0
  2394. *
  2395.     lea    wstruct,a5
  2396.     movem.w    xmin_clust,d0-d1
  2397. *
  2398.     sub.w    xoffset(a5),d0
  2399.     add.w    wx(a5),d0
  2400.     sub.w    yoffset(a5),d1
  2401.     add.w    wy(a5),d1
  2402.  
  2403.     movem.w    d0-d1,bsh_x
  2404. *
  2405.     bra    bckdoorm    ;start a move thru the back door
  2406. *
  2407. agxit:
  2408.     move.w    #WORLD,d0
  2409.     bsr    DaveInfo    ;put up exit msg
  2410. *
  2411.     moveq    #Arrow,d0
  2412.     bsr    Graf_Mouse
  2413.  
  2414.     movem.l    (sp)+,a0-a6/d0-d7
  2415.     rts
  2416. *
  2417. *
  2418. *
  2419. *******************************************
  2420. *
  2421. *  Build a cluster
  2422. *
  2423. *
  2424. *  Entry:
  2425. *
  2426. *   a list of ptr's to the cluster elements is found in the brshfile
  2427. *    buffer if cluster file is read in; else the 1st longword
  2428. *    in brshfile buffer is zero & it is assumed that tempbuf has
  2429. *    the list which needs to be put in painter's order.
  2430. *
  2431. *    aggreg  = $8000 + (count-1) if cluster
  2432. *        =    + (count-1) if bridge
  2433. *                 where "count" is # of elements
  2434. *
  2435. *    The following inputs define the size of the cluster:
  2436. *
  2437. *    xmin_clust
  2438. *    ymin_clust
  2439. *    xmax_clust
  2440. *    ymax_clust
  2441. *
  2442. *
  2443. *  Exit:
  2444. *        a0-> mono mask form
  2445. *        a1-> graphics form of new cluster brush  
  2446. clustit:
  2447. *
  2448. *  find size of form needed for this cluster
  2449. *
  2450.     movem.w    xmin_clust,d0-d3
  2451.     sub.w    d0,d2        ;get width
  2452.     sub.w    d1,d3        ;& height
  2453. *
  2454.     movem.w    d2-d3,bsh_wid
  2455. *
  2456.     lea    clustblt,a6    ;it should be alright to use this
  2457. *
  2458.     move.w    d2,d4
  2459.     addi.w    #15,d4
  2460.     andi.w    #$fff0,d4
  2461.     lsr.w    #1,d4        ;DST form-width
  2462. *
  2463.     move.w    #2,d_nxwd(a6)
  2464.     move.w    #2,s_nxwd(a6)
  2465.     move.w    d4,d_nxln(a6)
  2466.     move.w    d4,d5
  2467.     lsr.w    #2,d4
  2468.     move.w    d4,bsh_monoln
  2469.     move.w    d4,d_nxpl(a6)
  2470.     move.l    derivdend,a1    ;base of DST form
  2471.     move.l    a1,d_form(a6)
  2472.     moveq    #0,d7
  2473.     move.l    d7,p_addr(a6)
  2474.     move.l    d7,s_xmin(a6)
  2475. *
  2476.     move.w    maxderivd,d7
  2477.     addq.w    #1,d7
  2478.     move.w    d7,maxderivd
  2479.     move.w    d7,curbrush
  2480. *
  2481.     lea    bshblock,a2
  2482.     lsl.w    #4,d7
  2483.     move.w    d2,(a2,d7.w)    ;width
  2484.     move.w    d3,2(a2,d7.w)    ;height
  2485.     move.l    a1,4(a2,d7.w)    ;s_form
  2486.     move.l    derblkend,a3
  2487.     move.l    a3,8(a2,d7.w)    ;derive block ptr
  2488.     move.w    d5,14(a2,d7.w)    ;s_nxln
  2489. *    
  2490.     mulu    d3,d5        ;d5 = grafix form size
  2491.     move.w    d5,12(a2,d7.w)    ;mask-offset
  2492. *
  2493.     move.l    d5,d6
  2494.     lsr.l    #2,d6
  2495.     add.l    d5,d6        ;form size (with mask)
  2496.     add.l    a1,d6        ;add base to get end
  2497.     move.l    d6,derivdend    ;Malloc for this dude
  2498. *
  2499.     lsr.l    #2,d5        ;# of long words
  2500.     moveq    #0,d6
  2501. clusclr:
  2502.     move.l    d6,(a1)+    ;clear out the cluster form
  2503.     dbra    d5,clusclr
  2504. *
  2505.     move.l    dstrngend,a4
  2506.     move.l    a4,(a3)+    ;put in an id string
  2507. *
  2508.     lea    clustrng,a1
  2509.     move.w    aggreg,d7    ;get count
  2510.     bclr.l    #15,d7
  2511.     bne    cluscp0
  2512.     lea    bridstrng,a1
  2513. cluscp0:
  2514.     sub.w    #2,d7
  2515.  
  2516. cluscp:
  2517.     move.b    (a1)+,(a4)+
  2518.     bne    cluscp
  2519. *
  2520.     move.l    a4,dstrngend    
  2521. *
  2522.     addi.b    #1,-2(a1)
  2523. *
  2524.     move.w    d7,(a3)+    ;& a brush count (-1)
  2525. *
  2526. *  Now put selections in painters order
  2527. *
  2528.     move.w    d7,d4
  2529.     beq    buildc        ;br if only one entry
  2530. *
  2531.     move.l    wblkptr,d3    ;address beyond our limit 
  2532.     move.l    #worldblk,d2    ;get address of lowest entry
  2533. *
  2534.     lea    brshfile,a1
  2535.     tst.l    (a1)        ;are we already set in painter's order?
  2536.     bne    buildcc        ;skip ordering stuff if so
  2537. *
  2538. blist:
  2539.     move.w    d7,d4
  2540.     lea    tempbuf,a0
  2541. nolist:
  2542.     cmp.l    (a0)+,d2
  2543.     beq    olist
  2544.     dbra    d4,nolist
  2545.     bra    nnolist
  2546. olist:
  2547.     move.l    d2,(a1)+
  2548. nnolist:
  2549.     addq.l    #8,d2
  2550.     cmp    d3,d2
  2551.     bcs    blist        
  2552. *
  2553.     move.l    -(a1),d2
  2554.     addq.l    #8,d2
  2555.     move.l    d2,wblkcur    ;set priority 1 higher than highest
  2556. *
  2557. buildcc:
  2558.     lea    brshfile,a0
  2559. *    
  2560. buildc:
  2561.     move.l    (a0)+,a1    ;get world entry ptr
  2562.     move.w    (a1)+,d4
  2563.     move.w    d4,(a3)+    ;put in brush # (may be derived)
  2564.     clr.w    (a3)+        ;no special effect
  2565.     addq.l    #2,a1        ;skip special effects
  2566.     movem.w    (a1),d2-d3    ;x/ypos
  2567.     sub.w    d0,d2        ;xpos relative to cluster
  2568.     sub.w    d1,d3
  2569.     movem.w    d2-d3,(a3)
  2570.     addq.l    #8,a3        ;adjust for next entry
  2571.     move.w    d2,d_xmin(a6)
  2572.     move.w    d3,d_ymin(a6)
  2573. *
  2574.     lsl.w    #4,d4        ;get brush data
  2575.     move.w    (a2,d4.w),b_width(a6)
  2576.     move.w    2(a2,d4.w),b_height(a6)
  2577.     move.l    4(a2,d4.w),a4
  2578.     move.l    a4,-(sp)
  2579.     adda.w    12(a2,d4.w),a4    
  2580.     move.l    a4,s_form(a6)
  2581.     move.l    (sp)+,a4
  2582.     move.w    14(a2,d4.w),d2
  2583.     lsr.w    #2,d2
  2584.     move.w    d2,s_nxln(a6)
  2585.     clr.w    s_nxpl(a6)
  2586. *
  2587.     move.l    #$04040404,op_tab(a6)
  2588.     move.w    #4,plane_ct(a6)
  2589.  
  2590.     movem.l    a0/a2-a4/a6/d0-d1/d7,-(sp)
  2591.     .dc.w    bitblt    
  2592.     movem.l    (sp)+,a0/a2-a4/a6/d0-d1/d7
  2593.  
  2594.     move.l    a4,s_form(a6)
  2595.     move.l    #$07070707,op_tab(a6)
  2596.     move.w    #4,plane_ct(a6)
  2597.     move.w    s_nxln(a6),d2
  2598.     move.w    d2,s_nxpl(a6)
  2599.     add.w    d2,d2
  2600.     add.w    d2,d2
  2601.     move.w    d2,s_nxln(a6)
  2602.  
  2603.     movem.l    a0/a2-a4/a6/d0-d1/d7,-(sp)
  2604.     .dc.w    bitblt    
  2605.     movem.l    (sp)+,a0/a2-a4/a6/d0-d1/d7
  2606.     dbra    d7,buildc
  2607. *
  2608.     move.l    a3,derblkend        ;save new derive block end
  2609. *
  2610. *   Now build mask
  2611. *
  2612.     move.l    d_form(a6),a0
  2613.     move.w    d_nxln(a6),d0
  2614.     move.w    d0,d6
  2615.     lsr.w    #2,d0
  2616.     move.w    d0,d5
  2617.     lsr.w    #1,d5
  2618.     subq.w    #1,d5            ;d5 = # of words in line (-1)
  2619. *
  2620.     move.w    d0,d1
  2621.     add.w    d1,d1            ;d1 = offset to plane #2
  2622.     move.w    d1,d2
  2623.     add.w    d0,d2            ;d2 = offset to plane #3
  2624.     move.w    ymax_clust,d3
  2625.     sub.w    ymin_clust,d3        ;get form height
  2626.     mulu    d3,d6
  2627.     lea    (a0,d6.l),a1
  2628. *
  2629. *  Enter here if we need to rebuild mask
  2630. *
  2631. reclumsk:
  2632.     movem.l    a0/a1/d3,-(sp)
  2633.     bra    clust_8i
  2634. clust_81:
  2635.     move.w    d5,d6
  2636. clust_82:
  2637.     move.w    (a0,d2.w),d4
  2638.     or.w    (a0,d1.w),d4
  2639.     or.w    (a0,d0.w),d4
  2640.     or.w    (a0)+,d4
  2641.     move.w    d4,(a1)+
  2642.     dbra    d6,clust_82    
  2643.     adda.w    d2,a0
  2644. clust_8i:
  2645.     dbra    d3,clust_81
  2646. *
  2647.     movem.l    (sp)+,a0/a1/d3
  2648.     rts
  2649. *
  2650. ***********************************************
  2651. *
  2652. *
  2653. *
  2654. *   Build a rectangle fo' the people
  2655. *
  2656. dorect:
  2657.     movem.l    a0-a6/d0-d7,-(sp)
  2658. *
  2659.     moveq    #thincros,d0
  2660.     bsr    Graf_Mouse        ;put up a thin cross
  2661. *
  2662.     clr.w    butt            ;init 
  2663. *
  2664.     move.w    #1,rectwid
  2665.     move.w    #1,recthite
  2666. *    move.w    #15,rectcol
  2667. *
  2668.     lea    rectmsg,a0
  2669.     move.w    #WORLD,d0
  2670.     bsr    DaveInfo
  2671. *
  2672. rectlp:
  2673.     bsr    getmouse
  2674.     bsr    rectsel        ;check keyboard for color change
  2675.     
  2676.     and    #1,d3        ;any mouse button down yet
  2677.     beq    rectlp        ;br if none
  2678. *
  2679.     bclr.b    #1,BUT_STATE+1
  2680.     bne    rectx0
  2681. *
  2682.     bclr.b    #0,BUT_STATE+1
  2683.     beq    rectlp
  2684. *
  2685. *  Qualify left click (must be on world window)
  2686. *
  2687.     move.l    mouseptr,a0
  2688.     movem.w    (a0),d0-d1    ;save mouse position
  2689.     movem.w    d0-d1,-(sp)
  2690.     bsr    clipinit
  2691.     movem.w    (sp)+,d0-d1
  2692.     movem.w    d0-d1,(a0)    ;restore mouse
  2693.     cmp.w    Mclpxmn,d0
  2694.     blt    rectlp        ;mouse off the left side
  2695.     cmp.w    Mclpymn,d1
  2696.     blt    rectlp
  2697.     cmp.w    Mclpxmx,d0
  2698.     bge    rectlp
  2699.     cmp.w    Mclpymx,d1
  2700.     bge    rectlp
  2701. *
  2702. *  we're on the world window
  2703. *
  2704.     bsr    butninit
  2705. *
  2706.     move.w    maxderivd,d7
  2707.     addq.w    #1,d7
  2708. *
  2709. *    Build a brush block entry but don't allocate it yet
  2710. *
  2711. *    d7 = curbrush
  2712. *
  2713. rectloop:
  2714.     bsr    genarect    ;generate a filled rectangle entry
  2715.     movem.l    a1/d7,-(sp)
  2716. *
  2717.     move.w    #LIBRARY,d0
  2718.     move.l    a4,a0
  2719.     bsr    DaveInfo
  2720. *
  2721.     movem.w    mousex,d0-d1
  2722.     movem.w    rectwid,d2-d3
  2723.     move.w    d2,d4
  2724.     lsr.w    #1,d4
  2725.     sub.w    d4,d0
  2726.     move.w    d3,d4
  2727.     lsr.w    #1,d4
  2728.     sub.w    d4,d1
  2729.     moveq    #0,d4
  2730.     movem.w    d0-d4,bsh_x
  2731.     lea    allones,a3
  2732.     move.w    rectcol,d5
  2733.     lea    (a3,d5.w),a0    ;encode color in mask ptr
  2734. *
  2735.     bsr    bdisplay
  2736.     movem.l    (sp)+,a1/d7
  2737. *
  2738. momouse:
  2739.     bsr    getmouse
  2740.     bsr    rectsel        ;respond to color select
  2741. *
  2742.     andi.w    #1,d3        ;has button been released?
  2743.     beq    gotrect
  2744. *
  2745.     bclr.b    #1,BUT_STATE+1    ;was it a right button
  2746.     bne    rectx1        ;exit if so
  2747. *
  2748.     move.l    mouseptr,a2
  2749.     movem.w    (a2),d0-d1
  2750.     move.l    relcentx,(a2)
  2751. *
  2752.     move.w    d4,d3        ;d4 = 0 if no color change
  2753. *
  2754.     sub.w    relcentx,d0    ;get relative horz motion
  2755.     beq    rectlp3a
  2756.     addq.w    #1,d3
  2757.     add.w    rectwid,d0
  2758.     cmpi.w    #1,d0
  2759.     bge    rectlp2
  2760.     moveq    #1,d0
  2761. rectlp2:
  2762.     cmpi.w    #maxrectw,d0
  2763.     ble    rectlp3
  2764.     move.w    #maxrectw,d0
  2765. rectlp3:
  2766.     move.w    d0,rectwid
  2767. *
  2768. rectlp3a:
  2769.     sub.w    relcenty,d1    ;get relative vert motion
  2770.     beq    rectlp5a
  2771.     addq.w    #1,d3
  2772.     add.w    recthite,d1
  2773.     cmpi.w    #1,d1
  2774.     bge    rectlp4
  2775.     moveq    #1,d1
  2776. rectlp4:
  2777.     cmpi.w    #maxrecth,d1
  2778.     ble    rectlp5
  2779.     move.w    #maxrecth,d1
  2780. rectlp5:
  2781.     move.w    d1,recthite
  2782. rectlp5a:
  2783.     tst.w    d3
  2784.     beq    momouse        ;br if no move here
  2785. *
  2786.     bsr    pastund
  2787.     bra    rectloop
  2788. *
  2789. *   d0,d1 is screen hpos,vpos of cursor
  2790. *
  2791. rectx0:
  2792. *    move.l    mouseptr,a0
  2793. *    movem.w    (a0),d0-d1
  2794.     moveq    #1,d2
  2795.     moveq    #1,d3
  2796.     movem.w    d0-d3,bsh_x
  2797.     move.w    #-1,undhite    ;tell pastund not to do anything
  2798. *
  2799.     move.w    #MouseOff,d0
  2800.     bsr    Graf_Mouse
  2801. rectx1:
  2802.     move.w    #Arrow,d0
  2803.     bsr    Graf_Mouse
  2804. *
  2805.     move.w    #WORLD,d0
  2806.     lea    rectabrt,a0
  2807.     bsr    DaveInfo
  2808.     bra    lib_xita
  2809. *
  2810. *
  2811. gotrect:
  2812.     move.l    a1,dstrngend
  2813.     add.l    #18,derblkend
  2814.     addq.w    #1,maxderivd
  2815.     move.w    maxderivd,curbrush
  2816. *
  2817.     moveq    #Arrow,d0
  2818.     bsr    Graf_Mouse
  2819. *
  2820.     lea    allones,a3
  2821.     move.w    rectcol,d5
  2822.     lea    (a3,d5.w),a0
  2823.     bra    lib_m    
  2824. *
  2825. *
  2826. rectsel:
  2827.     tst.w    d4        ;check for any keys
  2828.     beq    rectselx
  2829.     cmpi.b    #"a",d4
  2830.     bcs    rectsel0
  2831.     subi.b    #$20,d4
  2832. rectsel0:
  2833.     subi.b    #"0",d4        ;check for a color key
  2834.     bcs    rectselx    ;br if not a 0-F
  2835.     cmpi.b    #10,d4        ;is it 0-9?
  2836.     bcs    rectsel1    ;br if so
  2837.     subi.b    #7,d4        
  2838.     cmpi.b    #10,d4
  2839.     bcs    rectselx
  2840.     cmpi.b    #16,d4
  2841.     bcc    rectselx
  2842. *
  2843. *  stuff the color
  2844. *
  2845. rectsel1:
  2846.     move.b    d4,rectcol+1
  2847.     moveq    #1,d4        ;indicate a color change
  2848.     rts
  2849. rectselx:
  2850.     moveq    #0,d4        ;no change
  2851.     rts
  2852. *
  2853. *
  2854. *  Generate the rect fill string
  2855. *
  2856. *    Entry:
  2857. *    d7 = curbrush
  2858. *    rectwid,recthite,rectcol are valid
  2859. *
  2860. *    Exit:
  2861. *    a1 -> end of fill ID string (+1) to save in dstrngend
  2862. *    a4 -> start of fill ID string (from dstrngend) 
  2863. genarect:
  2864.     lea    bshblock,a2
  2865.     move.w    d7,d0
  2866.     lsl.w    #4,d0
  2867.     movem.w    rectwid,d2-d4
  2868.     movem.w    d2-d3,(a2,d0.w)
  2869.     move.l    #allones,4(a2,d0.w)
  2870.     move.l    derblkend,a3
  2871.     move.l    a3,8(a2,d0.w)
  2872.     move.w    rectcol,12(a2,d0.w)    ;save color in offset
  2873.     clr.w    14(a2,d0.w)    ;s_nxln = 0
  2874.     move.l    dstrngend,a4    ;we'll build a derived string
  2875.     move.l    a4,(a3)+
  2876.     clr.w    (a3)+        ;object cnt = 0
  2877.     clr.w    (a3)+        ;bsh # (not relevent)
  2878.     move.w    rectcol,d0
  2879.     lsl.w    #8,d0
  2880.     ori.w    #$8000,d0
  2881.     move.w    d0,(a3)+    ;indicate effect + color
  2882.     clr.l    (a3)+
  2883.     move.l    a4,a1
  2884.     lea    rectstrg,a0
  2885. rectcp:
  2886.     move.b    (a0)+,(a1)+
  2887.     bne    rectcp
  2888. *
  2889.     subq.l    #1,a1
  2890.     move.w    d2,d0        ;put out width
  2891.     movem.w    d3-d4,-(sp)
  2892.     bsr    decitpad
  2893.     movem.w    (sp)+,d3-d4
  2894.     move.w    #"0",d0
  2895. rectcp0:
  2896.     cmp.b    -(a1),d0
  2897.     bhi    rectcp0
  2898.     addq.l    #1,a1
  2899.     move.b    #":",(a1)+
  2900.     move.b    #"h",(a1)+
  2901.     move.w    d3,d0        ;put out height
  2902.     move.w    d4,-(sp)
  2903.     bsr    decitpad
  2904.     move.w    (sp)+,d4
  2905.     move.w    #"0",d0
  2906. rectcp1:
  2907.     cmp.b    -(a1),d0
  2908.     bhi    rectcp1
  2909.     addq.l    #1,a1
  2910.     move.b    #":",(a1)+
  2911.     move.b    #"c",(a1)+
  2912.     move.w    d4,d0        ;put out color
  2913.     bsr    decitpad
  2914.     move.w    #"0",d0
  2915. rectcp2:
  2916.     cmp.b    -(a1),d0
  2917.     bhi    rectcp2
  2918.     addq.l    #1,a1
  2919.     clr.b    (a1)+
  2920.     rts
  2921. *
  2922. *
  2923. *
  2924. *
  2925. allones:
  2926.     .dc.w    $ffff
  2927. *
  2928. rectstrg:
  2929.     .dc.b    "FILL/w",0,0
  2930. *    .dc.b    "FILL/w000:h000:c000  ",0
  2931.