home *** CD-ROM | disk | FTP | other *** search
/ Media Share 9 / MEDIASHARE_09.ISO / progmisc / nfsrc21.zip / SETKEYS.ASM < prev    next >
Assembly Source File  |  1992-10-17  |  6KB  |  146 lines
  1. ; File......: SETKEYS.ASM
  2. ; Author....: Ted Means
  3. ; CIS ID....: 73067,3332
  4. ; Date......: $Date:   17 Oct 1992 16:27:42  $
  5. ; Revision..: $Revision:   1.1  $
  6. ; Log file..: $Logfile:   C:/nanfor/src/setkeys.asv  $
  7. ; 
  8. ; This is an original work by Ted Means and is placed in the
  9. ; public domain.
  10. ;
  11. ; Modification history:
  12. ; ---------------------
  13. ;
  14. ; $Log:   C:/nanfor/src/setkeys.asv  $
  15. ;  
  16. ;     Rev 1.1   17 Oct 1992 16:27:42   GLENN
  17. ;  Leo cleaned up documentation blocks.
  18. ;  
  19. ;     Rev 1.0   16 Oct 1992 00:02:42   GLENN
  20. ;  Initial revision.
  21. ; 
  22.  
  23. ;  $DOC$
  24. ;  $FUNCNAME$
  25. ;     FT_SETKEYS()
  26. ;  $CATEGORY$
  27. ;     Keyboard/Mouse
  28. ;  $ONELINER$
  29. ;     Get array of keys redirected via the SetKey() or SET KEY
  30. ;  $SYNTAX$
  31. ;     FT_SetKeys() --> aKeyValues
  32. ;  $ARGUMENTS$
  33. ;     None
  34. ;  $RETURNS$
  35. ;     An array from 0 to n elements, where n is the number of keys that
  36. ;     have been redirected via SetKey().  Each element in the array contains
  37. ;     the Inkey() value of a key that has been redirected.
  38. ;  $DESCRIPTION$
  39. ;     Nantucket encourages Clipper programmers to write modular code -- black
  40. ;     boxes that do not modify any global settings without resetting them
  41. ;     on exit.  In the past, this has proven cumbersome where SetKey() is
  42. ;     concerned, because the only way to see if a key had been redirected
  43. ;     was to call SetKey() and see if it returned NIL or a code block.  To
  44. ;     check every possible key value was unacceptably slow.
  45. ;
  46. ;     This function attempts to alleviate this problem by returning an array
  47. ;     that contains only those keys that have been redirected.  It is
  48. ;     substantially faster than the method mentioned above because it
  49. ;     directly accesses Clipper's internal table of redirected keys.
  50. ;
  51. ;     Some highly unorthodox programming techniques, not to mention rather
  52. ;     strange use of Clipper internals, was necessary to make this function
  53. ;     work.  If this makes you uncomfortable, then don't use this function,
  54. ;     you snivelling coward.
  55. ;
  56. ;  $EXAMPLES$
  57. ;     local aKeys := FT_SetKeys()    // Get the key table
  58. ;     local aBlox := {}              // Create a parallel array
  59. ;     local i
  60. ;
  61. ;     for i := 1 to len( aKeys )
  62. ;       // Nullify all redirections, while saving code block
  63. ;       // for later restoration
  64. ;
  65. ;       aadd( aBlox, setkey( aKeys[ i ], NIL )
  66. ;     next
  67. ;
  68. ;     // Do some stuff
  69. ;
  70. ;     for i := 1 to len( aKeys )
  71. ;       // Restore the redirections
  72. ;
  73. ;       setkey( aKeys[ i ], aBlox[ i ] )
  74. ;     next
  75. ;  $END$
  76. ;
  77.  
  78. IDEAL
  79.  
  80. Public   FT_SetKeys
  81.  
  82. VRefSize EQU       14
  83. Counter  EQU       Word Ptr BP - 2
  84.  
  85. Extrn    __RetNI:Far
  86. Extrn    __Keyboard:Far                      ; INTERNAL!
  87. Extrn    _ArrayNew:Far                       ; INTERNAL!
  88. Extrn    __Eval:Word                         ; INTERNAL!
  89. Extrn    __TOS:Word                          ; INTERNAL!
  90. Extrn    __cAtPut:Far                        ; INTERNAL!
  91. Extrn    __PutLN:Far                         ; INTERNAL!
  92.  
  93. Segment  _Nanfor   Word      Public    "CODE"
  94.          Assume    CS:_Nanfor
  95.  
  96. Proc     FT_SetKeys          Far
  97.  
  98.          Push      BP                        ; Preserve BP
  99.          Mov       BP,SP                     ; Set up stack reference
  100.          Sub       SP,2                      ; Allocate a local
  101.          Mov       [Counter],0               ; Initialize it to zero
  102.  
  103.          Mov       DX,Seg __Keyboard         ; Load segment of known symbol
  104.          Mov       BX,Offset __Keyboard      ; Load offset of known symbol
  105.          Add       BX,1Bh                    ; Calc offset into code segment
  106.          Mov       ES,DX                     ; Load segment register
  107.          Mov       BX,[Word Ptr ES:BX]       ; Lift address from machine code
  108.          Mov       CX,[Word Ptr BX]          ; Get size
  109.          LES       BX,[DWord Ptr BX + 2]     ; Get address of table
  110.          JCXZ      @@Save                    ; If table empty, skip next part
  111.  
  112. @@Top:   Mov       AX,[Word Ptr ES:BX]       ; Load key value
  113.          Or        AX,[Word Ptr ES:BX + 2]   ; See if it's null
  114.          JZ        @@Bottom                  ; If so, skip it
  115.          Inc       [Counter]                 ; Increment counter
  116.          Push      [Word Ptr ES:BX + 2]      ; Put key value on stack
  117.          Push      [Word Ptr ES:BX]
  118. @@Bottom:Add       BX,4                      ; Adjust offset
  119.          Loop      @@Top                     ; Check next value
  120.  
  121. @@Save:  Push      [Counter]                 ; Put key count on stack
  122.          Call      _ArrayNew                 ; Create Clipper array
  123.          
  124. @@Store: Cmp       [Counter],0               ; Reached end yet?
  125.          JE        @@Done                    ; If so, quit
  126.          Call      __PutLN                   ; Create entry on eval stack
  127.          Add       SP,4                      ; Remove entry from CPU stack
  128.          Push      [__TOS]                   ; Source VREF pointer on stack
  129.          Push      [Counter]                 ; Element # on stack
  130.          Push      [__Eval]                  ; Target VREF pointer on stack
  131.          Call      __cAtPut                  ; Store array element
  132.          Add       SP,6                      ; Realign stack
  133.          Sub       [__TOS],VRefSize          ; Remove entry from eval stack
  134.          Dec       [Counter]                 ; Decrement counter
  135.          Jmp       Short @@Store             ; Do next element
  136.  
  137. @@Done:  Mov       SP,BP                     ; Realign stack
  138.          Pop       BP
  139.          Ret
  140.  
  141. Endp     FT_SetKeys
  142. Ends     _Nanfor
  143. End
  144.  
  145.  
  146.